configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl First, define all of the version numbers up front.
   4 dnl In particular, this allows the version macro to be used in AC_INIT
   5
   6 dnl These first two version numbers are updated automatically on each release.
   7 m4_define([LIBARCHIVE_VERSION_S],[3.5.3dev])
   8 m4_define([LIBARCHIVE_VERSION_N],[3005003])
   9
  10 dnl bsdtar and bsdcpio versioning tracks libarchive
  11 m4_define([BSDTAR_VERSION_S],LIBARCHIVE_VERSION_S())
  12 m4_define([BSDCPIO_VERSION_S],LIBARCHIVE_VERSION_S())
  13 m4_define([BSDCAT_VERSION_S],LIBARCHIVE_VERSION_S())
  14
  15 AC_PREREQ([2.69])
  16
  17 #
  18 # Now starts the "real" configure script.
  19 #
  20
  21 AC_INIT([libarchive],[LIBARCHIVE_VERSION_S()],[libarchive-discuss@googlegroups.com])
  22 # Make sure the srcdir contains "libarchive" directory
  23 AC_CONFIG_SRCDIR([libarchive])
  24 # Use auxiliary subscripts from this subdirectory (cleans up root)
  25 AC_CONFIG_AUX_DIR([build/autoconf])
  26 # M4 scripts
  27 AC_CONFIG_MACRO_DIR([build/autoconf])
  28 # Must follow AC_CONFIG macros above...
  29 AM_INIT_AUTOMAKE([1.11 dist-xz dist-zip])
  30 AM_MAINTAINER_MODE([enable])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 # Libtool's "interface version" can be computed from the libarchive version.
  34
  35 # Libtool interface version bumps on any API change, so increments
  36 # whenever libarchive minor version does.
  37 ARCHIVE_MINOR=$(( (LIBARCHIVE_VERSION_N() / 1000) % 1000 ))
  38 # Libarchive 2.7 == libtool interface 9 = 2 + 7
  39 # Libarchive 2.8 == libtool interface 10 = 2 + 8
  40 # Libarchive 2.9 == libtool interface 11 = 2 + 8
  41 # Libarchive 3.0 == libtool interface 12
  42 # Libarchive 3.1 == libtool interface 13
  43 ARCHIVE_INTERFACE=`echo $((13 + ${ARCHIVE_MINOR}))`
  44 # Libarchive revision is bumped on any source change === libtool revision
  45 ARCHIVE_REVISION=$(( LIBARCHIVE_VERSION_N() % 1000 ))
  46 # Libarchive minor is bumped on any interface addition === libtool age
  47 ARCHIVE_LIBTOOL_VERSION=$ARCHIVE_INTERFACE:$ARCHIVE_REVISION:$ARCHIVE_MINOR
  48
  49 # Stick the version numbers into config.h
  50 AC_DEFINE([__LIBARCHIVE_CONFIG_H_INCLUDED], [1],
  51         [Internal macro for sanity checks])
  52 AC_DEFINE([LIBARCHIVE_VERSION_STRING],"LIBARCHIVE_VERSION_S()",
  53         [Version number of libarchive])
  54 AC_DEFINE_UNQUOTED([LIBARCHIVE_VERSION_NUMBER],"LIBARCHIVE_VERSION_N()",
  55         [Version number of libarchive as a single integer])
  56 AC_DEFINE([BSDCPIO_VERSION_STRING],"BSDCPIO_VERSION_S()",
  57         [Version number of bsdcpio])
  58 AC_DEFINE([BSDTAR_VERSION_STRING],"BSDTAR_VERSION_S()",
  59         [Version number of bsdtar])
  60 AC_DEFINE([BSDCAT_VERSION_STRING],"BSDTAR_VERSION_S()",
  61         [Version number of bsdcat])
  62
  63 # The shell variables here must be the same as the AC_SUBST() variables
  64 # below, but the shell variable names apparently cannot be the same as
  65 # the m4 macro names above.  Why?  Ask autoconf.
  66 BSDCPIO_VERSION_STRING=BSDCPIO_VERSION_S()
  67 BSDTAR_VERSION_STRING=BSDTAR_VERSION_S()
  68 BSDCAT_VERSION_STRING=BSDCAT_VERSION_S()
  69 LIBARCHIVE_VERSION_STRING=LIBARCHIVE_VERSION_S()
  70 LIBARCHIVE_VERSION_NUMBER=LIBARCHIVE_VERSION_N()
  71
  72 # Substitute the above version numbers into the various files below.
  73 # Yes, I believe this is the fourth time we define what are essentially
  74 # the same symbols.  Why? Ask autoconf.
  75 AC_SUBST(ARCHIVE_LIBTOOL_VERSION)
  76 AC_SUBST(BSDCPIO_VERSION_STRING)
  77 AC_SUBST(BSDTAR_VERSION_STRING)
  78 AC_SUBST(BSDCAT_VERSION_STRING)
  79 AC_SUBST(LIBARCHIVE_VERSION_STRING)
  80 AC_SUBST(LIBARCHIVE_VERSION_NUMBER)
  81
  82 AC_CONFIG_HEADERS([config.h])
  83 AC_CONFIG_FILES([Makefile])
  84 AC_CONFIG_FILES([build/pkgconfig/libarchive.pc])
  85
  86 # Check for host type
  87 AC_CANONICAL_HOST
  88
  89 dnl Compilation on mingw and Cygwin needs special Makefile rules
  90 inc_windows_files=no
  91 inc_cygwin_files=no
  92 case "$host_os" in
  93   *mingw* ) inc_windows_files=yes ;;
  94   *cygwin* | *msys*) inc_cygwin_files=yes ;;
  95 esac
  96 AM_CONDITIONAL([INC_WINDOWS_FILES], [test $inc_windows_files = yes])
  97 AM_CONDITIONAL([INC_CYGWIN_FILES], [test $inc_cygwin_files = yes])
  98
  99 dnl Defines that are required for specific platforms (e.g. -D_POSIX_SOURCE, etc)
 100 PLATFORMCPPFLAGS=
 101 case "$host_os" in
 102   *mingw* ) PLATFORMCPPFLAGS=-D__USE_MINGW_ANSI_STDIO ;;
 103 esac
 104 AC_SUBST(PLATFORMCPPFLAGS)
 105
 106 # Checks for programs.
 107 AC_PROG_CC
 108 AC_PROG_CC_C99
 109 AM_PROG_CC_C_O
 110 AC_PROG_CPP
 111 AC_USE_SYSTEM_EXTENSIONS
 112 AC_LIBTOOL_WIN32_DLL
 113 AC_PROG_LIBTOOL
 114 AC_CHECK_TOOL([STRIP],[strip])
 115 AC_PROG_MKDIR_P
 116
 117 #
 118 # Options for building bsdtar.
 119 #
 120 # Default is to build bsdtar, but allow people to override that.
 121 #
 122 AC_ARG_ENABLE([bsdtar],
 123         [AS_HELP_STRING([--enable-bsdtar], [enable build of bsdtar (default)])
 124         AS_HELP_STRING([--enable-bsdtar=static], [force static build of bsdtar])
 125         AS_HELP_STRING([--enable-bsdtar=shared], [force dynamic build of bsdtar])
 126 AS_HELP_STRING([--disable-bsdtar], [disable build of bsdtar])],
 127         [], [enable_bsdtar=yes])
 128
 129 case "$enable_bsdtar" in
 130 yes)
 131         if test "$enable_static" = "no"; then
 132                 static_bsdtar=no
 133         else
 134                 static_bsdtar=yes
 135         fi
 136         build_bsdtar=yes
 137         ;;
 138 dynamic|shared)
 139         if test "$enable_shared" = "no"; then
 140                 AC_MSG_FAILURE([Shared linking of bsdtar requires shared libarchive])
 141         fi
 142         build_bsdtar=yes
 143         static_bsdtar=no
 144         ;;
 145 static)
 146         build_bsdtar=yes
 147         static_bsdtar=yes
 148         ;;
 149 no)
 150         build_bsdtar=no
 151         static_bsdtar=no
 152         ;;
 153 *)
 154         AC_MSG_FAILURE([Unsupported value for --enable-bsdtar])
 155         ;;
 156 esac
 157
 158 AM_CONDITIONAL([BUILD_BSDTAR], [ test "$build_bsdtar" = yes ])
 159 AM_CONDITIONAL([STATIC_BSDTAR], [ test "$static_bsdtar" = yes ])
 160
 161 #
 162 # Options for building bsdcat.
 163 #
 164 # Default is to build bsdcat, but allow people to override that.
 165 #
 166 AC_ARG_ENABLE([bsdcat],
 167         [AS_HELP_STRING([--enable-bsdcat], [enable build of bsdcat (default)])
 168         AS_HELP_STRING([--enable-bsdcat=static], [force static build of bsdcat])
 169         AS_HELP_STRING([--enable-bsdcat=shared], [force dynamic build of bsdcat])
 170 AS_HELP_STRING([--disable-bsdcat], [disable build of bsdcat])],
 171         [], [enable_bsdcat=yes])
 172
 173 case "$enable_bsdcat" in
 174 yes)
 175         if test "$enable_static" = "no"; then
 176                 static_bsdcat=no
 177         else
 178                 static_bsdcat=yes
 179         fi
 180         build_bsdcat=yes
 181         ;;
 182 dynamic|shared)
 183         if test "$enable_shared" = "no"; then
 184                 AC_MSG_FAILURE([Shared linking of bsdcat requires shared libarchive])
 185         fi
 186         build_bsdcat=yes
 187         static_bsdcat=no
 188         ;;
 189 static)
 190         build_bsdcat=yes
 191         static_bsdcat=yes
 192         ;;
 193 no)
 194         build_bsdcat=no
 195         static_bsdcat=no
 196         ;;
 197 *)
 198         AC_MSG_FAILURE([Unsupported value for --enable-bsdcat])
 199         ;;
 200 esac
 201
 202 AM_CONDITIONAL([BUILD_BSDCAT], [ test "$build_bsdcat" = yes ])
 203 AM_CONDITIONAL([STATIC_BSDCAT], [ test "$static_bsdcat" = yes ])
 204
 205 #
 206 # Options for building bsdcpio.
 207 #
 208 # Default is not to build bsdcpio, but that can be overridden.
 209 #
 210 AC_ARG_ENABLE([bsdcpio],
 211         [AS_HELP_STRING([--enable-bsdcpio], [enable build of bsdcpio (default)])
 212         AS_HELP_STRING([--enable-bsdcpio=static], [static build of bsdcpio])
 213         AS_HELP_STRING([--enable-bsdcpio=shared], [dynamic build of bsdcpio])
 214 AS_HELP_STRING([--disable-bsdcpio], [disable build of bsdcpio])],
 215         [], [enable_bsdcpio=yes])
 216
 217 case "$enable_bsdcpio" in
 218 yes)
 219         if test "$enable_static" = "no"; then
 220            static_bsdcpio=no
 221         else
 222            static_bsdcpio=yes
 223         fi
 224         build_bsdcpio=yes
 225         ;;
 226 dynamic|shared)
 227         if test "$enabled_shared" = "no"; then
 228            AC_MSG_FAILURE([Shared linking of bsdcpio requires shared libarchive])
 229         fi
 230         build_bsdcpio=yes
 231         ;;
 232 static)
 233         build_bsdcpio=yes
 234         static_bsdcpio=yes
 235         ;;
 236 no)
 237         build_bsdcpio=no
 238         static_bsdcpio=no
 239         ;;
 240 *)
 241         AC_MSG_FAILURE([Unsupported value for --enable-bsdcpio])
 242         ;;
 243 esac
 244
 245 AM_CONDITIONAL([BUILD_BSDCPIO], [ test "$build_bsdcpio" = yes ])
 246 AM_CONDITIONAL([STATIC_BSDCPIO], [ test "$static_bsdcpio" = yes ])
 247
 248 # Set up defines needed before including any headers
 249 case $host in
 250   *mingw* | *cygwin* | *msys*  )
 251   AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 252     [[#ifdef _WIN32_WINNT
 253      # error _WIN32_WINNT already defined
 254      #endif
 255     ]],[[;]])
 256   ],[
 257     AC_DEFINE([_WIN32_WINNT], 0x0502, [Define to '0x0502' for Windows Server 2003 APIs.])
 258     AC_DEFINE([NTDDI_VERSION], 0x05020000, [Define to '0x05020000' for Windows Server 2003 APIs.])
 259   ])
 260   AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 261     [[#ifdef WINVER
 262      # error WINVER already defined
 263      #endif
 264     ]],[[;]])
 265   ],[
 266     AC_DEFINE([WINVER], 0x0502, [Define to '0x0502' for Windows Server 2003 APIs.])
 267   ])
 268   ;;
 269 esac
 270
 271 # Checks for header files.
 272 AC_HEADER_DIRENT
 273 AC_HEADER_SYS_WAIT
 274 AC_CHECK_HEADERS([acl/libacl.h attr/xattr.h])
 275 AC_CHECK_HEADERS([copyfile.h ctype.h])
 276 AC_CHECK_HEADERS([errno.h ext2fs/ext2_fs.h fcntl.h grp.h])
 277
 278 AC_CACHE_CHECK([whether EXT2_IOC_GETFLAGS is usable],
 279     [ac_cv_have_decl_EXT2_IOC_GETFLAGS],
 280     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([@%:@include <sys/ioctl.h>
 281 @%:@include <ext2fs/ext2_fs.h>],
 282                                    [int x = EXT2_IOC_GETFLAGS])],
 283                   [AS_VAR_SET([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [yes])],
 284                   [AS_VAR_SET([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [no])])])
 285
 286 AS_VAR_IF([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [yes],
 287     [AC_DEFINE_UNQUOTED([HAVE_WORKING_EXT2_IOC_GETFLAGS], [1],
 288                     [Define to 1 if you have a working EXT2_IOC_GETFLAGS])])
 289
 290 AC_CHECK_HEADERS([inttypes.h io.h langinfo.h limits.h])
 291 AC_CHECK_HEADERS([linux/fiemap.h linux/fs.h linux/magic.h linux/types.h])
 292
 293 AC_CACHE_CHECK([whether FS_IOC_GETFLAGS is usable],
 294     [ac_cv_have_decl_FS_IOC_GETFLAGS],
 295     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([@%:@include <sys/ioctl.h>
 296 @%:@include <linux/fs.h>],
 297                                    [int x = FS_IOC_GETFLAGS])],
 298                   [AS_VAR_SET([ac_cv_have_decl_FS_IOC_GETFLAGS], [yes])],
 299                   [AS_VAR_SET([ac_cv_have_decl_FS_IOC_GETFLAGS], [no])])])
 300
 301 AS_VAR_IF([ac_cv_have_decl_FS_IOC_GETFLAGS], [yes],
 302     [AC_DEFINE_UNQUOTED([HAVE_WORKING_FS_IOC_GETFLAGS], [1],
 303                     [Define to 1 if you have a working FS_IOC_GETFLAGS])])
 304
 305 AC_CHECK_HEADERS([locale.h membership.h paths.h poll.h pthread.h pwd.h])
 306 AC_CHECK_HEADERS([readpassphrase.h signal.h spawn.h])
 307 AC_CHECK_HEADERS([stdarg.h stdint.h stdlib.h string.h])
 308 AC_CHECK_HEADERS([sys/acl.h sys/cdefs.h sys/ea.h sys/extattr.h])
 309 AC_CHECK_HEADERS([sys/ioctl.h sys/mkdev.h sys/mount.h])
 310 AC_CHECK_HEADERS([sys/param.h sys/poll.h sys/richacl.h])
 311 AC_CHECK_HEADERS([sys/select.h sys/statfs.h sys/statvfs.h sys/sysmacros.h])
 312 AC_CHECK_HEADERS([sys/time.h sys/utime.h sys/utsname.h sys/vfs.h sys/xattr.h])
 313 AC_CHECK_HEADERS([time.h unistd.h utime.h wchar.h wctype.h])
 314 AC_CHECK_HEADERS([windows.h])
 315 # check windows.h first; the other headers require it.
 316 AC_CHECK_HEADERS([wincrypt.h winioctl.h],[],[],
 317 [[#ifdef HAVE_WINDOWS_H
 318 # include <windows.h>
 319 #endif
 320 ]])
 321
 322 # Checks for libraries.
 323 AC_ARG_WITH([zlib],
 324   AS_HELP_STRING([--without-zlib], [Don't build support for gzip through zlib]))
 325
 326 if test "x$with_zlib" != "xno"; then
 327   AC_CHECK_HEADERS([zlib.h])
 328   AC_CHECK_LIB(z,inflate)
 329 fi
 330
 331 AC_ARG_WITH([bz2lib],
 332   AS_HELP_STRING([--without-bz2lib], [Don't build support for bzip2 through bz2lib]))
 333
 334 if test "x$with_bz2lib" != "xno"; then
 335   AC_CHECK_HEADERS([bzlib.h])
 336   case "$host_os" in
 337     *mingw* | *cygwin* | *msys*)
 338       dnl AC_CHECK_LIB cannot be used on the Windows port of libbz2, therefore
 339           dnl use AC_LINK_IFELSE.
 340           AC_MSG_CHECKING([for BZ2_bzDecompressInit in -lbz2])
 341       old_LIBS="$LIBS"
 342       LIBS="-lbz2 $LIBS"
 343       AC_LINK_IFELSE(
 344         [AC_LANG_SOURCE(#include <bzlib.h>
 345           int main() { return BZ2_bzDecompressInit(NULL, 0, 0); })],
 346         [ac_cv_lib_bz2_BZ2_bzDecompressInit=yes],
 347         [ac_cv_lib_bz2_BZ2_bzDecompressInit=no])
 348       LIBS="$old_LIBS"
 349           AC_MSG_RESULT($ac_cv_lib_bz2_BZ2_bzDecompressInit)
 350       if test "x$ac_cv_lib_bz2_BZ2_bzDecompressInit" = xyes; then
 351         AC_DEFINE([HAVE_LIBBZ2], [1], [Define to 1 if you have the `bz2' library (-lbz2).])
 352         LIBS="-lbz2 $LIBS"
 353       fi
 354     ;;
 355     *)
 356       AC_CHECK_LIB(bz2,BZ2_bzDecompressInit)
 357     ;;
 358   esac
 359 fi
 360
 361 AC_ARG_WITH([libb2],
 362   AS_HELP_STRING([--without-libb2], [Don't build support for BLAKE2 through libb2]))
 363
 364 if test "x$with_libb2" != "xno"; then
 365   AC_CHECK_HEADERS([blake2.h])
 366   AC_CHECK_LIB(b2,blake2sp_init)
 367 fi
 368
 369 AM_CONDITIONAL([INC_BLAKE2], [test "x$ac_cv_lib_b2_blake2sp_init" != "xyes"])
 370
 371 AC_ARG_WITH([iconv],
 372   AS_HELP_STRING([--without-iconv], [Don't try to link against iconv]))
 373
 374 if test "x$with_iconv" != "xno"; then
 375   AM_ICONV
 376   AC_CHECK_HEADERS([iconv.h],[],[],[#include <stdlib.h>])
 377   if test "x$am_cv_func_iconv" = "xyes"; then
 378     AC_CHECK_HEADERS([localcharset.h])
 379     am_save_LIBS="$LIBS"
 380     LIBS="${LIBS} ${LIBICONV}"
 381     AC_CHECK_FUNCS([locale_charset])
 382     LIBS="${am_save_LIBS}"
 383     if test "x$ac_cv_func_locale_charset" != "xyes"; then
 384       # If locale_charset() is not in libiconv, we have to find libcharset.
 385       AC_CHECK_LIB(charset,locale_charset)
 386     fi
 387   fi
 388 fi
 389
 390 AC_ARG_WITH([lz4],
 391   AS_HELP_STRING([--without-lz4], [Don't build support for lz4 through liblz4]))
 392
 393 if test "x$with_lz4" != "xno"; then
 394   AC_CHECK_HEADERS([lz4.h lz4hc.h])
 395   AC_CHECK_LIB(lz4,LZ4_decompress_safe)
 396 fi
 397
 398 AC_ARG_WITH([zstd],
 399   AS_HELP_STRING([--without-zstd], [Don't build support for zstd through libzstd]))
 400
 401 if test "x$with_zstd" != "xno"; then
 402   AC_CHECK_HEADERS([zstd.h])
 403   AC_CHECK_LIB(zstd,ZSTD_decompressStream)
 404   AC_CHECK_LIB(zstd,ZSTD_compressStream,
 405     AC_DEFINE([HAVE_LIBZSTD_COMPRESSOR], [1], [Define to 1 if you have the `zstd' library (-lzstd) with compression support.]))
 406 fi
 407
 408 AC_ARG_WITH([lzma],
 409   AS_HELP_STRING([--without-lzma], [Don't build support for xz through lzma]))
 410
 411 if test "x$with_lzma" != "xno"; then
 412   AC_CHECK_HEADERS([lzma.h])
 413   AC_CHECK_LIB(lzma,lzma_stream_decoder)
 414   # Some pre-release (but widely distributed) versions of liblzma
 415   # included a disabled version of lzma_stream_encoder_mt that
 416   # fools a naive AC_CHECK_LIB or AC_CHECK_FUNC, so we need
 417   # to do something more complex here:
 418   AC_CACHE_CHECK(
 419     [whether we have multithread support in lzma],
 420     ac_cv_lzma_has_mt,
 421     [AC_LINK_IFELSE([
 422       AC_LANG_PROGRAM([[#include <lzma.h>]
 423                        [#if LZMA_VERSION < 50020000]
 424                        [#error unsupported]
 425                        [#endif]],
 426                       [[lzma_stream_encoder_mt(0, 0);]])],
 427       [ac_cv_lzma_has_mt=yes], [ac_cv_lzma_has_mt=no])])
 428   if test "x$ac_cv_lzma_has_mt" != xno; then
 429           AC_DEFINE([HAVE_LZMA_STREAM_ENCODER_MT], [1], [Define to 1 if you have the `lzma_stream_encoder_mt' function.])
 430   fi
 431 fi
 432
 433 AC_ARG_WITH([lzo2],
 434   AS_HELP_STRING([--with-lzo2], [Build with LZO support from liblzo2]))
 435
 436 if test "x$with_lzo2" = "xyes"; then
 437   AC_CHECK_HEADERS([lzo/lzoconf.h lzo/lzo1x.h])
 438   AC_CHECK_LIB(lzo2,lzo1x_decompress_safe)
 439 fi
 440
 441 AC_ARG_WITH([cng],
 442   AS_HELP_STRING([--without-cng], [Don't build support of CNG(Crypto Next Generation)]))
 443
 444 AC_ARG_WITH([mbedtls],
 445   AS_HELP_STRING([--with-mbedtls], [Build with crypto support from mbed TLS]))
 446 AC_ARG_WITH([nettle],
 447   AS_HELP_STRING([--with-nettle], [Build with crypto support from Nettle]))
 448 AC_ARG_WITH([openssl],
 449   AS_HELP_STRING([--without-openssl], [Don't build support for mtree and xar hashes through openssl]))
 450 case "$host_os" in
 451   *darwin* ) with_openssl=no ;;
 452 esac
 453
 454 AC_ARG_WITH([xml2],
 455   AS_HELP_STRING([--without-xml2], [Don't build support for xar through libxml2]))
 456 AC_ARG_WITH([expat],
 457   AS_HELP_STRING([--without-expat], [Don't build support for xar through expat]))
 458
 459 if test "x$with_xml2" != "xno"; then
 460   PKG_PROG_PKG_CONFIG
 461   PKG_CHECK_MODULES(LIBXML2_PC, [libxml-2.0], [
 462     CPPFLAGS="${CPPFLAGS} ${LIBXML2_PC_CFLAGS}"
 463     LIBS="${LIBS} ${LIBXML2_PC_LIBS}"
 464     AC_CHECK_LIB(xml2,xmlInitParser,[true],AC_MSG_FAILURE(Missing xml2 library))
 465   ], [
 466     AC_CHECK_LIB(xml2,xmlInitParser)
 467   ])
 468   AC_CHECK_HEADERS([libxml/xmlreader.h libxml/xmlwriter.h])
 469 fi
 470 if test "x$ac_cv_header_libxml_xmlreader_h" != "xyes"; then
 471   if test "x$with_expat" != "xno"; then
 472     AC_CHECK_HEADERS([expat.h])
 473     AC_CHECK_LIB(expat,XML_ParserCreate)
 474   fi
 475 fi
 476
 477 AC_ARG_ENABLE([posix-regex-lib],
 478   [AS_HELP_STRING([--enable-posix-regex-lib],
 479     [choose what library to use for POSIX regular expression support (default: auto)])
 480   AS_HELP_STRING([--enable-posix-regex-lib=libc], [use libc POSIX regular expression support])
 481   AS_HELP_STRING([--enable-posix-regex-lib=libregex], [use libregex POSIX regular expression support])
 482   AS_HELP_STRING([--enable-posix-regex-lib=libpcreposix], [use libpcreposix POSIX regular expression support])
 483   AS_HELP_STRING([--disable-posix-regex-lib], [don't enable POSIX regular expression support])],
 484   [], [enable_posix_regex_lib=auto])
 485
 486 posix_regex_lib_found=
 487 if test "$enable_posix_regex_lib" = "auto" || test "$enable_posix_regex_lib" = "libc" || test "$enable_posix_regex_lib" = "libregex"; then
 488   AC_CHECK_HEADERS([regex.h])
 489   if test "x$ac_cv_header_regex_h" != "xno"; then
 490     AC_CHECK_FUNC(regcomp)
 491     if test "x$ac_cv_func_regcomp" = xyes; then
 492       posix_regex_lib_found=1
 493     else
 494       AC_CHECK_LIB(regex,regcomp)
 495       if test "x$ac_cv_lib_regex_regcomp" = xyes; then
 496         posix_regex_lib_found=1
 497       fi
 498     fi
 499   fi
 500 fi
 501 if test -z $posix_regex_lib_found && (test "$enable_posix_regex_lib" = "auto" || test "$enable_posix_regex_lib" = "libpcreposix"); then
 502   AC_CHECK_HEADERS([pcreposix.h])
 503   AC_CHECK_LIB(pcreposix,regcomp)
 504   if test "x$ac_cv_lib_pcreposix_regcomp" != xyes; then
 505     AC_MSG_NOTICE(trying libpcreposix check again with libpcre)
 506         unset ac_cv_lib_pcreposix_regcomp
 507         AC_CHECK_LIB(pcre,pcre_exec)
 508     AC_CHECK_LIB(pcreposix,regcomp)
 509     if test "x$ac_cv_lib_pcre_pcre_exec" = xyes && test "x$ac_cv_lib_pcreposix_regcomp" = xyes; then
 510       AC_MSG_CHECKING(if PCRE_STATIC needs to be defined)
 511       AC_LINK_IFELSE(
 512         [AC_LANG_SOURCE(#include <pcreposix.h>
 513           int main() { return regcomp(NULL, NULL, 0); })],
 514         [without_pcre_static=yes],
 515         [without_pcre_static=no])
 516       AC_LINK_IFELSE(
 517         [AC_LANG_SOURCE(#define PCRE_STATIC
 518           #include <pcreposix.h>
 519           int main() { return regcomp(NULL, NULL, 0); })],
 520         [with_pcre_static=yes],
 521         [with_pcre_static=no])
 522       if test "x$without_pcre_static" != xyes && test "x$with_pcre_static" = xyes; then
 523         AC_MSG_RESULT(yes)
 524         AC_DEFINE([PCRE_STATIC], [1], [Define to 1 if PCRE_STATIC needs to be defined.])
 525       elif test "x$without_pcre_static" = xyes || test "x$with_pcre_static" = xyes; then
 526         AC_MSG_RESULT(no)
 527       fi
 528       posix_regex_lib_found=1
 529     fi
 530   else
 531     posix_regex_lib_found=1
 532   fi
 533 fi
 534
 535 # TODO: Give the user the option of using a pre-existing system
 536 # libarchive.  This will define HAVE_LIBARCHIVE which will cause
 537 # bsdtar_platform.h to use #include <...> for the libarchive headers.
 538 # Need to include Makefile.am magic to link against system
 539 # -larchive in that case.
 540 #AC_CHECK_LIB(archive,archive_version)
 541
 542 # Checks for supported compiler flags
 543 AX_APPEND_COMPILE_FLAGS([-Wall -Wformat -Wformat-security])
 544
 545 # Checks for typedefs, structures, and compiler characteristics.
 546 AC_C_CONST
 547 # la_TYPE_UID_T defaults to "int", which is incorrect for MinGW
 548 # and MSVC. Use a customized version.
 549 la_TYPE_UID_T
 550 AC_TYPE_MODE_T
 551 # AC_TYPE_OFF_T defaults to "long", which limits us to 4GB files on
 552 # most systems... default to "long long" instead.
 553 AC_CHECK_TYPE(off_t, [long long])
 554 AC_TYPE_SIZE_T
 555 AC_CHECK_TYPE(id_t, [unsigned long])
 556 AC_CHECK_TYPE(uintptr_t, [unsigned int])
 557
 558 # Check for tm_gmtoff in struct tm
 559 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,
 560 [
 561 #include <time.h>
 562 ])
 563
 564 # Check for f_namemax in struct statfs
 565 AC_CHECK_MEMBERS([struct statfs.f_namemax],,,
 566 [
 567 #include <sys/param.h>
 568 #include <sys/mount.h>
 569 ])
 570
 571 # Check for f_iosize in struct statfs
 572 AC_CHECK_MEMBERS([struct statfs.f_iosize],,,
 573 [
 574 #include <sys/param.h>
 575 #include <sys/mount.h>
 576 ])
 577
 578 # Check for f_iosize in struct statvfs
 579 AC_CHECK_MEMBERS([struct statvfs.f_iosize],,,
 580 [
 581 #include <sys/statvfs.h>
 582 ])
 583
 584 # Check for birthtime in struct stat
 585 AC_CHECK_MEMBERS([struct stat.st_birthtime])
 586
 587 # Check for high-resolution timestamps in struct stat
 588 AC_CHECK_MEMBERS([struct stat.st_birthtimespec.tv_nsec])
 589 AC_CHECK_MEMBERS([struct stat.st_mtimespec.tv_nsec])
 590 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec])
 591 AC_CHECK_MEMBERS([struct stat.st_mtime_n]) # AIX
 592 AC_CHECK_MEMBERS([struct stat.st_umtime]) # Tru64
 593 AC_CHECK_MEMBERS([struct stat.st_mtime_usec]) # Hurd
 594 # Check for block size support in struct stat
 595 AC_CHECK_MEMBERS([struct stat.st_blksize])
 596 # Check for st_flags in struct stat (BSD fflags)
 597 AC_CHECK_MEMBERS([struct stat.st_flags])
 598
 599 # If you have uintmax_t, we assume printf supports %ju
 600 # If you have unsigned long long, we assume printf supports %llu
 601 # TODO: Check for %ju and %llu support directly.
 602 AC_CHECK_TYPES([uintmax_t, unsigned long long])
 603
 604 # We use C99-style integer types
 605 # Declare them if the local platform doesn't already do so.
 606 AC_TYPE_INTMAX_T
 607 AC_TYPE_UINTMAX_T
 608 AC_TYPE_INT64_T
 609 AC_TYPE_UINT64_T
 610 AC_TYPE_INT32_T
 611 AC_TYPE_UINT32_T
 612 AC_TYPE_INT16_T
 613 AC_TYPE_UINT16_T
 614 AC_TYPE_UINT8_T
 615
 616 AC_CHECK_DECLS([SIZE_MAX, INT32_MAX, INT32_MIN])
 617 AC_CHECK_DECLS([INT64_MAX, INT64_MIN, UINT64_MAX, UINT32_MAX])
 618 AC_CHECK_DECLS([INTMAX_MAX, INTMAX_MIN, UINTMAX_MAX])
 619
 620 AC_CHECK_DECL([SSIZE_MAX],
 621                 [AC_DEFINE(HAVE_DECL_SSIZE_MAX, 1, [Define to 1 if you have the declaration of `SSIZE_MAX', and to 0 if you don't.])],
 622                 [],
 623                 [#include <limits.h>])
 624
 625 AC_CHECK_DECL([EFTYPE],
 626                 [AC_DEFINE(HAVE_EFTYPE, 1, [A possible errno value for invalid file format errors])],
 627                 [],
 628                 [#include <errno.h>])
 629 AC_CHECK_DECL([EILSEQ],
 630                 [AC_DEFINE(HAVE_EILSEQ, 1, [A possible errno value for invalid file format errors])],
 631                 [],
 632                 [#include <errno.h>])
 633 AC_CHECK_TYPE([wchar_t],
 634                 [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]wchar_t), 1, [Define to 1 if the system has the type `wchar_t'.])dnl
 635                 AC_CHECK_SIZEOF([wchar_t])],
 636                 [])
 637
 638 AX_COMPILE_CHECK_SIZEOF(int)
 639 AX_COMPILE_CHECK_SIZEOF(long)
 640
 641 AC_HEADER_TIME
 642
 643 # Checks for library functions.
 644 AC_PROG_GCC_TRADITIONAL
 645 AC_HEADER_MAJOR
 646 AC_FUNC_FSEEKO
 647 AC_FUNC_MEMCMP
 648 AC_FUNC_LSTAT
 649 AC_FUNC_STAT
 650 AC_FUNC_STRERROR_R
 651 AC_FUNC_STRFTIME
 652 AC_FUNC_VPRINTF
 653 # check for:
 654 #   CreateHardLinkA(LPCSTR, LPCSTR, LPSECURITY_ATTRIBUTES)
 655 # To avoid necessity for including windows.h or special forward declaration
 656 # workarounds, we use 'void *' for 'struct SECURITY_ATTRIBUTES *'
 657 AC_CHECK_STDCALL_FUNC([CreateHardLinkA],[const char *, const char *, void *])
 658 AC_CHECK_FUNCS([arc4random_buf chflags chown chroot ctime_r])
 659 AC_CHECK_FUNCS([fchdir fchflags fchmod fchown fcntl fdopendir fork])
 660 AC_CHECK_FUNCS([fstat fstatat fstatfs fstatvfs ftruncate])
 661 AC_CHECK_FUNCS([futimens futimes futimesat])
 662 AC_CHECK_FUNCS([geteuid getpid getgrgid_r getgrnam_r])
 663 AC_CHECK_FUNCS([getpwnam_r getpwuid_r getvfsbyname gmtime_r])
 664 AC_CHECK_FUNCS([lchflags lchmod lchown link linkat localtime_r lstat lutimes])
 665 AC_CHECK_FUNCS([mbrtowc memmove memset])
 666 AC_CHECK_FUNCS([mkdir mkfifo mknod mkstemp])
 667 AC_CHECK_FUNCS([nl_langinfo openat pipe poll posix_spawnp readlink readlinkat])
 668 AC_CHECK_FUNCS([readpassphrase])
 669 AC_CHECK_FUNCS([select setenv setlocale sigaction statfs statvfs])
 670 AC_CHECK_FUNCS([strchr strdup strerror strncpy_s strnlen strrchr symlink])
 671 AC_CHECK_FUNCS([timegm tzset unlinkat unsetenv utime utimensat utimes vfork])
 672 AC_CHECK_FUNCS([wcrtomb wcscmp wcscpy wcslen wctomb wmemcmp wmemcpy wmemmove])
 673 AC_CHECK_FUNCS([_ctime64_s _fseeki64])
 674 AC_CHECK_FUNCS([_get_timezone _gmtime64_s _localtime64_s _mkgmtime64])
 675 # detects cygwin-1.7, as opposed to older versions
 676 AC_CHECK_FUNCS([cygwin_conv_path])
 677
 678 # DragonFly uses vfsconf, FreeBSD xvfsconf.
 679 AC_CHECK_TYPES(struct vfsconf,,,
 680         [#if HAVE_SYS_TYPES_H
 681         #include <sys/types.h>
 682         #endif
 683         #include <sys/mount.h>
 684         ])
 685
 686 AC_CHECK_TYPES(struct xvfsconf,,,
 687         [#if HAVE_SYS_TYPES_H
 688         #include <sys/types.h>
 689         #endif
 690         #include <sys/mount.h>
 691         ])
 692
 693 AC_CHECK_TYPES(struct statfs,,,
 694         [#if HAVE_SYS_TYPES_H
 695         #include <sys/types.h>
 696         #endif
 697         #include <sys/mount.h>
 698         ])
 699
 700 # There are several variants of readdir_r around; we only
 701 # accept the POSIX-compliant version.
 702 AC_COMPILE_IFELSE(
 703  [AC_LANG_PROGRAM([[#include <dirent.h>]],
 704                   [[DIR *dir; struct dirent e, *r;
 705                     return(readdir_r(dir, &e, &r));]])],
 706  [AC_DEFINE(HAVE_READDIR_R,1,[Define to 1 if you have a POSIX compatible readdir_r])]
 707 )
 708 # dirfd can be either a function or a macro.
 709 AC_COMPILE_IFELSE(
 710  [AC_LANG_PROGRAM([[#include <dirent.h>
 711                     DIR *dir;]],
 712                   [[return(dirfd(dir));]])],
 713  [AC_DEFINE(HAVE_DIRFD,1,[Define to 1 if you have a dirfd function or macro])]
 714 )
 715
 716 # FreeBSD's nl_langinfo supports an option to specify whether the
 717 # current locale uses month/day or day/month ordering.  It makes the
 718 # output a little prettier...
 719 AC_CHECK_DECL([D_MD_ORDER],
 720 [AC_DEFINE(HAVE_D_MD_ORDER, 1, [Define to 1 if nl_langinfo supports D_MD_ORDER])],
 721 [],
 722 [#if HAVE_LANGINFO_H
 723 #include <langinfo.h>
 724 #endif
 725 ])
 726
 727 # Check for dirent.d_namlen field explicitly
 728 # (This is a bit more straightforward than, if not quite as portable as,
 729 # the recipe given by the autoconf maintainers.)
 730 AC_CHECK_MEMBER(struct dirent.d_namlen,,,
 731 [#if HAVE_DIRENT_H
 732 #include <dirent.h>
 733 #endif
 734 ])
 735
 736 # Check for Extended Attributes support
 737 AC_ARG_ENABLE([xattr],
 738                 AS_HELP_STRING([--disable-xattr],
 739                 [Disable Extended Attributes support (default: check)]))
 740
 741 if test "x$enable_xattr" != "xno"; then
 742     AC_SEARCH_LIBS([setxattr], [attr gnu])
 743     AC_CHECK_DECLS([EXTATTR_NAMESPACE_USER], [], [], [#include <sys/types.h>
 744 #include <sys/extattr.h>
 745 ])
 746     AC_CHECK_DECLS([XATTR_NOFOLLOW], [], [], [#include <sys/xattr.h>
 747 ])
 748     if test "x$ac_cv_header_sys_xattr_h" = "xyes" \
 749          -a "x$ac_cv_have_decl_XATTR_NOFOLLOW" = "xyes"; then
 750         # Darwin extended attributes support
 751         AC_CACHE_VAL([ac_cv_archive_xattr_darwin],
 752           [AC_CHECK_FUNCS(fgetxattr \
 753                           flistxattr \
 754                           fsetxattr \
 755                           getxattr \
 756                           listxattr \
 757                           setxattr,
 758           [ac_cv_archive_xattr_darwin=yes],
 759           [ac_cv_archive_xattr_darwin=no],
 760           [#include <sys/xattr.h>
 761 ])
 762         ]
 763       )
 764     elif test "x$ac_cv_header_sys_extattr_h" = "xyes" \
 765            -a "x$ac_cv_have_decl_EXTATTR_NAMESPACE_USER" = "xyes"; then
 766         # FreeBSD extended attributes support
 767         AC_CACHE_VAL([ac_cv_archive_xattr_freebsd],
 768           [AC_CHECK_FUNCS(extattr_get_fd \
 769                           extattr_get_file \
 770                           extattr_get_link \
 771                           extattr_list_fd \
 772                           extattr_list_file \
 773                           extattr_list_link \
 774                           extattr_set_fd \
 775                           extattr_set_link,
 776           [ac_cv_archive_xattr_freebsd=yes],
 777           [ac_cv_archive_xattr_freebsd=no],
 778           [#include <sys/types.h>
 779 #include <sys/extattr.h>
 780 ])
 781           ]
 782         )
 783     elif test "x$ac_cv_header_sys_xattr_h" = "xyes" \
 784            -o "x$ac_cv_header_attr_xattr_h" = "xyes"; then
 785         # Linux extended attributes support
 786         AC_CACHE_VAL([ac_cv_archive_xattr_linux],
 787           [AC_CHECK_FUNCS(fgetxattr \
 788                           flistxattr \
 789                           fsetxattr \
 790                           getxattr \
 791                           lgetxattr \
 792                           listxattr \
 793                           llistxattr \
 794                           lsetxattr,
 795           [ac_cv_archive_xattr_linux=yes],
 796           [ac_cv_archive_xattr_linux=no],
 797           [#if HAVE_SYS_TYPES_H
 798 #include <sys/types.h>
 799 #endif
 800 #if HAVE_SYS_XATTR_H
 801 #include <sys/xattr.h>
 802 #endif
 803 #if HAVE_ATTR_XATTR_H
 804 #include <attr/xatr.h>
 805 #endif
 806 ])
 807         ]
 808       )
 809     elif test "x$ac_cv_header_sys_ea_h" = "xyes"; then
 810         # AIX extended attributes support
 811         AC_CACHE_VAL([ac_cv_archive_xattr_aix],
 812           [AC_CHECK_FUNCS(fgetea \
 813                           flistea \
 814                           fsetea \
 815                           getea \
 816                           lgetea \
 817                           listea \
 818                           llistea \
 819                           lsetea,
 820           [ac_cv_archive_xattr_aix=yes],
 821           [ac_cv_archive_xattr_aix=no],
 822           [#include <sys/ea.h>
 823 ])
 824           ]
 825         )
 826     fi
 827
 828     AC_MSG_CHECKING([for extended attributes support])
 829     if test "x$ac_cv_archive_xattr_linux" = "xyes"; then
 830         AC_DEFINE([ARCHIVE_XATTR_LINUX], [1], [Linux xattr support])
 831         AC_MSG_RESULT([Linux])
 832     elif test "x$ac_cv_archive_xattr_darwin" = "xyes"; then
 833         AC_DEFINE([ARCHIVE_XATTR_DARWIN], [1], [Darwin xattr support])
 834         AC_MSG_RESULT([Darwin])
 835     elif test "x$ac_cv_archive_xattr_freebsd" = "xyes"; then
 836         AC_DEFINE([ARCHIVE_XATTR_FREEBSD], [1], [FreeBSD xattr support])
 837         AC_MSG_RESULT([FreeBSD])
 838     elif test "x$ac_cv_archive_xattr_aix" = "xyes"; then
 839         AC_DEFINE([ARCHIVE_XATTR_AIX], [1], [AIX xattr support])
 840         AC_MSG_RESULT([AIX])
 841     else
 842         AC_MSG_RESULT([none])
 843     fi
 844 fi
 845
 846 # Check for ACL support
 847 #
 848 # The ACL support in libarchive is written against the POSIX1e draft,
 849 # which was never officially approved and varies quite a bit across
 850 # platforms.  Worse, some systems have completely non-POSIX acl functions,
 851 # which makes the following checks rather more complex than I would like.
 852 #
 853 AC_ARG_ENABLE([acl],
 854                 AS_HELP_STRING([--disable-acl],
 855                 [Disable ACL support (default: check)]))
 856
 857 if test "x$enable_acl" != "xno"; then
 858     # Libacl
 859     AC_CHECK_LIB([acl], [acl_get_file])
 860
 861     AC_CHECK_TYPES([acl_t, acl_entry_t, acl_permset_t, acl_tag_t], [], [], [
 862       #if HAVE_SYS_TYPES_H
 863       #include <sys/types.h>
 864       #endif
 865       #if HAVE_SYS_ACL_H
 866       #include <sys/acl.h>
 867       #endif
 868     ])
 869
 870     AC_CHECK_LIB([richacl], [richacl_get_file])
 871
 872     AC_CHECK_TYPES([[struct richace], [struct richacl]], [], [], [
 873       #if HAVE_SYS_RICHACL_H
 874       #include <sys/richacl.h>
 875       #endif
 876     ])
 877
 878     # Solaris and derivates ACLs
 879     AC_CHECK_FUNCS(acl facl)
 880
 881     if test "x$ac_cv_lib_richacl_richacl_get_file" = "xyes" \
 882          -a "x$ac_cv_type_struct_richace" = "xyes" \
 883          -a "x$ac_cv_type_struct_richacl" = "xyes"; then
 884         AC_CACHE_VAL([ac_cv_archive_acl_librichacl],
 885           [AC_CHECK_FUNCS(richacl_alloc \
 886                           richacl_equiv_mode \
 887                           richacl_free \
 888                           richacl_get_fd \
 889                           richacl_get_file \
 890                           richacl_set_fd \
 891                           richacl_set_file,
 892           [ac_cv_archive_acl_librichacl=yes], [ac_cv_archive_acl_librichacl=no],          [#include <sys/richacl.h>])])
 893     fi
 894
 895     if test "x$ac_cv_func_acl" = "xyes" \
 896          -a "x$ac_cv_func_facl" = "xyes"; then
 897         AC_CHECK_TYPES([aclent_t], [], [], [[#include <sys/acl.h>]])
 898         if test "x$ac_cv_type_aclent_t" = "xyes"; then
 899             AC_CACHE_VAL([ac_cv_archive_acl_sunos],
 900               [AC_CHECK_DECLS([GETACL, SETACL, GETACLCNT],
 901               [ac_cv_archive_acl_sunos=yes], [ac_cv_archive_acl_sunos=no],
 902               [#include <sys/acl.h>])])
 903             AC_CHECK_TYPES([ace_t], [], [], [[#include <sys/acl.h>]])
 904             if test "x$ac_cv_type_ace_t" = "xyes"; then
 905                 AC_CACHE_VAL([ac_cv_archive_acl_sunos_nfs4],
 906                   [AC_CHECK_DECLS([ACE_GETACL, ACE_SETACL, ACE_GETACLCNT],
 907                   [ac_cv_archive_acl_sunos_nfs4=yes],
 908                   [ac_cv_archive_acl_sonos_nfs4=no],
 909                   [#include <sys/acl.h>])])
 910             fi
 911         fi
 912     elif test "x$ac_cv_type_acl_t" = "xyes" \
 913          -a "x$ac_cv_type_acl_entry_t" = "xyes" \
 914          -a "x$ac_cv_type_acl_permset_t" = "xyes" \
 915          -a "x$ac_cv_type_acl_tag_t" = "xyes"; then
 916         # POSIX.1e ACL functions
 917         AC_CACHE_VAL([ac_cv_posix_acl_funcs],
 918           [AC_CHECK_FUNCS(acl_add_perm \
 919                           acl_clear_perms \
 920                           acl_create_entry \
 921                           acl_delete_def_file \
 922                           acl_free \
 923                           acl_get_entry \
 924                           acl_get_fd \
 925                           acl_get_file \
 926                           acl_get_permset \
 927                           acl_get_qualifier \
 928                           acl_get_tag_type \
 929                           acl_init \
 930                           acl_set_fd \
 931                           acl_set_file \
 932                           acl_set_qualifier \
 933                           acl_set_tag_type,
 934           [ac_cv_posix_acl_funcs=yes], [ac_cv_posix_acl_funcs=no],
 935           [#if HAVE_SYS_TYPES_H
 936            #include <sys/types.h>
 937            #endif
 938            #if HAVE_SYS_ACL_H
 939            #include <sys/acl.h>
 940            #endif
 941           ])
 942         ])
 943
 944         AC_CHECK_FUNCS(acl_get_perm)
 945
 946         if test "x$ac_cv_posix_acl_funcs" = "xyes" \
 947              -a "x$ac_cv_header_acl_libacl_h" = "xyes" \
 948              -a "x$ac_cv_lib_acl_acl_get_file" = "xyes" \
 949              -a "x$ac_cv_func_acl_get_perm"; then
 950             AC_CACHE_VAL([ac_cv_archive_acl_libacl],
 951               [ac_cv_archive_acl_libacl=yes])
 952             AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
 953               [POSIX.1e ACL support via libacl])
 954         else
 955              # FreeBSD/Darwin
 956              AC_CHECK_FUNCS(acl_add_flag_np \
 957                             acl_clear_flags_np \
 958                             acl_get_brand_np \
 959                             acl_get_entry_type_np \
 960                             acl_get_flag_np \
 961                             acl_get_flagset_np \
 962                             acl_get_fd_np \
 963                             acl_get_link_np \
 964                             acl_get_perm_np \
 965                             acl_is_trivial_np \
 966                             acl_set_entry_type_np \
 967                             acl_set_fd_np \
 968                             acl_set_link_np,,,
 969               [#include <sys/types.h>
 970                #include <sys/acl.h>])
 971
 972             AC_CHECK_FUNCS(mbr_uid_to_uuid \
 973                            mbr_uuid_to_id \
 974                            mbr_gid_to_uuid,,,
 975               [#include <membership.h>])
 976
 977             AC_CHECK_DECLS([ACL_TYPE_EXTENDED, ACL_TYPE_NFS4, ACL_USER,
 978               ACL_SYNCHRONIZE], [], [],
 979               [#include <sys/types.h>
 980                #include <sys/acl.h>])
 981             if test "x$ac_cv_posix_acl_funcs" = "xyes" \
 982                  -a "x$ac_cv_func_acl_get_fd_np" = "xyes" \
 983                  -a "x$ac_cv_func_acl_get_perm" != "xyes" \
 984                  -a "x$ac_cv_func_acl_get_perm_np" = "xyes" \
 985                  -a "x$ac_cv_func_acl_set_fd_np" = "xyes"; then
 986                 if test "x$ac_cv_have_decl_ACL_USER" = "xyes"; then
 987                     AC_CACHE_VAL([ac_cv_archive_acl_freebsd],
 988                       [ac_cv_archive_acl_freebsd=yes])
 989                     if test "x$ac_cv_have_decl_ACL_TYPE_NFS4" = "xyes" \
 990                          -a "x$ac_cv_func_acl_add_flag_np" = "xyes" \
 991                          -a "x$ac_cv_func_acl_get_brand_np" = "xyes" \
 992                          -a "x$ac_cv_func_acl_get_entry_type_np" = "xyes" \
 993                          -a "x$ac_cv_func_acl_get_flagset_np" = "xyes" \
 994                          -a "x$ac_cv_func_acl_set_entry_type_np" = "xyes"; then
 995                         AC_CACHE_VAL([ac_cv_archive_acl_freebsd_nfs4],
 996                           [ac_cv_archive_acl_freebsd_nfs4=yes])
 997                     fi
 998                 elif test "x$ac_cv_have_decl_ACL_TYPE_EXTENDED" = "xyes" \
 999                        -a "x$ac_cv_func_acl_add_flag_np" = "xyes" \
1000                        -a "x$ac_cv_func_acl_get_flagset_np" = "xyes" \
1001                        -a "x$ac_cv_func_acl_get_link_np" = "xyes" \
1002                        -a "x$ac_cv_func_acl_set_link_np" = "xyes" \
1003                        -a "x$ac_cv_func_mbr_uid_to_uuid" = "xyes" \
1004                        -a "x$ac_cv_func_mbr_uuid_to_id" = "xyes" \
1005                        -a "x$ac_cv_func_mbr_gid_to_uuid" = "xyes"; then
1006                     AC_CACHE_VAL([ac_cv_archive_acl_darwin],
1007                       [ac_cv_archive_acl_darwin=yes])
1008                 fi
1009             fi
1010         fi
1011     fi
1012     AC_MSG_CHECKING([for ACL support])
1013     if test "x$ac_cv_archive_acl_libacl" = "xyes" \
1014          -a "x$ac_cv_archive_acl_librichacl" = "xyes"; then
1015         AC_MSG_RESULT([libacl (POSIX.1e) + librichacl (NFSv4)])
1016         AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
1017           [Linux POSIX.1e ACL support via libacl])
1018         AC_DEFINE([ARCHIVE_ACL_LIBRICHACL], [1],
1019           [Linux NFSv4 ACL support via librichacl])
1020     elif test "x$ac_cv_archive_acl_libacl" = "xyes"; then
1021         AC_MSG_RESULT([libacl (POSIX.1e)])
1022         AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
1023           [Linux POSIX.1e ACL support via libacl])
1024     elif test "x$ac_cv_archive_acl_librichacl" = "xyes"; then
1025         AC_MSG_RESULT([librichacl (NFSv4)])
1026         AC_DEFINE([ARCHIVE_ACL_LIBRICHACL], [1],
1027           [Linux NFSv4 ACL support via librichacl])
1028     elif test "x$ac_cv_archive_acl_darwin" = "xyes"; then
1029         AC_DEFINE([ARCHIVE_ACL_DARWIN], [1], [Darwin ACL support])
1030         AC_MSG_RESULT([Darwin (limited NFSv4)])
1031     elif test "x$ac_cv_archive_acl_sunos" = "xyes"; then
1032         AC_DEFINE([ARCHIVE_ACL_SUNOS], [1], [Solaris ACL support])
1033         if test "x$ac_cv_archive_acl_sunos_nfs4" = "xyes"; then
1034             AC_DEFINE([ARCHIVE_ACL_SUNOS_NFS4], [1],
1035               [Solaris NFSv4 ACL support])
1036             AC_MSG_RESULT([Solaris (POSIX.1e and NFSv4)])
1037         else
1038             AC_MSG_RESULT([Solaris (POSIX.1e)])
1039         fi
1040     elif test "x$ac_cv_archive_acl_freebsd" = "xyes"; then
1041         AC_DEFINE([ARCHIVE_ACL_FREEBSD], [1], [FreeBSD ACL support])
1042         if test "x$ac_cv_archive_acl_freebsd_nfs4" = "xyes"; then
1043             AC_DEFINE([ARCHIVE_ACL_FREEBSD_NFS4], [1],
1044               [FreeBSD NFSv4 ACL support])
1045             AC_MSG_RESULT([FreeBSD (POSIX.1e and NFSv4)])
1046         else
1047             AC_MSG_RESULT([FreeBSD (POSIX.1e)])
1048         fi
1049     else
1050         AC_MSG_RESULT([none])
1051     fi
1052 fi
1053
1054
1055 AM_CONDITIONAL([INC_LINUX_ACL],
1056   [test "x$ac_cv_archive_acl_libacl" = "xyes" \
1057      -o "x$ac_cv_archive_acl_librichacl" = "xyes"])
1058 AM_CONDITIONAL([INC_SUNOS_ACL], [test "x$ac_cv_archive_acl_sunos" = "xyes"])
1059 AM_CONDITIONAL([INC_DARWIN_ACL],
1060           [test "x$ac_cv_archive_acl_darwin" = "xyes"])
1061 AM_CONDITIONAL([INC_FREEBSD_ACL],
1062           [test "x$ac_cv_archive_acl_freebsd" = "xyes"])
1063
1064 # Additional requirements
1065 AC_SYS_LARGEFILE
1066
1067 dnl NOTE: Crypto checks must run last.
1068 AC_DEFUN([CRYPTO_CHECK], [
1069   if test "$found_$1" != yes; then
1070     saved_CPPFLAGS="$CPPFLAGS"
1071     CPPFLAGS="$CPPFLAGS -I. -I$srcdir -I$srcdir/libarchive"
1072     touch "check_crypto_md.h"
1073     AC_MSG_CHECKING([support for ARCHIVE_CRYPTO_$1_$2])
1074     AC_LINK_IFELSE([AC_LANG_SOURCE([
1075 #define ARCHIVE_$1_COMPILE_TEST
1076 #define ARCHIVE_CRYPTO_$1_$2
1077 #define PLATFORM_CONFIG_H "check_crypto_md.h"
1078
1079 $(cat "$srcdir/libarchive/archive_digest.c")
1080
1081 int
1082 main(int argc, char **argv)
1083 {
1084   archive_$3_ctx ctx;
1085   archive_$3_init(&ctx);
1086   archive_$3_update(&ctx, *argv, argc);
1087   archive_$3_final(&ctx, NULL);
1088   return 0;
1089 }
1090 ])],
1091     [ AC_MSG_RESULT([yes])
1092       found_$1=yes
1093       found_$2=yes
1094       AC_DEFINE(ARCHIVE_CRYPTO_$1_$2, 1, [ $1 via ARCHIVE_CRYPTO_$1_$2 supported.])
1095     ],
1096     [ AC_MSG_RESULT([no])])
1097     CPPFLAGS="$saved_CPPFLAGS"
1098     rm "check_crypto_md.h"
1099   fi
1100 ])
1101
1102 AC_DEFUN([CRYPTO_CHECK_WIN], [
1103   if test "$found_$1" != yes; then
1104     AC_MSG_CHECKING([support for ARCHIVE_CRYPTO_$1_WIN])
1105     AC_LINK_IFELSE([AC_LANG_SOURCE([
1106 #define ARCHIVE_$1_COMPILE_TEST
1107 #include <windows.h>
1108 #include <wincrypt.h>
1109
1110 int
1111 main(int argc, char **argv)
1112 {
1113         (void)argc;
1114         (void)argv;
1115
1116         return ($2);
1117 }
1118 ])],
1119     [ AC_MSG_RESULT([yes])
1120       found_$1=yes
1121       found_WIN=yes
1122       AC_DEFINE(ARCHIVE_CRYPTO_$1_WIN, 1, [ $1 via ARCHIVE_CRYPTO_$1_WIN supported.])
1123     ],
1124     [ AC_MSG_RESULT([no])])
1125   fi
1126 ])
1127
1128 case "$host_os" in
1129   *mingw* | *cygwin* | *msys*)
1130         ;;
1131   *)
1132         CRYPTO_CHECK(MD5, LIBC, md5)
1133         CRYPTO_CHECK(MD5, LIBSYSTEM, md5)
1134         CRYPTO_CHECK(RMD160, LIBC, rmd160)
1135         CRYPTO_CHECK(SHA1, LIBC, sha1)
1136         CRYPTO_CHECK(SHA1, LIBSYSTEM, sha1)
1137         CRYPTO_CHECK(SHA256, LIBC, sha256)
1138         CRYPTO_CHECK(SHA256, LIBC2, sha256)
1139         CRYPTO_CHECK(SHA256, LIBC3, sha256)
1140         CRYPTO_CHECK(SHA256, LIBSYSTEM, sha256)
1141         CRYPTO_CHECK(SHA384, LIBC, sha384)
1142         CRYPTO_CHECK(SHA384, LIBC2, sha384)
1143         CRYPTO_CHECK(SHA384, LIBC3, sha384)
1144         CRYPTO_CHECK(SHA384, LIBSYSTEM, sha384)
1145         CRYPTO_CHECK(SHA512, LIBC, sha512)
1146         CRYPTO_CHECK(SHA512, LIBC2, sha512)
1147         CRYPTO_CHECK(SHA512, LIBC3, sha512)
1148         CRYPTO_CHECK(SHA512, LIBSYSTEM, sha512)
1149         ;;
1150 esac
1151
1152 if test "x$with_cng" != "xno"; then
1153     AC_CHECK_HEADERS([bcrypt.h],[
1154         LIBS="$LIBS -lbcrypt"
1155     ],[],
1156     [[#ifdef HAVE_WINDOWS_H
1157     # include <windows.h>
1158     #endif
1159     ]])
1160 fi
1161
1162 if test "x$with_mbedtls" = "xyes"; then
1163     AC_CHECK_HEADERS([mbedtls/aes.h mbedtls/md.h mbedtls/pkcs5.h])
1164     saved_LIBS=$LIBS
1165     AC_CHECK_LIB(mbedcrypto,mbedtls_sha1_init)
1166     CRYPTO_CHECK(MD5, MBEDTLS, md5)
1167     CRYPTO_CHECK(RMD160, MBEDTLS, rmd160)
1168     CRYPTO_CHECK(SHA1, MBEDTLS, sha1)
1169     CRYPTO_CHECK(SHA256, MBEDTLS, sha256)
1170     CRYPTO_CHECK(SHA384, MBEDTLS, sha384)
1171     CRYPTO_CHECK(SHA512, MBEDTLS, sha512)
1172     if test "x$found_MBEDTLS" != "xyes"; then
1173       LIBS=$saved_LIBS
1174     fi
1175 fi
1176
1177 if test "x$with_nettle" = "xyes"; then
1178     AC_CHECK_HEADERS([nettle/md5.h nettle/ripemd160.h nettle/sha.h])
1179     AC_CHECK_HEADERS([nettle/pbkdf2.h nettle/aes.h nettle/hmac.h])
1180     saved_LIBS=$LIBS
1181     AC_CHECK_LIB(nettle,nettle_sha1_init)
1182     CRYPTO_CHECK(MD5, NETTLE, md5)
1183     CRYPTO_CHECK(RMD160, NETTLE, rmd160)
1184     CRYPTO_CHECK(SHA1, NETTLE, sha1)
1185     CRYPTO_CHECK(SHA256, NETTLE, sha256)
1186     CRYPTO_CHECK(SHA384, NETTLE, sha384)
1187     CRYPTO_CHECK(SHA512, NETTLE, sha512)
1188     if test "x$found_NETTLE" != "xyes"; then
1189       LIBS=$saved_LIBS
1190     fi
1191 fi
1192
1193 if test "x$with_openssl" != "xno"; then
1194     AC_CHECK_HEADERS([openssl/evp.h])
1195     saved_LIBS=$LIBS
1196     case "$host_os" in
1197       *mingw* | *cygwin* | *msys*)
1198         case "$host_cpu" in
1199           x86_64)
1200             AC_CHECK_LIB(eay64,OPENSSL_config)
1201             if test "x$ac_cv_lib_eay64_main" != "xyes"; then
1202               AC_CHECK_LIB(eay32,OPENSSL_config)
1203             fi
1204             ;;
1205           *)
1206             AC_CHECK_LIB(eay32,OPENSSL_config)
1207             ;;
1208         esac
1209         ;;
1210       *)
1211         AC_CHECK_LIB(crypto,OPENSSL_config)
1212         ;;
1213     esac
1214     CRYPTO_CHECK(MD5, OPENSSL, md5)
1215     CRYPTO_CHECK(RMD160, OPENSSL, rmd160)
1216     CRYPTO_CHECK(SHA1, OPENSSL, sha1)
1217     CRYPTO_CHECK(SHA256, OPENSSL, sha256)
1218     CRYPTO_CHECK(SHA384, OPENSSL, sha384)
1219     CRYPTO_CHECK(SHA512, OPENSSL, sha512)
1220     AC_CHECK_FUNCS([PKCS5_PBKDF2_HMAC_SHA1])
1221 fi
1222
1223 # Probe libmd AFTER OpenSSL/libcrypto.
1224 # The two are incompatible and OpenSSL is more complete.
1225 AC_CHECK_HEADERS([md5.h ripemd.h sha.h sha256.h sha512.h])
1226 saved_LIBS=$LIBS
1227 AC_CHECK_LIB(md,MD5Init)
1228 CRYPTO_CHECK(MD5, LIBMD, md5)
1229 CRYPTO_CHECK(RMD160, LIBMD, rmd160)
1230 CRYPTO_CHECK(SHA1, LIBMD, sha1)
1231 CRYPTO_CHECK(SHA256, LIBMD, sha256)
1232 CRYPTO_CHECK(SHA512, LIBMD, sha512)
1233 if test "x$found_LIBMD" != "xyes"; then
1234   LIBS=$saved_LIBS
1235 fi
1236
1237 case "$host_os" in
1238   *mingw* | *cygwin* | *msys*)
1239         CRYPTO_CHECK_WIN(MD5, CALG_MD5)
1240         CRYPTO_CHECK_WIN(SHA1, CALG_SHA1)
1241         CRYPTO_CHECK_WIN(SHA256, CALG_SHA_256)
1242         CRYPTO_CHECK_WIN(SHA384, CALG_SHA_384)
1243         CRYPTO_CHECK_WIN(SHA512, CALG_SHA_512)
1244         ;;
1245 esac
1246
1247 # Ensure test directories are present if building out-of-tree
1248 AC_CONFIG_COMMANDS([mkdirs],
1249                    [mkdir -p libarchive/test tar/test cat/test cpio/test])
1250
1251 AC_OUTPUT