configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [230],
  24         [http://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=systemd
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96
  97 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  98 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  99
 100 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap], [$PATH:/usr/sbin:/sbin])
 101
 102 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 103
 104 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 105
 106 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 107
 108 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 109
 110 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 111 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 112
 113 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 114
 115 M4_DEFINES=
 116
 117 AC_CHECK_TOOL(OBJCOPY, objcopy)
 118 AC_CHECK_TOOL(STRINGS, strings)
 119 AC_CHECK_TOOL(GPERF, gperf)
 120 if test -z "$GPERF" ; then
 121         AC_MSG_ERROR([*** gperf not found])
 122 fi
 123
 124 # ------------------------------------------------------------------------------
 125 address_sanitizer_cflags=
 126 address_sanitizer_cppflags=
 127 address_sanitizer_ldflags=
 128 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 129 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 130             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 131             AS_IF([test -z "$with_as_cflags"],
 132                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 133             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 134             address_sanitizer_cppflags="-DVALGRIND=1"
 135             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 136       ])
 137
 138 undefined_sanitizer_cflags=
 139 undefined_sanitizer_cppflags=
 140 undefined_sanitizer_ldflags=
 141 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 142 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 143             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 144             AS_IF([test -z "$with_us_cflags"],
 145                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 146             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 147             undefined_sanitizer_cppflags="-DVALGRIND=1"
 148             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 149       ])
 150
 151 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 152 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 153 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 154
 155 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 156         -pipe \
 157         -Wall \
 158         -Wextra \
 159         -Wundef \
 160         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 161         -Wlogical-op \
 162         -Wmissing-include-dirs \
 163         -Wold-style-definition \
 164         -Wpointer-arith \
 165         -Winit-self \
 166         -Wdeclaration-after-statement \
 167         -Wfloat-equal \
 168         -Wsuggest-attribute=noreturn \
 169         -Werror=missing-prototypes \
 170         -Werror=implicit-function-declaration \
 171         -Werror=missing-declarations \
 172         -Werror=return-type \
 173         -Wstrict-prototypes \
 174         -Wredundant-decls \
 175         -Wmissing-noreturn \
 176         -Wshadow \
 177         -Wendif-labels \
 178         -Wstrict-aliasing=2 \
 179         -Wwrite-strings \
 180         -Wno-unused-parameter \
 181         -Wno-missing-field-initializers \
 182         -Wno-unused-result \
 183         -Wno-format-signedness \
 184         -Werror=overflow \
 185         -Wdate-time \
 186         -Wnested-externs \
 187         -ffast-math \
 188         -fno-common \
 189         -fdiagnostics-show-option \
 190         -fno-strict-aliasing \
 191         -fvisibility=hidden \
 192         -fstack-protector \
 193         -fstack-protector-strong \
 194         -fPIE \
 195         --param=ssp-buffer-size=4])
 196
 197 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
 198 #include <time.h>
 199 #include <inttypes.h>
 200 typedef uint64_t usec_t;
 201 usec_t now(clockid_t clock);
 202 int main(void) {
 203         struct timespec now;
 204         return 0;
 205 }
 206 ])
 207
 208 AS_CASE([$CC], [*clang*],
 209         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 210                -Wno-typedef-redefinition \
 211                -Wno-gnu-variable-sized-type-not-at-end \
 212         ])])
 213
 214 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 215         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 216                -flto])],
 217         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 218 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 219
 220 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 221         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 222                -Wp,-D_FORTIFY_SOURCE=2])],
 223         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 224 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 225
 226 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 227         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 228                -Wl,--gc-sections])],
 229         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 230 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 231
 232 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 233         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 234                -ffunction-sections -fdata-sections])],
 235         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 236 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 237
 238 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 239         -Wl,--as-needed \
 240         -Wl,--no-undefined \
 241         -Wl,-z,relro \
 242         -Wl,-z,now \
 243         -pie \
 244         -Wl,-fuse-ld=gold])
 245 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 246
 247 AC_CHECK_SIZEOF(pid_t)
 248 AC_CHECK_SIZEOF(uid_t)
 249 AC_CHECK_SIZEOF(gid_t)
 250 AC_CHECK_SIZEOF(time_t)
 251 AC_CHECK_SIZEOF(dev_t)
 252 AC_CHECK_SIZEOF(ino_t)
 253 AC_CHECK_SIZEOF(rlim_t,,[
 254        #include <sys/time.h>
 255        #include <sys/resource.h>
 256 ])
 257
 258 # ------------------------------------------------------------------------------
 259 # we use python to build the man page index
 260 have_python=no
 261 AC_ARG_WITH([python],
 262         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 263
 264 have_lxml=no
 265 AS_IF([test "x$with_python" != "xno"], [
 266         AM_PATH_PYTHON(,, [:])
 267         AS_IF([test "x$PYTHON" != "x:"], [
 268                 AC_MSG_CHECKING([for python lxml module])
 269                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 270                 AC_MSG_RESULT([$have_lxml])
 271                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 272                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 273         ])
 274 ])
 275 AS_IF([test "$have_python" != "yes"], [
 276       AS_IF([test "$with_python" = "yes"],
 277             [AC_MSG_ERROR([*** python support requested but python support not found])])
 278       AS_IF([test "$with_python" != "no"],
 279             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 280 ])
 281 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 282
 283 # ------------------------------------------------------------------------------
 284
 285 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 286 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 287 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 288
 289 # unconditionally pull-in librt with old glibc versions
 290 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 291
 292 save_LIBS="$LIBS"
 293 LIBS=
 294 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 295 CAP_LIBS="$LIBS"
 296 LIBS="$save_LIBS"
 297 AC_SUBST(CAP_LIBS)
 298
 299 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 300 AC_CHECK_DECLS([
 301         memfd_create,
 302         gettid,
 303         pivot_root,
 304         name_to_handle_at,
 305         setns,
 306         getrandom,
 307         renameat2,
 308         kcmp,
 309         keyctl,
 310         LO_FLAGS_PARTSCAN,
 311         copy_file_range],
 312         [], [], [[
 313 #include <sys/types.h>
 314 #include <unistd.h>
 315 #include <sys/mount.h>
 316 #include <fcntl.h>
 317 #include <sched.h>
 318 #include <linux/loop.h>
 319 #include <linux/random.h>
 320 ]])
 321
 322 AC_CHECK_TYPES([char16_t, char32_t, key_serial_t],
 323                [], [], [[
 324 #include <uchar.h>
 325 ]])
 326
 327 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 328                 IN6_ADDR_GEN_MODE_STABLE_PRIVACY,
 329                 IFLA_VRF_TABLE,
 330                 IFLA_MACVLAN_FLAGS,
 331                 IFLA_IPVLAN_MODE,
 332                 IFLA_VTI_REMOTE,
 333                 IFLA_PHYS_PORT_ID,
 334                 IFLA_BOND_AD_INFO,
 335                 IFLA_VLAN_PROTOCOL,
 336                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 337                 IFLA_IPTUN_ENCAP_DPORT,
 338                 IFLA_GRE_ENCAP_DPORT,
 339                 IFLA_BRIDGE_VLAN_INFO,
 340                 IFLA_BRPORT_PROXYARP,
 341                 IFLA_BRPORT_LEARNING_SYNC,
 342                 IFLA_BR_VLAN_DEFAULT_PVID,
 343                 NDA_IFINDEX,
 344                 IFA_FLAGS],
 345 [], [], [[
 346 #include <inttypes.h>
 347 #include <netinet/in.h>
 348 #include <netinet/ether.h>
 349 #include <linux/rtnetlink.h>
 350 #include <net/if.h>
 351 #include <linux/ip.h>
 352 #include <linux/if_tunnel.h>
 353 #include <linux/if_link.h>
 354 #include <linux/if_bridge.h>
 355 #include <linux/if_addr.h>
 356 #include <linux/neighbour.h>
 357 ]])
 358
 359 # This makes sure pkg.m4 is available.
 360 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 361
 362 # ------------------------------------------------------------------------------
 363 have_dbus=no
 364 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 365 AS_IF([test "x$enable_dbus" != "xno"], [
 366         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 367                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 368                 [have_dbus=no])
 369         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 370                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 371 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 372
 373 # ------------------------------------------------------------------------------
 374 have_utmp=yes
 375 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 376         AS_CASE("x${enableval}",
 377                 [xyes], [have_utmp=yes],
 378                 [xno],  [have_utmp=no],
 379                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 380 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 381 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 382
 383 # ------------------------------------------------------------------------------
 384 have_coverage=no
 385 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 386 if test "x$enable_coverage" = "xyes" ; then
 387         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 388         if test "x$lcov_found" = xno ; then
 389                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 390         else
 391                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 392                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 393                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 394                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 395                 else
 396                         have_coverage=yes
 397                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 398                         -fprofile-arcs \
 399                         -ftest-coverage])
 400                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 401                 fi
 402         fi
 403 fi
 404 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 405
 406 # ------------------------------------------------------------------------------
 407 have_kmod=no
 408 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 409 if test "x$enable_kmod" != "xno"; then
 410         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 411         if test "x$have_kmod" = "xyes"; then
 412                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 413                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 414                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 415         fi
 416         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 417                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 418         fi
 419 fi
 420 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 421
 422 # ------------------------------------------------------------------------------
 423 have_xkbcommon=no
 424 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 425 if test "x$enable_xkbcommon" != "xno"; then
 426         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 427                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 428         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 429                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 430         fi
 431 fi
 432 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 433
 434 # ------------------------------------------------------------------------------
 435 have_blkid=no
 436 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 437 if test "x$enable_blkid" != "xno"; then
 438         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 439                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 440         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 441                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 442         fi
 443 fi
 444 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 445
 446 # ------------------------------------------------------------------------------
 447 have_libmount=no
 448 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.27 ],
 449         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 450 if test "x$have_libmount" = xno; then
 451         AC_MSG_ERROR([*** libmount support required but libraries not found])
 452 fi
 453 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 454
 455 # ------------------------------------------------------------------------------
 456 have_seccomp=no
 457 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 458 if test "x$enable_seccomp" != "xno"; then
 459         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 460                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 461                 have_seccomp=yes
 462                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 463                [have_seccomp=no])
 464         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 465                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 466         fi
 467 fi
 468 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 469
 470 # ------------------------------------------------------------------------------
 471 have_ima=yes
 472 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 473                 [case "${enableval}" in
 474                         yes) have_ima=yes ;;
 475                         no) have_ima=no ;;
 476                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 477                 esac],
 478                 [have_ima=yes])
 479
 480 if test "x${have_ima}" != xno ; then
 481         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 482 fi
 483
 484 # ------------------------------------------------------------------------------
 485 have_selinux=no
 486 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 487 if test "x$enable_selinux" != "xno"; then
 488         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 489                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 490                  have_selinux=yes
 491                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 492                 [have_selinux=no])
 493         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 494                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 495         fi
 496 fi
 497 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 498
 499 have_apparmor=no
 500 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 501 if test "x$enable_apparmor" != "xno"; then
 502         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 503                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 504                  have_apparmor=yes
 505                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 506                 [have_apparmor=no])
 507         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 508                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 509         fi
 510 fi
 511 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 512
 513 have_adm_group=no
 514 AC_ARG_ENABLE(adm-group, AS_HELP_STRING([--disable-adm-group], [disable adm group]))
 515 AS_IF([test "x$enable_adm_group" != "xno"], [
 516         AC_DEFINE(ENABLE_ADM_GROUP, 1, [Define if the ACL for adm group should be enabled])
 517         have_adm_group=yes
 518         M4_DEFINES="$M4_DEFINES -DENABLE_ADM_GROUP"
 519 ])
 520
 521 have_wheel_group=no
 522 AC_ARG_ENABLE(wheel-group, AS_HELP_STRING([--disable-wheel-group], [disable wheel group]))
 523 AS_IF([test "x$enable_wheel_group" != "xno"], [
 524         AC_DEFINE(ENABLE_WHEEL_GROUP, 1, [Define if the ACL for wheel group should be enabled])
 525         have_wheel_group=yes
 526         M4_DEFINES="$M4_DEFINES -DENABLE_WHEEL_GROUP"
 527 ])
 528
 529
 530 AC_ARG_WITH(debug-shell,
 531         AS_HELP_STRING([--with-debug-shell=PATH],
 532                 [Path to debug shell binary]),
 533         [SUSHELL="$withval"],[
 534         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 535
 536 AC_SUBST(SUSHELL)
 537
 538 AC_ARG_WITH([debug-tty],
 539         AS_HELP_STRING([--with-debug-tty=PATH],
 540                 [Specify the tty device for debug shell]),
 541         [DEBUGTTY="$withval"],
 542         [DEBUGTTY=/dev/tty9])
 543
 544 AC_SUBST(DEBUGTTY)
 545
 546 AC_ARG_WITH([certificate-root],
 547         AS_HELP_STRING([--with-certificate-root=PATH],
 548                 [Specify the prefix for TLS certificates [/etc/ssl]]),
 549         [CERTIFICATEROOT="$withval"],
 550         [CERTIFICATEROOT="/etc/ssl"])
 551
 552 AC_SUBST(CERTIFICATEROOT)
 553
 554 # ------------------------------------------------------------------------------
 555 have_xz=no
 556 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 557 AS_IF([test "x$enable_xz" != "xno"], [
 558         PKG_CHECK_MODULES(XZ, [ liblzma ],
 559                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available])
 560                  have_xz=yes],
 561                  have_xz=no)
 562         AS_IF([test "x$have_xz" = xno -a "x$enable_xz" = xyes],
 563               [AC_MSG_ERROR([*** XZ support requested but libraries not found])])
 564 ])
 565 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 566
 567 # ------------------------------------------------------------------------------
 568 have_zlib=no
 569 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [Disable optional ZLIB support]))
 570 AS_IF([test "x$enable_zlib" != "xno"], [
 571         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 572                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available])
 573                  have_zlib=yes],
 574                  have_zlib=no)
 575         AS_IF([test "x$have_zlib" = xno -a "x$enable_zlib" = xyes],
 576               [AC_MSG_ERROR([*** ZLIB support requested but libraries not found])])
 577 ])
 578 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 579
 580 # ------------------------------------------------------------------------------
 581 have_bzip2=no
 582 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--enable-bzip2], [Enable optional BZIP2 support]))
 583 AS_IF([test "x$enable_bzip2" != "xno"], [
 584         AC_CHECK_HEADERS(bzlib.h,
 585                 [AC_DEFINE(HAVE_BZIP2, 1, [Define if BZIP2 is available])
 586                  have_bzip2=yes],
 587                 [AS_IF([test "x$enable_bzip2" = xyes],
 588                        [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])]
 589         )
 590 ])
 591 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 592
 593 # ------------------------------------------------------------------------------
 594 have_lz4=no
 595 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--disable-lz4], [Disable optional LZ4 support]))
 596 AS_IF([test "x$enable_lz4" != "xno"], [
 597         PKG_CHECK_MODULES(LZ4, [ liblz4 >= 125 ],
 598                [AC_DEFINE(HAVE_LZ4, 1, [Define in LZ4 is available])
 599                 have_lz4=yes],
 600                 have_lz4=no)
 601         AS_IF([test "x$have_lz4" = xno -a "x$enable_lz4" = xyes],
 602               [AC_MSG_ERROR([*** LZ4 support requested but libraries not found])])
 603 ])
 604 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 605
 606 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 607
 608 # ------------------------------------------------------------------------------
 609 AC_ARG_ENABLE([pam],
 610         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 611                 [case "${enableval}" in
 612                         yes) have_pam=yes ;;
 613                         no) have_pam=no ;;
 614                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 615                 esac],
 616                 [have_pam=auto])
 617
 618 if test "x${have_pam}" != xno ; then
 619         AC_CHECK_HEADERS(
 620                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 621                 [have_pam=yes],
 622                 [if test "x$have_pam" = xyes ; then
 623                         AC_MSG_ERROR([*** PAM headers not found.])
 624                 fi])
 625
 626         AC_CHECK_LIB(
 627                 [pam],
 628                 [pam_syslog],
 629                 [have_pam=yes],
 630                 [if test "x$have_pam" = xyes ; then
 631                         AC_MSG_ERROR([*** libpam not found.])
 632                 fi])
 633
 634         if test "x$have_pam" = xyes ; then
 635                 PAM_LIBS="-lpam -lpam_misc"
 636                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 637                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 638         else
 639                 have_pam=no
 640         fi
 641 else
 642         PAM_LIBS=
 643 fi
 644 AC_SUBST(PAM_LIBS)
 645 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 646
 647 # ------------------------------------------------------------------------------
 648 AC_ARG_ENABLE([acl],
 649         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 650                 [case "${enableval}" in
 651                         yes) have_acl=yes ;;
 652                         no) have_acl=no ;;
 653                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 654                 esac],
 655                 [have_acl=auto])
 656
 657 if test "x${have_acl}" != xno ; then
 658         AC_CHECK_HEADERS(
 659                 [sys/acl.h acl/libacl.h],
 660                 [have_acl=yes],
 661                 [if test "x$have_acl" = xyes ; then
 662                         AC_MSG_ERROR([*** ACL headers not found.])
 663                 fi])
 664
 665         AC_CHECK_LIB(
 666                 [acl],
 667                 [acl_get_file],
 668                 [have_acl=yes],
 669                 [if test "x$have_acl" = xyes ; then
 670                         AC_MSG_ERROR([*** libacl not found.])
 671                 fi])
 672
 673         if test "x$have_acl" = xyes ; then
 674                 ACL_LIBS="-lacl"
 675                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 676                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 677         else
 678                 have_acl=no
 679         fi
 680 else
 681         ACL_LIBS=
 682 fi
 683 AC_SUBST(ACL_LIBS)
 684 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 685
 686 # ------------------------------------------------------------------------------
 687 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 688                 [case "${enableval}" in
 689                         yes) have_smack=yes ;;
 690                         no) have_smack=no ;;
 691                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 692                 esac],
 693                 [have_smack=auto])
 694
 695 if test "x${have_smack}" != xno; then
 696         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 697         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 698         have_smack=yes
 699 fi
 700
 701 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 702
 703 have_smack_run_label=no
 704 AC_ARG_WITH(smack-run-label,
 705 AS_HELP_STRING([--with-smack-run-label=STRING],
 706         [run systemd --system itself with a specific SMACK label]),
 707         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
 708         [])
 709
 710 if test "x${have_smack_run_label}" = xyes; then
 711         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
 712 fi
 713
 714 AC_ARG_WITH(smack-default-process-label,
 715 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 716         [default SMACK label for executed processes]),
 717         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 718         [])
 719
 720 # ------------------------------------------------------------------------------
 721 AC_ARG_ENABLE([gcrypt],
 722         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 723                 [case "${enableval}" in
 724                         yes) have_gcrypt=yes ;;
 725                         no) have_gcrypt=no ;;
 726                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 727                 esac],
 728                 [have_gcrypt=auto])
 729
 730 if test "x${have_gcrypt}" != xno ; then
 731         m4_define([AM_PATH_LIBGCRYPT_FAIL],
 732                 [{ test "x$have_gcrypt" != xyes || AC_MSG_ERROR([*** GCRYPT/GPG-ERROR headers not found.]); }]
 733         )
 734         m4_ifdef([AM_PATH_LIBGCRYPT], [AM_PATH_LIBGCRYPT(
 735                         [1.4.5],
 736                         [have_gcrypt=yes],
 737                         dnl  If we have the gcrypt m4 macros, but don't have
 738                         dnl  gcrypt, throw an error if gcrypt is explicitly
 739                         dnl  requested.
 740                         [AM_PATH_LIBGCRYPT_FAIL]
 741                 )],
 742                 dnl  If we don't have the gcrypt m4 macros, but build with
 743                 dnl  gcrypt explicitly requested, throw an error.
 744                 [AM_PATH_LIBGCRYPT_FAIL]
 745         )
 746
 747         have_gpg_error=no
 748         m4_ifdef([AM_PATH_GPG_ERROR], [AM_PATH_GPG_ERROR(
 749                         [1.12],
 750                         [have_gpg_error=yes],
 751                         [AM_PATH_LIBGCRYPT_FAIL]
 752                 )],
 753                 [AM_PATH_LIBGCRYPT_FAIL]
 754         )
 755
 756         if test "x$have_gcrypt" = xyes -a "x$have_gpg_error" = xyes ; then
 757                 GCRYPT_LIBS="$LIBGCRYPT_LIBS $GPG_ERROR_LIBS"
 758                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS $GPG_ERROR_CFLAGS"
 759                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 760         else
 761                 have_gcrypt=no
 762                 have_gpg_error=no
 763         fi
 764 else
 765         GCRYPT_LIBS=
 766         GCRYPT_CFLAGS=
 767 fi
 768 AC_SUBST(GCRYPT_LIBS)
 769 AC_SUBST(GCRYPT_CFLAGS)
 770 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 771
 772 # ------------------------------------------------------------------------------
 773 AC_ARG_ENABLE([audit],
 774         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 775                 [case "${enableval}" in
 776                         yes) have_audit=yes ;;
 777                         no) have_audit=no ;;
 778                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 779                 esac],
 780                 [have_audit=auto])
 781
 782 if test "x${have_audit}" != xno ; then
 783         AC_CHECK_HEADERS(
 784                 [libaudit.h],
 785                 [have_audit=yes],
 786                 [if test "x$have_audit" = xyes ; then
 787                         AC_MSG_ERROR([*** AUDIT headers not found.])
 788                 fi])
 789
 790         AC_CHECK_LIB(
 791                 [audit],
 792                 [audit_open],
 793                 [have_audit=yes],
 794                 [if test "x$have_audit" = xyes ; then
 795                         AC_MSG_ERROR([*** libaudit not found.])
 796                 fi])
 797
 798         if test "x$have_audit" = xyes ; then
 799                 AUDIT_LIBS="-laudit"
 800                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 801         else
 802                 have_audit=no
 803         fi
 804 else
 805         AUDIT_LIBS=
 806 fi
 807 AC_SUBST(AUDIT_LIBS)
 808 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 809
 810 # ------------------------------------------------------------------------------
 811 AC_ARG_ENABLE([elfutils],
 812         AS_HELP_STRING([--disable-elfutils],[Disable optional ELFUTILS support]),
 813                 [case "${enableval}" in
 814                         yes) have_elfutils=yes ;;
 815                         no) have_elfutils=no ;;
 816                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 817                 esac],
 818                 [have_elfutils=auto])
 819
 820 if test "x${have_elfutils}" != xno ; then
 821         AC_CHECK_HEADERS(
 822                 [elfutils/libdwfl.h],
 823                 [],
 824                 [if test "x$have_elfutils" = xyes ; then
 825                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 826                 fi])
 827
 828         AC_CHECK_LIB(
 829                 [dw],
 830                 [dwfl_core_file_attach],
 831                 [have_elfutils=yes],
 832                 [if test "x$have_elfutils" = xyes ; then
 833                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 834                 fi])
 835
 836         if test "x$have_elfutils" = xyes ; then
 837                 ELFUTILS_LIBS="-lelf -ldw"
 838                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 839         else
 840                 have_elfutils=no
 841         fi
 842 else
 843         ELFUTILS_LIBS=
 844 fi
 845 AC_SUBST(ELFUTILS_LIBS)
 846 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 847
 848 # ------------------------------------------------------------------------------
 849 have_libcryptsetup=no
 850 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 851 if test "x$enable_libcryptsetup" != "xno"; then
 852         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 853                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 854         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 855                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 856         fi
 857 fi
 858 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 859
 860 # ------------------------------------------------------------------------------
 861 have_qrencode=no
 862 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 863 if test "x$enable_qrencode" != "xno"; then
 864         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 865                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 866         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 867                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 868         fi
 869 fi
 870 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 871
 872 # ------------------------------------------------------------------------------
 873 have_gnutls=no
 874 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 875 if test "x$enable_gnutls" != "xno"; then
 876         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 877                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 878         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 879                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 880         fi
 881 fi
 882 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 883
 884 # ------------------------------------------------------------------------------
 885 have_microhttpd=no
 886 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 887 if test "x$enable_microhttpd" != "xno"; then
 888         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 889                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available])
 890                  have_microhttpd=yes
 891                  M4_DEFINES="$M4_DEFINES -DHAVE_MICROHTTPD"],
 892                 [have_microhttpd=no])
 893         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 894                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 895         fi
 896 fi
 897 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 898
 899 # ------------------------------------------------------------------------------
 900 have_libcurl=no
 901 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 902 if test "x$enable_libcurl" != "xno"; then
 903         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.32.0],
 904                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available])
 905                  have_libcurl=yes
 906                  M4_DEFINES="$M4_DEFINES -DHAVE_LIBCURL"],
 907                 [have_libcurl=no])
 908         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 909                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 910         fi
 911 fi
 912 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 913
 914 # ------------------------------------------------------------------------------
 915 AM_CONDITIONAL(HAVE_REMOTE, [test "$have_microhttpd" = "yes" -o "$have_libcurl" = "yes"])
 916
 917 # ------------------------------------------------------------------------------
 918 have_libidn=no
 919 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [Disable optional LIBIDN support]))
 920 if test "x$enable_libidn" != "xno"; then
 921         PKG_CHECK_MODULES(LIBIDN, [libidn],
 922                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 923                 have_libidn=yes
 924                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 925                [have_libidn=no])
 926         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 927                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 928         fi
 929 fi
 930 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 931
 932 # ------------------------------------------------------------------------------
 933 have_libiptc=no
 934 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [Disable optional LIBIPTC support]))
 935 if test "x$enable_libiptc" != "xno"; then
 936         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
 937                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
 938                 have_libiptc=yes
 939                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
 940                [have_libiptc=no])
 941         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
 942                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
 943         fi
 944 fi
 945 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
 946
 947 # ------------------------------------------------------------------------------
 948 have_binfmt=no
 949 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 950 if test "x$enable_binfmt" != "xno"; then
 951         have_binfmt=yes
 952 fi
 953 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 954
 955 # ------------------------------------------------------------------------------
 956 have_vconsole=no
 957 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 958 if test "x$enable_vconsole" != "xno"; then
 959         have_vconsole=yes
 960 fi
 961 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 962
 963 # ------------------------------------------------------------------------------
 964 have_quotacheck=no
 965 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 966 if test "x$enable_quotacheck" != "xno"; then
 967         have_quotacheck=yes
 968 fi
 969 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 970
 971 # ------------------------------------------------------------------------------
 972 have_tmpfiles=no
 973 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 974 if test "x$enable_tmpfiles" != "xno"; then
 975         have_tmpfiles=yes
 976 fi
 977 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 978
 979 # ------------------------------------------------------------------------------
 980 have_sysusers=no
 981 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
 982 if test "x$enable_sysusers" != "xno"; then
 983         have_sysusers=yes
 984 fi
 985 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
 986
 987 # ------------------------------------------------------------------------------
 988 have_firstboot=no
 989 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
 990 if test "x$enable_firstboot" != "xno"; then
 991         have_firstboot=yes
 992 fi
 993 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
 994
 995 # ------------------------------------------------------------------------------
 996 have_randomseed=no
 997 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 998 if test "x$enable_randomseed" != "xno"; then
 999         have_randomseed=yes
1000 fi
1001 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
1002
1003 # ------------------------------------------------------------------------------
1004 have_backlight=no
1005 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
1006 if test "x$enable_backlight" != "xno"; then
1007         have_backlight=yes
1008 fi
1009 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
1010
1011 # ------------------------------------------------------------------------------
1012 have_rfkill=no
1013 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
1014 if test "x$enable_rfkill" != "xno"; then
1015         have_rfkill=yes
1016 fi
1017 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
1018
1019 # ------------------------------------------------------------------------------
1020 have_logind=no
1021 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
1022 if test "x$enable_logind" != "xno"; then
1023         have_logind=yes
1024 fi
1025 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
1026 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
1027
1028 AC_ARG_WITH([kill-user-processes],
1029         [AS_HELP_STRING([--without-kill-user-processes], [Set logind's KillUserProcesses=no by default])])
1030 AS_IF([test "$with_kill_user_processes" != "no"],
1031        [kill_user_processes=true
1032         KILL_USER_PROCESSES=yes],
1033        [kill_user_processes=false
1034         KILL_USER_PROCESSES=no])
1035 AC_DEFINE_UNQUOTED(KILL_USER_PROCESSES, [$kill_user_processes], [Default KillUserProcesses setting])
1036 AC_SUBST(KILL_USER_PROCESSES)
1037
1038 # ------------------------------------------------------------------------------
1039 have_machined=no
1040 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
1041 if test "x$enable_machined" != "xno"; then
1042         have_machined=yes
1043         AC_DEFINE(HAVE_MACHINED, [1], [systemd-machined is enabled])
1044 fi
1045 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
1046
1047 # ------------------------------------------------------------------------------
1048 have_importd=no
1049 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
1050 if test "x$enable_importd" != "xno"; then
1051         have_importd=yes
1052 fi
1053 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
1054 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
1055
1056 # ------------------------------------------------------------------------------
1057 have_hostnamed=no
1058 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1059 if test "x$enable_hostnamed" != "xno"; then
1060         have_hostnamed=yes
1061 fi
1062 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1063
1064 # ------------------------------------------------------------------------------
1065 have_timedated=no
1066 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1067 if test "x$enable_timedated" != "xno"; then
1068         have_timedated=yes
1069 fi
1070 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1071
1072 # ------------------------------------------------------------------------------
1073 have_timesyncd=no
1074 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1075 if test "x$enable_timesyncd" != "xno"; then
1076         have_timesyncd=yes
1077         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1078 fi
1079 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1080
1081 AC_ARG_WITH(ntp-servers,
1082         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1083                 [Space-separated list of default NTP servers]),
1084         [NTP_SERVERS="$withval"],
1085         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"
1086         AC_MSG_WARN([*** Using Google NTP servers.
1087                         Do not ship OSes or devices with these default settings.
1088                         See DISTRO_PORTING for details!])])
1089
1090 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1091 AC_SUBST(NTP_SERVERS)
1092
1093 AC_ARG_WITH(time-epoch,
1094         AS_HELP_STRING([--with-time-epoch=SECONDS],
1095                 [Time epoch for time clients]),
1096         [TIME_EPOCH="$withval"],
1097         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1098
1099 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1100
1101 # ------------------------------------------------------------------------------
1102 AC_ARG_WITH(system-uid-max,
1103         AS_HELP_STRING([--with-system-uid-max=UID]
1104                 [Maximum UID for system users]),
1105         [SYSTEM_UID_MAX="$withval"],
1106         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1107
1108 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1109 AC_SUBST(SYSTEM_UID_MAX)
1110
1111 # ------------------------------------------------------------------------------
1112 AC_ARG_WITH(system-gid-max,
1113         AS_HELP_STRING([--with-system-gid-max=GID]
1114                 [Maximum GID for system groups]),
1115         [SYSTEM_GID_MAX="$withval"],
1116         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1117
1118 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1119 AC_SUBST(SYSTEM_GID_MAX)
1120
1121 # ------------------------------------------------------------------------------
1122 have_localed=no
1123 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1124 if test "x$enable_localed" != "xno"; then
1125         have_localed=yes
1126 fi
1127 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1128
1129 # ------------------------------------------------------------------------------
1130 have_coredump=no
1131 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1132 if test "x$enable_coredump" != "xno"; then
1133         have_coredump=yes
1134         M4_DEFINES="$M4_DEFINES -DENABLE_COREDUMP"
1135 fi
1136 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1137
1138 # ------------------------------------------------------------------------------
1139 have_polkit=no
1140 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1141 if test "x$enable_polkit" != "xno"; then
1142         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1143         have_polkit=yes
1144 fi
1145 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1146
1147 # ------------------------------------------------------------------------------
1148 have_resolved=no
1149 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1150 AS_IF([test "x$enable_resolved" != "xno"], [
1151         AC_CHECK_LIB([dl], [dlsym], [true], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
1152
1153         have_resolved=yes
1154         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1155         AC_DEFINE(HAVE_RESOLVED, [1], [systemd-resolved is enabled])
1156 ])
1157 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1158
1159 AC_ARG_WITH(dns-servers,
1160         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1161                 [Space-separated list of default DNS servers]),
1162         [DNS_SERVERS="$withval"],
1163         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1164
1165 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1166 AC_SUBST(DNS_SERVERS)
1167
1168 AC_ARG_WITH(default-dnssec,
1169         AS_HELP_STRING([--with-default-dnssec=MODE],
1170                [Default DNSSEC mode, defaults to "allow-downgrade"]),
1171         [DEFAULT_DNSSEC_MODE="$withval"],
1172         [DEFAULT_DNSSEC_MODE="allow-downgrade"])
1173
1174 AS_CASE("x${DEFAULT_DNSSEC_MODE}",
1175         [xno], [mode=DNSSEC_NO],
1176         [xyes], [mode=DNSSEC_YES],
1177         [xallow-downgrade], [mode=DNSSEC_ALLOW_DOWNGRADE],
1178         AC_MSG_ERROR(Bad DNSSEC mode ${DEFAULT_DNSSEC_MODE}))
1179 AC_DEFINE_UNQUOTED(DEFAULT_DNSSEC_MODE, [$mode], [Default DNSSEC mode])
1180 AC_SUBST(DEFAULT_DNSSEC_MODE)
1181
1182 # ------------------------------------------------------------------------------
1183 have_networkd=no
1184 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1185 AS_IF([test "x$enable_networkd" != "xno"], [
1186         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1187         have_networkd=yes
1188         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1189 ])
1190 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1191
1192 # ------------------------------------------------------------------------------
1193 have_efi=no
1194 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
1195 if test "x$enable_efi" != "xno"; then
1196         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
1197         have_efi=yes
1198 fi
1199 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1200
1201 # ------------------------------------------------------------------------------
1202 AC_CHECK_TOOL(EFI_CC, gcc)
1203
1204 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1205
1206 AM_COND_IF(ARCH_IA32, [
1207         EFI_ARCH=ia32
1208         EFI_MACHINE_TYPE_NAME=ia32])
1209
1210 AM_COND_IF(ARCH_X86_64, [
1211         EFI_MACHINE_TYPE_NAME=x64])
1212
1213 AM_COND_IF(ARCH_AARCH64, [
1214         EFI_MACHINE_TYPE_NAME=aa64])
1215
1216 AC_SUBST([EFI_ARCH])
1217 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1218
1219 have_gnuefi=no
1220 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [Enable optional gnuefi support]))
1221 AS_IF([test "x$enable_gnuefi" != "xno"], [
1222         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
1223                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1224                  have_gnuefi=yes],
1225                 [AS_IF([test "x$enable_gnuefi" = xyes],
1226                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1227         ])
1228
1229         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1230
1231         EFI_LIB_DIR="$efiroot"
1232         AC_ARG_WITH(efi-libdir,
1233                 AS_HELP_STRING([--with-efi-libdir=PATH], [Path to EFI lib directory]),
1234                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1235         )
1236         AC_SUBST([EFI_LIB_DIR])
1237
1238         have_efi_lds=no
1239         AC_ARG_WITH(efi-ldsdir,
1240                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [Path to EFI lds directory]),
1241                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1242                         [have_efi_lds=yes])],
1243                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1244                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1245                                        [have_efi_lds=yes && break])])])
1246         AS_IF([test "x$have_efi_lds" = xyes],
1247               [AC_SUBST([EFI_LDS_DIR])],
1248               [AS_IF([test "x$enable_gnuefi" = xyes],
1249                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1250                      [have_gnuefi=no])])
1251
1252         AC_ARG_WITH(efi-includedir,
1253                 AS_HELP_STRING([--with-efi-includedir=PATH], [Path to EFI include directory]),
1254                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1255         )
1256         AC_SUBST([EFI_INC_DIR])
1257 ])
1258 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1259
1260 # ------------------------------------------------------------------------------
1261 have_tpm=no
1262 AC_ARG_ENABLE([tpm], AS_HELP_STRING([--enable-tpm],[Enable optional TPM support]),
1263                 [case "${enableval}" in
1264                         yes) have_tpm=yes ;;
1265                         no) have_tpm=no ;;
1266                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tpm) ;;
1267                 esac],
1268                 [have_tpm=no])
1269
1270 if test "x${have_tpm}" != xno ; then
1271         AC_DEFINE(SD_BOOT_LOG_TPM, 1, [Define if TPM should be used to log events and extend the registers])
1272 fi
1273
1274 AC_ARG_WITH(tpm-pcrindex,
1275         AS_HELP_STRING([--with-tpm-pcrindex=<NUM>],
1276                 [TPM PCR register number to use]),
1277         [SD_TPM_PCR="$withval"],
1278         [SD_TPM_PCR="8"])
1279
1280 AC_DEFINE_UNQUOTED(SD_TPM_PCR, [$SD_TPM_PCR], [TPM PCR register number to use])
1281
1282 # ------------------------------------------------------------------------------
1283 AC_ARG_WITH(rc-local-script-path-start,
1284         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1285                 [Path to /etc/rc.local]),
1286         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1287         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1288
1289 AC_ARG_WITH(rc-local-script-path-stop,
1290         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1291                 [Path to /usr/sbin/halt.local]),
1292         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1293         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1294
1295 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1296 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1297
1298 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1299 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1300
1301 # ------------------------------------------------------------------------------
1302 AC_ARG_WITH(kbd-loadkeys,
1303         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1304                 [Path to loadkeys]),
1305         [KBD_LOADKEYS="$withval"],
1306         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1307
1308 AC_ARG_WITH(kbd-setfont,
1309         AS_HELP_STRING([--with-kbd-setfont=PATH],
1310                 [Path to setfont]),
1311         [KBD_SETFONT="$withval"],
1312         [KBD_SETFONT="/usr/bin/setfont"])
1313
1314 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1315 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1316
1317 AC_SUBST(KBD_LOADKEYS)
1318 AC_SUBST(KBD_SETFONT)
1319
1320 AC_ARG_WITH(telinit,
1321         AS_HELP_STRING([--with-telinit=PATH],
1322                 [Path to telinit]),
1323         [TELINIT="$withval"],
1324         [TELINIT="/lib/sysvinit/telinit"])
1325
1326 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1327
1328 AC_SUBST(TELINIT)
1329
1330 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1331
1332 # ------------------------------------------------------------------------------
1333 have_myhostname=no
1334 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1335 if test "x$enable_myhostname" != "xno"; then
1336         AC_HEADER_STDC
1337         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1338
1339         AC_C_CONST
1340         AC_TYPE_SIZE_T
1341         AC_HEADER_TIME
1342
1343         AC_FUNC_SELECT_ARGTYPES
1344         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1345
1346         have_myhostname=yes
1347         AC_DEFINE(HAVE_MYHOSTNAME, [1], [nss-myhostname is enabled])
1348 fi
1349 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1350
1351 # ------------------------------------------------------------------------------
1352 AC_ARG_ENABLE(hwdb, [AC_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1353        enable_hwdb=$enableval, enable_hwdb=yes)
1354 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1355
1356 # ------------------------------------------------------------------------------
1357 have_manpages=no
1358 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1359 AC_PATH_PROG([XSLTPROC], [xsltproc])
1360 AS_IF([test "x$enable_manpages" != xno], [
1361        have_manpages=yes
1362        AS_IF([test -z "$XSLTPROC"],
1363              AC_MSG_ERROR([*** xsltproc is required for man pages]))
1364 ])
1365 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1366
1367 # ------------------------------------------------------------------------------
1368 AC_ARG_ENABLE(hibernate,
1369        [AC_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1370        enable_hibernate=$enableval, enable_hibernate=yes)
1371 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1372
1373 # ------------------------------------------------------------------------------
1374 AC_ARG_ENABLE(ldconfig,
1375        [AC_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1376        enable_ldconfig=$enableval, enable_ldconfig=yes)
1377 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1378
1379 # ------------------------------------------------------------------------------
1380 # Location of the init scripts as mandated by LSB
1381 SYSTEM_SYSVINIT_PATH=/etc/init.d
1382 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1383
1384 AC_ARG_WITH([sysvinit-path],
1385         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1386                 [Specify the path to where the SysV init scripts are located])],
1387         [SYSTEM_SYSVINIT_PATH="$withval"],
1388         [])
1389
1390 AC_ARG_WITH([sysvrcnd-path],
1391         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1392                 [Specify the path to the base directory for the SysV rcN.d directories])],
1393         [SYSTEM_SYSVRCND_PATH="$withval"],
1394         [])
1395
1396 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1397         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1398         SYSTEM_SYSV_COMPAT="yes"
1399         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1400 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1401         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1402 else
1403         SYSTEM_SYSV_COMPAT="no"
1404 fi
1405
1406 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1407 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1408 AC_SUBST(M4_DEFINES)
1409
1410 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1411
1412 AC_ARG_WITH([tty-gid],
1413         [AS_HELP_STRING([--with-tty-gid=GID],
1414                 [Specify the numeric GID of the 'tty' group])],
1415         [TTY_GID="$withval"],
1416         [TTY_GID="5"])
1417
1418 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1419 AC_SUBST(TTY_GID)
1420
1421 AC_ARG_WITH([dbuspolicydir],
1422         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1423         [],
1424         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
1425 AX_NORMALIZE_PATH([with_dbuspolicydir])
1426
1427 AC_ARG_WITH([dbussessionservicedir],
1428         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1429         [],
1430         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1431 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1432
1433 AC_ARG_WITH([dbussystemservicedir],
1434         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1435         [],
1436         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1437 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1438
1439 AC_ARG_WITH([bashcompletiondir],
1440         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
1441         [],
1442         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1443                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1444         ] , [
1445                 with_bashcompletiondir=${datadir}/bash-completion/completions
1446         ])])
1447 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1448 AX_NORMALIZE_PATH([with_bashcompletiondir])
1449
1450 AC_ARG_WITH([zshcompletiondir],
1451         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
1452         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1453 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1454 AX_NORMALIZE_PATH([with_zshcompletiondir])
1455
1456 AC_ARG_WITH([rootprefix],
1457         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1458         [], [with_rootprefix=${ac_default_prefix}])
1459 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1460 # defaults those to ".", solve that here for now until we can find a suitable
1461 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1462 # See: https://github.com/systemd/systemd/issues/54
1463 if test "x${with_rootprefix}" = "x"; then
1464         with_rootprefix="/"
1465 fi
1466 AX_NORMALIZE_PATH([with_rootprefix])
1467
1468 AC_ARG_WITH([rootlibdir],
1469         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
1470         [],
1471         [with_rootlibdir=${libdir}])
1472 AX_NORMALIZE_PATH([with_rootlibdir])
1473
1474 AC_ARG_WITH([pamlibdir],
1475         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1476         [],
1477         [with_pamlibdir=${with_rootlibdir}/security])
1478 AX_NORMALIZE_PATH([with_pamlibdir])
1479
1480 AC_ARG_WITH([pamconfdir],
1481         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1482         [],
1483         [with_pamconfdir=${sysconfdir}/pam.d])
1484 AX_NORMALIZE_PATH([with_pamconfdir])
1485
1486 AC_ARG_ENABLE([split-usr],
1487         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1488         [],
1489         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1490                 enable_split_usr=yes
1491         ], [
1492                 enable_split_usr=no
1493         ])])
1494
1495 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1496         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1497 ])
1498 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1499
1500 # work around intltool-update issues during 'make distcheck'
1501 AS_IF([test "x$0" != "x./configure"], [
1502         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1503 ])
1504
1505 # QEMU and OVMF UEFI firmware
1506 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1507         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1508         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1509                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1510         AC_SUBST([QEMU_BIOS])
1511 ])
1512
1513 AC_ARG_ENABLE(tests,
1514         [AC_HELP_STRING([--disable-tests], [disable tests, or enable extra tests with =unsafe])],
1515         enable_tests=$enableval, enable_tests=yes)
1516 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes -o x$enable_tests = xunsafe])
1517 AM_CONDITIONAL(ENABLE_UNSAFE_TESTS, [test x$enable_tests = xunsafe])
1518
1519 AC_ARG_ENABLE(debug,
1520         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1521         [if test "x$enableval" = "xyes"; then
1522                 enableval="hashmap,mmap-cache"
1523         fi
1524         saved_ifs="$IFS"
1525         IFS="$IFS$PATH_SEPARATOR,"
1526         for name in $enableval; do
1527                 case $name in
1528                 hashmap)
1529                         enable_debug_hashmap=yes
1530                         ;;
1531                 mmap-cache)
1532                         enable_debug_mmap_cache=yes
1533                         ;;
1534                 esac
1535         done
1536         IFS="$saved_ifs"],[])
1537
1538 enable_debug=""
1539 AS_IF([test x$enable_debug_hashmap = xyes], [
1540         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1541         enable_debug="hashmap $enable_debug"
1542 ])
1543 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1544         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1545         enable_debug="mmap-cache $enable_debug"
1546 ])
1547 test -z "$enable_debug" && enable_debug="none"
1548
1549 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1550 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1551 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1552 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1553 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1554 AC_SUBST([pamlibdir], [$with_pamlibdir])
1555 AC_SUBST([pamconfdir], [$with_pamconfdir])
1556 AC_SUBST([rootprefix], [$with_rootprefix])
1557 AC_SUBST([rootlibdir], [$with_rootlibdir])
1558
1559 AC_CONFIG_FILES([
1560         Makefile
1561         po/Makefile.in
1562 ])
1563
1564 AC_OUTPUT
1565 AC_MSG_RESULT([
1566         $PACKAGE_NAME $VERSION
1567
1568         libcryptsetup:                     ${have_libcryptsetup}
1569         PAM:                               ${have_pam}
1570         AUDIT:                             ${have_audit}
1571         IMA:                               ${have_ima}
1572         AppArmor:                          ${have_apparmor}
1573         SELinux:                           ${have_selinux}
1574         SECCOMP:                           ${have_seccomp}
1575         SMACK:                             ${have_smack}
1576         ZLIB:                              ${have_zlib}
1577         XZ:                                ${have_xz}
1578         LZ4:                               ${have_lz4}
1579         BZIP2:                             ${have_bzip2}
1580         ACL:                               ${have_acl}
1581         GCRYPT:                            ${have_gcrypt}
1582         QRENCODE:                          ${have_qrencode}
1583         MICROHTTPD:                        ${have_microhttpd}
1584         GNUTLS:                            ${have_gnutls}
1585         libcurl:                           ${have_libcurl}
1586         libidn:                            ${have_libidn}
1587         libiptc:                           ${have_libiptc}
1588         ELFUTILS:                          ${have_elfutils}
1589         binfmt:                            ${have_binfmt}
1590         vconsole:                          ${have_vconsole}
1591         quotacheck:                        ${have_quotacheck}
1592         tmpfiles:                          ${have_tmpfiles}
1593         sysusers:                          ${have_sysusers}
1594         firstboot:                         ${have_firstboot}
1595         randomseed:                        ${have_randomseed}
1596         backlight:                         ${have_backlight}
1597         rfkill:                            ${have_rfkill}
1598         logind:                            ${have_logind}
1599         Default KillUserProcesses setting: ${KILL_USER_PROCESSES}
1600         machined:                          ${have_machined}
1601         importd:                           ${have_importd}
1602         hostnamed:                         ${have_hostnamed}
1603         timedated:                         ${have_timedated}
1604         timesyncd:                         ${have_timesyncd}
1605         Default NTP servers:               ${NTP_SERVERS}
1606         time epoch:                        ${TIME_EPOCH}
1607         localed:                           ${have_localed}
1608         networkd:                          ${have_networkd}
1609         resolved:                          ${have_resolved}
1610         Default DNS servers:               ${DNS_SERVERS}
1611         Default DNSSEC mode:               ${DEFAULT_DNSSEC_MODE}
1612         coredump:                          ${have_coredump}
1613         polkit:                            ${have_polkit}
1614         efi:                               ${have_efi}
1615         gnuefi:                            ${have_gnuefi}
1616         efi arch:                          ${EFI_ARCH}
1617         EFI machine type:                  ${EFI_MACHINE_TYPE_NAME}
1618         EFI CC                             ${EFI_CC}
1619         EFI libdir:                        ${EFI_LIB_DIR}
1620         EFI ldsdir:                        ${EFI_LDS_DIR}
1621         EFI includedir:                    ${EFI_INC_DIR}
1622         kmod:                              ${have_kmod}
1623         xkbcommon:                         ${have_xkbcommon}
1624         blkid:                             ${have_blkid}
1625         libmount:                          ${have_libmount}
1626         dbus:                              ${have_dbus}
1627         nss-myhostname:                    ${have_myhostname}
1628         hwdb:                              ${enable_hwdb}
1629         tpm:                               ${have_tpm}
1630         kdbus:                             ${have_kdbus}
1631         Python:                            ${have_python}
1632         man pages:                         ${have_manpages}
1633         test coverage:                     ${have_coverage}
1634         Split /usr:                        ${enable_split_usr}
1635         SysV compatibility:                ${SYSTEM_SYSV_COMPAT}
1636         utmp/wtmp support:                 ${have_utmp}
1637         ldconfig support:                  ${enable_ldconfig}
1638         hibernate support:                 ${enable_hibernate}
1639         extra debugging:                   ${enable_debug}
1640         tests:                             ${enable_tests}
1641
1642         prefix:                            ${prefix}
1643         rootprefix:                        ${with_rootprefix}
1644         sysconf dir:                       ${sysconfdir}
1645         datarootdir:                       ${datarootdir}
1646         includedir:                        ${includedir}
1647         lib dir:                           ${libdir}
1648         rootlib dir:                       ${with_rootlibdir}
1649         SysV init scripts:                 ${SYSTEM_SYSVINIT_PATH}
1650         SysV rc?.d directories:            ${SYSTEM_SYSVRCND_PATH}
1651         Build Python:                      ${PYTHON}
1652         PAM modules dir:                   ${with_pamlibdir}
1653         PAM configuration dir:             ${with_pamconfdir}
1654         D-Bus policy dir:                  ${with_dbuspolicydir}
1655         D-Bus session dir:                 ${with_dbussessionservicedir}
1656         D-Bus system dir:                  ${with_dbussystemservicedir}
1657         Bash completions dir:              ${with_bashcompletiondir}
1658         Zsh completions dir:               ${with_zshcompletiondir}
1659         Extra start script:                ${RC_LOCAL_SCRIPT_PATH_START}
1660         Extra stop script:                 ${RC_LOCAL_SCRIPT_PATH_STOP}
1661         Adm group:                         ${have_adm_group}
1662         Wheel group:                       ${have_wheel_group}
1663         Debug shell:                       ${SUSHELL} @ ${DEBUGTTY}
1664         TTY GID:                           ${TTY_GID}
1665         Maximum System UID:                ${SYSTEM_UID_MAX}
1666         Maximum System GID:                ${SYSTEM_GID_MAX}
1667         Certificate root:                  ${CERTIFICATEROOT}
1668
1669         CFLAGS:   ${OUR_CFLAGS} ${CFLAGS}
1670         CPPFLAGS: ${OUR_CPPFLAGS} ${CPPFLAGS}
1671         LDFLAGS:  ${OUR_LDFLAGS} ${LDFLAGS}
1672 ])