configure.ac

   1
   2 AC_INIT([iptables], [1.4.20])
   3
   4 # See libtool.info "Libtool's versioning system"
   5 libxtables_vcurrent=10
   6 libxtables_vage=0
   7
   8 AC_CONFIG_AUX_DIR([build-aux])
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_PROG_INSTALL
  12 AM_INIT_AUTOMAKE([-Wall])
  13 AC_PROG_CC
  14 AM_PROG_CC_C_O
  15 AC_DISABLE_STATIC
  16 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  17 AM_PROG_LIBTOOL
  18
  19 AC_ARG_WITH([kernel],
  20         AS_HELP_STRING([--with-kernel=PATH],
  21         [Path to kernel source/build directory]),
  22         [kbuilddir="$withval"; ksourcedir="$withval";])
  23 AC_ARG_WITH([kbuild],
  24         AS_HELP_STRING([--with-kbuild=PATH],
  25         [Path to kernel build directory [[/lib/modules/CURRENT/build]]]),
  26         [kbuilddir="$withval"])
  27 AC_ARG_WITH([ksource],
  28         AS_HELP_STRING([--with-ksource=PATH],
  29         [Path to kernel source directory [[/lib/modules/CURRENT/source]]]),
  30         [ksourcedir="$withval"])
  31 AC_ARG_WITH([xtlibdir],
  32         AS_HELP_STRING([--with-xtlibdir=PATH],
  33         [Path where to install Xtables extensions [[LIBEXECDIR/xtables]]]),
  34         [xtlibdir="$withval"],
  35         [xtlibdir="${libdir}/xtables"])
  36 AC_ARG_ENABLE([ipv4],
  37         AS_HELP_STRING([--disable-ipv4], [Do not build iptables]),
  38         [enable_ipv4="$enableval"], [enable_ipv4="yes"])
  39 AC_ARG_ENABLE([ipv6],
  40         AS_HELP_STRING([--disable-ipv6], [Do not build ip6tables]),
  41         [enable_ipv6="$enableval"], [enable_ipv6="yes"])
  42 AC_ARG_ENABLE([largefile],
  43         AS_HELP_STRING([--disable-largefile], [Do not build largefile support]),
  44         [enable_largefile="$enableval"],
  45         [enable_largefile="yes";
  46         largefile_cppflags='-D_LARGEFILE_SOURCE=1 -D_LARGE_FILES -D_FILE_OFFSET_BITS=64'])
  47 AC_ARG_ENABLE([devel],
  48         AS_HELP_STRING([--enable-devel],
  49         [Install Xtables development headers]),
  50         [enable_devel="$enableval"], [enable_devel="yes"])
  51 AC_ARG_ENABLE([libipq],
  52         AS_HELP_STRING([--enable-libipq], [Build and install libipq]),
  53         [enable_libipq="$enableval"], [enable_libipq="no"])
  54 AC_ARG_ENABLE([bpf-compiler],
  55         AS_HELP_STRING([--enable-bpf-compiler], [Build bpf compiler]),
  56         [enable_bpfc="yes"], [enable_bpfc="no"])
  57 AC_ARG_WITH([pkgconfigdir], AS_HELP_STRING([--with-pkgconfigdir=PATH],
  58         [Path to the pkgconfig directory [[LIBDIR/pkgconfig]]]),
  59         [pkgconfigdir="$withval"], [pkgconfigdir='${libdir}/pkgconfig'])
  60
  61 libiptc_LDFLAGS2="";
  62 AX_CHECK_LINKER_FLAGS([-Wl,--no-as-needed],
  63         [libiptc_LDFLAGS2="-Wl,--no-as-needed"])
  64 AC_SUBST([libiptc_LDFLAGS2])
  65
  66 AC_MSG_CHECKING([whether $LD knows -Wl,--no-undefined])
  67 saved_LDFLAGS="$LDFLAGS";
  68 LDFLAGS="-Wl,--no-undefined";
  69 AC_LINK_IFELSE([AC_LANG_SOURCE([int main(void) {}])],
  70         [noundef_LDFLAGS="$LDFLAGS"; AC_MSG_RESULT([yes])],
  71         [AC_MSG_RESULT([no])]
  72 )
  73 LDFLAGS="$saved_LDFLAGS";
  74
  75 blacklist_modules="";
  76
  77 AC_CHECK_HEADERS([linux/dccp.h linux/ip_vs.h linux/magic.h linux/proc_fs.h])
  78 if test "$ac_cv_header_linux_dccp_h" != "yes"; then
  79         blacklist_modules="$blacklist_modules dccp";
  80 fi;
  81 if test "$ac_cv_header_linux_ip_vs_h" != "yes"; then
  82         blacklist_modules="$blacklist_modules ipvs";
  83 fi;
  84
  85 PKG_CHECK_MODULES([libnetfilter_conntrack], [libnetfilter_conntrack >= 1.0.4],
  86         [nfconntrack=1], [nfconntrack=0])
  87 AM_CONDITIONAL([HAVE_LIBNETFILTER_CONNTRACK], [test "$nfconntrack" = 1])
  88
  89 if test "$nfconntrack" -ne 1; then
  90         blacklist_modules="$blacklist_modules connlabel";
  91         echo "WARNING: libnetfilter_conntrack not found, connlabel match will not be built";
  92 fi;
  93
  94 AC_SUBST([blacklist_modules])
  95 AC_CHECK_SIZEOF([struct ip6_hdr], [], [#include <netinet/ip6.h>])
  96
  97 AM_CONDITIONAL([ENABLE_STATIC], [test "$enable_static" = "yes"])
  98 AM_CONDITIONAL([ENABLE_SHARED], [test "$enable_shared" = "yes"])
  99 AM_CONDITIONAL([ENABLE_IPV4], [test "$enable_ipv4" = "yes"])
 100 AM_CONDITIONAL([ENABLE_IPV6], [test "$enable_ipv6" = "yes"])
 101 AM_CONDITIONAL([ENABLE_LARGEFILE], [test "$enable_largefile" = "yes"])
 102 AM_CONDITIONAL([ENABLE_DEVEL], [test "$enable_devel" = "yes"])
 103 AM_CONDITIONAL([ENABLE_LIBIPQ], [test "$enable_libipq" = "yes"])
 104 AM_CONDITIONAL([ENABLE_BPFC], [test "$enable_bpfc" = "yes"])
 105
 106 if test "x$enable_bpfc" = "xyes"; then
 107         AC_CHECK_LIB(pcap, pcap_compile,, AC_MSG_ERROR(missing libpcap library required by bpf compiler))
 108 fi
 109
 110 PKG_CHECK_MODULES([libnfnetlink], [libnfnetlink >= 1.0],
 111         [nfnetlink=1], [nfnetlink=0])
 112 AM_CONDITIONAL([HAVE_LIBNFNETLINK], [test "$nfnetlink" = 1])
 113
 114 regular_CFLAGS="-Wall -Waggregate-return -Wmissing-declarations \
 115         -Wmissing-prototypes -Wredundant-decls -Wshadow -Wstrict-prototypes \
 116         -Winline -pipe";
 117 regular_CPPFLAGS="${largefile_cppflags} -D_REENTRANT \
 118         -DXTABLES_LIBDIR=\\\"\${xtlibdir}\\\" -DXTABLES_INTERNAL";
 119 kinclude_CPPFLAGS="";
 120 if [[ -n "$kbuilddir" ]]; then
 121         kinclude_CPPFLAGS="$kinclude_CPPFLAGS -I$kbuilddir/include/uapi -I$kbuilddir/include";
 122 fi;
 123 if [[ -n "$ksourcedir" ]]; then
 124         kinclude_CPPFLAGS="$kinclude_CPPFLAGS -I$ksourcedir/include/uapi -I$ksourcedir/include";
 125 fi;
 126 pkgdatadir='${datadir}/xtables';
 127
 128 define([EXPAND_VARIABLE],
 129 [$2=[$]$1
 130 if test $prefix = 'NONE'; then
 131         prefix="/usr/local"
 132 fi
 133 while true; do
 134   case "[$]$2" in
 135     *\[$]* ) eval "$2=[$]$2" ;;
 136     *) break ;;
 137   esac
 138 done
 139 eval "$2=[$]$2"
 140 ])dnl EXPAND_VARIABLE
 141
 142 AC_SUBST([regular_CFLAGS])
 143 AC_SUBST([regular_CPPFLAGS])
 144 AC_SUBST([noundef_LDFLAGS])
 145 AC_SUBST([kinclude_CPPFLAGS])
 146 AC_SUBST([kbuilddir])
 147 AC_SUBST([ksourcedir])
 148 AC_SUBST([xtlibdir])
 149 AC_SUBST([pkgconfigdir])
 150 AC_SUBST([pkgdatadir])
 151 AC_SUBST([libxtables_vcurrent])
 152 AC_SUBST([libxtables_vage])
 153 libxtables_vmajor=$(($libxtables_vcurrent - $libxtables_vage));
 154 AC_SUBST([libxtables_vmajor])
 155
 156 AC_CONFIG_FILES([Makefile extensions/GNUmakefile include/Makefile
 157         iptables/Makefile iptables/xtables.pc
 158         iptables/iptables.8 iptables/iptables-extensions.8.tmpl
 159         libipq/Makefile libipq/libipq.pc
 160         libiptc/Makefile libiptc/libiptc.pc
 161         libiptc/libip4tc.pc libiptc/libip6tc.pc
 162         libxtables/Makefile utils/Makefile
 163         include/xtables-version.h include/iptables/internal.h])
 164 AC_OUTPUT
 165
 166
 167 EXPAND_VARIABLE(xtlibdir, e_xtlibdir)
 168 EXPAND_VARIABLE(pkgconfigdir, e_pkgconfigdir)
 169
 170 echo "
 171 Iptables Configuration:
 172   IPv4 support:                         ${enable_ipv4}
 173   IPv6 support:                         ${enable_ipv6}
 174   Devel support:                        ${enable_devel}
 175   IPQ support:                          ${enable_libipq}
 176   Large file support:                   ${enable_largefile}
 177   BPF utils support:                    ${enable_bpfc}
 178
 179 Build parameters:
 180   Put plugins into executable (static): ${enable_static}
 181   Support plugins via dlopen (shared):  ${enable_shared}
 182   Installation prefix (--prefix):       ${prefix}
 183   Xtables extension directory:          ${e_xtlibdir}
 184   Pkg-config directory:                 ${e_pkgconfigdir}"
 185
 186 if [[ -n "$ksourcedir" ]]; then
 187         echo "  Kernel source directory:                ${ksourcedir}"
 188 fi;
 189 if [[ -n "$kbuilddir" ]]; then
 190         echo "  Kernel build directory:         ${kbuilddir}"
 191 fi;
 192
 193 echo "  Host:                                   ${host}
 194   GCC binary:                           ${CC}"
 195
 196 test x"$blacklist_modules" = "x" || echo "
 197 Iptables modules that will not be built: $blacklist_modules"