configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl First, define all of the version numbers up front.
   4 dnl In particular, this allows the version macro to be used in AC_INIT
   5
   6 dnl These first two version numbers are updated automatically on each release.
   7 m4_define([LIBARCHIVE_VERSION_S],[3.5.3dev])
   8 m4_define([LIBARCHIVE_VERSION_N],[3005003])
   9
  10 dnl bsdtar and bsdcpio versioning tracks libarchive
  11 m4_define([BSDTAR_VERSION_S],LIBARCHIVE_VERSION_S())
  12 m4_define([BSDCPIO_VERSION_S],LIBARCHIVE_VERSION_S())
  13 m4_define([BSDCAT_VERSION_S],LIBARCHIVE_VERSION_S())
  14
  15 AC_PREREQ([2.69])
  16
  17 #
  18 # Now starts the "real" configure script.
  19 #
  20
  21 AC_INIT([libarchive],[LIBARCHIVE_VERSION_S()],[libarchive-discuss@googlegroups.com])
  22 # Make sure the srcdir contains "libarchive" directory
  23 AC_CONFIG_SRCDIR([libarchive])
  24 # Use auxiliary subscripts from this subdirectory (cleans up root)
  25 AC_CONFIG_AUX_DIR([build/autoconf])
  26 # M4 scripts
  27 AC_CONFIG_MACRO_DIR([build/autoconf])
  28 # Must follow AC_CONFIG macros above...
  29 AM_INIT_AUTOMAKE([1.11 dist-xz dist-zip])
  30 AM_MAINTAINER_MODE([enable])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 # Libtool's "interface version" can be computed from the libarchive version.
  34
  35 # Libtool interface version bumps on any API change, so increments
  36 # whenever libarchive minor version does.
  37 ARCHIVE_MINOR=$(( (LIBARCHIVE_VERSION_N() / 1000) % 1000 ))
  38 # Libarchive 2.7 == libtool interface 9 = 2 + 7
  39 # Libarchive 2.8 == libtool interface 10 = 2 + 8
  40 # Libarchive 2.9 == libtool interface 11 = 2 + 8
  41 # Libarchive 3.0 == libtool interface 12
  42 # Libarchive 3.1 == libtool interface 13
  43 ARCHIVE_INTERFACE=`echo $((13 + ${ARCHIVE_MINOR}))`
  44 # Libarchive revision is bumped on any source change === libtool revision
  45 ARCHIVE_REVISION=$(( LIBARCHIVE_VERSION_N() % 1000 ))
  46 # Libarchive minor is bumped on any interface addition === libtool age
  47 ARCHIVE_LIBTOOL_VERSION=$ARCHIVE_INTERFACE:$ARCHIVE_REVISION:$ARCHIVE_MINOR
  48
  49 # Stick the version numbers into config.h
  50 AC_DEFINE([__LIBARCHIVE_CONFIG_H_INCLUDED], [1],
  51         [Internal macro for sanity checks])
  52 AC_DEFINE([LIBARCHIVE_VERSION_STRING],"LIBARCHIVE_VERSION_S()",
  53         [Version number of libarchive])
  54 AC_DEFINE_UNQUOTED([LIBARCHIVE_VERSION_NUMBER],"LIBARCHIVE_VERSION_N()",
  55         [Version number of libarchive as a single integer])
  56 AC_DEFINE([BSDCPIO_VERSION_STRING],"BSDCPIO_VERSION_S()",
  57         [Version number of bsdcpio])
  58 AC_DEFINE([BSDTAR_VERSION_STRING],"BSDTAR_VERSION_S()",
  59         [Version number of bsdtar])
  60 AC_DEFINE([BSDCAT_VERSION_STRING],"BSDTAR_VERSION_S()",
  61         [Version number of bsdcat])
  62
  63 # The shell variables here must be the same as the AC_SUBST() variables
  64 # below, but the shell variable names apparently cannot be the same as
  65 # the m4 macro names above.  Why?  Ask autoconf.
  66 BSDCPIO_VERSION_STRING=BSDCPIO_VERSION_S()
  67 BSDTAR_VERSION_STRING=BSDTAR_VERSION_S()
  68 BSDCAT_VERSION_STRING=BSDCAT_VERSION_S()
  69 LIBARCHIVE_VERSION_STRING=LIBARCHIVE_VERSION_S()
  70 LIBARCHIVE_VERSION_NUMBER=LIBARCHIVE_VERSION_N()
  71
  72 # Substitute the above version numbers into the various files below.
  73 # Yes, I believe this is the fourth time we define what are essentially
  74 # the same symbols.  Why? Ask autoconf.
  75 AC_SUBST(ARCHIVE_LIBTOOL_VERSION)
  76 AC_SUBST(BSDCPIO_VERSION_STRING)
  77 AC_SUBST(BSDTAR_VERSION_STRING)
  78 AC_SUBST(BSDCAT_VERSION_STRING)
  79 AC_SUBST(LIBARCHIVE_VERSION_STRING)
  80 AC_SUBST(LIBARCHIVE_VERSION_NUMBER)
  81
  82 AC_CONFIG_HEADERS([config.h])
  83 AC_CONFIG_FILES([Makefile])
  84 AC_CONFIG_FILES([build/pkgconfig/libarchive.pc])
  85
  86 # Check for host type
  87 AC_CANONICAL_HOST
  88
  89 dnl Compilation on mingw and Cygwin needs special Makefile rules
  90 inc_windows_files=no
  91 inc_cygwin_files=no
  92 case "$host_os" in
  93   *mingw* ) inc_windows_files=yes ;;
  94   *cygwin* | *msys*) inc_cygwin_files=yes ;;
  95 esac
  96 AM_CONDITIONAL([INC_WINDOWS_FILES], [test $inc_windows_files = yes])
  97 AM_CONDITIONAL([INC_CYGWIN_FILES], [test $inc_cygwin_files = yes])
  98
  99 dnl Defines that are required for specific platforms (e.g. -D_POSIX_SOURCE, etc)
 100 PLATFORMCPPFLAGS=
 101 case "$host_os" in
 102   *mingw* ) PLATFORMCPPFLAGS=-D__USE_MINGW_ANSI_STDIO ;;
 103 esac
 104 AC_SUBST(PLATFORMCPPFLAGS)
 105
 106 # Checks for programs.
 107 AC_PROG_CC
 108 AC_PROG_CC_C99
 109 AM_PROG_CC_C_O
 110 AC_PROG_CPP
 111 AC_USE_SYSTEM_EXTENSIONS
 112 AC_LIBTOOL_WIN32_DLL
 113 AC_PROG_LIBTOOL
 114 AC_CHECK_TOOL([STRIP],[strip])
 115 AC_PROG_MKDIR_P
 116
 117 #
 118 # Options for building bsdtar.
 119 #
 120 # Default is to build bsdtar, but allow people to override that.
 121 #
 122 AC_ARG_ENABLE([bsdtar],
 123         [AS_HELP_STRING([--enable-bsdtar], [enable build of bsdtar (default)])
 124         AS_HELP_STRING([--enable-bsdtar=static], [force static build of bsdtar])
 125         AS_HELP_STRING([--enable-bsdtar=shared], [force dynamic build of bsdtar])
 126 AS_HELP_STRING([--disable-bsdtar], [disable build of bsdtar])],
 127         [], [enable_bsdtar=yes])
 128
 129 case "$enable_bsdtar" in
 130 yes)
 131         if test "$enable_static" = "no"; then
 132                 static_bsdtar=no
 133         else
 134                 static_bsdtar=yes
 135         fi
 136         build_bsdtar=yes
 137         ;;
 138 dynamic|shared)
 139         if test "$enable_shared" = "no"; then
 140                 AC_MSG_FAILURE([Shared linking of bsdtar requires shared libarchive])
 141         fi
 142         build_bsdtar=yes
 143         static_bsdtar=no
 144         ;;
 145 static)
 146         build_bsdtar=yes
 147         static_bsdtar=yes
 148         ;;
 149 no)
 150         build_bsdtar=no
 151         static_bsdtar=no
 152         ;;
 153 *)
 154         AC_MSG_FAILURE([Unsupported value for --enable-bsdtar])
 155         ;;
 156 esac
 157
 158 AM_CONDITIONAL([BUILD_BSDTAR], [ test "$build_bsdtar" = yes ])
 159 AM_CONDITIONAL([STATIC_BSDTAR], [ test "$static_bsdtar" = yes ])
 160
 161 #
 162 # Options for building bsdcat.
 163 #
 164 # Default is to build bsdcat, but allow people to override that.
 165 #
 166 AC_ARG_ENABLE([bsdcat],
 167         [AS_HELP_STRING([--enable-bsdcat], [enable build of bsdcat (default)])
 168         AS_HELP_STRING([--enable-bsdcat=static], [force static build of bsdcat])
 169         AS_HELP_STRING([--enable-bsdcat=shared], [force dynamic build of bsdcat])
 170 AS_HELP_STRING([--disable-bsdcat], [disable build of bsdcat])],
 171         [], [enable_bsdcat=yes])
 172
 173 case "$enable_bsdcat" in
 174 yes)
 175         if test "$enable_static" = "no"; then
 176                 static_bsdcat=no
 177         else
 178                 static_bsdcat=yes
 179         fi
 180         build_bsdcat=yes
 181         ;;
 182 dynamic|shared)
 183         if test "$enable_shared" = "no"; then
 184                 AC_MSG_FAILURE([Shared linking of bsdcat requires shared libarchive])
 185         fi
 186         build_bsdcat=yes
 187         static_bsdcat=no
 188         ;;
 189 static)
 190         build_bsdcat=yes
 191         static_bsdcat=yes
 192         ;;
 193 no)
 194         build_bsdcat=no
 195         static_bsdcat=no
 196         ;;
 197 *)
 198         AC_MSG_FAILURE([Unsupported value for --enable-bsdcat])
 199         ;;
 200 esac
 201
 202 AM_CONDITIONAL([BUILD_BSDCAT], [ test "$build_bsdcat" = yes ])
 203 AM_CONDITIONAL([STATIC_BSDCAT], [ test "$static_bsdcat" = yes ])
 204
 205 #
 206 # Options for building bsdcpio.
 207 #
 208 # Default is not to build bsdcpio, but that can be overridden.
 209 #
 210 AC_ARG_ENABLE([bsdcpio],
 211         [AS_HELP_STRING([--enable-bsdcpio], [enable build of bsdcpio (default)])
 212         AS_HELP_STRING([--enable-bsdcpio=static], [static build of bsdcpio])
 213         AS_HELP_STRING([--enable-bsdcpio=shared], [dynamic build of bsdcpio])
 214 AS_HELP_STRING([--disable-bsdcpio], [disable build of bsdcpio])],
 215         [], [enable_bsdcpio=yes])
 216
 217 case "$enable_bsdcpio" in
 218 yes)
 219         if test "$enable_static" = "no"; then
 220            static_bsdcpio=no
 221         else
 222            static_bsdcpio=yes
 223         fi
 224         build_bsdcpio=yes
 225         ;;
 226 dynamic|shared)
 227         if test "$enabled_shared" = "no"; then
 228            AC_MSG_FAILURE([Shared linking of bsdcpio requires shared libarchive])
 229         fi
 230         build_bsdcpio=yes
 231         ;;
 232 static)
 233         build_bsdcpio=yes
 234         static_bsdcpio=yes
 235         ;;
 236 no)
 237         build_bsdcpio=no
 238         static_bsdcpio=no
 239         ;;
 240 *)
 241         AC_MSG_FAILURE([Unsupported value for --enable-bsdcpio])
 242         ;;
 243 esac
 244
 245 AM_CONDITIONAL([BUILD_BSDCPIO], [ test "$build_bsdcpio" = yes ])
 246 AM_CONDITIONAL([STATIC_BSDCPIO], [ test "$static_bsdcpio" = yes ])
 247
 248 # Set up defines needed before including any headers
 249 case $host in
 250   *mingw* | *cygwin* | *msys*  )
 251   AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 252     [[#ifdef _WIN32_WINNT
 253      # error _WIN32_WINNT already defined
 254      #endif
 255     ]],[[;]])
 256   ],[
 257     AC_DEFINE([_WIN32_WINNT], 0x0502, [Define to '0x0502' for Windows Server 2003 APIs.])
 258     AC_DEFINE([NTDDI_VERSION], 0x05020000, [Define to '0x05020000' for Windows Server 2003 APIs.])
 259   ])
 260   AC_PREPROC_IFELSE([AC_LANG_PROGRAM(
 261     [[#ifdef WINVER
 262      # error WINVER already defined
 263      #endif
 264     ]],[[;]])
 265   ],[
 266     AC_DEFINE([WINVER], 0x0502, [Define to '0x0502' for Windows Server 2003 APIs.])
 267   ])
 268   ;;
 269 esac
 270
 271 # Checks for header files.
 272 AC_HEADER_DIRENT
 273 AC_HEADER_SYS_WAIT
 274 AC_CHECK_HEADERS([acl/libacl.h attr/xattr.h])
 275 AC_CHECK_HEADERS([copyfile.h ctype.h])
 276 AC_CHECK_HEADERS([errno.h ext2fs/ext2_fs.h fcntl.h grp.h])
 277
 278 AC_CACHE_CHECK([whether EXT2_IOC_GETFLAGS is usable],
 279     [ac_cv_have_decl_EXT2_IOC_GETFLAGS],
 280     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([@%:@include <sys/ioctl.h>
 281 @%:@include <ext2fs/ext2_fs.h>],
 282                                    [int x = EXT2_IOC_GETFLAGS])],
 283                   [AS_VAR_SET([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [yes])],
 284                   [AS_VAR_SET([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [no])])])
 285
 286 AS_VAR_IF([ac_cv_have_decl_EXT2_IOC_GETFLAGS], [yes],
 287     [AC_DEFINE_UNQUOTED([HAVE_WORKING_EXT2_IOC_GETFLAGS], [1],
 288                     [Define to 1 if you have a working EXT2_IOC_GETFLAGS])])
 289
 290 AC_CHECK_HEADERS([inttypes.h io.h langinfo.h limits.h])
 291 AC_CHECK_HEADERS([linux/fiemap.h linux/fs.h linux/magic.h linux/types.h])
 292
 293 AC_CACHE_CHECK([whether FS_IOC_GETFLAGS is usable],
 294     [ac_cv_have_decl_FS_IOC_GETFLAGS],
 295     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([@%:@include <sys/ioctl.h>
 296 @%:@include <linux/fs.h>],
 297                                    [int x = FS_IOC_GETFLAGS])],
 298                   [AS_VAR_SET([ac_cv_have_decl_FS_IOC_GETFLAGS], [yes])],
 299                   [AS_VAR_SET([ac_cv_have_decl_FS_IOC_GETFLAGS], [no])])])
 300
 301 AS_VAR_IF([ac_cv_have_decl_FS_IOC_GETFLAGS], [yes],
 302     [AC_DEFINE_UNQUOTED([HAVE_WORKING_FS_IOC_GETFLAGS], [1],
 303                     [Define to 1 if you have a working FS_IOC_GETFLAGS])])
 304
 305 AC_CHECK_HEADERS([locale.h membership.h paths.h poll.h pthread.h pwd.h])
 306 AC_CHECK_HEADERS([readpassphrase.h signal.h spawn.h])
 307 AC_CHECK_HEADERS([stdarg.h stdint.h stdlib.h string.h])
 308 AC_CHECK_HEADERS([sys/acl.h sys/cdefs.h sys/ea.h sys/extattr.h])
 309 AC_CHECK_HEADERS([sys/ioctl.h sys/mkdev.h sys/mount.h])
 310 AC_CHECK_HEADERS([sys/param.h sys/poll.h sys/richacl.h])
 311 AC_CHECK_HEADERS([sys/select.h sys/statfs.h sys/statvfs.h sys/sysmacros.h])
 312 AC_CHECK_HEADERS([sys/time.h sys/utime.h sys/utsname.h sys/vfs.h sys/xattr.h])
 313 AC_CHECK_HEADERS([time.h unistd.h utime.h wchar.h wctype.h])
 314 AC_CHECK_HEADERS([windows.h])
 315 # check windows.h first; the other headers require it.
 316 AC_CHECK_HEADERS([wincrypt.h winioctl.h],[],[],
 317 [[#ifdef HAVE_WINDOWS_H
 318 # include <windows.h>
 319 #endif
 320 ]])
 321
 322 # Checks for libraries.
 323 AC_ARG_WITH([zlib],
 324   AS_HELP_STRING([--without-zlib], [Don't build support for gzip through zlib]))
 325
 326 if test "x$with_zlib" != "xno"; then
 327   AC_CHECK_HEADERS([zlib.h])
 328   AC_CHECK_LIB(z,inflate)
 329 fi
 330
 331 AC_ARG_WITH([bz2lib],
 332   AS_HELP_STRING([--without-bz2lib], [Don't build support for bzip2 through bz2lib]))
 333
 334 if test "x$with_bz2lib" != "xno"; then
 335   AC_CHECK_HEADERS([bzlib.h])
 336   case "$host_os" in
 337     *mingw* | *cygwin* | *msys*)
 338       dnl AC_CHECK_LIB cannot be used on the Windows port of libbz2, therefore
 339           dnl use AC_LINK_IFELSE.
 340           AC_MSG_CHECKING([for BZ2_bzDecompressInit in -lbz2])
 341       old_LIBS="$LIBS"
 342       LIBS="-lbz2 $LIBS"
 343       AC_LINK_IFELSE(
 344         [AC_LANG_SOURCE(#include <bzlib.h>
 345           int main() { return BZ2_bzDecompressInit(NULL, 0, 0); })],
 346         [ac_cv_lib_bz2_BZ2_bzDecompressInit=yes],
 347         [ac_cv_lib_bz2_BZ2_bzDecompressInit=no])
 348       LIBS="$old_LIBS"
 349           AC_MSG_RESULT($ac_cv_lib_bz2_BZ2_bzDecompressInit)
 350       if test "x$ac_cv_lib_bz2_BZ2_bzDecompressInit" = xyes; then
 351         AC_DEFINE([HAVE_LIBBZ2], [1], [Define to 1 if you have the `bz2' library (-lbz2).])
 352         LIBS="-lbz2 $LIBS"
 353       fi
 354     ;;
 355     *)
 356       AC_CHECK_LIB(bz2,BZ2_bzDecompressInit)
 357     ;;
 358   esac
 359 fi
 360
 361 AC_ARG_WITH([libb2],
 362   AS_HELP_STRING([--without-libb2], [Don't build support for BLAKE2 through libb2]))
 363
 364 if test "x$with_libb2" != "xno"; then
 365   AC_CHECK_HEADERS([blake2.h])
 366   AC_CHECK_LIB(b2,blake2sp_init)
 367 fi
 368
 369 AM_CONDITIONAL([INC_BLAKE2], [test "x$ac_cv_lib_b2_blake2sp_init" != "xyes"])
 370
 371 AC_ARG_WITH([iconv],
 372   AS_HELP_STRING([--without-iconv], [Don't try to link against iconv]))
 373
 374 if test "x$with_iconv" != "xno"; then
 375   AM_ICONV
 376   AC_CHECK_HEADERS([iconv.h],[],[],[#include <stdlib.h>])
 377   if test "x$am_cv_func_iconv" = "xyes"; then
 378     AC_CHECK_HEADERS([localcharset.h])
 379     am_save_LIBS="$LIBS"
 380     LIBS="${LIBS} ${LIBICONV}"
 381     AC_CHECK_FUNCS([locale_charset])
 382     LIBS="${am_save_LIBS}"
 383     if test "x$ac_cv_func_locale_charset" != "xyes"; then
 384       # If locale_charset() is not in libiconv, we have to find libcharset.
 385       AC_CHECK_LIB(charset,locale_charset)
 386     fi
 387   fi
 388 fi
 389
 390 AC_ARG_WITH([lz4],
 391   AS_HELP_STRING([--without-lz4], [Don't build support for lz4 through liblz4]))
 392
 393 if test "x$with_lz4" != "xno"; then
 394   AC_CHECK_HEADERS([lz4.h lz4hc.h])
 395   AC_CHECK_LIB(lz4,LZ4_decompress_safe)
 396 fi
 397
 398 AC_ARG_WITH([zstd],
 399   AS_HELP_STRING([--without-zstd], [Don't build support for zstd through libzstd]))
 400
 401 if test "x$with_zstd" != "xno"; then
 402   AC_CHECK_HEADERS([zstd.h])
 403   AC_CHECK_LIB(zstd,ZSTD_compressStream)
 404 fi
 405
 406 AC_ARG_WITH([lzma],
 407   AS_HELP_STRING([--without-lzma], [Don't build support for xz through lzma]))
 408
 409 if test "x$with_lzma" != "xno"; then
 410   AC_CHECK_HEADERS([lzma.h])
 411   AC_CHECK_LIB(lzma,lzma_stream_decoder)
 412   # Some pre-release (but widely distributed) versions of liblzma
 413   # included a disabled version of lzma_stream_encoder_mt that
 414   # fools a naive AC_CHECK_LIB or AC_CHECK_FUNC, so we need
 415   # to do something more complex here:
 416   AC_CACHE_CHECK(
 417     [whether we have multithread support in lzma],
 418     ac_cv_lzma_has_mt,
 419     [AC_LINK_IFELSE([
 420       AC_LANG_PROGRAM([[#include <lzma.h>]
 421                        [#if LZMA_VERSION < 50020000]
 422                        [#error unsupported]
 423                        [#endif]],
 424                       [[lzma_stream_encoder_mt(0, 0);]])],
 425       [ac_cv_lzma_has_mt=yes], [ac_cv_lzma_has_mt=no])])
 426   if test "x$ac_cv_lzma_has_mt" != xno; then
 427           AC_DEFINE([HAVE_LZMA_STREAM_ENCODER_MT], [1], [Define to 1 if you have the `lzma_stream_encoder_mt' function.])
 428   fi
 429 fi
 430
 431 AC_ARG_WITH([lzo2],
 432   AS_HELP_STRING([--with-lzo2], [Build with LZO support from liblzo2]))
 433
 434 if test "x$with_lzo2" = "xyes"; then
 435   AC_CHECK_HEADERS([lzo/lzoconf.h lzo/lzo1x.h])
 436   AC_CHECK_LIB(lzo2,lzo1x_decompress_safe)
 437 fi
 438
 439 AC_ARG_WITH([cng],
 440   AS_HELP_STRING([--without-cng], [Don't build support of CNG(Crypto Next Generation)]))
 441
 442 AC_ARG_WITH([mbedtls],
 443   AS_HELP_STRING([--with-mbedtls], [Build with crypto support from mbed TLS]))
 444 AC_ARG_WITH([nettle],
 445   AS_HELP_STRING([--with-nettle], [Build with crypto support from Nettle]))
 446 AC_ARG_WITH([openssl],
 447   AS_HELP_STRING([--without-openssl], [Don't build support for mtree and xar hashes through openssl]))
 448 case "$host_os" in
 449   *darwin* ) with_openssl=no ;;
 450 esac
 451
 452 AC_ARG_WITH([xml2],
 453   AS_HELP_STRING([--without-xml2], [Don't build support for xar through libxml2]))
 454 AC_ARG_WITH([expat],
 455   AS_HELP_STRING([--without-expat], [Don't build support for xar through expat]))
 456
 457 if test "x$with_xml2" != "xno"; then
 458   PKG_PROG_PKG_CONFIG
 459   PKG_CHECK_MODULES(LIBXML2_PC, [libxml-2.0], [
 460     CPPFLAGS="${CPPFLAGS} ${LIBXML2_PC_CFLAGS}"
 461     LIBS="${LIBS} ${LIBXML2_PC_LIBS}"
 462     AC_CHECK_LIB(xml2,xmlInitParser,[true],AC_MSG_FAILURE(Missing xml2 library))
 463   ], [
 464     AC_CHECK_LIB(xml2,xmlInitParser)
 465   ])
 466   AC_CHECK_HEADERS([libxml/xmlreader.h libxml/xmlwriter.h])
 467 fi
 468 if test "x$ac_cv_header_libxml_xmlreader_h" != "xyes"; then
 469   if test "x$with_expat" != "xno"; then
 470     AC_CHECK_HEADERS([expat.h])
 471     AC_CHECK_LIB(expat,XML_ParserCreate)
 472   fi
 473 fi
 474
 475 AC_ARG_ENABLE([posix-regex-lib],
 476   [AS_HELP_STRING([--enable-posix-regex-lib],
 477     [choose what library to use for POSIX regular expression support (default: auto)])
 478   AS_HELP_STRING([--enable-posix-regex-lib=libc], [use libc POSIX regular expression support])
 479   AS_HELP_STRING([--enable-posix-regex-lib=libregex], [use libregex POSIX regular expression support])
 480   AS_HELP_STRING([--enable-posix-regex-lib=libpcreposix], [use libpcreposix POSIX regular expression support])
 481   AS_HELP_STRING([--disable-posix-regex-lib], [don't enable POSIX regular expression support])],
 482   [], [enable_posix_regex_lib=auto])
 483
 484 posix_regex_lib_found=
 485 if test "$enable_posix_regex_lib" = "auto" || test "$enable_posix_regex_lib" = "libc" || test "$enable_posix_regex_lib" = "libregex"; then
 486   AC_CHECK_HEADERS([regex.h])
 487   if test "x$ac_cv_header_regex_h" != "xno"; then
 488     AC_CHECK_FUNC(regcomp)
 489     if test "x$ac_cv_func_regcomp" = xyes; then
 490       posix_regex_lib_found=1
 491     else
 492       AC_CHECK_LIB(regex,regcomp)
 493       if test "x$ac_cv_lib_regex_regcomp" = xyes; then
 494         posix_regex_lib_found=1
 495       fi
 496     fi
 497   fi
 498 fi
 499 if test -z $posix_regex_lib_found && (test "$enable_posix_regex_lib" = "auto" || test "$enable_posix_regex_lib" = "libpcreposix"); then
 500   AC_CHECK_HEADERS([pcreposix.h])
 501   AC_CHECK_LIB(pcreposix,regcomp)
 502   if test "x$ac_cv_lib_pcreposix_regcomp" != xyes; then
 503     AC_MSG_NOTICE(trying libpcreposix check again with libpcre)
 504         unset ac_cv_lib_pcreposix_regcomp
 505         AC_CHECK_LIB(pcre,pcre_exec)
 506     AC_CHECK_LIB(pcreposix,regcomp)
 507     if test "x$ac_cv_lib_pcre_pcre_exec" = xyes && test "x$ac_cv_lib_pcreposix_regcomp" = xyes; then
 508       AC_MSG_CHECKING(if PCRE_STATIC needs to be defined)
 509       AC_LINK_IFELSE(
 510         [AC_LANG_SOURCE(#include <pcreposix.h>
 511           int main() { return regcomp(NULL, NULL, 0); })],
 512         [without_pcre_static=yes],
 513         [without_pcre_static=no])
 514       AC_LINK_IFELSE(
 515         [AC_LANG_SOURCE(#define PCRE_STATIC
 516           #include <pcreposix.h>
 517           int main() { return regcomp(NULL, NULL, 0); })],
 518         [with_pcre_static=yes],
 519         [with_pcre_static=no])
 520       if test "x$without_pcre_static" != xyes && test "x$with_pcre_static" = xyes; then
 521         AC_MSG_RESULT(yes)
 522         AC_DEFINE([PCRE_STATIC], [1], [Define to 1 if PCRE_STATIC needs to be defined.])
 523       elif test "x$without_pcre_static" = xyes || test "x$with_pcre_static" = xyes; then
 524         AC_MSG_RESULT(no)
 525       fi
 526       posix_regex_lib_found=1
 527     fi
 528   else
 529     posix_regex_lib_found=1
 530   fi
 531 fi
 532
 533 # TODO: Give the user the option of using a pre-existing system
 534 # libarchive.  This will define HAVE_LIBARCHIVE which will cause
 535 # bsdtar_platform.h to use #include <...> for the libarchive headers.
 536 # Need to include Makefile.am magic to link against system
 537 # -larchive in that case.
 538 #AC_CHECK_LIB(archive,archive_version)
 539
 540 # Checks for supported compiler flags
 541 AX_APPEND_COMPILE_FLAGS([-Wall -Wformat -Wformat-security])
 542
 543 # Place the functions and data into separate sections, allowing the linker
 544 # to garbage collect the unused ones.
 545 save_LDFLAGS=$LDFLAGS
 546 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 547 AC_MSG_CHECKING([whether ld supports --gc-sections])
 548 AC_LINK_IFELSE(
 549     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 550     [AC_MSG_RESULT([yes])
 551         GC_SECTIONS="-Wl,--gc-sections";
 552         AX_APPEND_COMPILE_FLAGS([-ffunction-sections -fdata-sections])],
 553     [AC_MSG_RESULT([no])
 554         GC_SECTIONS="";])
 555 LDFLAGS=$save_LDFLAGS
 556
 557 AC_SUBST(GC_SECTIONS)
 558
 559 # Checks for typedefs, structures, and compiler characteristics.
 560 AC_C_CONST
 561 # la_TYPE_UID_T defaults to "int", which is incorrect for MinGW
 562 # and MSVC. Use a customized version.
 563 la_TYPE_UID_T
 564 AC_TYPE_MODE_T
 565 # AC_TYPE_OFF_T defaults to "long", which limits us to 4GB files on
 566 # most systems... default to "long long" instead.
 567 AC_CHECK_TYPE(off_t, [long long])
 568 AC_TYPE_SIZE_T
 569 AC_CHECK_TYPE(id_t, [unsigned long])
 570 AC_CHECK_TYPE(uintptr_t, [unsigned int])
 571
 572 # Check for tm_gmtoff in struct tm
 573 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,
 574 [
 575 #include <time.h>
 576 ])
 577
 578 # Check for f_namemax in struct statfs
 579 AC_CHECK_MEMBERS([struct statfs.f_namemax],,,
 580 [
 581 #include <sys/param.h>
 582 #include <sys/mount.h>
 583 ])
 584
 585 # Check for f_iosize in struct statfs
 586 AC_CHECK_MEMBERS([struct statfs.f_iosize],,,
 587 [
 588 #include <sys/param.h>
 589 #include <sys/mount.h>
 590 ])
 591
 592 # Check for f_iosize in struct statvfs
 593 AC_CHECK_MEMBERS([struct statvfs.f_iosize],,,
 594 [
 595 #include <sys/statvfs.h>
 596 ])
 597
 598 # Check for birthtime in struct stat
 599 AC_CHECK_MEMBERS([struct stat.st_birthtime])
 600
 601 # Check for high-resolution timestamps in struct stat
 602 AC_CHECK_MEMBERS([struct stat.st_birthtimespec.tv_nsec])
 603 AC_CHECK_MEMBERS([struct stat.st_mtimespec.tv_nsec])
 604 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec])
 605 AC_CHECK_MEMBERS([struct stat.st_mtime_n]) # AIX
 606 AC_CHECK_MEMBERS([struct stat.st_umtime]) # Tru64
 607 AC_CHECK_MEMBERS([struct stat.st_mtime_usec]) # Hurd
 608 # Check for block size support in struct stat
 609 AC_CHECK_MEMBERS([struct stat.st_blksize])
 610 # Check for st_flags in struct stat (BSD fflags)
 611 AC_CHECK_MEMBERS([struct stat.st_flags])
 612
 613 # If you have uintmax_t, we assume printf supports %ju
 614 # If you have unsigned long long, we assume printf supports %llu
 615 # TODO: Check for %ju and %llu support directly.
 616 AC_CHECK_TYPES([uintmax_t, unsigned long long])
 617
 618 # We use C99-style integer types
 619 # Declare them if the local platform doesn't already do so.
 620 AC_TYPE_INTMAX_T
 621 AC_TYPE_UINTMAX_T
 622 AC_TYPE_INT64_T
 623 AC_TYPE_UINT64_T
 624 AC_TYPE_INT32_T
 625 AC_TYPE_UINT32_T
 626 AC_TYPE_INT16_T
 627 AC_TYPE_UINT16_T
 628 AC_TYPE_UINT8_T
 629
 630 AC_CHECK_DECLS([SIZE_MAX, INT32_MAX, INT32_MIN])
 631 AC_CHECK_DECLS([INT64_MAX, INT64_MIN, UINT64_MAX, UINT32_MAX])
 632 AC_CHECK_DECLS([INTMAX_MAX, INTMAX_MIN, UINTMAX_MAX])
 633
 634 AC_CHECK_DECL([SSIZE_MAX],
 635                 [AC_DEFINE(HAVE_DECL_SSIZE_MAX, 1, [Define to 1 if you have the declaration of `SSIZE_MAX', and to 0 if you don't.])],
 636                 [],
 637                 [#include <limits.h>])
 638
 639 AC_CHECK_DECL([EFTYPE],
 640                 [AC_DEFINE(HAVE_EFTYPE, 1, [A possible errno value for invalid file format errors])],
 641                 [],
 642                 [#include <errno.h>])
 643 AC_CHECK_DECL([EILSEQ],
 644                 [AC_DEFINE(HAVE_EILSEQ, 1, [A possible errno value for invalid file format errors])],
 645                 [],
 646                 [#include <errno.h>])
 647 AC_CHECK_TYPE([wchar_t],
 648                 [AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]wchar_t), 1, [Define to 1 if the system has the type `wchar_t'.])dnl
 649                 AC_CHECK_SIZEOF([wchar_t])],
 650                 [])
 651
 652 AC_HEADER_TIME
 653
 654 # Checks for library functions.
 655 AC_PROG_GCC_TRADITIONAL
 656 AC_HEADER_MAJOR
 657 AC_FUNC_FSEEKO
 658 AC_FUNC_MEMCMP
 659 AC_FUNC_LSTAT
 660 AC_FUNC_STAT
 661 AC_FUNC_STRERROR_R
 662 AC_FUNC_STRFTIME
 663 AC_FUNC_VPRINTF
 664 # check for:
 665 #   CreateHardLinkA(LPCSTR, LPCSTR, LPSECURITY_ATTRIBUTES)
 666 # To avoid necessity for including windows.h or special forward declaration
 667 # workarounds, we use 'void *' for 'struct SECURITY_ATTRIBUTES *'
 668 AC_CHECK_STDCALL_FUNC([CreateHardLinkA],[const char *, const char *, void *])
 669 AC_CHECK_FUNCS([arc4random_buf chflags chown chroot ctime_r])
 670 AC_CHECK_FUNCS([fchdir fchflags fchmod fchown fcntl fdopendir fork])
 671 AC_CHECK_FUNCS([fstat fstatat fstatfs fstatvfs ftruncate])
 672 AC_CHECK_FUNCS([futimens futimes futimesat])
 673 AC_CHECK_FUNCS([geteuid getpid getgrgid_r getgrnam_r])
 674 AC_CHECK_FUNCS([getpwnam_r getpwuid_r getvfsbyname gmtime_r])
 675 AC_CHECK_FUNCS([lchflags lchmod lchown link linkat localtime_r lstat lutimes])
 676 AC_CHECK_FUNCS([mbrtowc memmove memset])
 677 AC_CHECK_FUNCS([mkdir mkfifo mknod mkstemp])
 678 AC_CHECK_FUNCS([nl_langinfo openat pipe poll posix_spawnp readlink readlinkat])
 679 AC_CHECK_FUNCS([readpassphrase])
 680 AC_CHECK_FUNCS([select setenv setlocale sigaction statfs statvfs])
 681 AC_CHECK_FUNCS([strchr strdup strerror strncpy_s strnlen strrchr symlink])
 682 AC_CHECK_FUNCS([timegm tzset unlinkat unsetenv utime utimensat utimes vfork])
 683 AC_CHECK_FUNCS([wcrtomb wcscmp wcscpy wcslen wctomb wmemcmp wmemcpy wmemmove])
 684 AC_CHECK_FUNCS([_ctime64_s _fseeki64])
 685 AC_CHECK_FUNCS([_get_timezone _gmtime64_s _localtime64_s _mkgmtime64])
 686 # detects cygwin-1.7, as opposed to older versions
 687 AC_CHECK_FUNCS([cygwin_conv_path])
 688
 689 # DragonFly uses vfsconf, FreeBSD xvfsconf.
 690 AC_CHECK_TYPES(struct vfsconf,,,
 691         [#if HAVE_SYS_TYPES_H
 692         #include <sys/types.h>
 693         #endif
 694         #include <sys/mount.h>
 695         ])
 696
 697 AC_CHECK_TYPES(struct xvfsconf,,,
 698         [#if HAVE_SYS_TYPES_H
 699         #include <sys/types.h>
 700         #endif
 701         #include <sys/mount.h>
 702         ])
 703
 704 AC_CHECK_TYPES(struct statfs,,,
 705         [#if HAVE_SYS_TYPES_H
 706         #include <sys/types.h>
 707         #endif
 708         #include <sys/mount.h>
 709         ])
 710
 711 # There are several variants of readdir_r around; we only
 712 # accept the POSIX-compliant version.
 713 AC_COMPILE_IFELSE(
 714  [AC_LANG_PROGRAM([[#include <dirent.h>]],
 715                   [[DIR *dir; struct dirent e, *r;
 716                     return(readdir_r(dir, &e, &r));]])],
 717  [AC_DEFINE(HAVE_READDIR_R,1,[Define to 1 if you have a POSIX compatible readdir_r])]
 718 )
 719 # dirfd can be either a function or a macro.
 720 AC_COMPILE_IFELSE(
 721  [AC_LANG_PROGRAM([[#include <dirent.h>
 722                     DIR *dir;]],
 723                   [[return(dirfd(dir));]])],
 724  [AC_DEFINE(HAVE_DIRFD,1,[Define to 1 if you have a dirfd function or macro])]
 725 )
 726
 727 # FreeBSD's nl_langinfo supports an option to specify whether the
 728 # current locale uses month/day or day/month ordering.  It makes the
 729 # output a little prettier...
 730 AC_CHECK_DECL([D_MD_ORDER],
 731 [AC_DEFINE(HAVE_D_MD_ORDER, 1, [Define to 1 if nl_langinfo supports D_MD_ORDER])],
 732 [],
 733 [#if HAVE_LANGINFO_H
 734 #include <langinfo.h>
 735 #endif
 736 ])
 737
 738 # Check for dirent.d_namlen field explicitly
 739 # (This is a bit more straightforward than, if not quite as portable as,
 740 # the recipe given by the autoconf maintainers.)
 741 AC_CHECK_MEMBER(struct dirent.d_namlen,,,
 742 [#if HAVE_DIRENT_H
 743 #include <dirent.h>
 744 #endif
 745 ])
 746
 747 # Check for Extended Attributes support
 748 AC_ARG_ENABLE([xattr],
 749                 AS_HELP_STRING([--disable-xattr],
 750                 [Disable Extended Attributes support (default: check)]))
 751
 752 if test "x$enable_xattr" != "xno"; then
 753     AC_SEARCH_LIBS([setxattr], [attr gnu])
 754     AC_CHECK_DECLS([EXTATTR_NAMESPACE_USER], [], [], [#include <sys/types.h>
 755 #include <sys/extattr.h>
 756 ])
 757     AC_CHECK_DECLS([XATTR_NOFOLLOW], [], [], [#include <sys/xattr.h>
 758 ])
 759     if test "x$ac_cv_header_sys_xattr_h" = "xyes" \
 760          -a "x$ac_cv_have_decl_XATTR_NOFOLLOW" = "xyes"; then
 761         # Darwin extended attributes support
 762         AC_CACHE_VAL([ac_cv_archive_xattr_darwin],
 763           [AC_CHECK_FUNCS(fgetxattr \
 764                           flistxattr \
 765                           fsetxattr \
 766                           getxattr \
 767                           listxattr \
 768                           setxattr,
 769           [ac_cv_archive_xattr_darwin=yes],
 770           [ac_cv_archive_xattr_darwin=no],
 771           [#include <sys/xattr.h>
 772 ])
 773         ]
 774       )
 775     elif test "x$ac_cv_header_sys_extattr_h" = "xyes" \
 776            -a "x$ac_cv_have_decl_EXTATTR_NAMESPACE_USER" = "xyes"; then
 777         # FreeBSD extended attributes support
 778         AC_CACHE_VAL([ac_cv_archive_xattr_freebsd],
 779           [AC_CHECK_FUNCS(extattr_get_fd \
 780                           extattr_get_file \
 781                           extattr_get_link \
 782                           extattr_list_fd \
 783                           extattr_list_file \
 784                           extattr_list_link \
 785                           extattr_set_fd \
 786                           extattr_set_link,
 787           [ac_cv_archive_xattr_freebsd=yes],
 788           [ac_cv_archive_xattr_freebsd=no],
 789           [#include <sys/types.h>
 790 #include <sys/extattr.h>
 791 ])
 792           ]
 793         )
 794     elif test "x$ac_cv_header_sys_xattr_h" = "xyes" \
 795            -o "x$ac_cv_header_attr_xattr_h" = "xyes"; then
 796         # Linux extended attributes support
 797         AC_CACHE_VAL([ac_cv_archive_xattr_linux],
 798           [AC_CHECK_FUNCS(fgetxattr \
 799                           flistxattr \
 800                           fsetxattr \
 801                           getxattr \
 802                           lgetxattr \
 803                           listxattr \
 804                           llistxattr \
 805                           lsetxattr,
 806           [ac_cv_archive_xattr_linux=yes],
 807           [ac_cv_archive_xattr_linux=no],
 808           [#if HAVE_SYS_TYPES_H
 809 #include <sys/types.h>
 810 #endif
 811 #if HAVE_SYS_XATTR_H
 812 #include <sys/xattr.h>
 813 #endif
 814 #if HAVE_ATTR_XATTR_H
 815 #include <attr/xatr.h>
 816 #endif
 817 ])
 818         ]
 819       )
 820     elif test "x$ac_cv_header_sys_ea_h" = "xyes"; then
 821         # AIX extended attributes support
 822         AC_CACHE_VAL([ac_cv_archive_xattr_aix],
 823           [AC_CHECK_FUNCS(fgetea \
 824                           flistea \
 825                           fsetea \
 826                           getea \
 827                           lgetea \
 828                           listea \
 829                           llistea \
 830                           lsetea,
 831           [ac_cv_archive_xattr_aix=yes],
 832           [ac_cv_archive_xattr_aix=no],
 833           [#include <sys/ea.h>
 834 ])
 835           ]
 836         )
 837     fi
 838
 839     AC_MSG_CHECKING([for extended attributes support])
 840     if test "x$ac_cv_archive_xattr_linux" = "xyes"; then
 841         AC_DEFINE([ARCHIVE_XATTR_LINUX], [1], [Linux xattr support])
 842         AC_MSG_RESULT([Linux])
 843     elif test "x$ac_cv_archive_xattr_darwin" = "xyes"; then
 844         AC_DEFINE([ARCHIVE_XATTR_DARWIN], [1], [Darwin xattr support])
 845         AC_MSG_RESULT([Darwin])
 846     elif test "x$ac_cv_archive_xattr_freebsd" = "xyes"; then
 847         AC_DEFINE([ARCHIVE_XATTR_FREEBSD], [1], [FreeBSD xattr support])
 848         AC_MSG_RESULT([FreeBSD])
 849     elif test "x$ac_cv_archive_xattr_aix" = "xyes"; then
 850         AC_DEFINE([ARCHIVE_XATTR_AIX], [1], [AIX xattr support])
 851         AC_MSG_RESULT([AIX])
 852     else
 853         AC_MSG_RESULT([none])
 854     fi
 855 fi
 856
 857 # Check for ACL support
 858 #
 859 # The ACL support in libarchive is written against the POSIX1e draft,
 860 # which was never officially approved and varies quite a bit across
 861 # platforms.  Worse, some systems have completely non-POSIX acl functions,
 862 # which makes the following checks rather more complex than I would like.
 863 #
 864 AC_ARG_ENABLE([acl],
 865                 AS_HELP_STRING([--disable-acl],
 866                 [Disable ACL support (default: check)]))
 867
 868 if test "x$enable_acl" != "xno"; then
 869     # Libacl
 870     AC_CHECK_LIB([acl], [acl_get_file])
 871
 872     AC_CHECK_TYPES([acl_t, acl_entry_t, acl_permset_t, acl_tag_t], [], [], [
 873       #if HAVE_SYS_TYPES_H
 874       #include <sys/types.h>
 875       #endif
 876       #if HAVE_SYS_ACL_H
 877       #include <sys/acl.h>
 878       #endif
 879     ])
 880
 881     AC_CHECK_LIB([richacl], [richacl_get_file])
 882
 883     AC_CHECK_TYPES([[struct richace], [struct richacl]], [], [], [
 884       #if HAVE_SYS_RICHACL_H
 885       #include <sys/richacl.h>
 886       #endif
 887     ])
 888
 889     # Solaris and derivates ACLs
 890     AC_CHECK_FUNCS(acl facl)
 891
 892     if test "x$ac_cv_lib_richacl_richacl_get_file" = "xyes" \
 893          -a "x$ac_cv_type_struct_richace" = "xyes" \
 894          -a "x$ac_cv_type_struct_richacl" = "xyes"; then
 895         AC_CACHE_VAL([ac_cv_archive_acl_librichacl],
 896           [AC_CHECK_FUNCS(richacl_alloc \
 897                           richacl_equiv_mode \
 898                           richacl_free \
 899                           richacl_get_fd \
 900                           richacl_get_file \
 901                           richacl_set_fd \
 902                           richacl_set_file,
 903           [ac_cv_archive_acl_librichacl=yes], [ac_cv_archive_acl_librichacl=no],          [#include <sys/richacl.h>])])
 904     fi
 905
 906     if test "x$ac_cv_func_acl" = "xyes" \
 907          -a "x$ac_cv_func_facl" = "xyes"; then
 908         AC_CHECK_TYPES([aclent_t], [], [], [[#include <sys/acl.h>]])
 909         if test "x$ac_cv_type_aclent_t" = "xyes"; then
 910             AC_CACHE_VAL([ac_cv_archive_acl_sunos],
 911               [AC_CHECK_DECLS([GETACL, SETACL, GETACLCNT],
 912               [ac_cv_archive_acl_sunos=yes], [ac_cv_archive_acl_sunos=no],
 913               [#include <sys/acl.h>])])
 914             AC_CHECK_TYPES([ace_t], [], [], [[#include <sys/acl.h>]])
 915             if test "x$ac_cv_type_ace_t" = "xyes"; then
 916                 AC_CACHE_VAL([ac_cv_archive_acl_sunos_nfs4],
 917                   [AC_CHECK_DECLS([ACE_GETACL, ACE_SETACL, ACE_GETACLCNT],
 918                   [ac_cv_archive_acl_sunos_nfs4=yes],
 919                   [ac_cv_archive_acl_sonos_nfs4=no],
 920                   [#include <sys/acl.h>])])
 921             fi
 922         fi
 923     elif test "x$ac_cv_type_acl_t" = "xyes" \
 924          -a "x$ac_cv_type_acl_entry_t" = "xyes" \
 925          -a "x$ac_cv_type_acl_permset_t" = "xyes" \
 926          -a "x$ac_cv_type_acl_tag_t" = "xyes"; then
 927         # POSIX.1e ACL functions
 928         AC_CACHE_VAL([ac_cv_posix_acl_funcs],
 929           [AC_CHECK_FUNCS(acl_add_perm \
 930                           acl_clear_perms \
 931                           acl_create_entry \
 932                           acl_delete_def_file \
 933                           acl_free \
 934                           acl_get_entry \
 935                           acl_get_fd \
 936                           acl_get_file \
 937                           acl_get_permset \
 938                           acl_get_qualifier \
 939                           acl_get_tag_type \
 940                           acl_init \
 941                           acl_set_fd \
 942                           acl_set_file \
 943                           acl_set_qualifier \
 944                           acl_set_tag_type,
 945           [ac_cv_posix_acl_funcs=yes], [ac_cv_posix_acl_funcs=no],
 946           [#if HAVE_SYS_TYPES_H
 947            #include <sys/types.h>
 948            #endif
 949            #if HAVE_SYS_ACL_H
 950            #include <sys/acl.h>
 951            #endif
 952           ])
 953         ])
 954
 955         AC_CHECK_FUNCS(acl_get_perm)
 956
 957         if test "x$ac_cv_posix_acl_funcs" = "xyes" \
 958              -a "x$ac_cv_header_acl_libacl_h" = "xyes" \
 959              -a "x$ac_cv_lib_acl_acl_get_file" = "xyes" \
 960              -a "x$ac_cv_func_acl_get_perm"; then
 961             AC_CACHE_VAL([ac_cv_archive_acl_libacl],
 962               [ac_cv_archive_acl_libacl=yes])
 963             AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
 964               [POSIX.1e ACL support via libacl])
 965         else
 966              # FreeBSD/Darwin
 967              AC_CHECK_FUNCS(acl_add_flag_np \
 968                             acl_clear_flags_np \
 969                             acl_get_brand_np \
 970                             acl_get_entry_type_np \
 971                             acl_get_flag_np \
 972                             acl_get_flagset_np \
 973                             acl_get_fd_np \
 974                             acl_get_link_np \
 975                             acl_get_perm_np \
 976                             acl_is_trivial_np \
 977                             acl_set_entry_type_np \
 978                             acl_set_fd_np \
 979                             acl_set_link_np,,,
 980               [#include <sys/types.h>
 981                #include <sys/acl.h>])
 982
 983             AC_CHECK_FUNCS(mbr_uid_to_uuid \
 984                            mbr_uuid_to_id \
 985                            mbr_gid_to_uuid,,,
 986               [#include <membership.h>])
 987
 988             AC_CHECK_DECLS([ACL_TYPE_EXTENDED, ACL_TYPE_NFS4, ACL_USER,
 989               ACL_SYNCHRONIZE], [], [],
 990               [#include <sys/types.h>
 991                #include <sys/acl.h>])
 992             if test "x$ac_cv_posix_acl_funcs" = "xyes" \
 993                  -a "x$ac_cv_func_acl_get_fd_np" = "xyes" \
 994                  -a "x$ac_cv_func_acl_get_perm" != "xyes" \
 995                  -a "x$ac_cv_func_acl_get_perm_np" = "xyes" \
 996                  -a "x$ac_cv_func_acl_set_fd_np" = "xyes"; then
 997                 if test "x$ac_cv_have_decl_ACL_USER" = "xyes"; then
 998                     AC_CACHE_VAL([ac_cv_archive_acl_freebsd],
 999                       [ac_cv_archive_acl_freebsd=yes])
1000                     if test "x$ac_cv_have_decl_ACL_TYPE_NFS4" = "xyes" \
1001                          -a "x$ac_cv_func_acl_add_flag_np" = "xyes" \
1002                          -a "x$ac_cv_func_acl_get_brand_np" = "xyes" \
1003                          -a "x$ac_cv_func_acl_get_entry_type_np" = "xyes" \
1004                          -a "x$ac_cv_func_acl_get_flagset_np" = "xyes" \
1005                          -a "x$ac_cv_func_acl_set_entry_type_np" = "xyes"; then
1006                         AC_CACHE_VAL([ac_cv_archive_acl_freebsd_nfs4],
1007                           [ac_cv_archive_acl_freebsd_nfs4=yes])
1008                     fi
1009                 elif test "x$ac_cv_have_decl_ACL_TYPE_EXTENDED" = "xyes" \
1010                        -a "x$ac_cv_func_acl_add_flag_np" = "xyes" \
1011                        -a "x$ac_cv_func_acl_get_flagset_np" = "xyes" \
1012                        -a "x$ac_cv_func_acl_get_link_np" = "xyes" \
1013                        -a "x$ac_cv_func_acl_set_link_np" = "xyes" \
1014                        -a "x$ac_cv_func_mbr_uid_to_uuid" = "xyes" \
1015                        -a "x$ac_cv_func_mbr_uuid_to_id" = "xyes" \
1016                        -a "x$ac_cv_func_mbr_gid_to_uuid" = "xyes"; then
1017                     AC_CACHE_VAL([ac_cv_archive_acl_darwin],
1018                       [ac_cv_archive_acl_darwin=yes])
1019                 fi
1020             fi
1021         fi
1022     fi
1023     AC_MSG_CHECKING([for ACL support])
1024     if test "x$ac_cv_archive_acl_libacl" = "xyes" \
1025          -a "x$ac_cv_archive_acl_librichacl" = "xyes"; then
1026         AC_MSG_RESULT([libacl (POSIX.1e) + librichacl (NFSv4)])
1027         AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
1028           [Linux POSIX.1e ACL support via libacl])
1029         AC_DEFINE([ARCHIVE_ACL_LIBRICHACL], [1],
1030           [Linux NFSv4 ACL support via librichacl])
1031     elif test "x$ac_cv_archive_acl_libacl" = "xyes"; then
1032         AC_MSG_RESULT([libacl (POSIX.1e)])
1033         AC_DEFINE([ARCHIVE_ACL_LIBACL], [1],
1034           [Linux POSIX.1e ACL support via libacl])
1035     elif test "x$ac_cv_archive_acl_librichacl" = "xyes"; then
1036         AC_MSG_RESULT([librichacl (NFSv4)])
1037         AC_DEFINE([ARCHIVE_ACL_LIBRICHACL], [1],
1038           [Linux NFSv4 ACL support via librichacl])
1039     elif test "x$ac_cv_archive_acl_darwin" = "xyes"; then
1040         AC_DEFINE([ARCHIVE_ACL_DARWIN], [1], [Darwin ACL support])
1041         AC_MSG_RESULT([Darwin (limited NFSv4)])
1042     elif test "x$ac_cv_archive_acl_sunos" = "xyes"; then
1043         AC_DEFINE([ARCHIVE_ACL_SUNOS], [1], [Solaris ACL support])
1044         if test "x$ac_cv_archive_acl_sunos_nfs4" = "xyes"; then
1045             AC_DEFINE([ARCHIVE_ACL_SUNOS_NFS4], [1],
1046               [Solaris NFSv4 ACL support])
1047             AC_MSG_RESULT([Solaris (POSIX.1e and NFSv4)])
1048         else
1049             AC_MSG_RESULT([Solaris (POSIX.1e)])
1050         fi
1051     elif test "x$ac_cv_archive_acl_freebsd" = "xyes"; then
1052         AC_DEFINE([ARCHIVE_ACL_FREEBSD], [1], [FreeBSD ACL support])
1053         if test "x$ac_cv_archive_acl_freebsd_nfs4" = "xyes"; then
1054             AC_DEFINE([ARCHIVE_ACL_FREEBSD_NFS4], [1],
1055               [FreeBSD NFSv4 ACL support])
1056             AC_MSG_RESULT([FreeBSD (POSIX.1e and NFSv4)])
1057         else
1058             AC_MSG_RESULT([FreeBSD (POSIX.1e)])
1059         fi
1060     else
1061         AC_MSG_RESULT([none])
1062     fi
1063 fi
1064
1065
1066 AM_CONDITIONAL([INC_LINUX_ACL],
1067   [test "x$ac_cv_archive_acl_libacl" = "xyes" \
1068      -o "x$ac_cv_archive_acl_librichacl" = "xyes"])
1069 AM_CONDITIONAL([INC_SUNOS_ACL], [test "x$ac_cv_archive_acl_sunos" = "xyes"])
1070 AM_CONDITIONAL([INC_DARWIN_ACL],
1071           [test "x$ac_cv_archive_acl_darwin" = "xyes"])
1072 AM_CONDITIONAL([INC_FREEBSD_ACL],
1073           [test "x$ac_cv_archive_acl_freebsd" = "xyes"])
1074
1075 # Additional requirements
1076 AC_SYS_LARGEFILE
1077
1078 dnl NOTE: Crypto checks must run last.
1079 AC_DEFUN([CRYPTO_CHECK], [
1080   if test "$found_$1" != yes; then
1081     saved_CPPFLAGS="$CPPFLAGS"
1082     CPPFLAGS="$CPPFLAGS -I. -I$srcdir -I$srcdir/libarchive"
1083     touch "check_crypto_md.h"
1084     AC_MSG_CHECKING([support for ARCHIVE_CRYPTO_$1_$2])
1085     AC_LINK_IFELSE([AC_LANG_SOURCE([
1086 #define ARCHIVE_$1_COMPILE_TEST
1087 #define ARCHIVE_CRYPTO_$1_$2
1088 #define PLATFORM_CONFIG_H "check_crypto_md.h"
1089
1090 $(cat "$srcdir/libarchive/archive_digest.c")
1091
1092 int
1093 main(int argc, char **argv)
1094 {
1095   archive_$3_ctx ctx;
1096   archive_$3_init(&ctx);
1097   archive_$3_update(&ctx, *argv, argc);
1098   archive_$3_final(&ctx, NULL);
1099   return 0;
1100 }
1101 ])],
1102     [ AC_MSG_RESULT([yes])
1103       found_$1=yes
1104       found_$2=yes
1105       AC_DEFINE(ARCHIVE_CRYPTO_$1_$2, 1, [ $1 via ARCHIVE_CRYPTO_$1_$2 supported.])
1106     ],
1107     [ AC_MSG_RESULT([no])])
1108     CPPFLAGS="$saved_CPPFLAGS"
1109     rm "check_crypto_md.h"
1110   fi
1111 ])
1112
1113 AC_DEFUN([CRYPTO_CHECK_WIN], [
1114   if test "$found_$1" != yes; then
1115     AC_MSG_CHECKING([support for ARCHIVE_CRYPTO_$1_WIN])
1116     AC_LINK_IFELSE([AC_LANG_SOURCE([
1117 #define ARCHIVE_$1_COMPILE_TEST
1118 #include <windows.h>
1119 #include <wincrypt.h>
1120
1121 int
1122 main(int argc, char **argv)
1123 {
1124         (void)argc;
1125         (void)argv;
1126
1127         return ($2);
1128 }
1129 ])],
1130     [ AC_MSG_RESULT([yes])
1131       found_$1=yes
1132       found_WIN=yes
1133       AC_DEFINE(ARCHIVE_CRYPTO_$1_WIN, 1, [ $1 via ARCHIVE_CRYPTO_$1_WIN supported.])
1134     ],
1135     [ AC_MSG_RESULT([no])])
1136   fi
1137 ])
1138
1139 case "$host_os" in
1140   *mingw* | *cygwin* | *msys*)
1141         ;;
1142   *)
1143         CRYPTO_CHECK(MD5, LIBC, md5)
1144         CRYPTO_CHECK(MD5, LIBSYSTEM, md5)
1145         CRYPTO_CHECK(RMD160, LIBC, rmd160)
1146         CRYPTO_CHECK(SHA1, LIBC, sha1)
1147         CRYPTO_CHECK(SHA1, LIBSYSTEM, sha1)
1148         CRYPTO_CHECK(SHA256, LIBC, sha256)
1149         CRYPTO_CHECK(SHA256, LIBC2, sha256)
1150         CRYPTO_CHECK(SHA256, LIBC3, sha256)
1151         CRYPTO_CHECK(SHA256, LIBSYSTEM, sha256)
1152         CRYPTO_CHECK(SHA384, LIBC, sha384)
1153         CRYPTO_CHECK(SHA384, LIBC2, sha384)
1154         CRYPTO_CHECK(SHA384, LIBC3, sha384)
1155         CRYPTO_CHECK(SHA384, LIBSYSTEM, sha384)
1156         CRYPTO_CHECK(SHA512, LIBC, sha512)
1157         CRYPTO_CHECK(SHA512, LIBC2, sha512)
1158         CRYPTO_CHECK(SHA512, LIBC3, sha512)
1159         CRYPTO_CHECK(SHA512, LIBSYSTEM, sha512)
1160         ;;
1161 esac
1162
1163 if test "x$with_cng" != "xno"; then
1164     AC_CHECK_HEADERS([bcrypt.h],[
1165         LIBS="$LIBS -lbcrypt"
1166     ],[],
1167     [[#ifdef HAVE_WINDOWS_H
1168     # include <windows.h>
1169     #endif
1170     ]])
1171 fi
1172
1173 if test "x$with_mbedtls" = "xyes"; then
1174     AC_CHECK_HEADERS([mbedtls/aes.h mbedtls/md.h mbedtls/pkcs5.h])
1175     saved_LIBS=$LIBS
1176     AC_CHECK_LIB(mbedcrypto,mbedtls_sha1_init)
1177     CRYPTO_CHECK(MD5, MBEDTLS, md5)
1178     CRYPTO_CHECK(RMD160, MBEDTLS, rmd160)
1179     CRYPTO_CHECK(SHA1, MBEDTLS, sha1)
1180     CRYPTO_CHECK(SHA256, MBEDTLS, sha256)
1181     CRYPTO_CHECK(SHA384, MBEDTLS, sha384)
1182     CRYPTO_CHECK(SHA512, MBEDTLS, sha512)
1183     if test "x$found_MBEDTLS" != "xyes"; then
1184       LIBS=$saved_LIBS
1185     fi
1186 fi
1187
1188 if test "x$with_nettle" = "xyes"; then
1189     AC_CHECK_HEADERS([nettle/md5.h nettle/ripemd160.h nettle/sha.h])
1190     AC_CHECK_HEADERS([nettle/pbkdf2.h nettle/aes.h nettle/hmac.h])
1191     saved_LIBS=$LIBS
1192     AC_CHECK_LIB(nettle,nettle_sha1_init)
1193     CRYPTO_CHECK(MD5, NETTLE, md5)
1194     CRYPTO_CHECK(RMD160, NETTLE, rmd160)
1195     CRYPTO_CHECK(SHA1, NETTLE, sha1)
1196     CRYPTO_CHECK(SHA256, NETTLE, sha256)
1197     CRYPTO_CHECK(SHA384, NETTLE, sha384)
1198     CRYPTO_CHECK(SHA512, NETTLE, sha512)
1199     if test "x$found_NETTLE" != "xyes"; then
1200       LIBS=$saved_LIBS
1201     fi
1202 fi
1203
1204 if test "x$with_openssl" != "xno"; then
1205     AC_CHECK_HEADERS([openssl/evp.h])
1206     saved_LIBS=$LIBS
1207     case "$host_os" in
1208       *mingw* | *cygwin* | *msys*)
1209         case "$host_cpu" in
1210           x86_64)
1211             AC_CHECK_LIB(eay64,OPENSSL_config)
1212             if test "x$ac_cv_lib_eay64_main" != "xyes"; then
1213               AC_CHECK_LIB(eay32,OPENSSL_config)
1214             fi
1215             ;;
1216           *)
1217             AC_CHECK_LIB(eay32,OPENSSL_config)
1218             ;;
1219         esac
1220         ;;
1221       *)
1222         AC_CHECK_LIB(crypto,OPENSSL_config)
1223         ;;
1224     esac
1225     CRYPTO_CHECK(MD5, OPENSSL, md5)
1226     CRYPTO_CHECK(RMD160, OPENSSL, rmd160)
1227     CRYPTO_CHECK(SHA1, OPENSSL, sha1)
1228     CRYPTO_CHECK(SHA256, OPENSSL, sha256)
1229     CRYPTO_CHECK(SHA384, OPENSSL, sha384)
1230     CRYPTO_CHECK(SHA512, OPENSSL, sha512)
1231     AC_CHECK_FUNCS([PKCS5_PBKDF2_HMAC_SHA1])
1232 fi
1233
1234 # Probe libmd AFTER OpenSSL/libcrypto.
1235 # The two are incompatible and OpenSSL is more complete.
1236 AC_CHECK_HEADERS([md5.h ripemd.h sha.h sha256.h sha512.h])
1237 saved_LIBS=$LIBS
1238 AC_CHECK_LIB(md,MD5Init)
1239 CRYPTO_CHECK(MD5, LIBMD, md5)
1240 CRYPTO_CHECK(RMD160, LIBMD, rmd160)
1241 CRYPTO_CHECK(SHA1, LIBMD, sha1)
1242 CRYPTO_CHECK(SHA256, LIBMD, sha256)
1243 CRYPTO_CHECK(SHA512, LIBMD, sha512)
1244 if test "x$found_LIBMD" != "xyes"; then
1245   LIBS=$saved_LIBS
1246 fi
1247
1248 case "$host_os" in
1249   *mingw* | *cygwin* | *msys*)
1250         CRYPTO_CHECK_WIN(MD5, CALG_MD5)
1251         CRYPTO_CHECK_WIN(SHA1, CALG_SHA1)
1252         CRYPTO_CHECK_WIN(SHA256, CALG_SHA_256)
1253         CRYPTO_CHECK_WIN(SHA384, CALG_SHA_384)
1254         CRYPTO_CHECK_WIN(SHA512, CALG_SHA_512)
1255         ;;
1256 esac
1257
1258 # Ensure test directories are present if building out-of-tree
1259 AC_CONFIG_COMMANDS([mkdirs],
1260                    [mkdir -p libarchive/test tar/test cat/test cpio/test])
1261
1262 AC_OUTPUT