configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [233],
  24         [https://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [https://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=systemd
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96
  97 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  98 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  99
 100 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 101
 102 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 103
 104 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 105
 106 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 107
 108 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 109 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 110
 111 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 112
 113 M4_DEFINES=
 114
 115 AC_CHECK_TOOL(OBJCOPY, objcopy)
 116 AC_CHECK_TOOL(STRINGS, strings)
 117 AC_CHECK_TOOL(GPERF, gperf)
 118 if test -z "$GPERF" ; then
 119         AC_MSG_ERROR([*** gperf not found])
 120 fi
 121
 122 # ------------------------------------------------------------------------------
 123 address_sanitizer_cflags=
 124 address_sanitizer_cppflags=
 125 address_sanitizer_ldflags=
 126 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 127 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 128             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 129             AS_IF([test -z "$with_as_cflags"],
 130                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 131             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 132             address_sanitizer_cppflags="-DVALGRIND=1"
 133             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 134       ])
 135
 136 undefined_sanitizer_cflags=
 137 undefined_sanitizer_cppflags=
 138 undefined_sanitizer_ldflags=
 139 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 140 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 141             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 142             AS_IF([test -z "$with_us_cflags"],
 143                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 144             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 145             undefined_sanitizer_cppflags="-DVALGRIND=1"
 146             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 147       ])
 148
 149 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 150 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 151 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 152
 153 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 154         -pipe \
 155         -Wall \
 156         -Wextra \
 157         -Wundef \
 158         -Wlogical-op \
 159         -Wmissing-include-dirs \
 160         -Wold-style-definition \
 161         -Wpointer-arith \
 162         -Winit-self \
 163         -Wdeclaration-after-statement \
 164         -Wfloat-equal \
 165         -Wsuggest-attribute=noreturn \
 166         -Werror=missing-prototypes \
 167         -Werror=implicit-function-declaration \
 168         -Werror=missing-declarations \
 169         -Werror=return-type \
 170         -Werror=format=2 \
 171         -Wstrict-prototypes \
 172         -Wredundant-decls \
 173         -Wmissing-noreturn \
 174         -Wshadow \
 175         -Wendif-labels \
 176         -Wstrict-aliasing=2 \
 177         -Wwrite-strings \
 178         -Wno-unused-parameter \
 179         -Wno-missing-field-initializers \
 180         -Wno-unused-result \
 181         -Wno-format-signedness \
 182         -Werror=overflow \
 183         -Wdate-time \
 184         -Wnested-externs \
 185         -ffast-math \
 186         -fno-common \
 187         -fdiagnostics-show-option \
 188         -fno-strict-aliasing \
 189         -fvisibility=hidden \
 190         -fstack-protector \
 191         -fstack-protector-strong \
 192         -fPIE \
 193         --param=ssp-buffer-size=4])
 194
 195 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
 196 #include <time.h>
 197 #include <inttypes.h>
 198 typedef uint64_t usec_t;
 199 usec_t now(clockid_t clock);
 200 int main(void) {
 201         struct timespec now;
 202         return 0;
 203 }
 204 ])
 205
 206 AS_CASE([$CC], [*clang*],
 207         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 208                -Wno-typedef-redefinition \
 209                -Wno-gnu-variable-sized-type-not-at-end \
 210         ])])
 211
 212 AC_ARG_ENABLE([lto], [AS_HELP_STRING([--disable-lto], [disable -flto])],
 213                      [], [enable_lto=yes])
 214 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 215         [AS_IF([test "x$enable_lto" = "xyes"],
 216                [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-flto])],
 217                [AC_MSG_RESULT([disabling -flto as requested])])],
 218         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 219
 220 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 221         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 222                -Wp,-D_FORTIFY_SOURCE=2])],
 223         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 224
 225 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 226         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 227                -Wl,--gc-sections])],
 228         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 229
 230 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 231         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 232                -ffunction-sections -fdata-sections])],
 233         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 234
 235 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 236         -Wl,--as-needed \
 237         -Wl,--no-undefined \
 238         -Wl,-z,relro \
 239         -Wl,-z,now \
 240         -pie \
 241         -Wl,-fuse-ld=gold])
 242
 243 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 244 AC_SUBST([OUR_CFLAGS], "-D__SANE_USERSPACE_TYPES__ $with_cflags $sanitizer_cflags")
 245 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 246
 247 AC_CHECK_SIZEOF(pid_t)
 248 AC_CHECK_SIZEOF(uid_t)
 249 AC_CHECK_SIZEOF(gid_t)
 250 AC_CHECK_SIZEOF(time_t)
 251 AC_CHECK_SIZEOF(dev_t)
 252 AC_CHECK_SIZEOF(ino_t)
 253 AC_CHECK_SIZEOF(rlim_t,,[
 254        #include <sys/time.h>
 255        #include <sys/resource.h>
 256 ])
 257
 258 GPERF_TEST="$(echo foo,bar | ${GPERF} -L ANSI-C)"
 259
 260 AC_COMPILE_IFELSE(
 261         [AC_LANG_PROGRAM([
 262                 #include <string.h>
 263                 const char * in_word_set(const char *, size_t);
 264                 $GPERF_TEST]
 265         )],
 266         [GPERF_LEN_TYPE=size_t],
 267         [AC_COMPILE_IFELSE(
 268                 [AC_LANG_PROGRAM([
 269                         #include <string.h>
 270                         const char * in_word_set(const char *, unsigned);
 271                         $GPERF_TEST]
 272                 )],
 273                 [GPERF_LEN_TYPE=unsigned],
 274                 [AC_MSG_ERROR([** unable to determine gperf len type])]
 275         )]
 276 )
 277
 278 AC_DEFINE_UNQUOTED([GPERF_LEN_TYPE], [$GPERF_LEN_TYPE], [gperf len type])
 279
 280 # ------------------------------------------------------------------------------
 281 # we use python to build the man page index
 282 have_python=no
 283 AC_ARG_WITH([python],
 284         [AS_HELP_STRING([--without-python], [disable building the man page index and systemd-python (default: test)])])
 285
 286 have_lxml=no
 287 AS_IF([test "x$with_python" != "xno"], [
 288         AM_PATH_PYTHON([3],, [:])
 289         AS_IF([test "x$PYTHON" != "x:"], [
 290                 AC_MSG_CHECKING([for python lxml module])
 291                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 292                 AC_MSG_RESULT([$have_lxml])
 293                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 294                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 295         ])
 296 ])
 297 AS_IF([test "$have_python" != "yes"], [
 298       AS_IF([test "$with_python" = "yes"],
 299             [AC_MSG_ERROR([*** python support requested but python support not found])])
 300       AS_IF([test "$with_python" != "no"],
 301             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 302 ])
 303 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 304
 305 # ------------------------------------------------------------------------------
 306
 307 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 308 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 309 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 310 AC_CHECK_HEADERS([linux/vm_sockets.h], [], [], [#include <sys/socket.h>])
 311
 312 # unconditionally pull-in librt with old glibc versions
 313 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 314
 315 save_LIBS="$LIBS"
 316 LIBS=
 317 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 318 CAP_LIBS="$LIBS"
 319 LIBS="$save_LIBS"
 320 AC_SUBST(CAP_LIBS)
 321
 322 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 323 AC_CHECK_DECLS([
 324         memfd_create,
 325         gettid,
 326         pivot_root,
 327         name_to_handle_at,
 328         setns,
 329         getrandom,
 330         renameat2,
 331         kcmp,
 332         keyctl,
 333         LO_FLAGS_PARTSCAN,
 334         copy_file_range,
 335         explicit_bzero],
 336         [], [], [[
 337 #include <sys/types.h>
 338 #include <unistd.h>
 339 #include <sys/mount.h>
 340 #include <fcntl.h>
 341 #include <sched.h>
 342 #include <string.h>
 343 #include <linux/loop.h>
 344 #include <linux/random.h>
 345 ]])
 346
 347 AC_CHECK_TYPES([char16_t, char32_t, key_serial_t, struct ethtool_link_settings],
 348                [], [], [[
 349 #include <uchar.h>
 350 #include <linux/ethtool.h>
 351 ]])
 352
 353 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 354                 IN6_ADDR_GEN_MODE_STABLE_PRIVACY,
 355                 IFLA_VRF_TABLE,
 356                 IFLA_MACVLAN_FLAGS,
 357                 IFLA_IPVLAN_MODE,
 358                 IFLA_VTI_REMOTE,
 359                 IFLA_PHYS_PORT_ID,
 360                 IFLA_BOND_AD_INFO,
 361                 IFLA_VLAN_PROTOCOL,
 362                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 363                 IFLA_IPTUN_ENCAP_DPORT,
 364                 IFLA_GRE_ENCAP_DPORT,
 365                 IFLA_BRIDGE_VLAN_INFO,
 366                 IFLA_BRPORT_PROXYARP,
 367                 IFLA_BRPORT_LEARNING_SYNC,
 368                 IFLA_BR_VLAN_DEFAULT_PVID,
 369                 NDA_IFINDEX,
 370                 IFA_FLAGS],
 371 [], [], [[
 372 #include <inttypes.h>
 373 #include <netinet/in.h>
 374 #include <netinet/ether.h>
 375 #include <linux/rtnetlink.h>
 376 #include <net/if.h>
 377 #include <linux/ip.h>
 378 #include <linux/if_tunnel.h>
 379 #include <linux/if_link.h>
 380 #include <linux/if_bridge.h>
 381 #include <linux/if_addr.h>
 382 #include <linux/neighbour.h>
 383 ]])
 384
 385 # This makes sure pkg.m4 is available.
 386 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 387
 388 # ------------------------------------------------------------------------------
 389 have_dbus=no
 390 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 391 AS_IF([test "x$enable_dbus" != "xno"], [
 392         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 393                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 394                 [have_dbus=no])
 395         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 396                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 397 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 398
 399 # ------------------------------------------------------------------------------
 400 have_utmp=yes
 401 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 402         AS_CASE("x${enableval}",
 403                 [xyes], [have_utmp=yes],
 404                 [xno],  [have_utmp=no],
 405                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 406 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 407 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 408
 409 # ------------------------------------------------------------------------------
 410 have_coverage=no
 411 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 412 if test "x$enable_coverage" = "xyes" ; then
 413         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 414         if test "x$lcov_found" = xno ; then
 415                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 416         else
 417                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 418                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 419                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 420                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 421                 else
 422                         have_coverage=yes
 423                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 424                         -fprofile-arcs \
 425                         -ftest-coverage])
 426                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 427                 fi
 428         fi
 429 fi
 430 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 431
 432 # ------------------------------------------------------------------------------
 433 have_kmod=no
 434 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 435 if test "x$enable_kmod" != "xno"; then
 436         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 437         if test "x$have_kmod" = "xyes"; then
 438                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 439                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 440                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 441         fi
 442         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 443                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 444         fi
 445 fi
 446 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 447
 448 # ------------------------------------------------------------------------------
 449 have_xkbcommon=no
 450 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 451 if test "x$enable_xkbcommon" != "xno"; then
 452         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 453                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 454         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 455                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 456         fi
 457 fi
 458 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 459
 460 # ------------------------------------------------------------------------------
 461 have_blkid=no
 462 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 463 if test "x$enable_blkid" != "xno"; then
 464         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 465                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 466         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 467                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 468         fi
 469 fi
 470 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 471
 472 # ------------------------------------------------------------------------------
 473 have_libmount=no
 474 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.27 ],
 475         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 476 if test "x$have_libmount" = xno; then
 477         AC_MSG_ERROR([*** libmount support required but libraries not found])
 478 fi
 479 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 480
 481 # ------------------------------------------------------------------------------
 482 have_seccomp=no
 483 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [disable optional SECCOMP support]))
 484 if test "x$enable_seccomp" != "xno"; then
 485         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 2.3.1],
 486                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 487                 have_seccomp=yes
 488                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 489                [have_seccomp=no])
 490         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 491                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 492         fi
 493 fi
 494 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 495
 496 # ------------------------------------------------------------------------------
 497 have_ima=yes
 498 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima], [disable optional IMA support]),
 499                 [case "${enableval}" in
 500                         yes) have_ima=yes ;;
 501                         no) have_ima=no ;;
 502                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 503                 esac],
 504                 [have_ima=yes])
 505
 506 if test "x${have_ima}" != xno ; then
 507         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 508 fi
 509
 510 # ------------------------------------------------------------------------------
 511 have_selinux=no
 512 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [disable optional SELINUX support]))
 513 if test "x$enable_selinux" != "xno"; then
 514         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 515                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 516                  have_selinux=yes
 517                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 518                 [have_selinux=no])
 519         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 520                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 521         fi
 522 fi
 523 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 524
 525 have_apparmor=no
 526 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [disable optional AppArmor support]))
 527 if test "x$enable_apparmor" != "xno"; then
 528         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 529                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 530                  have_apparmor=yes
 531                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 532                 [have_apparmor=no])
 533         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 534                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 535         fi
 536 fi
 537 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 538
 539 have_adm_group=no
 540 AC_ARG_ENABLE(adm-group, AS_HELP_STRING([--disable-adm-group], [disable adm group]))
 541 AS_IF([test "x$enable_adm_group" != "xno"], [
 542         AC_DEFINE(ENABLE_ADM_GROUP, 1, [Define if the ACL for adm group should be enabled])
 543         have_adm_group=yes
 544         M4_DEFINES="$M4_DEFINES -DENABLE_ADM_GROUP"
 545 ])
 546
 547 have_wheel_group=no
 548 AC_ARG_ENABLE(wheel-group, AS_HELP_STRING([--disable-wheel-group], [disable wheel group]))
 549 AS_IF([test "x$enable_wheel_group" != "xno"], [
 550         AC_DEFINE(ENABLE_WHEEL_GROUP, 1, [Define if the ACL for wheel group should be enabled])
 551         have_wheel_group=yes
 552         M4_DEFINES="$M4_DEFINES -DENABLE_WHEEL_GROUP"
 553 ])
 554
 555
 556 AC_ARG_WITH(debug-shell,
 557         AS_HELP_STRING([--with-debug-shell=PATH],
 558                 [path to debug shell binary]),
 559         [SUSHELL="$withval"],
 560         [SUSHELL="/bin/sh"])
 561
 562 AC_SUBST(SUSHELL)
 563
 564 AC_ARG_WITH([debug-tty],
 565         AS_HELP_STRING([--with-debug-tty=PATH],
 566                 [specify the tty device for debug shell]),
 567         [DEBUGTTY="$withval"],
 568         [DEBUGTTY=/dev/tty9])
 569
 570 AC_SUBST(DEBUGTTY)
 571
 572 AC_ARG_WITH([certificate-root],
 573         AS_HELP_STRING([--with-certificate-root=PATH],
 574                 [specify the prefix for TLS certificates [/etc/ssl]]),
 575         [CERTIFICATEROOT="$withval"],
 576         [CERTIFICATEROOT="/etc/ssl"])
 577
 578 AC_SUBST(CERTIFICATEROOT)
 579
 580 AC_ARG_WITH([support-url],
 581         AS_HELP_STRING([--with-support-url=URL],
 582                 [specify the support URL to show in catalog entries included in systemd]),
 583         [SUPPORT_URL="$withval"],
 584         [SUPPORT_URL=https://lists.freedesktop.org/mailman/listinfo/systemd-devel])
 585
 586 AC_SUBST(SUPPORT_URL)
 587
 588 AC_ARG_WITH([nobody-user],
 589         AS_HELP_STRING([--with-nobody-user=NAME],
 590                 [specify the name of the nobody user (the one with UID 65534)]),
 591         [NOBODY_USER_NAME="$withval"],
 592         [NOBODY_USER_NAME=nobody])
 593
 594 AC_SUBST(NOBODY_USER_NAME)
 595 AC_DEFINE_UNQUOTED(NOBODY_USER_NAME, ["$NOBODY_USER_NAME"], [The name of the nobody user (the one with UID 65534)])
 596
 597 AC_ARG_WITH([nobody-group],
 598         AS_HELP_STRING([--with-nobody-group=NAME],
 599                 [specify the name of the nobody group (the one with GID 65534)]),
 600         [NOBODY_GROUP_NAME="$withval"],
 601         [NOBODY_GROUP_NAME=nobody])
 602
 603 AC_SUBST(NOBODY_GROUP_NAME)
 604 AC_DEFINE_UNQUOTED(NOBODY_GROUP_NAME, ["$NOBODY_GROUP_NAME"], [The name of the nobody group (the one with GID 65534)])
 605
 606 AC_ARG_WITH([fallback-hostname],
 607         AS_HELP_STRING([--with-fallback-hostname=NAME],
 608                 [specify the hostname used if none configured]),
 609         [FALLBACK_HOSTNAME="$withval"],
 610         [FALLBACK_HOSTNAME=localhost])
 611
 612 AC_SUBST(FALLBACK_HOSTNAME)
 613 AC_DEFINE_UNQUOTED(FALLBACK_HOSTNAME, ["$FALLBACK_HOSTNAME"], [The hostname used if none configured])
 614
 615 # ------------------------------------------------------------------------------
 616 have_xz=no
 617 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [disable optional XZ support]))
 618 AS_IF([test "x$enable_xz" != "xno"], [
 619         PKG_CHECK_MODULES(XZ, [ liblzma ],
 620                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available])
 621                  have_xz=yes],
 622                  have_xz=no)
 623         AS_IF([test "x$have_xz" = xno -a "x$enable_xz" = xyes],
 624               [AC_MSG_ERROR([*** XZ support requested but libraries not found])])
 625 ])
 626 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 627
 628 # ------------------------------------------------------------------------------
 629 have_zlib=no
 630 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [disable optional ZLIB support]))
 631 AS_IF([test "x$enable_zlib" != "xno"], [
 632         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 633                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available])
 634                  have_zlib=yes],
 635                  have_zlib=no)
 636         AS_IF([test "x$have_zlib" = xno -a "x$enable_zlib" = xyes],
 637               [AC_MSG_ERROR([*** ZLIB support requested but libraries not found])])
 638 ])
 639 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 640
 641 # ------------------------------------------------------------------------------
 642 have_bzip2=no
 643 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--disable-bzip2], [disable optional BZIP2 support]))
 644 AS_IF([test "x$enable_bzip2" != "xno"], [
 645         AC_CHECK_HEADERS(bzlib.h,
 646                 [AC_DEFINE(HAVE_BZIP2, 1, [Define if BZIP2 is available])
 647                  have_bzip2=yes],
 648                 [AS_IF([test "x$enable_bzip2" = xyes],
 649                        [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])]
 650         )
 651 ])
 652 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 653
 654 # ------------------------------------------------------------------------------
 655 have_lz4=no
 656 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--disable-lz4], [disable optional LZ4 support]))
 657 AS_IF([test "x$enable_lz4" != "xno"], [
 658         PKG_CHECK_MODULES(LZ4, [ liblz4 < 10 ],
 659                [AC_DEFINE(HAVE_LZ4, 1, [Define if LZ4 is available])
 660                 have_lz4=yes],
 661                 [PKG_CHECK_MODULES(LZ4, [ liblz4 >= 125 ],
 662                       [AC_DEFINE(HAVE_LZ4, 1, [Define if LZ4 is available])
 663                       have_lz4=yes],
 664                       have_lz4=no)])
 665         AS_IF([test "x$have_lz4" = xno -a "x$enable_lz4" = xyes],
 666               [AC_MSG_ERROR([*** LZ4 support requested but libraries not found])])
 667 ])
 668 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 669
 670 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 671
 672 # ------------------------------------------------------------------------------
 673 AC_ARG_ENABLE([pam],
 674         AS_HELP_STRING([--disable-pam], [disable optional PAM support]),
 675                 [case "${enableval}" in
 676                         yes) have_pam=yes ;;
 677                         no) have_pam=no ;;
 678                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 679                 esac],
 680                 [have_pam=auto])
 681
 682 if test "x${have_pam}" != xno ; then
 683         AC_CHECK_HEADERS(
 684                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 685                 [have_pam=yes],
 686                 [if test "x$have_pam" = xyes ; then
 687                         AC_MSG_ERROR([*** PAM headers not found.])
 688                 fi])
 689
 690         AC_CHECK_LIB(
 691                 [pam],
 692                 [pam_syslog],
 693                 [have_pam=yes],
 694                 [if test "x$have_pam" = xyes ; then
 695                         AC_MSG_ERROR([*** libpam not found.])
 696                 fi])
 697
 698         if test "x$have_pam" = xyes ; then
 699                 PAM_LIBS="-lpam -lpam_misc"
 700                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 701                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 702         else
 703                 have_pam=no
 704         fi
 705 else
 706         PAM_LIBS=
 707 fi
 708 AC_SUBST(PAM_LIBS)
 709 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 710
 711 # ------------------------------------------------------------------------------
 712 AC_ARG_ENABLE([acl],
 713         AS_HELP_STRING([--disable-acl], [disable optional ACL support]),
 714                 [case "${enableval}" in
 715                         yes) have_acl=yes ;;
 716                         no) have_acl=no ;;
 717                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 718                 esac],
 719                 [have_acl=auto])
 720
 721 if test "x${have_acl}" != xno ; then
 722         AC_CHECK_HEADERS(
 723                 [sys/acl.h acl/libacl.h],
 724                 [have_acl=yes],
 725                 [if test "x$have_acl" = xyes ; then
 726                         AC_MSG_ERROR([*** ACL headers not found.])
 727                 fi])
 728
 729         AC_CHECK_LIB(
 730                 [acl],
 731                 [acl_get_file],
 732                 [have_acl=yes],
 733                 [if test "x$have_acl" = xyes ; then
 734                         AC_MSG_ERROR([*** libacl not found.])
 735                 fi])
 736
 737         if test "x$have_acl" = xyes ; then
 738                 ACL_LIBS="-lacl"
 739                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 740                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 741         else
 742                 have_acl=no
 743         fi
 744 else
 745         ACL_LIBS=
 746 fi
 747 AC_SUBST(ACL_LIBS)
 748 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 749
 750 # ------------------------------------------------------------------------------
 751 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack], [disable optional SMACK support]),
 752                 [case "${enableval}" in
 753                         yes) have_smack=yes ;;
 754                         no) have_smack=no ;;
 755                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 756                 esac],
 757                 [have_smack=auto])
 758
 759 if test "x${have_smack}" != xno; then
 760         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 761         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 762         have_smack=yes
 763 fi
 764
 765 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 766
 767 have_smack_run_label=no
 768 AC_ARG_WITH(smack-run-label,
 769 AS_HELP_STRING([--with-smack-run-label=STRING],
 770         [run systemd --system itself with a specific SMACK label]),
 771         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
 772         [])
 773
 774 if test "x${have_smack_run_label}" = xyes; then
 775         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
 776 fi
 777
 778 AC_ARG_WITH(smack-default-process-label,
 779 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 780         [default SMACK label for executed processes]),
 781         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 782         [])
 783
 784 # ------------------------------------------------------------------------------
 785 AC_ARG_ENABLE([gcrypt],
 786         AS_HELP_STRING([--disable-gcrypt], [disable optional GCRYPT support]),
 787                 [case "${enableval}" in
 788                         yes) have_gcrypt=yes ;;
 789                         no) have_gcrypt=no ;;
 790                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 791                 esac],
 792                 [have_gcrypt=auto])
 793
 794 if test "x${have_gcrypt}" != xno ; then
 795         m4_define([AM_PATH_LIBGCRYPT_FAIL],
 796                 [{ test "x$have_gcrypt" != xyes || AC_MSG_ERROR([*** GCRYPT/GPG-ERROR headers not found.]); }]
 797         )
 798         m4_ifdef([AM_PATH_LIBGCRYPT], [AM_PATH_LIBGCRYPT(
 799                         [1.4.5],
 800                         [have_gcrypt=yes],
 801                         dnl  If we have the gcrypt m4 macros, but don't have
 802                         dnl  gcrypt, throw an error if gcrypt is explicitly
 803                         dnl  requested.
 804                         [AM_PATH_LIBGCRYPT_FAIL]
 805                 )],
 806                 dnl  If we don't have the gcrypt m4 macros, but build with
 807                 dnl  gcrypt explicitly requested, throw an error.
 808                 [AM_PATH_LIBGCRYPT_FAIL]
 809         )
 810
 811         have_gpg_error=no
 812         m4_ifdef([AM_PATH_GPG_ERROR], [AM_PATH_GPG_ERROR(
 813                         [1.12],
 814                         [have_gpg_error=yes],
 815                         [AM_PATH_LIBGCRYPT_FAIL]
 816                 )],
 817                 [AM_PATH_LIBGCRYPT_FAIL]
 818         )
 819
 820         if test "x$have_gcrypt" = xyes -a "x$have_gpg_error" = xyes ; then
 821                 GCRYPT_LIBS="$LIBGCRYPT_LIBS $GPG_ERROR_LIBS"
 822                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS $GPG_ERROR_CFLAGS"
 823                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 824         else
 825                 have_gcrypt=no
 826                 have_gpg_error=no
 827         fi
 828 else
 829         GCRYPT_LIBS=
 830         GCRYPT_CFLAGS=
 831 fi
 832 AC_SUBST(GCRYPT_LIBS)
 833 AC_SUBST(GCRYPT_CFLAGS)
 834 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 835
 836 # ------------------------------------------------------------------------------
 837 AC_ARG_ENABLE([audit],
 838         AS_HELP_STRING([--disable-audit], [disable optional AUDIT support]),
 839                 [case "${enableval}" in
 840                         yes) have_audit=yes ;;
 841                         no) have_audit=no ;;
 842                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 843                 esac],
 844                 [have_audit=auto])
 845
 846 if test "x${have_audit}" != xno ; then
 847         AC_CHECK_HEADERS(
 848                 [libaudit.h],
 849                 [have_audit=yes],
 850                 [if test "x$have_audit" = xyes ; then
 851                         AC_MSG_ERROR([*** AUDIT headers not found.])
 852                 fi])
 853
 854         AC_CHECK_LIB(
 855                 [audit],
 856                 [audit_open],
 857                 [have_audit=yes],
 858                 [if test "x$have_audit" = xyes ; then
 859                         AC_MSG_ERROR([*** libaudit not found.])
 860                 fi])
 861
 862         if test "x$have_audit" = xyes ; then
 863                 AUDIT_LIBS="-laudit"
 864                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 865         else
 866                 have_audit=no
 867         fi
 868 else
 869         AUDIT_LIBS=
 870 fi
 871 AC_SUBST(AUDIT_LIBS)
 872 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 873
 874 # ------------------------------------------------------------------------------
 875 AC_ARG_ENABLE([elfutils],
 876         AS_HELP_STRING([--disable-elfutils], [disable optional ELFUTILS support]),
 877                 [case "${enableval}" in
 878                         yes) have_elfutils=yes ;;
 879                         no) have_elfutils=no ;;
 880                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 881                 esac],
 882                 [have_elfutils=auto])
 883
 884 if test "x${have_elfutils}" != xno ; then
 885         AC_CHECK_HEADERS(
 886                 [elfutils/libdwfl.h],
 887                 [],
 888                 [if test "x$have_elfutils" = xyes ; then
 889                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 890                 fi])
 891
 892         AC_CHECK_LIB(
 893                 [dw],
 894                 [dwfl_core_file_attach],
 895                 [have_elfutils=yes],
 896                 [if test "x$have_elfutils" = xyes ; then
 897                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 898                 fi])
 899
 900         if test "x$have_elfutils" = xyes ; then
 901                 ELFUTILS_LIBS="-lelf -ldw"
 902                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 903         else
 904                 have_elfutils=no
 905         fi
 906 else
 907         ELFUTILS_LIBS=
 908 fi
 909 AC_SUBST(ELFUTILS_LIBS)
 910 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 911
 912 # ------------------------------------------------------------------------------
 913 have_libcryptsetup=no
 914 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 915 if test "x$enable_libcryptsetup" != "xno"; then
 916         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 917                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 918         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 919                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 920         fi
 921 fi
 922 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 923
 924 # ------------------------------------------------------------------------------
 925 have_qrencode=no
 926 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 927 if test "x$enable_qrencode" != "xno"; then
 928         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 929                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 930         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 931                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 932         fi
 933 fi
 934 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 935
 936 # ------------------------------------------------------------------------------
 937 have_gnutls=no
 938 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 939 if test "x$enable_gnutls" != "xno"; then
 940         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 941                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 942         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 943                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 944         fi
 945 fi
 946 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 947
 948 # ------------------------------------------------------------------------------
 949 have_microhttpd=no
 950 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 951 if test "x$enable_microhttpd" != "xno"; then
 952         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 953                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available])
 954                  have_microhttpd=yes
 955                  M4_DEFINES="$M4_DEFINES -DHAVE_MICROHTTPD"],
 956                 [have_microhttpd=no])
 957         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 958                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 959         fi
 960 fi
 961 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 962
 963 # ------------------------------------------------------------------------------
 964 have_libcurl=no
 965 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 966 if test "x$enable_libcurl" != "xno"; then
 967         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.32.0],
 968                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available])
 969                  have_libcurl=yes
 970                  M4_DEFINES="$M4_DEFINES -DHAVE_LIBCURL"],
 971                 [have_libcurl=no])
 972         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 973                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 974         fi
 975 fi
 976 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 977
 978 # ------------------------------------------------------------------------------
 979 AM_CONDITIONAL(HAVE_REMOTE, [test "$have_microhttpd" = "yes" -o "$have_libcurl" = "yes"])
 980
 981 # ------------------------------------------------------------------------------
 982 have_libidn=no
 983 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [disable optional LIBIDN support]))
 984 if test "x$enable_libidn" != "xno"; then
 985         PKG_CHECK_MODULES(LIBIDN, [libidn],
 986                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 987                 have_libidn=yes
 988                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 989                [have_libidn=no])
 990         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 991                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 992         fi
 993 fi
 994 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 995
 996 # ------------------------------------------------------------------------------
 997 have_libiptc=no
 998 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [disable optional LIBIPTC support]))
 999 if test "x$enable_libiptc" != "xno"; then
1000         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
1001                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
1002                 have_libiptc=yes
1003                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
1004                [have_libiptc=no])
1005         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
1006                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
1007         fi
1008 fi
1009 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
1010
1011 # ------------------------------------------------------------------------------
1012 have_binfmt=no
1013 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
1014 if test "x$enable_binfmt" != "xno"; then
1015         have_binfmt=yes
1016 fi
1017 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
1018
1019 # ------------------------------------------------------------------------------
1020 have_vconsole=no
1021 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
1022 if test "x$enable_vconsole" != "xno"; then
1023         have_vconsole=yes
1024 fi
1025 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
1026
1027 # ------------------------------------------------------------------------------
1028 have_quotacheck=no
1029 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
1030 if test "x$enable_quotacheck" != "xno"; then
1031         have_quotacheck=yes
1032 fi
1033 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
1034
1035 # ------------------------------------------------------------------------------
1036 have_tmpfiles=no
1037 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
1038 if test "x$enable_tmpfiles" != "xno"; then
1039         have_tmpfiles=yes
1040 fi
1041 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
1042
1043 # ------------------------------------------------------------------------------
1044 have_environment_d=no
1045 AC_ARG_ENABLE(environment-d, AS_HELP_STRING([--disable-environment-d], [disable environment.d support]))
1046 if test "x$enable_environment_d" != "xno"; then
1047         have_environment_d=yes
1048 fi
1049 AM_CONDITIONAL(ENABLE_ENVIRONMENT_D, [test "$have_environment_d" = "yes"])
1050
1051 # ------------------------------------------------------------------------------
1052 have_sysusers=no
1053 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
1054 if test "x$enable_sysusers" != "xno"; then
1055         have_sysusers=yes
1056 fi
1057 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
1058
1059 # ------------------------------------------------------------------------------
1060 have_firstboot=no
1061 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
1062 if test "x$enable_firstboot" != "xno"; then
1063         have_firstboot=yes
1064 fi
1065 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
1066
1067 # ------------------------------------------------------------------------------
1068 have_randomseed=no
1069 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
1070 if test "x$enable_randomseed" != "xno"; then
1071         have_randomseed=yes
1072 fi
1073 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
1074
1075 # ------------------------------------------------------------------------------
1076 have_backlight=no
1077 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
1078 if test "x$enable_backlight" != "xno"; then
1079         have_backlight=yes
1080 fi
1081 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
1082
1083 # ------------------------------------------------------------------------------
1084 have_rfkill=no
1085 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
1086 if test "x$enable_rfkill" != "xno"; then
1087         have_rfkill=yes
1088 fi
1089 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
1090
1091 # ------------------------------------------------------------------------------
1092 have_logind=no
1093 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
1094 if test "x$enable_logind" != "xno"; then
1095         have_logind=yes
1096 fi
1097 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
1098 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
1099
1100 AC_ARG_WITH([kill-user-processes],
1101         [AS_HELP_STRING([--without-kill-user-processes], [set logind's KillUserProcesses=no by default])])
1102 AS_IF([test "$with_kill_user_processes" != "no"],
1103        [kill_user_processes=true
1104         KILL_USER_PROCESSES=yes],
1105        [kill_user_processes=false
1106         KILL_USER_PROCESSES=no])
1107 AC_DEFINE_UNQUOTED(KILL_USER_PROCESSES, [$kill_user_processes], [Default KillUserProcesses setting])
1108 AC_SUBST(KILL_USER_PROCESSES)
1109
1110 # ------------------------------------------------------------------------------
1111 have_machined=no
1112 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
1113 if test "x$enable_machined" != "xno"; then
1114         have_machined=yes
1115         AC_DEFINE(HAVE_MACHINED, [1], [systemd-machined is enabled])
1116 fi
1117 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
1118
1119 # ------------------------------------------------------------------------------
1120 have_importd=no
1121 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
1122 if test "x$enable_importd" != "xno"; then
1123         have_importd=yes
1124 fi
1125 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
1126 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
1127
1128 # ------------------------------------------------------------------------------
1129 have_hostnamed=no
1130 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1131 if test "x$enable_hostnamed" != "xno"; then
1132         have_hostnamed=yes
1133 fi
1134 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1135
1136 # ------------------------------------------------------------------------------
1137 have_timedated=no
1138 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1139 if test "x$enable_timedated" != "xno"; then
1140         have_timedated=yes
1141 fi
1142 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1143
1144 # ------------------------------------------------------------------------------
1145 have_timesyncd=no
1146 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1147 if test "x$enable_timesyncd" != "xno"; then
1148         have_timesyncd=yes
1149         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1150 fi
1151 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1152
1153 AC_ARG_WITH(ntp-servers,
1154         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1155                 [space-separated list of default NTP servers]),
1156         [NTP_SERVERS="$withval"],
1157         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"])
1158
1159 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1160 AC_SUBST(NTP_SERVERS)
1161
1162 AC_ARG_WITH(time-epoch,
1163         AS_HELP_STRING([--with-time-epoch=SECONDS],
1164                 [time epoch for time clients]),
1165         [TIME_EPOCH="$withval"],
1166         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1167
1168 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1169
1170 # ------------------------------------------------------------------------------
1171 AC_ARG_WITH(system-uid-max,
1172         AS_HELP_STRING([--with-system-uid-max=UID]
1173                 [maximum UID for system users]),
1174         [SYSTEM_UID_MAX="$withval"],
1175         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1176
1177 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1178 AC_SUBST(SYSTEM_UID_MAX)
1179
1180 # ------------------------------------------------------------------------------
1181 AC_ARG_WITH(system-gid-max,
1182         AS_HELP_STRING([--with-system-gid-max=GID]
1183                 [maximum GID for system groups]),
1184         [SYSTEM_GID_MAX="$withval"],
1185         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1186
1187 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1188 AC_SUBST(SYSTEM_GID_MAX)
1189
1190 # ------------------------------------------------------------------------------
1191 have_localed=no
1192 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1193 if test "x$enable_localed" != "xno"; then
1194         have_localed=yes
1195 fi
1196 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1197
1198 # ------------------------------------------------------------------------------
1199 have_coredump=no
1200 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1201 if test "x$enable_coredump" != "xno"; then
1202         have_coredump=yes
1203         M4_DEFINES="$M4_DEFINES -DENABLE_COREDUMP"
1204 fi
1205 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1206
1207 # ------------------------------------------------------------------------------
1208 have_polkit=no
1209 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1210 if test "x$enable_polkit" != "xno"; then
1211         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1212         have_polkit=yes
1213 fi
1214 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1215
1216 # ------------------------------------------------------------------------------
1217 have_resolved=no
1218 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1219 AS_IF([test "x$enable_resolved" != "xno"], [
1220         AC_CHECK_LIB([dl], [dlsym], [true], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
1221
1222         have_resolved=yes
1223         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1224         AC_DEFINE(HAVE_RESOLVED, [1], [systemd-resolved is enabled])
1225 ])
1226 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1227
1228 AC_ARG_WITH(dns-servers,
1229         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1230                 [space-separated list of default DNS servers]),
1231         [DNS_SERVERS="$withval"],
1232         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1233
1234 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1235 AC_SUBST(DNS_SERVERS)
1236
1237 AC_ARG_WITH(default-dnssec,
1238         AS_HELP_STRING([--with-default-dnssec=MODE],
1239                [default DNSSEC mode, defaults to "allow-downgrade"]),
1240         [DEFAULT_DNSSEC_MODE="$withval"],
1241         [DEFAULT_DNSSEC_MODE="allow-downgrade"])
1242
1243 AS_CASE("x${DEFAULT_DNSSEC_MODE}",
1244         [xno], [mode=DNSSEC_NO],
1245         [xyes], [mode=DNSSEC_YES],
1246         [xallow-downgrade], [mode=DNSSEC_ALLOW_DOWNGRADE],
1247         AC_MSG_ERROR(Bad DNSSEC mode ${DEFAULT_DNSSEC_MODE}))
1248 AC_DEFINE_UNQUOTED(DEFAULT_DNSSEC_MODE, [$mode], [Default DNSSEC mode])
1249 AC_SUBST(DEFAULT_DNSSEC_MODE)
1250
1251 # ------------------------------------------------------------------------------
1252 have_networkd=no
1253 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1254 AS_IF([test "x$enable_networkd" != "xno"], [
1255         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1256         have_networkd=yes
1257         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1258 ])
1259 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1260
1261 # ------------------------------------------------------------------------------
1262 have_efi=no
1263 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable systemd-boot and bootctl (EFI support)]))
1264 if test "x$enable_efi" != "xno"; then
1265         AC_DEFINE(ENABLE_EFI, 1, [Define if systemd-boot and bootctl are to be enabled])
1266         have_efi=yes
1267 fi
1268 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1269
1270 # ------------------------------------------------------------------------------
1271 AC_CHECK_TOOL(EFI_CC, gcc)
1272
1273 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1274
1275 AM_COND_IF(ARCH_IA32, [
1276         EFI_ARCH=ia32
1277         EFI_MACHINE_TYPE_NAME=ia32])
1278
1279 AM_COND_IF(ARCH_X86_64, [
1280         EFI_MACHINE_TYPE_NAME=x64])
1281
1282 AM_COND_IF(ARCH_AARCH64, [
1283         EFI_MACHINE_TYPE_NAME=aa64])
1284
1285 AC_SUBST([EFI_ARCH])
1286 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1287
1288 have_gnuefi=no
1289 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [enable optional gnuefi support]))
1290 AS_IF([test "x$enable_gnuefi" != "xno"], [
1291         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
1292                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1293                  have_gnuefi=yes],
1294                 [AS_IF([test "x$enable_gnuefi" = xyes],
1295                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1296         ])
1297
1298         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1299
1300         EFI_LIB_DIR="$efiroot"
1301         AC_ARG_WITH(efi-libdir,
1302                 AS_HELP_STRING([--with-efi-libdir=PATH], [path to EFI lib directory]),
1303                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1304         )
1305         AC_SUBST([EFI_LIB_DIR])
1306
1307         have_efi_lds=no
1308         AC_ARG_WITH(efi-ldsdir,
1309                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [path to EFI lds directory]),
1310                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1311                         [have_efi_lds=yes])],
1312                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1313                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1314                                        [have_efi_lds=yes && break])])])
1315         AS_IF([test "x$have_efi_lds" = xyes],
1316               [AC_SUBST([EFI_LDS_DIR])],
1317               [AS_IF([test "x$enable_gnuefi" = xyes],
1318                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1319                      [have_gnuefi=no])])
1320
1321         AC_ARG_WITH(efi-includedir,
1322                 AS_HELP_STRING([--with-efi-includedir=PATH], [path to EFI include directory]),
1323                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1324         )
1325         AC_SUBST([EFI_INC_DIR])
1326 ])
1327 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1328
1329 # ------------------------------------------------------------------------------
1330 have_tpm=no
1331 AC_ARG_ENABLE([tpm], AS_HELP_STRING([--enable-tpm], [enable optional TPM support]),
1332                 [case "${enableval}" in
1333                         yes) have_tpm=yes ;;
1334                         no) have_tpm=no ;;
1335                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tpm) ;;
1336                 esac],
1337                 [have_tpm=no])
1338
1339 if test "x${have_tpm}" != xno ; then
1340         AC_DEFINE(SD_BOOT_LOG_TPM, 1, [Define if TPM should be used to log events and extend the registers])
1341 fi
1342
1343 AC_ARG_WITH(tpm-pcrindex,
1344         AS_HELP_STRING([--with-tpm-pcrindex=<NUM>],
1345                 [TPM PCR register number to use]),
1346         [SD_TPM_PCR="$withval"],
1347         [SD_TPM_PCR="8"])
1348
1349 AC_DEFINE_UNQUOTED(SD_TPM_PCR, [$SD_TPM_PCR], [TPM PCR register number to use])
1350
1351 # ------------------------------------------------------------------------------
1352 AC_ARG_WITH(rc-local-script-path-start,
1353         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1354                 [path to /etc/rc.local]),
1355         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1356         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1357
1358 AC_ARG_WITH(rc-local-script-path-stop,
1359         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1360                 [path to /usr/sbin/halt.local]),
1361         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1362         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1363
1364 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1365 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1366
1367 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1368 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1369
1370 # ------------------------------------------------------------------------------
1371 AC_ARG_WITH(kbd-loadkeys,
1372         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1373                 [path to loadkeys]),
1374         [KBD_LOADKEYS="$withval"],
1375         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1376
1377 AC_ARG_WITH(kbd-setfont,
1378         AS_HELP_STRING([--with-kbd-setfont=PATH],
1379                 [path to setfont]),
1380         [KBD_SETFONT="$withval"],
1381         [KBD_SETFONT="/usr/bin/setfont"])
1382
1383 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1384 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1385
1386 AC_SUBST(KBD_LOADKEYS)
1387 AC_SUBST(KBD_SETFONT)
1388
1389 AC_ARG_WITH(telinit,
1390         AS_HELP_STRING([--with-telinit=PATH],
1391                 [path to telinit]),
1392         [TELINIT="$withval"],
1393         [TELINIT="/lib/sysvinit/telinit"])
1394
1395 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1396
1397 AC_SUBST(TELINIT)
1398
1399 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1400
1401 # ------------------------------------------------------------------------------
1402 have_myhostname=no
1403 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1404 if test "x$enable_myhostname" != "xno"; then
1405         AC_HEADER_STDC
1406         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1407
1408         AC_C_CONST
1409         AC_TYPE_SIZE_T
1410         AC_HEADER_TIME
1411
1412         AC_FUNC_SELECT_ARGTYPES
1413         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1414
1415         have_myhostname=yes
1416         AC_DEFINE(HAVE_MYHOSTNAME, [1], [nss-myhostname is enabled])
1417 fi
1418 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1419
1420 # ------------------------------------------------------------------------------
1421 AC_ARG_ENABLE(hwdb, [AS_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1422        enable_hwdb=$enableval, enable_hwdb=yes)
1423 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1424
1425 # ------------------------------------------------------------------------------
1426 have_manpages=no
1427 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1428 AC_PATH_PROG([XSLTPROC], [xsltproc])
1429 AS_IF([test "x$enable_manpages" != xno], [
1430        have_manpages=yes
1431        AS_IF([test -z "$XSLTPROC"],
1432              AC_MSG_ERROR([*** xsltproc is required for man pages]))
1433 ])
1434 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1435
1436 # ------------------------------------------------------------------------------
1437 AC_ARG_ENABLE(hibernate,
1438        [AS_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1439        enable_hibernate=$enableval, enable_hibernate=yes)
1440 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1441
1442 # ------------------------------------------------------------------------------
1443 AC_ARG_ENABLE(ldconfig,
1444        [AS_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1445        enable_ldconfig=$enableval, enable_ldconfig=yes)
1446 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1447
1448 # ------------------------------------------------------------------------------
1449 # Location of the init scripts as mandated by LSB
1450 SYSTEM_SYSVINIT_PATH=/etc/init.d
1451 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1452
1453 AC_ARG_WITH([sysvinit-path],
1454         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1455                 [specify the path to where the SysV init scripts are located])],
1456         [SYSTEM_SYSVINIT_PATH="$withval"],
1457         [])
1458
1459 AC_ARG_WITH([sysvrcnd-path],
1460         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1461                 [specify the path to the base directory for the SysV rcN.d directories])],
1462         [SYSTEM_SYSVRCND_PATH="$withval"],
1463         [])
1464
1465 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1466         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1467         SYSTEM_SYSV_COMPAT="yes"
1468         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1469 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1470         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1471 else
1472         SYSTEM_SYSV_COMPAT="no"
1473 fi
1474
1475 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1476 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1477 AC_SUBST(M4_DEFINES)
1478
1479 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1480
1481 AC_ARG_WITH([tty-gid],
1482         [AS_HELP_STRING([--with-tty-gid=GID],
1483                 [specify the numeric GID of the 'tty' group])],
1484         [TTY_GID="$withval"],
1485         [TTY_GID="5"])
1486
1487 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1488 AC_SUBST(TTY_GID)
1489
1490 AC_ARG_WITH([dbuspolicydir],
1491         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1492         [],
1493         [with_dbuspolicydir=${datadir}/dbus-1/system.d])
1494 AX_NORMALIZE_PATH([with_dbuspolicydir])
1495
1496 AC_ARG_WITH([dbussessionservicedir],
1497         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1498         [],
1499         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1500 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1501
1502 AC_ARG_WITH([dbussystemservicedir],
1503         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1504         [],
1505         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1506 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1507
1508 AC_ARG_WITH([bashcompletiondir],
1509         AS_HELP_STRING([--with-bashcompletiondir=DIR], [bash completions directory]),
1510         [],
1511         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1512                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1513         ] , [
1514                 with_bashcompletiondir=${datadir}/bash-completion/completions
1515         ])])
1516 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1517 AX_NORMALIZE_PATH([with_bashcompletiondir])
1518
1519 AC_ARG_WITH([zshcompletiondir],
1520         AS_HELP_STRING([--with-zshcompletiondir=DIR], [zsh completions directory]),
1521         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1522 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1523 AX_NORMALIZE_PATH([with_zshcompletiondir])
1524
1525 AC_ARG_WITH([rootprefix],
1526         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1527         [], [with_rootprefix=${ac_default_prefix}])
1528 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1529 # defaults those to ".", solve that here for now until we can find a suitable
1530 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1531 # See: https://github.com/systemd/systemd/issues/54
1532 if test "x${with_rootprefix}" = "x"; then
1533         with_rootprefix="/"
1534 fi
1535 AX_NORMALIZE_PATH([with_rootprefix])
1536
1537 AC_ARG_WITH([rootlibdir],
1538         AS_HELP_STRING([--with-rootlibdir=DIR], [root directory for libraries necessary for boot]),
1539         [],
1540         [with_rootlibdir=${libdir}])
1541 AX_NORMALIZE_PATH([with_rootlibdir])
1542
1543 AC_ARG_WITH([pamlibdir],
1544         AS_HELP_STRING([--with-pamlibdir=DIR], [directory for PAM modules]),
1545         [],
1546         [with_pamlibdir=${with_rootlibdir}/security])
1547 AX_NORMALIZE_PATH([with_pamlibdir])
1548
1549 AC_ARG_WITH([pamconfdir],
1550         AS_HELP_STRING([--with-pamconfdir=DIR], [directory for PAM configuration (pass no to disable installing)]),
1551         [],
1552         [with_pamconfdir=${sysconfdir}/pam.d])
1553 AM_CONDITIONAL(ENABLE_PAM_CONFIG, [test "$with_pamconfdir" != "no"])
1554 AX_NORMALIZE_PATH([with_pamconfdir])
1555
1556 AC_ARG_ENABLE([split-usr],
1557         AS_HELP_STRING([--enable-split-usr], [assume that /bin, /sbin aren't symlinks into /usr]),
1558         [],
1559         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1560                 enable_split_usr=yes
1561         ], [
1562                 enable_split_usr=no
1563         ])])
1564
1565 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1566         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1567 ])
1568 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1569
1570 # work around intltool-update issues during 'make distcheck'
1571 AS_IF([test "x$0" != "x./configure"], [
1572         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1573 ])
1574
1575 # QEMU and OVMF UEFI firmware
1576 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1577         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1578         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1579                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1580         AC_SUBST([QEMU_BIOS])
1581 ])
1582
1583 AC_ARG_ENABLE(tests,
1584         [AS_HELP_STRING([--disable-tests], [disable tests, or enable extra tests with =unsafe])],
1585         enable_tests=$enableval, enable_tests=yes)
1586 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes -o x$enable_tests = xunsafe])
1587 AM_CONDITIONAL(ENABLE_UNSAFE_TESTS, [test x$enable_tests = xunsafe])
1588
1589 AC_ARG_ENABLE(debug,
1590         [AS_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1591         [if test "x$enableval" = "xyes"; then
1592                 enableval="hashmap,mmap-cache"
1593         fi
1594         saved_ifs="$IFS"
1595         IFS="$IFS$PATH_SEPARATOR,"
1596         for name in $enableval; do
1597                 case $name in
1598                 hashmap)
1599                         enable_debug_hashmap=yes
1600                         ;;
1601                 mmap-cache)
1602                         enable_debug_mmap_cache=yes
1603                         ;;
1604                 esac
1605         done
1606         IFS="$saved_ifs"],[])
1607
1608 enable_debug=""
1609 AS_IF([test x$enable_debug_hashmap = xyes], [
1610         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1611         enable_debug="hashmap $enable_debug"
1612 ])
1613 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1614         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1615         enable_debug="mmap-cache $enable_debug"
1616 ])
1617 test -z "$enable_debug" && enable_debug="none"
1618
1619 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1620 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1621 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1622 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1623 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1624 AC_SUBST([pamlibdir], [$with_pamlibdir])
1625 AC_SUBST([pamconfdir], [$with_pamconfdir])
1626 AC_SUBST([rootprefix], [$with_rootprefix])
1627 AC_SUBST([rootlibdir], [$with_rootlibdir])
1628
1629 AC_CONFIG_FILES([
1630         Makefile
1631         po/Makefile.in
1632 ])
1633
1634 AC_OUTPUT
1635 AC_MSG_RESULT([
1636         $PACKAGE_NAME $VERSION
1637
1638         libcryptsetup:                     ${have_libcryptsetup}
1639         PAM:                               ${have_pam}
1640         AUDIT:                             ${have_audit}
1641         IMA:                               ${have_ima}
1642         AppArmor:                          ${have_apparmor}
1643         SELinux:                           ${have_selinux}
1644         SECCOMP:                           ${have_seccomp}
1645         SMACK:                             ${have_smack}
1646         ZLIB:                              ${have_zlib}
1647         XZ:                                ${have_xz}
1648         LZ4:                               ${have_lz4}
1649         BZIP2:                             ${have_bzip2}
1650         ACL:                               ${have_acl}
1651         GCRYPT:                            ${have_gcrypt}
1652         QRENCODE:                          ${have_qrencode}
1653         MICROHTTPD:                        ${have_microhttpd}
1654         GNUTLS:                            ${have_gnutls}
1655         libcurl:                           ${have_libcurl}
1656         libidn:                            ${have_libidn}
1657         libiptc:                           ${have_libiptc}
1658         ELFUTILS:                          ${have_elfutils}
1659         binfmt:                            ${have_binfmt}
1660         vconsole:                          ${have_vconsole}
1661         quotacheck:                        ${have_quotacheck}
1662         tmpfiles:                          ${have_tmpfiles}
1663         environment.d:                     ${have_environment_d}
1664         sysusers:                          ${have_sysusers}
1665         firstboot:                         ${have_firstboot}
1666         randomseed:                        ${have_randomseed}
1667         backlight:                         ${have_backlight}
1668         rfkill:                            ${have_rfkill}
1669         logind:                            ${have_logind}
1670         Default KillUserProcesses setting: ${KILL_USER_PROCESSES}
1671         machined:                          ${have_machined}
1672         importd:                           ${have_importd}
1673         hostnamed:                         ${have_hostnamed}
1674         timedated:                         ${have_timedated}
1675         timesyncd:                         ${have_timesyncd}
1676         Default NTP servers:               ${NTP_SERVERS}
1677         time epoch:                        ${TIME_EPOCH}
1678         localed:                           ${have_localed}
1679         networkd:                          ${have_networkd}
1680         resolved:                          ${have_resolved}
1681         Default DNS servers:               ${DNS_SERVERS}
1682         Default DNSSEC mode:               ${DEFAULT_DNSSEC_MODE}
1683         coredump:                          ${have_coredump}
1684         polkit:                            ${have_polkit}
1685         efi:                               ${have_efi}
1686         gnuefi:                            ${have_gnuefi}
1687         efi arch:                          ${EFI_ARCH}
1688         EFI machine type:                  ${EFI_MACHINE_TYPE_NAME}
1689         EFI CC                             ${EFI_CC}
1690         EFI libdir:                        ${EFI_LIB_DIR}
1691         EFI ldsdir:                        ${EFI_LDS_DIR}
1692         EFI includedir:                    ${EFI_INC_DIR}
1693         kmod:                              ${have_kmod}
1694         xkbcommon:                         ${have_xkbcommon}
1695         blkid:                             ${have_blkid}
1696         libmount:                          ${have_libmount}
1697         dbus:                              ${have_dbus}
1698         nss-myhostname:                    ${have_myhostname}
1699         hwdb:                              ${enable_hwdb}
1700         tpm:                               ${have_tpm}
1701         Python:                            ${have_python}
1702         man pages:                         ${have_manpages}
1703         test coverage:                     ${have_coverage}
1704         Split /usr:                        ${enable_split_usr}
1705         SysV compatibility:                ${SYSTEM_SYSV_COMPAT}
1706         utmp/wtmp support:                 ${have_utmp}
1707         ldconfig support:                  ${enable_ldconfig}
1708         hibernate support:                 ${enable_hibernate}
1709         extra debugging:                   ${enable_debug}
1710         tests:                             ${enable_tests}
1711
1712         prefix:                            ${prefix}
1713         rootprefix:                        ${with_rootprefix}
1714         sysconf dir:                       ${sysconfdir}
1715         datarootdir:                       ${datarootdir}
1716         includedir:                        ${includedir}
1717         lib dir:                           ${libdir}
1718         rootlib dir:                       ${with_rootlibdir}
1719         SysV init scripts:                 ${SYSTEM_SYSVINIT_PATH}
1720         SysV rc?.d directories:            ${SYSTEM_SYSVRCND_PATH}
1721         Build Python:                      ${PYTHON}
1722         PAM modules dir:                   ${with_pamlibdir}
1723         PAM configuration dir:             ${with_pamconfdir}
1724         D-Bus policy dir:                  ${with_dbuspolicydir}
1725         D-Bus session dir:                 ${with_dbussessionservicedir}
1726         D-Bus system dir:                  ${with_dbussystemservicedir}
1727         Bash completions dir:              ${with_bashcompletiondir}
1728         Zsh completions dir:               ${with_zshcompletiondir}
1729         Extra start script:                ${RC_LOCAL_SCRIPT_PATH_START}
1730         Extra stop script:                 ${RC_LOCAL_SCRIPT_PATH_STOP}
1731         Adm group:                         ${have_adm_group}
1732         Wheel group:                       ${have_wheel_group}
1733         Debug shell:                       ${SUSHELL} @ ${DEBUGTTY}
1734         TTY GID:                           ${TTY_GID}
1735         Maximum system UID:                ${SYSTEM_UID_MAX}
1736         Maximum system GID:                ${SYSTEM_GID_MAX}
1737         Certificate root:                  ${CERTIFICATEROOT}
1738         Support URL:                       ${SUPPORT_URL}
1739         nobody user name:                  ${NOBODY_USER_NAME}
1740         nobody group name:                 ${NOBODY_GROUP_NAME}
1741         Fallback hostname:                 ${FALLBACK_HOSTNAME}
1742
1743         CFLAGS:   ${OUR_CFLAGS} ${CFLAGS}
1744         CPPFLAGS: ${OUR_CPPFLAGS} ${CPPFLAGS}
1745         LDFLAGS:  ${OUR_LDFLAGS} ${LDFLAGS}
1746 ])