configure.ac

   1 #
   2 # Copyright (C) 2007-2015 Tobias Brunner
   3 # Copyright (C) 2006-2014 Andreas Steffen
   4 # Copyright (C) 2006-2014 Martin Willi
   5 # Hochschule fuer Technik Rapperswil
   6 #
   7 # This program is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by the
   9 # Free Software Foundation; either version 2 of the License, or (at your
  10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 # for more details.
  16 #
  17
  18 # ============================
  19 #  initialize & set some vars
  20 # ============================
  21
  22 AC_INIT([strongSwan],[5.3.1])
  23 AM_INIT_AUTOMAKE(m4_esyscmd([
  24         echo tar-ustar
  25         echo subdir-objects
  26         case `automake --version | head -n 1` in
  27                 *" 1.9"*);;
  28                 *" 1.10"*);;
  29                 *" 1.11"*);;
  30                 # don't use parallel test harness in 1.12 and up
  31                 *) echo serial-tests;;
  32         esac
  33 ]))
  34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  35 AC_CONFIG_MACRO_DIR([m4/config])
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
  38 PKG_PROG_PKG_CONFIG
  39
  40 m4_include(m4/macros/split-package-version.m4)
  41 SPLIT_PACKAGE_VERSION
  42
  43 # =================================
  44 #  check --enable-xxx & --with-xxx
  45 # =================================
  46
  47 m4_include(m4/macros/with.m4)
  48
  49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
  50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
  51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
  52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
  53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
  54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
  55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
  56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
  57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
  58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
  59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
  60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
  61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
  62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
  63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
  64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
  65
  66 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
  67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
  68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
  69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
  70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
  71 ARG_WITH_SET([rubygemdir],           ["gem environment gemdir"], [path to install ruby gems to])
  72 ARG_WITH_SET([pythoneggdir],         ["main site-packages directory"], [path to install python eggs to to])
  73
  74 if test -n "$PKG_CONFIG"; then
  75         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
  76 fi
  77 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
  78 AC_SUBST(systemdsystemunitdir)
  79
  80 AC_ARG_WITH(
  81         [user],
  82         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
  83         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
  84          AC_SUBST(ipsecuser, "$withval")],
  85         [AC_SUBST(ipsecuser, "root")]
  86 )
  87
  88 AC_ARG_WITH(
  89         [group],
  90         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
  91         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
  92          AC_SUBST(ipsecgroup, "$withval")],
  93         [AC_SUBST(ipsecgroup, "root")]
  94 )
  95
  96 AC_ARG_WITH(
  97         [charon-udp-port],
  98         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
  99         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
 100          AC_SUBST(charon_udp_port, [$withval])],
 101         [AC_SUBST(charon_udp_port, 500)]
 102 )
 103
 104 AC_ARG_WITH(
 105         [charon-natt-port],
 106         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
 107         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
 108          AC_SUBST(charon_natt_port, [$withval])],
 109         [AC_SUBST(charon_natt_port, 4500)]
 110 )
 111
 112 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
 113 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
 114         AC_MSG_ERROR(the ports have to be different)
 115 else
 116         AC_MSG_RESULT(ok)
 117 fi
 118
 119 # convert script name to uppercase
 120 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
 121
 122 m4_include(m4/macros/enable-disable.m4)
 123
 124 # crypto plugins
 125 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
 126 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
 127 ARG_ENABL_SET([bliss],          [enable BLISS software implementation plugin.])
 128 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
 129 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
 130 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
 131 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
 132 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
 133 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
 134 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
 135 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
 136 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
 137 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
 138 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
 139 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
 140 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
 141 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
 142 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
 143 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
 144 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
 145 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
 146 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
 147 ARG_ENABL_SET([aesni],          [enable Intel AES-NI crypto plugin.])
 148 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
 149 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
 150 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
 151 # encoding/decoding plugins
 152 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
 153 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
 154 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
 155 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
 156 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
 157 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
 158 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
 159 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
 160 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
 161 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
 162 # fetcher/resolver plugins
 163 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
 164 ARG_ENABL_SET([files],          [enable simple file:// URI fetcher.])
 165 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
 166 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
 167 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
 168 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
 169 # database plugins
 170 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
 171 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
 172 # authentication/credential plugins
 173 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
 174 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
 175 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
 176 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
 177 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
 178 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
 179 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
 180 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
 181 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
 182 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
 183 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
 184 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
 185 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
 186 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
 187 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
 188 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
 189 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
 190 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
 191 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
 192 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
 193 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
 194 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
 195 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
 196 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
 197 ARG_ENABL_SET([ext-auth],       [enable plugin calling an external authorization script.])
 198 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
 199 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
 200 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
 201 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
 202 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
 203 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
 204 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
 205 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
 206 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
 207 # kernel interfaces / sockets
 208 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
 209 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
 210 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
 211 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
 212 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
 213 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
 214 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
 215 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
 216 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
 217 # configuration/control plugins
 218 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
 219 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
 220 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
 221 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
 222 ARG_ENABL_SET([vici],           [enable strongSwan IKE generic IPC interface plugin.])
 223 # attribute provider/consumer plugins
 224 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
 225 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
 226 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
 227 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
 228 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
 229 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
 230 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
 231 # TNC modules/plugins
 232 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
 233 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
 234 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
 235 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
 236 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
 237 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
 238 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
 239 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
 240 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
 241 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
 242 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
 243 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
 244 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
 245 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
 246 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
 247 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
 248 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
 249 # misc plugins
 250 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
 251 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
 252 ARG_ENABL_SET([connmark],       [enable connmark plugin using conntrack based marks to select return path SA.])
 253 ARG_ENABL_SET([forecast],       [enable forecast plugin forwarding broadcast/multicast messages.])
 254 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
 255 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
 256 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
 257 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
 258 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
 259 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
 260 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
 261 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
 262 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
 263 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
 264 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
 265 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
 266 # programs/components
 267 ARG_ENABL_SET([aikgen],         [enable AIK generator.])
 268 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
 269 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
 270 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
 271 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
 272 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
 273 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
 274 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
 275 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
 276 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
 277 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
 278 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
 279 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
 280 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
 281 ARG_ENABL_SET([svc],            [enable charon Windows service.])
 282 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
 283 ARG_ENABL_SET([swanctl],        [enable swanctl configuration and control tool.])
 284 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
 285 # optional features
 286 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
 287 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
 288 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
 289 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
 290 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
 291 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
 292 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
 293 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
 294 ARG_ENABL_SET([ruby-gems],      [enable build of provided ruby gems.])
 295 ARG_ENABL_SET([ruby-gems-install],[enable installation of provided ruby gems.])
 296 ARG_ENABL_SET([python-eggs],    [enable build of provided python eggs.])
 297 ARG_ENABL_SET([python-eggs-install],[enable installation of provided python eggs.])
 298 # compile options
 299 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
 300 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
 301 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
 302 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
 303
 304 # ===================================
 305 #  option to disable default options
 306 # ===================================
 307
 308 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
 309
 310 if test x$defaults = xfalse; then
 311         for option in $enabled_by_default; do
 312                 eval test x\${${option}_given} = xtrue && continue
 313                 eval $option=false
 314         done
 315 fi
 316
 317 # ==============================
 318 #  option to enable all options
 319 # ==============================
 320
 321 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
 322
 323 if test x$all_given = xtrue; then
 324         for option in $disabled_by_default; do
 325                 eval test x\${${option}_given} = xtrue && continue
 326                 eval $option=true
 327         done
 328 fi
 329
 330 # ===========================
 331 #  set up compiler and flags
 332 # ===========================
 333
 334 if test -z "$CFLAGS"; then
 335         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
 336 fi
 337 AC_PROG_CC
 338 AM_PROG_CC_C_O
 339
 340 AC_LIB_PREFIX
 341 AC_C_BIGENDIAN
 342
 343 # =========================
 344 #  check required programs
 345 # =========================
 346
 347 LT_INIT
 348 AC_PROG_INSTALL
 349 AC_PROG_EGREP
 350 AC_PROG_AWK
 351 AC_PROG_LEX
 352 AC_PROG_YACC
 353 AM_PATH_PYTHON(,,[:])
 354 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 355 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 356
 357 # because gperf is not needed by end-users we just report it but do not abort on failure
 358 AC_MSG_CHECKING([gperf version >= 3.0.0])
 359 if test -x "$GPERF"; then
 360         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
 361                 AC_MSG_RESULT([yes])
 362         else
 363                 AC_MSG_RESULT([no])
 364         fi
 365 else
 366         AC_MSG_RESULT([not found])
 367 fi
 368
 369 # ========================
 370 #  dependency calculation
 371 # ========================
 372
 373 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
 374         xauth_generic=false;
 375 fi
 376
 377 if test x$kernel_libipsec = xtrue; then
 378         libipsec=true;
 379 fi
 380
 381 if test x$eap_aka_3gpp2 = xtrue; then
 382         gmp=true;
 383 fi
 384
 385 if test x$eap_aka = xtrue; then
 386         fips_prf=true;
 387         simaka=true;
 388 fi
 389
 390 if test x$eap_sim = xtrue; then
 391         fips_prf=true;
 392         simaka=true;
 393 fi
 394
 395 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
 396         radius=true;
 397 fi
 398
 399 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
 400         tnc_tnccs=true;
 401 fi
 402
 403 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
 404         tls=true;
 405 fi
 406
 407 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
 408         imcv=true;
 409 fi
 410
 411 if test x$fips_prf = xtrue; then
 412         if test x$openssl = xfalse; then
 413                 sha1=true;
 414         fi
 415 fi
 416
 417 if test x$swanctl = xtrue; then
 418         vici=true
 419 fi
 420
 421 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
 422         xml=true
 423 fi
 424
 425 if test x$manager = xtrue; then
 426         fast=true
 427 fi
 428
 429 if test x$medsrv = xtrue; then
 430         mediation=true
 431         fast=true
 432 fi
 433
 434 if test x$medcli = xtrue; then
 435         mediation=true
 436 fi
 437
 438 if test x$ruby_gems_install = xtrue; then
 439         ruby_gems=true
 440 fi
 441
 442 if test x$python_eggs_install = xtrue; then
 443         python_eggs=true
 444 fi
 445
 446 # ===========================================
 447 #  check required libraries and header files
 448 # ===========================================
 449
 450 AC_HEADER_STDBOOL
 451 AC_FUNC_ALLOCA
 452 AC_FUNC_STRERROR_R
 453
 454 #  libraries needed on some platforms but not on others
 455 # ------------------------------------------------------
 456 saved_LIBS=$LIBS
 457
 458 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
 459 LIBS=""
 460 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
 461 AC_SUBST(DLLIB)
 462
 463 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
 464 LIBS=""
 465 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
 466 AC_CHECK_FUNCS(backtrace)
 467 AC_SUBST(BTLIB)
 468
 469 # OpenSolaris needs libsocket and libnsl for socket()
 470 LIBS=""
 471 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
 472         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
 473 )
 474 AC_SUBST(SOCKLIB)
 475
 476 # Android has pthread_* functions in bionic (libc), others need libpthread
 477 LIBS=""
 478 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
 479 AC_SUBST(PTHREADLIB)
 480
 481 LIBS=$saved_LIBS
 482 # ------------------------------------------------------
 483
 484 AC_MSG_CHECKING(for dladdr)
 485 AC_COMPILE_IFELSE(
 486         [AC_LANG_PROGRAM(
 487                 [[#define _GNU_SOURCE
 488                   #include <dlfcn.h>]],
 489                 [[Dl_info* info = 0;
 490                   dladdr(0, info);]])],
 491         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
 492         [AC_MSG_RESULT([no])]
 493 )
 494
 495 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
 496 saved_LIBS=$LIBS
 497 LIBS=$PTHREADLIB
 498 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
 499 AC_RUN_IFELSE(
 500         [AC_LANG_SOURCE(
 501                 [[#include <pthread.h>
 502                   int main() { pthread_condattr_t attr;
 503                         pthread_condattr_init(&attr);
 504                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
 505         [AC_MSG_RESULT([yes]);
 506          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 507                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
 508         [AC_MSG_RESULT([no])],
 509         # Check existence of pthread_condattr_setclock if cross-compiling
 510         [AC_MSG_RESULT([unknown]);
 511          AC_CHECK_FUNCS(pthread_condattr_setclock,
 512                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 513                                    [have pthread_condattr_setclock()])]
 514         )]
 515 )
 516 # check if we actually are able to configure attributes on cond vars
 517 AC_CHECK_FUNCS(pthread_condattr_init)
 518 # instead of pthread_condattr_setclock Android has this function
 519 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
 520 # check if we can cancel threads
 521 AC_CHECK_FUNCS(pthread_cancel)
 522 # check if native rwlocks are available
 523 AC_CHECK_FUNCS(pthread_rwlock_init)
 524 # check if pthread spinlocks are available
 525 AC_CHECK_FUNCS(pthread_spin_init)
 526 # check if we have POSIX semaphore functions, including timed-wait
 527 AC_CHECK_FUNCS(sem_timedwait)
 528 LIBS=$saved_LIBS
 529
 530 AC_CHECK_FUNC(
 531         [gettid],
 532         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
 533         [AC_MSG_CHECKING([for SYS_gettid])
 534          AC_COMPILE_IFELSE(
 535                 [AC_LANG_PROGRAM(
 536                         [[#define _GNU_SOURCE
 537                           #include <unistd.h>
 538                           #include <sys/syscall.h>]],
 539                         [[int main() {
 540                           return syscall(SYS_gettid);}]])],
 541                 [AC_MSG_RESULT([yes]);
 542                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
 543                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
 544                 [AC_MSG_RESULT([no])]
 545         )]
 546 )
 547
 548 AC_CHECK_FUNC(
 549         [qsort_r],
 550         [
 551                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
 552                 # set -Werror so that we get an error for "argument ... has
 553                 # incompatible pointer type" warnings
 554                 save_CFLAGS="$CFLAGS"
 555                 CFLAGS="$CFLAGS -Werror"
 556                 AC_MSG_CHECKING([for GNU-style qsort_r])
 557                 AC_COMPILE_IFELSE(
 558                         [AC_LANG_PROGRAM(
 559                                 [[#define _GNU_SOURCE
 560                                   #include <stdlib.h>
 561                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
 562                                 [[int arr[] = { 0, 1 };
 563                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
 564                 [AC_MSG_RESULT([yes]);
 565                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
 566                 [
 567                         AC_MSG_RESULT([no]);
 568                         AC_MSG_CHECKING([for BSD-style qsort_r])
 569                         AC_COMPILE_IFELSE(
 570                                 [AC_LANG_PROGRAM(
 571                                         [[#include <stdlib.h>
 572                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
 573                                         [[int arr[] = { 0, 1 };
 574                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
 575                         [AC_MSG_RESULT([yes]);
 576                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
 577                         [AC_MSG_RESULT([no]);
 578                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
 579                 ])
 580                 CFLAGS="$save_CFLAGS"
 581         ]
 582 )
 583
 584 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
 585 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime)
 586
 587 AC_CHECK_FUNC([syslog], [
 588         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
 589         syslog=true
 590 ])
 591 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
 592
 593 AC_CHECK_HEADERS(sys/sockio.h glob.h net/if_tun.h)
 594 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
 595 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
 596 [
 597         #include <sys/types.h>
 598         #include <netinet/in.h>
 599 ])
 600
 601 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
 602 [
 603         #include <sys/types.h>
 604         #include <sys/socket.h>
 605 ])
 606
 607 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
 608 [
 609         #include <sys/types.h>
 610         #ifdef HAVE_NET_PFKEYV2_H
 611         #include <net/pfkeyv2.h>
 612         #else
 613         #include <stdint.h>
 614         #include <linux/pfkeyv2.h>
 615         #endif
 616 ])
 617
 618 AC_MSG_CHECKING([for in6addr_any])
 619 AC_COMPILE_IFELSE(
 620         [AC_LANG_PROGRAM(
 621                 [[#include <sys/types.h>
 622                   #include <sys/socket.h>
 623                   #include <netinet/in.h>]],
 624                 [[struct in6_addr in6 __attribute__((unused));
 625                   in6 = in6addr_any;]])],
 626         [AC_MSG_RESULT([yes]);
 627          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
 628         [AC_MSG_RESULT([no])]
 629 )
 630
 631 AC_MSG_CHECKING([for in6_pktinfo])
 632 AC_COMPILE_IFELSE(
 633         [AC_LANG_PROGRAM(
 634                 [[#define _GNU_SOURCE
 635                   #include <sys/types.h>
 636                   #include <sys/socket.h>
 637                   #include <netinet/in.h>]],
 638                 [[struct in6_pktinfo pi;
 639                   if (pi.ipi6_ifindex)
 640                   {
 641                     return 0;
 642                   }]])],
 643         [AC_MSG_RESULT([yes]);
 644          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
 645         [AC_MSG_RESULT([no])]
 646 )
 647
 648 AC_MSG_CHECKING([for RTM_IFANNOUNCE])
 649 AC_COMPILE_IFELSE(
 650         [AC_LANG_PROGRAM(
 651                 [[#include <sys/socket.h>
 652                   #include <net/if.h>
 653                   #include <net/route.h>]],
 654                 [[return RTM_IFANNOUNCE;]])],
 655         [AC_MSG_RESULT([yes]);
 656          AC_DEFINE([HAVE_RTM_IFANNOUNCE], [], [have PF_ROUTE RTM_IFANNOUNCE defined])],
 657         [AC_MSG_RESULT([no])]
 658 )
 659
 660 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
 661 AC_COMPILE_IFELSE(
 662         [AC_LANG_PROGRAM(
 663                 [[#include <sys/types.h>
 664                   #ifdef HAVE_NETIPSEC_IPSEC_H
 665                   #include <netipsec/ipsec.h>
 666                   #elif defined(HAVE_NETINET6_IPSEC_H)
 667                   #include <netinet6/ipsec.h>
 668                   #else
 669                   #include <stdint.h>
 670                   #include <linux/ipsec.h>
 671                   #endif]],
 672                 [[int mode = IPSEC_MODE_BEET;
 673                   return mode;]])],
 674         [AC_MSG_RESULT([yes]);
 675          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
 676         [AC_MSG_RESULT([no])]
 677 )
 678
 679 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
 680 AC_COMPILE_IFELSE(
 681         [AC_LANG_PROGRAM(
 682                 [[#include <sys/types.h>
 683                   #ifdef HAVE_NETIPSEC_IPSEC_H
 684                   #include <netipsec/ipsec.h>
 685                   #elif defined(HAVE_NETINET6_IPSEC_H)
 686                   #include <netinet6/ipsec.h>
 687                   #else
 688                   #include <stdint.h>
 689                   #include <linux/ipsec.h>
 690                   #endif]],
 691                 [[int dir = IPSEC_DIR_FWD;
 692                   return dir;]])],
 693         [AC_MSG_RESULT([yes]);
 694          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
 695         [AC_MSG_RESULT([no])]
 696 )
 697
 698 AC_MSG_CHECKING([for RTA_TABLE])
 699 AC_COMPILE_IFELSE(
 700         [AC_LANG_PROGRAM(
 701                 [[#include <sys/socket.h>
 702                   #include <linux/netlink.h>
 703                   #include <linux/rtnetlink.h>]],
 704                 [[int rta_type = RTA_TABLE;
 705                   return rta_type;]])],
 706         [AC_MSG_RESULT([yes]);
 707          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
 708         [AC_MSG_RESULT([no])]
 709 )
 710
 711 AC_MSG_CHECKING([for __int128])
 712 AC_COMPILE_IFELSE(
 713         [AC_LANG_PROGRAM(
 714                 [[#include <sys/types.h>]],
 715                 [[__int128 x = 0;
 716                   return x;]])],
 717         [AC_MSG_RESULT([yes]);
 718          AC_DEFINE([HAVE_INT128], [], [have __int128 type support])],
 719         [AC_MSG_RESULT([no])]
 720 )
 721
 722 AC_MSG_CHECKING([for GCC __sync operations])
 723 AC_RUN_IFELSE([AC_LANG_SOURCE(
 724         [[
 725                         int main() {
 726                         int ref = 1;
 727                         __sync_fetch_and_add (&ref, 1);
 728                         __sync_sub_and_fetch (&ref, 1);
 729                         __sync_val_compare_and_swap(&ref, 1, 0);
 730                         return ref;
 731                 }
 732         ]])],
 733         [AC_MSG_RESULT([yes]);
 734          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
 735                    [have GCC __sync_* operations])],
 736         [AC_MSG_RESULT([no])],
 737         [AC_MSG_RESULT([no])]
 738 )
 739
 740 case "$printf_hooks" in
 741 auto|builtin|glibc|vstr)
 742         ;;
 743 *)
 744         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
 745         printf_hooks=auto
 746         ;;
 747 esac
 748
 749 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
 750         # check for the new register_printf_specifier function with len argument,
 751         # or the deprecated register_printf_function without
 752         AC_CHECK_FUNC(
 753                 [register_printf_specifier],
 754                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
 755                 [AC_CHECK_FUNC(
 756                         [register_printf_function],
 757                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
 758                         [
 759                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
 760                                 if test x$printf_hooks = xglibc; then
 761                                         AC_MSG_ERROR([please select a different printf hook implementation])
 762                                 else
 763                                         # fallback to builtin printf hook implementation
 764                                         printf_hooks=builtin
 765                                 fi
 766                         ]
 767                 )]
 768         )
 769 fi
 770
 771 AC_MSG_CHECKING([for Windows target])
 772 AC_COMPILE_IFELSE(
 773         [AC_LANG_PROGRAM(
 774                 [[#include <windows.h>]],
 775                 [[#ifndef WIN32
 776                   # error WIN32 undefined
 777                   #endif
 778                 ]])],
 779         [
 780                 AC_MSG_RESULT([yes])
 781                 windows=true
 782                 openssl_lib=eay32
 783                 AC_SUBST(PTHREADLIB, "")
 784                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
 785                 case "$CFLAGS" in
 786                         *ms-bitfields*) ;;
 787                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
 788                 esac
 789         ],
 790         [
 791                 AC_MSG_RESULT([no])
 792                 openssl_lib=crypto
 793
 794                 # check for clock_gettime() on non-Windows only. Otherwise this
 795                 # check might find clock_gettime() in libwinpthread, but we don't want
 796                 # to link against it.
 797                 saved_LIBS=$LIBS
 798                 # FreeBSD has clock_gettime in libc, Linux needs librt
 799                 LIBS=""
 800                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
 801                 AC_CHECK_FUNCS(clock_gettime)
 802                 AC_SUBST(RTLIB)
 803                 LIBS=$saved_LIBS
 804         ]
 805 )
 806 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
 807 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
 808
 809 AC_MSG_CHECKING([for working __attribute__((packed))])
 810 AC_COMPILE_IFELSE(
 811         [AC_LANG_PROGRAM([], [[
 812                 struct test { char a; short b; } __attribute__((packed));
 813                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
 814                         __attribute__((unused));
 815                 return 0;
 816         ]])],
 817         [AC_MSG_RESULT([yes])],
 818         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
 819 )
 820
 821 AC_MSG_CHECKING([clang])
 822 AC_COMPILE_IFELSE(
 823         [AC_LANG_PROGRAM(
 824                 [], [[
 825                  #ifndef __clang__
 826                  # error not using LLVM clang
 827                  #endif
 828                 ]])],
 829         [
 830                 AC_MSG_RESULT([yes])
 831         ],
 832         [
 833                 AC_MSG_RESULT([no])
 834                 # GCC, but not MinGW requires -rdynamic for plugins
 835                 if test x$windows != xtrue; then
 836                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
 837                 fi
 838         ]
 839 )
 840
 841 if test x$printf_hooks = xvstr; then
 842         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
 843         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
 844 fi
 845
 846 if test x$printf_hooks = xbuiltin; then
 847         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
 848 fi
 849
 850 if test x$gmp = xtrue; then
 851         saved_LIBS=$LIBS
 852         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
 853         AC_MSG_CHECKING([mpz_powm_sec])
 854         if test x$mpz_powm_sec = xyes; then
 855                 AC_COMPILE_IFELSE(
 856                         [AC_LANG_PROGRAM(
 857                                 [[#include "gmp.h"]],
 858                                 [[void *x = mpz_powm_sec;]])],
 859                         [AC_MSG_RESULT([yes]);
 860                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
 861                         [AC_MSG_RESULT([no])]
 862                 )
 863         else
 864                 AC_MSG_RESULT([disabled])
 865         fi
 866         LIBS=$saved_LIBS
 867         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
 868         AC_COMPILE_IFELSE(
 869                 [AC_LANG_PROGRAM(
 870                         [[#include "gmp.h"]],
 871                         [[
 872                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
 873                                         #error bad gmp
 874                                 #endif]])],
 875                 [AC_MSG_RESULT([yes])],
 876                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
 877         )
 878 fi
 879
 880 if test x$ldap = xtrue; then
 881         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
 882         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
 883         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
 884 fi
 885
 886 if test x$curl = xtrue; then
 887         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
 888         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
 889 fi
 890
 891 if test x$unbound = xtrue; then
 892         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
 893         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
 894         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
 895         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
 896 fi
 897
 898 if test x$soup = xtrue; then
 899         PKG_CHECK_MODULES(soup, [libsoup-2.4])
 900         AC_SUBST(soup_CFLAGS)
 901         AC_SUBST(soup_LIBS)
 902 fi
 903
 904 if test x$xml = xtrue; then
 905         PKG_CHECK_MODULES(xml, [libxml-2.0])
 906         AC_SUBST(xml_CFLAGS)
 907         AC_SUBST(xml_LIBS)
 908 fi
 909
 910 if test x$systemd = xtrue; then
 911         AC_MSG_CHECKING([for systemd system unit directory])
 912         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
 913                 AC_MSG_RESULT([$systemdsystemunitdir])
 914         else
 915                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
 916         fi
 917
 918         PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
 919         AC_SUBST(systemd_daemon_CFLAGS)
 920         AC_SUBST(systemd_daemon_LIBS)
 921
 922         PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
 923         AC_SUBST(systemd_journal_CFLAGS)
 924         AC_SUBST(systemd_journal_LIBS)
 925 fi
 926
 927 if test x$tss = xtrousers; then
 928         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
 929         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
 930         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
 931 fi
 932
 933 if test x$imv_swid = xtrue; then
 934         PKG_CHECK_MODULES(json, [json-c], [],
 935                 [PKG_CHECK_MODULES(json, [json])])
 936         AC_SUBST(json_CFLAGS)
 937         AC_SUBST(json_LIBS)
 938 fi
 939
 940 if test x$dumm = xtrue; then
 941         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
 942         AC_SUBST(gtk_CFLAGS)
 943         AC_SUBST(gtk_LIBS)
 944         AC_CHECK_PROGS(RUBY, ruby)
 945         AC_MSG_CHECKING([for Ruby header files])
 946         if test -n "$RUBY"; then
 947                 RUBYINCLUDE=
 948                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
 949                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 950                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
 951                         if test -n "$RUBYARCH"; then
 952                                 AC_MSG_RESULT([$RUBYDIR])
 953                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
 954                         fi
 955                 else
 956                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
 957                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 958                                 AC_MSG_RESULT([$RUBYDIR])
 959                                 RUBYINCLUDE="-I$RUBYDIR"
 960                         fi
 961                 fi
 962                 if test -z "$RUBYINCLUDE"; then
 963                         AC_MSG_ERROR([ruby.h not found])
 964                 fi
 965                 AC_SUBST(RUBYINCLUDE)
 966         else
 967                 AC_MSG_ERROR([don't know how to run ruby])
 968         fi
 969         AC_MSG_CHECKING([for libruby])
 970         saved_LIBS=$LIBS
 971         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
 972         AC_TRY_LINK_FUNC(ruby_init,
 973                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
 974                 [AC_MSG_ERROR([not found])])
 975         AC_SUBST(RUBYLIB)
 976         AC_CHECK_FUNCS(rb_errinfo)
 977         LIBS=$saved_LIBS
 978 fi
 979
 980 if test x$fast = xtrue; then
 981         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
 982         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
 983         AC_MSG_CHECKING([ClearSilver requires zlib])
 984         saved_CFLAGS=$CFLAGS
 985         saved_LIBS=$LIBS
 986         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
 987         CFLAGS="-I/usr/include/ClearSilver"
 988         AC_LINK_IFELSE(
 989                 [AC_LANG_PROGRAM(
 990                         [[#include <ClearSilver.h>]],
 991                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
 992                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
 993                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
 994         )
 995         AC_SUBST(clearsilver_LIBS)
 996         LIBS=$saved_LIBS
 997         CFLAGS=$saved_CFLAGS
 998 # autoconf does not like CamelCase!? How to fix this?
 999 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
1000
1001         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
1002         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
1003 fi
1004
1005 if test x$mysql = xtrue; then
1006         if test "x$windows" = xtrue; then
1007                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
1008                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
1009                 AC_SUBST(MYSQLLIB, -lmysql)
1010         else
1011                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1012                 if test x$MYSQLCONFIG = x; then
1013                         AC_MSG_ERROR([mysql_config not found!])
1014                 fi
1015                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
1016                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
1017         fi
1018 fi
1019
1020 if test x$sqlite = xtrue; then
1021         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
1022         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
1023         AC_MSG_CHECKING([sqlite3_prepare_v2])
1024         AC_COMPILE_IFELSE(
1025                 [AC_LANG_PROGRAM(
1026                         [[#include <sqlite3.h>]],
1027                         [[void *test = sqlite3_prepare_v2;]])],
1028                 [AC_MSG_RESULT([yes]);
1029                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
1030                 [AC_MSG_RESULT([no])]
1031         )
1032         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
1033         AC_COMPILE_IFELSE(
1034                 [AC_LANG_PROGRAM(
1035                         [[#include <sqlite3.h>]],
1036                         [[
1037                                 #if SQLITE_VERSION_NUMBER < 3003001
1038                                         #error bad sqlite
1039                                 #endif]])],
1040                 [AC_MSG_RESULT([yes])],
1041                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1042         )
1043 fi
1044
1045 if test x$openssl = xtrue; then
1046         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[])
1047         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1048 fi
1049
1050 if test x$gcrypt = xtrue; then
1051         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1052         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1053         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1054         AC_COMPILE_IFELSE(
1055                 [AC_LANG_PROGRAM(
1056                         [[#include <gcrypt.h>]],
1057                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1058                 [AC_MSG_RESULT([yes]);
1059                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1060                 [AC_MSG_RESULT([no])]
1061         )
1062 fi
1063
1064 if test x$uci = xtrue; then
1065         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1066         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1067 fi
1068
1069 if test x$android_dns = xtrue; then
1070         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1071         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1072         # we have to force the use of libdl here because the autodetection
1073         # above does not work correctly when cross-compiling for android.
1074         DLLIB="-ldl"
1075         AC_SUBST(DLLIB)
1076 fi
1077
1078 if test x$maemo = xtrue; then
1079         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
1080         AC_SUBST(maemo_CFLAGS)
1081         AC_SUBST(maemo_LIBS)
1082         dbusservicedir="/usr/share/dbus-1/system-services"
1083         AC_SUBST(dbusservicedir)
1084 fi
1085
1086 if test x$eap_sim_pcsc = xtrue; then
1087         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1088         AC_SUBST(pcsclite_CFLAGS)
1089         AC_SUBST(pcsclite_LIBS)
1090 fi
1091
1092 if test x$nm = xtrue; then
1093         PKG_CHECK_EXISTS([libnm-glib],
1094                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1095                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1096         )
1097         AC_SUBST(nm_CFLAGS)
1098         AC_SUBST(nm_LIBS)
1099 fi
1100
1101 if test x$xauth_pam = xtrue; then
1102         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1103         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1104 fi
1105
1106 if test x$connmark = xtrue -o x$forecast = xtrue; then
1107         PKG_CHECK_MODULES(libiptc, [libiptc])
1108         AC_SUBST(libiptc_CFLAGS)
1109         AC_SUBST(libiptc_LIBS)
1110 fi
1111
1112 if test x$capabilities = xnative; then
1113         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1114         # Linux requires the following for capset(), Android does not have it,
1115         # but defines capset() in unistd.h instead.
1116         AC_CHECK_HEADERS([sys/capability.h])
1117         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1118         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1119 fi
1120
1121 if test x$capabilities = xlibcap; then
1122         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1123         AC_CHECK_HEADER([sys/capability.h],
1124                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1125                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1126         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1127 fi
1128
1129 if test x$integrity_test = xtrue; then
1130         AC_MSG_CHECKING([for dladdr()])
1131         AC_COMPILE_IFELSE(
1132                 [AC_LANG_PROGRAM(
1133                         [[#define _GNU_SOURCE
1134                           #include <dlfcn.h>]],
1135                         [[Dl_info info; dladdr(main, &info);]])],
1136                 [AC_MSG_RESULT([yes])],
1137                 [AC_MSG_RESULT([no]);
1138                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1139         )
1140         AC_MSG_CHECKING([for dl_iterate_phdr()])
1141         AC_COMPILE_IFELSE(
1142                 [AC_LANG_PROGRAM(
1143                         [[#define _GNU_SOURCE
1144                           #include <link.h>]],
1145                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1146                 [AC_MSG_RESULT([yes])],
1147                 [AC_MSG_RESULT([no]);
1148                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1149         )
1150 fi
1151
1152 if test x$bfd_backtraces = xtrue; then
1153         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1154         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1155                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1156         BFDLIB="-lbfd"
1157         AC_SUBST(BFDLIB)
1158 fi
1159
1160 if test x$unwind_backtraces = xtrue; then
1161         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1162         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1163                 [AC_MSG_ERROR([libunwind.h header not found!])])
1164         UNWINDLIB="-lunwind"
1165         AC_SUBST(UNWINDLIB)
1166 fi
1167
1168 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1169 if test x$dev_headers = xyes; then
1170         dev_headers="$includedir/strongswan"
1171 fi
1172 AC_SUBST(dev_headers)
1173
1174 CFLAGS="$CFLAGS -include `pwd`/config.h"
1175
1176 if test x$tkm = xtrue; then
1177         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1178         if test x$GPRBUILD = x; then
1179                 AC_MSG_ERROR([gprbuild not found])
1180         fi
1181 fi
1182
1183 if test x$coverage = xtrue; then
1184         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1185         if test x$LCOV = x; then
1186                 AC_MSG_ERROR([lcov not found])
1187         fi
1188         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1189         if test x$GENHTML = x; then
1190                 AC_MSG_ERROR([genhtml not found])
1191         fi
1192
1193         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1194         COVERAGE_LDFLAGS="-fprofile-arcs"
1195         AC_SUBST(COVERAGE_CFLAGS)
1196         AC_SUBST(COVERAGE_LDFLAGS)
1197
1198         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1199         CFLAGS="${CFLAGS} -g -O0"
1200 fi
1201
1202 if test x$ruby_gems = xtrue; then
1203         AC_PATH_PROG([GEM], [gem], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1204         if test x$GEM = x; then
1205                 AC_MSG_ERROR(RubyGems package manager not found)
1206         fi
1207         if test "x$rubygemdir" = "xgem environment gemdir"; then
1208                 rubygemdir=$($GEM environment gemdir)
1209         fi
1210         AC_SUBST(RUBYGEMDIR, "$rubygemdir")
1211 fi
1212 AM_CONDITIONAL(RUBY_GEMS_INSTALL, [test "x$ruby_gems_install" = xtrue])
1213
1214 if test x$python_eggs = xtrue; then
1215         if test x$python_eggs_install = xtrue; then
1216                 AC_PATH_PROG([EASY_INSTALL], [easy_install], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1217                 if test x$EASY_INSTALL = x; then
1218                         AC_MSG_ERROR(Python easy_install not found)
1219                 fi
1220         fi
1221         if test "x$pythoneggdir" = "xmain site-packages directory"; then
1222                 AC_SUBST(PYTHONEGGINSTALLDIR, "")
1223         else
1224                 AC_SUBST(PYTHONEGGINSTALLDIR, "--install-dir $pythoneggdir")
1225         fi
1226         AC_PATH_PROG([PY_TEST], [py.test], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1227 fi
1228 AM_CONDITIONAL(PYTHON_EGGS_INSTALL, [test "x$python_eggs_install" = xtrue])
1229
1230 # ===============================================
1231 #  collect plugin list for strongSwan components
1232 # ===============================================
1233
1234 m4_include(m4/macros/add-plugin.m4)
1235
1236 # plugin lists for all components
1237 charon_plugins=
1238 starter_plugins=
1239 pool_plugins=
1240 attest_plugins=
1241 scepclient_plugins=
1242 pki_plugins=
1243 scripts_plugins=
1244 manager_plugins=
1245 medsrv_plugins=
1246 nm_plugins=
1247 cmd_plugins=
1248 aikgen_plugins=
1249
1250 # location specific lists for checksumming,
1251 # for src/libcharon, src/libhydra, src/libstrongswan and src/libtnccs
1252 c_plugins=
1253 h_plugins=
1254 s_plugins=
1255 t_plugins=
1256
1257 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1258 ADD_PLUGIN([unbound],              [s charon scripts])
1259 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1260 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1261 ADD_PLUGIN([aesni],                [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1262 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1263 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1264 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1265 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1266 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1267 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1268 ADD_PLUGIN([md4],                  [s charon manager scepclient pki nm cmd])
1269 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1270 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1271 ADD_PLUGIN([random],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1272 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1273 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1274 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1275 ADD_PLUGIN([constraints],          [s charon nm cmd])
1276 ADD_PLUGIN([acert],                [s charon])
1277 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1278 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1279 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1280 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1281 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1282 ADD_PLUGIN([pgp],                  [s charon])
1283 ADD_PLUGIN([dnskey],               [s charon pki])
1284 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1285 ADD_PLUGIN([dnscert],              [c charon])
1286 ADD_PLUGIN([ipseckey],             [c charon])
1287 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1288 ADD_PLUGIN([padlock],              [s charon])
1289 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1290 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1291 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1292 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1293 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1294 ADD_PLUGIN([agent],                [s charon nm cmd])
1295 ADD_PLUGIN([keychain],             [s charon cmd])
1296 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1297 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1298 ADD_PLUGIN([hmac],                 [s charon pki scripts nm cmd])
1299 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1300 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1301 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1302 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1303 ADD_PLUGIN([bliss],                [s charon pki scripts nm cmd])
1304 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1305 ADD_PLUGIN([files],                [s charon scepclient pki scripts nm cmd])
1306 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1307 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1308 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1309 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1310 ADD_PLUGIN([attr],                 [c charon])
1311 ADD_PLUGIN([attr-sql],             [c charon])
1312 ADD_PLUGIN([load-tester],          [c charon])
1313 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1314 ADD_PLUGIN([kernel-wfp],           [c charon])
1315 ADD_PLUGIN([kernel-iph],           [c charon])
1316 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1317 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1318 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1319 ADD_PLUGIN([resolve],              [c charon cmd])
1320 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1321 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1322 ADD_PLUGIN([socket-win],           [c charon])
1323 ADD_PLUGIN([connmark],             [c charon])
1324 ADD_PLUGIN([forecast],             [c charon])
1325 ADD_PLUGIN([farp],                 [c charon])
1326 ADD_PLUGIN([stroke],               [c charon])
1327 ADD_PLUGIN([vici],                 [c charon])
1328 ADD_PLUGIN([smp],                  [c charon])
1329 ADD_PLUGIN([sql],                  [c charon])
1330 ADD_PLUGIN([updown],               [c charon])
1331 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1332 ADD_PLUGIN([eap-sim],              [c charon])
1333 ADD_PLUGIN([eap-sim-file],         [c charon])
1334 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1335 ADD_PLUGIN([eap-aka],              [c charon])
1336 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1337 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1338 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1339 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1340 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1341 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1342 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1343 ADD_PLUGIN([eap-dynamic],          [c charon])
1344 ADD_PLUGIN([eap-radius],           [c charon])
1345 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1346 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1347 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1348 ADD_PLUGIN([eap-tnc],              [c charon])
1349 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1350 ADD_PLUGIN([xauth-eap],            [c charon])
1351 ADD_PLUGIN([xauth-pam],            [c charon])
1352 ADD_PLUGIN([xauth-noauth],         [c charon])
1353 ADD_PLUGIN([tnc-ifmap],            [c charon])
1354 ADD_PLUGIN([tnc-pdp],              [c charon])
1355 ADD_PLUGIN([tnc-imc],              [t charon])
1356 ADD_PLUGIN([tnc-imv],              [t charon])
1357 ADD_PLUGIN([tnc-tnccs],            [t charon])
1358 ADD_PLUGIN([tnccs-20],             [t charon])
1359 ADD_PLUGIN([tnccs-11],             [t charon])
1360 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1361 ADD_PLUGIN([medsrv],               [c charon])
1362 ADD_PLUGIN([medcli],               [c charon])
1363 ADD_PLUGIN([dhcp],                 [c charon])
1364 ADD_PLUGIN([osx-attr],             [c charon cmd])
1365 ADD_PLUGIN([android-dns],          [c charon])
1366 ADD_PLUGIN([android-log],          [c charon])
1367 ADD_PLUGIN([ha],                   [c charon])
1368 ADD_PLUGIN([whitelist],            [c charon])
1369 ADD_PLUGIN([ext-auth],             [c charon])
1370 ADD_PLUGIN([lookip],               [c charon])
1371 ADD_PLUGIN([error-notify],         [c charon])
1372 ADD_PLUGIN([certexpire],           [c charon])
1373 ADD_PLUGIN([systime-fix],          [c charon])
1374 ADD_PLUGIN([led],                  [c charon])
1375 ADD_PLUGIN([duplicheck],           [c charon])
1376 ADD_PLUGIN([coupling],             [c charon])
1377 ADD_PLUGIN([radattr],              [c charon])
1378 ADD_PLUGIN([maemo],                [c charon])
1379 ADD_PLUGIN([uci],                  [c charon])
1380 ADD_PLUGIN([addrblock],            [c charon])
1381 ADD_PLUGIN([unity],                [c charon])
1382
1383 AC_SUBST(charon_plugins)
1384 AC_SUBST(starter_plugins)
1385 AC_SUBST(pool_plugins)
1386 AC_SUBST(attest_plugins)
1387 AC_SUBST(scepclient_plugins)
1388 AC_SUBST(pki_plugins)
1389 AC_SUBST(scripts_plugins)
1390 AC_SUBST(manager_plugins)
1391 AC_SUBST(medsrv_plugins)
1392 AC_SUBST(nm_plugins)
1393 AC_SUBST(cmd_plugins)
1394 AC_SUBST(aikgen_plugins)
1395
1396 AC_SUBST(c_plugins)
1397 AC_SUBST(h_plugins)
1398 AC_SUBST(s_plugins)
1399 AC_SUBST(t_plugins)
1400
1401 # ======================
1402 #  set Makefile.am vars
1403 # ======================
1404
1405 #  libstrongswan plugins
1406 # -----------------------
1407 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1408 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1409 AM_CONDITIONAL(USE_FILES, test x$files = xtrue)
1410 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1411 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1412 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1413 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1414 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1415 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1416 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1417 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1418 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1419 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1420 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1421 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1422 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1423 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1424 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1425 AM_CONDITIONAL(USE_AESNI, test x$aesni = xtrue)
1426 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1427 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1428 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1429 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1430 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1431 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1432 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1433 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1434 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1435 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1436 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1437 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1438 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1439 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1440 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1441 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1442 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1443 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1444 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1445 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1446 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1447 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1448 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1449 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1450 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1451 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1452 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1453 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1454 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1455 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1456 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1457 AM_CONDITIONAL(USE_BLISS, test x$bliss = xtrue)
1458
1459 #  charon plugins
1460 # ----------------
1461 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1462 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1463 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1464 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1465 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1466 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1467 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1468 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1469 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1470 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1471 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1472 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1473 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1474 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1475 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1476 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1477 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1478 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1479 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1480 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1481 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1482 AM_CONDITIONAL(USE_EXT_AUTH, test x$ext_auth = xtrue)
1483 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1484 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1485 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1486 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1487 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1488 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1489 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1490 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1491 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1492 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1493 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1494 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1495 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1496 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1497 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1498 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1499 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1500 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1501 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1502 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1503 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1504 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1505 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1506 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1507 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1508 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1509 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1510 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1511 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1512 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1513 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1514 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1515 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1516 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1517 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1518 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1519 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1520 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1521 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1522 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1523 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1524 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1525 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1526 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1527 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1528 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1529 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1530 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1531 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1532 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1533 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1534 AM_CONDITIONAL(USE_CONNMARK, test x$connmark = xtrue)
1535 AM_CONDITIONAL(USE_FORECAST, test x$forecast = xtrue)
1536 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1537 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1538 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1539 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1540 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1541 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1542
1543 #  hydra plugins
1544 # ---------------
1545 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1546 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1547 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1548
1549 #  other options
1550 # ---------------
1551 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1552 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1553 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1554 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1555 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1556 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1557 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1558 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1559 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1560 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1561 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1562 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1563 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1564 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1565 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1566 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1567 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1568 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1569 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1570 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1571 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1572 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1573 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1574 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1575 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1576 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1577 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1578 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1579 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1580 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1581 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1582 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1583 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1584 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1585 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers -o x$aikgen = xtrue)
1586 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1587 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1588 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1589 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1590 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1591 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1592 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1593 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1594 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1595 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1596 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1597 AM_CONDITIONAL(USE_RUBY_GEMS, test x$ruby_gems = xtrue)
1598 AM_CONDITIONAL(USE_PYTHON_EGGS, test x$python_eggs = xtrue)
1599 AM_CONDITIONAL(USE_PY_TEST, test "x$PY_TEST" != x)
1600
1601 # ========================
1602 #  set global definitions
1603 # ========================
1604
1605 if test x$mediation = xtrue; then
1606         AC_DEFINE([ME], [], [mediation extension support])
1607 fi
1608 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1609         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1610 fi
1611 if test x$monolithic = xtrue; then
1612         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1613 fi
1614 if test x$ikev1 = xtrue; then
1615         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1616 fi
1617 if test x$ikev2 = xtrue; then
1618         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1619 fi
1620
1621 # ====================================================
1622 #  options for enabled modules (see conf/Makefile.am)
1623 # ====================================================
1624
1625 strongswan_options=
1626
1627 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1628 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1629 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1630 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1631 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1632 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1633 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1634 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1635 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1636 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1637 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1638 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1639 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1640
1641 AC_SUBST(strongswan_options)
1642
1643 # =================
1644 #  build Makefiles
1645 # =================
1646
1647 AC_CONFIG_FILES([
1648         Makefile
1649         conf/Makefile
1650         man/Makefile
1651         init/Makefile
1652         init/systemd/Makefile
1653         init/systemd-swanctl/Makefile
1654         src/Makefile
1655         src/include/Makefile
1656         src/libstrongswan/Makefile
1657         src/libstrongswan/plugins/aes/Makefile
1658         src/libstrongswan/plugins/cmac/Makefile
1659         src/libstrongswan/plugins/des/Makefile
1660         src/libstrongswan/plugins/blowfish/Makefile
1661         src/libstrongswan/plugins/rc2/Makefile
1662         src/libstrongswan/plugins/md4/Makefile
1663         src/libstrongswan/plugins/md5/Makefile
1664         src/libstrongswan/plugins/sha1/Makefile
1665         src/libstrongswan/plugins/sha2/Makefile
1666         src/libstrongswan/plugins/fips_prf/Makefile
1667         src/libstrongswan/plugins/gmp/Makefile
1668         src/libstrongswan/plugins/rdrand/Makefile
1669         src/libstrongswan/plugins/aesni/Makefile
1670         src/libstrongswan/plugins/random/Makefile
1671         src/libstrongswan/plugins/nonce/Makefile
1672         src/libstrongswan/plugins/hmac/Makefile
1673         src/libstrongswan/plugins/xcbc/Makefile
1674         src/libstrongswan/plugins/x509/Makefile
1675         src/libstrongswan/plugins/revocation/Makefile
1676         src/libstrongswan/plugins/constraints/Makefile
1677         src/libstrongswan/plugins/acert/Makefile
1678         src/libstrongswan/plugins/pubkey/Makefile
1679         src/libstrongswan/plugins/pkcs1/Makefile
1680         src/libstrongswan/plugins/pkcs7/Makefile
1681         src/libstrongswan/plugins/pkcs8/Makefile
1682         src/libstrongswan/plugins/pkcs12/Makefile
1683         src/libstrongswan/plugins/pgp/Makefile
1684         src/libstrongswan/plugins/dnskey/Makefile
1685         src/libstrongswan/plugins/sshkey/Makefile
1686         src/libstrongswan/plugins/pem/Makefile
1687         src/libstrongswan/plugins/curl/Makefile
1688         src/libstrongswan/plugins/files/Makefile
1689         src/libstrongswan/plugins/winhttp/Makefile
1690         src/libstrongswan/plugins/unbound/Makefile
1691         src/libstrongswan/plugins/soup/Makefile
1692         src/libstrongswan/plugins/ldap/Makefile
1693         src/libstrongswan/plugins/mysql/Makefile
1694         src/libstrongswan/plugins/sqlite/Makefile
1695         src/libstrongswan/plugins/padlock/Makefile
1696         src/libstrongswan/plugins/openssl/Makefile
1697         src/libstrongswan/plugins/gcrypt/Makefile
1698         src/libstrongswan/plugins/agent/Makefile
1699         src/libstrongswan/plugins/keychain/Makefile
1700         src/libstrongswan/plugins/pkcs11/Makefile
1701         src/libstrongswan/plugins/ctr/Makefile
1702         src/libstrongswan/plugins/ccm/Makefile
1703         src/libstrongswan/plugins/gcm/Makefile
1704         src/libstrongswan/plugins/af_alg/Makefile
1705         src/libstrongswan/plugins/ntru/Makefile
1706         src/libstrongswan/plugins/bliss/Makefile
1707         src/libstrongswan/plugins/bliss/tests/Makefile
1708         src/libstrongswan/plugins/test_vectors/Makefile
1709         src/libstrongswan/tests/Makefile
1710         src/libhydra/Makefile
1711         src/libhydra/plugins/kernel_netlink/Makefile
1712         src/libhydra/plugins/kernel_pfkey/Makefile
1713         src/libhydra/plugins/kernel_pfroute/Makefile
1714         src/libhydra/tests/Makefile
1715         src/libipsec/Makefile
1716         src/libsimaka/Makefile
1717         src/libtls/Makefile
1718         src/libtls/tests/Makefile
1719         src/libradius/Makefile
1720         src/libtncif/Makefile
1721         src/libtnccs/Makefile
1722         src/libtnccs/plugins/tnc_tnccs/Makefile
1723         src/libtnccs/plugins/tnc_imc/Makefile
1724         src/libtnccs/plugins/tnc_imv/Makefile
1725         src/libtnccs/plugins/tnccs_11/Makefile
1726         src/libtnccs/plugins/tnccs_20/Makefile
1727         src/libtnccs/plugins/tnccs_dynamic/Makefile
1728         src/libpttls/Makefile
1729         src/libimcv/Makefile
1730         src/libimcv/plugins/imc_test/Makefile
1731         src/libimcv/plugins/imv_test/Makefile
1732         src/libimcv/plugins/imc_scanner/Makefile
1733         src/libimcv/plugins/imv_scanner/Makefile
1734         src/libimcv/plugins/imc_os/Makefile
1735         src/libimcv/plugins/imv_os/Makefile
1736         src/libimcv/plugins/imc_attestation/Makefile
1737         src/libimcv/plugins/imv_attestation/Makefile
1738         src/libimcv/plugins/imc_swid/Makefile
1739         src/libimcv/plugins/imv_swid/Makefile
1740         src/charon/Makefile
1741         src/charon-nm/Makefile
1742         src/charon-tkm/Makefile
1743         src/charon-cmd/Makefile
1744         src/charon-svc/Makefile
1745         src/charon-systemd/Makefile
1746         src/libcharon/Makefile
1747         src/libcharon/plugins/eap_aka/Makefile
1748         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1749         src/libcharon/plugins/eap_dynamic/Makefile
1750         src/libcharon/plugins/eap_identity/Makefile
1751         src/libcharon/plugins/eap_md5/Makefile
1752         src/libcharon/plugins/eap_gtc/Makefile
1753         src/libcharon/plugins/eap_sim/Makefile
1754         src/libcharon/plugins/eap_sim_file/Makefile
1755         src/libcharon/plugins/eap_sim_pcsc/Makefile
1756         src/libcharon/plugins/eap_simaka_sql/Makefile
1757         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1758         src/libcharon/plugins/eap_simaka_reauth/Makefile
1759         src/libcharon/plugins/eap_mschapv2/Makefile
1760         src/libcharon/plugins/eap_tls/Makefile
1761         src/libcharon/plugins/eap_ttls/Makefile
1762         src/libcharon/plugins/eap_peap/Makefile
1763         src/libcharon/plugins/eap_tnc/Makefile
1764         src/libcharon/plugins/eap_radius/Makefile
1765         src/libcharon/plugins/xauth_generic/Makefile
1766         src/libcharon/plugins/xauth_eap/Makefile
1767         src/libcharon/plugins/xauth_pam/Makefile
1768         src/libcharon/plugins/xauth_noauth/Makefile
1769         src/libcharon/plugins/tnc_ifmap/Makefile
1770         src/libcharon/plugins/tnc_pdp/Makefile
1771         src/libcharon/plugins/socket_default/Makefile
1772         src/libcharon/plugins/socket_dynamic/Makefile
1773         src/libcharon/plugins/socket_win/Makefile
1774         src/libcharon/plugins/connmark/Makefile
1775         src/libcharon/plugins/forecast/Makefile
1776         src/libcharon/plugins/farp/Makefile
1777         src/libcharon/plugins/smp/Makefile
1778         src/libcharon/plugins/sql/Makefile
1779         src/libcharon/plugins/dnscert/Makefile
1780         src/libcharon/plugins/ipseckey/Makefile
1781         src/libcharon/plugins/medsrv/Makefile
1782         src/libcharon/plugins/medcli/Makefile
1783         src/libcharon/plugins/addrblock/Makefile
1784         src/libcharon/plugins/unity/Makefile
1785         src/libcharon/plugins/uci/Makefile
1786         src/libcharon/plugins/ha/Makefile
1787         src/libcharon/plugins/kernel_libipsec/Makefile
1788         src/libcharon/plugins/kernel_wfp/Makefile
1789         src/libcharon/plugins/kernel_iph/Makefile
1790         src/libcharon/plugins/whitelist/Makefile
1791         src/libcharon/plugins/ext_auth/Makefile
1792         src/libcharon/plugins/lookip/Makefile
1793         src/libcharon/plugins/error_notify/Makefile
1794         src/libcharon/plugins/certexpire/Makefile
1795         src/libcharon/plugins/systime_fix/Makefile
1796         src/libcharon/plugins/led/Makefile
1797         src/libcharon/plugins/duplicheck/Makefile
1798         src/libcharon/plugins/coupling/Makefile
1799         src/libcharon/plugins/radattr/Makefile
1800         src/libcharon/plugins/osx_attr/Makefile
1801         src/libcharon/plugins/android_dns/Makefile
1802         src/libcharon/plugins/android_log/Makefile
1803         src/libcharon/plugins/maemo/Makefile
1804         src/libcharon/plugins/stroke/Makefile
1805         src/libcharon/plugins/vici/Makefile
1806         src/libcharon/plugins/vici/ruby/Makefile
1807         src/libcharon/plugins/vici/python/Makefile
1808         src/libcharon/plugins/updown/Makefile
1809         src/libcharon/plugins/dhcp/Makefile
1810         src/libcharon/plugins/load_tester/Makefile
1811         src/libcharon/plugins/resolve/Makefile
1812         src/libcharon/plugins/attr/Makefile
1813         src/libcharon/plugins/attr_sql/Makefile
1814         src/libcharon/tests/Makefile
1815         src/stroke/Makefile
1816         src/ipsec/Makefile
1817         src/starter/Makefile
1818         src/starter/tests/Makefile
1819         src/_updown/Makefile
1820         src/_copyright/Makefile
1821         src/scepclient/Makefile
1822         src/aikgen/Makefile
1823         src/pki/Makefile
1824         src/pki/man/Makefile
1825         src/pool/Makefile
1826         src/dumm/Makefile
1827         src/dumm/ext/extconf.rb
1828         src/libfast/Makefile
1829         src/manager/Makefile
1830         src/medsrv/Makefile
1831         src/checksum/Makefile
1832         src/conftest/Makefile
1833         src/pt-tls-client/Makefile
1834         src/swanctl/Makefile
1835         scripts/Makefile
1836         testing/Makefile
1837 ])
1838
1839 # =================
1840 #  build man pages
1841 # =================
1842
1843 AC_CONFIG_FILES([
1844         conf/strongswan.conf.5.head
1845         conf/strongswan.conf.5.tail
1846         man/ipsec.conf.5
1847         man/ipsec.secrets.5
1848         src/charon-cmd/charon-cmd.8
1849         src/pki/man/pki.1
1850         src/pki/man/pki---gen.1
1851         src/pki/man/pki---issue.1
1852         src/pki/man/pki---keyid.1
1853         src/pki/man/pki---pkcs7.1
1854         src/pki/man/pki---pkcs12.1
1855         src/pki/man/pki---print.1
1856         src/pki/man/pki---pub.1
1857         src/pki/man/pki---req.1
1858         src/pki/man/pki---self.1
1859         src/pki/man/pki---signcrl.1
1860         src/pki/man/pki---acert.1
1861         src/pki/man/pki---verify.1
1862         src/swanctl/swanctl.8
1863         src/swanctl/swanctl.conf.5.head
1864         src/swanctl/swanctl.conf.5.tail
1865 ])
1866
1867 AC_OUTPUT
1868
1869 # ========================
1870 #  report enabled plugins
1871 # ========================
1872
1873 AC_MSG_RESULT([])
1874 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1875 AC_MSG_RESULT([-----------------------------------------------------])
1876
1877 AC_MSG_RESULT([libstrongswan:$s_plugins])
1878 AC_MSG_RESULT([libcharon:    $c_plugins])
1879 AC_MSG_RESULT([libhydra:     $h_plugins])
1880 AC_MSG_RESULT([libtnccs:     $t_plugins])
1881 AC_MSG_RESULT([])