configure.ac-base

   1 AC_INIT([DHCP],[4.4.0-dev],[dhcp-users@isc.org])
   2
   3 @BEGIN WITH LIBTOOL
   4 # for libtool
   5 AC_CONFIG_MACRO_DIR([m4])
   6 @END WITH LIBTOOL
   7
   8 # we specify "foreign" to avoid having to have the GNU mandated files,
   9 # like AUTHORS, COPYING, and such
  10 AM_INIT_AUTOMAKE([foreign])
  11
  12 # we specify AM_MAINTAINER_MODE to avoid problems with rebuilding
  13 # the configure and makefiles.  Without it users doing things that
  14 # change the timestamps on the code, like checking it into a cvs
  15 # tree, could trigger a rebuild of the infrastructure files which
  16 # might fail if they don't have the correct tools.
  17 AM_MAINTAINER_MODE
  18
  19 AC_CANONICAL_HOST
  20
  21 # We want to turn on warnings if we are using gcc and the user did
  22 # not specify CFLAGS. The autoconf check for the C compiler sets the
  23 # CFLAGS if gcc is used, so we will save it before we run that check.
  24 SAVE_CFLAGS="$CFLAGS"
  25
  26 # Now find our C compiler.
  27 AC_PROG_CC
  28
  29 # Suppress warnings about --datarootdir
  30 AC_DEFUN([AC_DATAROOTDIR_CHECKED])
  31
  32 # If we have gcc, and AC_PROG_CC changed the flags, then we know the
  33 # user did not specify any flags. Add warnings in this case.
  34 if test "$GCC" = "yes"; then
  35         if test "$CFLAGS" != "$SAVE_CFLAGS"; then
  36                 STD_CWARNINGS="$STD_CWARNINGS -Wall -Werror -fno-strict-aliasing"
  37         fi
  38 fi
  39
  40 # We can have some flags to pass to bind configure
  41 BINDCONFIG=
  42 if test "$cross_compiling" = "yes"; then
  43         BINDCONFIG="--host=$host"
  44 fi
  45 # Pass CFLAGS and co. $ac_configure_args looks like "'arg1' 'arg2' ..."
  46 # and as there can be a space inside an argument some magic is required.
  47 # This sets $1 ... $N to my_configure_args, arg1 ... argN
  48 eval "set my_configure_args $ac_configure_args"
  49 # remove my_configure_args, i.e., the guard against empty $ac_configure_args
  50 shift
  51 # iterate on arguments and copying 'arg' when it begins by an upper case
  52 for a
  53 do
  54         case $a in
  55                 [[A-Z]]*) BINDCONFIG="$BINDCONFIG '$a'" ;;
  56         esac
  57 done
  58 AC_SUBST(BINDCONFIG)
  59
  60 # POSIX doesn't include the IPv6 Advanced Socket API and glibc hides
  61 # parts of the IPv6 Advanced Socket API as a result.  This is stupid
  62 # as it breaks how the two halves (Basic and Advanced) of the IPv6
  63 # Socket API were designed to be used but we have to live with it.
  64 # Use this to define _GNU_SOURCE to pull in the IPv6 Advanced Socket API.
  65 AC_USE_SYSTEM_EXTENSIONS
  66
  67 @BEGIN WITHOUT LIBTOOL
  68 AC_PROG_RANLIB
  69 @END WITHOUT LIBTOOL
  70
  71 AC_PATH_PROG(AR, ar)
  72 AC_SUBST(AR)
  73
  74 if test "X$AR" = "X"; then
  75         AC_MSG_ERROR([
  76 ar program not found.  Please fix your PATH to include the directory in
  77 which ar resides, or set AR in the environment with the full path to ar.])
  78 fi
  79
  80 AC_CONFIG_HEADERS([includes/config.h])
  81
  82 # we sometimes need to know byte order for building packets
  83 AC_C_BIGENDIAN(AC_SUBST(byte_order, BIG_ENDIAN),
  84                AC_SUBST(byte_order, LITTLE_ENDIAN))
  85 AC_DEFINE_UNQUOTED([DHCP_BYTE_ORDER], [$byte_order],
  86                    [Define to BIG_ENDIAN for MSB (Motorola or SPARC CPUs)
  87                     or LITTLE_ENDIAN for LSB (Intel CPUs).])
  88
  89 # Optional compile-time DEBUGging.
  90 AC_ARG_ENABLE(debug,
  91         AS_HELP_STRING([--enable-debug],[create a debug-only version of the software (default is no).]),
  92   [case "${enableval}" in
  93     yes) enable_debug=yes
  94         AC_DEFINE([DEBUG], [1],
  95             [Define to compile debug-only DHCP software.])
  96         # Just override CFLAGS totally to remove optimization.
  97         CFLAGS="-g";;
  98     no)  enable_debug=no ;;
  99     *)   AC_MSG_ERROR([bad value ${enableval} for --enable-debug]) ;;
 100   esac],[enable_debug=no])
 101
 102 # XXX: there are actually quite a lot more DEBUG_ features we could enable,
 103 # but I don't want to pollute the --help space.
 104 #
 105 #/* #define DEBUG_TOKENS */
 106 #/* #define DEBUG_PACKET */
 107 #/* #define DEBUG_EXPRESSIONS */
 108 #/* #define DEBUG_FIND_LEASE */
 109 #/* #define DEBUG_EXPRESSION_PARSE */
 110 #/* #define DEBUG_CLASS_MATCHING */
 111 #/* #define DEBUG_MEMORY_LEAKAGE */
 112 #/* #define DEBUG_MALLOC_POOL */
 113 #/* #define DEBUG_LEASE_STATE_TRANSITIONS */
 114 #/* #define DEBUG_RC_HISTORY */
 115 #/* #define DEBUG_RC_HISTORY_EXHAUSTIVELY */
 116 #/* #define RC_HISTORY_MAX 10240 */
 117 #/* #define POINTER_DEBUG */
 118 #/* #define DEBUG_FAILOVER_MESSAGES */
 119 #/* #define DEBUG_FAILOVER_TIMING */
 120 #/* #define DEBUG_DUMP_ALL_LEASES */
 121
 122 # Failover optional compile-time feature.
 123 AC_ARG_ENABLE(failover,
 124         AS_HELP_STRING([--enable-failover],[enable support for failover (default is yes)]))
 125 # Failover is on by default, so define if it is not explicitly disabled.
 126 if test "$enable_failover" != "no"; then
 127     enable_failover="yes"
 128         AC_DEFINE([FAILOVER_PROTOCOL], [1],
 129                   [Define to include Failover Protocol support.])
 130 fi
 131
 132 # execute() support.
 133 AC_ARG_ENABLE(execute,
 134         AS_HELP_STRING([--enable-execute],[enable support for execute() in config (default is yes)]))
 135 # execute() is on by default, so define if it is not explicitly disabled.
 136 if test "$enable_execute" != "no" ; then
 137     enable_execute="yes"
 138         AC_DEFINE([ENABLE_EXECUTE], [1],
 139                   [Define to include execute() config language support.])
 140 fi
 141
 142 # Server tracing support.
 143 AC_ARG_ENABLE(tracing,
 144         AS_HELP_STRING([--enable-tracing],[enable support for server activity tracing (default is yes)]))
 145 # tracing is on by default, so define if it is not explicitly disabled.
 146 if test "$enable_tracing" != "no" ; then
 147         AC_DEFINE([TRACING], [1],
 148                   [Define to include server activity tracing support.])
 149 fi
 150
 151 # Delayed-ack feature support (experimental).
 152 AC_ARG_ENABLE(delayed_ack,
 153         AS_HELP_STRING([--enable-delayed-ack],[queues multiple DHCPACK replies (default is no)]))
 154 if test "$enable_delayed_ack" = "yes"; then
 155         AC_DEFINE([DELAYED_ACK], [1],
 156                   [Define to queue multiple DHCPACK replies per fsync.])
 157 else
 158     enable_delayed_ack="no"
 159 fi
 160
 161 # DHCPv6 optional compile-time feature.
 162 AC_ARG_ENABLE(dhcpv6,
 163         AS_HELP_STRING([--enable-dhcpv6],[enable support for DHCPv6 (default is yes)]))
 164 # DHCPv6 is on by default, so define if it is not explicitly disabled.
 165 if test "$enable_dhcpv6" != "no"; then
 166     enable_dhcpv6="yes"
 167         AC_DEFINE([DHCPv6], [1],
 168                   [Define to 1 to include DHCPv6 support.])
 169 fi
 170
 171 # DHCPv4o6 optional compile-time feature.
 172 AC_ARG_ENABLE(dhcpv4o6,
 173         AS_HELP_STRING([--enable-dhcpv4o6],[enable support for DHCPv4-over-DHCPv6 (default is no)]))
 174 # DHCPv4o6 is off by default, so define if it is explicitly enabled.
 175 if test "$enable_dhcpv4o6" = "yes"; then
 176         # DHCPv4o6 requires DHCPv6
 177         if test "$enable_dhcpv6" = "no"; then
 178                 AC_MSG_ERROR([dhcpv4o6 requires dhcpv6])
 179         fi
 180         # DHCPv4o6 is not yet compatible with delayed-ack
 181         if test "$enable_delayed_ack" = "yes"; then
 182                 AC_MSG_ERROR([dhcpv4o6 is not compatible with delayed-ack])
 183         fi
 184         AC_DEFINE([DHCP4o6], [1],
 185                   [Define to 1 to include DHCPv4 over DHCPv6 support.])
 186 fi
 187
 188 # PARANOIA is off by default (until we can test it with all features)
 189 AC_ARG_ENABLE(paranoia,
 190         AS_HELP_STRING([--enable-paranoia],[enable support for chroot/setuid (default is no)]))
 191 AC_ARG_ENABLE(early_chroot,
 192         AS_HELP_STRING([--enable-early-chroot],[enable chrooting prior to configuration (default is no)]))
 193 # If someone enables early chroot, but does not enable paranoia, do so for
 194 # them.
 195 if test "$enable_paranoia" != "yes" && \
 196    test "$enable_early_chroot" = "yes" ; then
 197         enable_paranoia="yes"
 198 fi
 199
 200 if test "$enable_paranoia" = "yes" ; then
 201         AC_DEFINE([PARANOIA], [1],
 202                   [Define to any value to include Ari's PARANOIA patch.])
 203 fi
 204 if test "$enable_early_chroot" = "yes" ; then
 205         AC_DEFINE([EARLY_CHROOT], [1],
 206                   [Define to any value to chroot() prior to loading config.])
 207 fi
 208
 209 AC_ARG_ENABLE(ipv4_pktinfo,
 210         AS_HELP_STRING([--enable-ipv4-pktinfo],[enable use of pktinfo on IPv4 sockets (default is no)]))
 211
 212 if test "$enable_ipv4_pktinfo" = "yes"; then
 213         AC_DEFINE([USE_V4_PKTINFO], [1],
 214                 [Define to 1 to enable IPv4 packet info support.])
 215 fi
 216
 217 AC_ARG_ENABLE(use_sockets,
 218         AS_HELP_STRING([--enable-use-sockets],[use the standard BSD socket API (default is no)]))
 219
 220 if test "$enable_use_sockets" = "yes"; then
 221         AC_DEFINE([USE_SOCKETS], [1],
 222                 [Define to 1 to use the standard BSD socket API.])
 223 fi
 224
 225 # Try to hnadle incorrect byte order for secs field
 226 # This is off by default
 227 AC_ARG_ENABLE(secs_byteorder,
 228         AS_HELP_STRING([--enable-secs-byteorder],[Correct bad byteorders in the secs field (default is no).]))
 229
 230 if test "$enable_secs_byteorder" = "yes" ; then
 231         AC_DEFINE([SECS_BYTEORDER], [1],
 232                 [Define to correct bad byteorders in secs field.])
 233 fi
 234
 235 # Include the PID in the log messages.  This is useful when there may
 236 # be multiple instances of a program.
 237 # This is off by default
 238 AC_ARG_ENABLE(log_pid,
 239         AS_HELP_STRING([--enable-log-pid],[Include PIDs in syslog messages (default is no).]))
 240 if test "$enable_log_pid" = "yes" ; then
 241         AC_DEFINE([USE_LOG_PID], [1],
 242                 [Define to include PIDs in syslog messages.])
 243 fi
 244
 245 # Allow for binary search when inserting v4 leases into queues
 246 AC_ARG_ENABLE(binary_leases,
 247         AS_HELP_STRING([--enable-binary-leases],[enable support for binary insertion of leases (default is no)]))
 248 # binary_leases is off by default.
 249 if test "$enable_binary_leases" = "yes"; then
 250         AC_DEFINE([BINARY_LEASES], [1],
 251                   [Define to support binary insertion of leases into queues.])
 252 else
 253     enable_binary_leases="no"
 254 fi
 255
 256 # Testing section
 257
 258 DISTCHECK_ATF_CONFIGURE_FLAG=
 259 atf_path="no"
 260 AC_ARG_WITH([atf],
 261     AS_HELP_STRING([--with-atf=PATH],[specify location where atf was installed (or "bind")]),
 262     [atf_path="$withval"])
 263 AM_CONDITIONAL(BIND_ATF, test "$atf_path" = "bind")
 264 if test "$atf_path" = "bind" ; then
 265     DISTCHECK_ATF_CONFIGURE_FLAG="--with-atf=bind"
 266     atf_pcp="bind"
 267     atf_path="\${top_srcdir}/bind/atf"
 268     ATF_CFLAGS="-I$atf_path/include -DUNIT_TEST"
 269     ATF_LDFLAGS="-L$atf_path/lib -latf-c"
 270     ATF_BIN=`cd $srcdir; pwd`/bind/atf/bin
 271     AC_SUBST(ATF_CFLAGS)
 272     AC_SUBST(ATF_LDFLAGS)
 273     AC_SUBST(ATF_BIN)
 274     BINDCONFIG="$BINDCONFIG --with-atf"
 275 elif test "$atf_path" != "no" ; then
 276     DISTCHECK_ATF_CONFIGURE_FLAG="--with-atf=$atf_path"
 277     # Config path for pkg-config
 278     atf_pcp=""
 279     if test "$atf_path" != "yes" ; then
 280         if test -f $atf_path/lib/pkgconfig/atf-c.pc ; then
 281             atf_pcp=$atf_path/lib/pkgconfig
 282         elif test -f $atf_path/lib64/pkgconfig/atf-c.pc ; then
 283             atf_pcp=$atf_path/lib64/pkgconfig
 284         fi
 285     else
 286         # Not specified, try some common paths
 287         atf_dirs="/usr /usr/local /usr/pkg /opt /opt/local"
 288         for d in $atf_dirs
 289         do
 290             if test -f $d/lib/pkgconfig/atf-c.pc ; then
 291                 atf_pcp=$d/lib/pkgconfig
 292                 atf_path=$d
 293             elif test -f $d/lib64/pkgconfig/atf-c.pc ; then
 294                 atf_pcp=$d/lib64/pkgconfig
 295                 atf_path=$d
 296             fi
 297         done
 298     fi
 299
 300     if test "$atf_pcp" = "" ; then
 301         AC_MSG_ERROR([Unable to find atf files in location specified])
 302     else
 303         AC_CHECK_PROG([pkgcfg_found],[pkg-config],[pkg-config],[])
 304         if test "$pkgcfg_found" = ""; then
 305             AC_MSG_ERROR([Could not locate ATF, pkg-config not installed])
 306         fi
 307         ATF_CFLAGS="`PKG_CONFIG_PATH=$atf_pcp pkg-config --cflags atf-c` -DUNIT_TEST"
 308         ATF_LDFLAGS="`PKG_CONFIG_PATH=$atf_pcp pkg-config --libs atf-c`"
 309         if  test -f $atf_pcp/atf-sh.pc ; then
 310                 ATF_BIN="`PKG_CONFIG_PATH=$atf_pcp pkg-config --variable=exec_prefix atf-sh`/bin"
 311         else
 312                 # older versions don't have atf-sh, try usual place
 313                 ATF_BIN=$atf_path/bin
 314         fi
 315
 316         if test ! -x $ATF_BIN/atf-run  -o  ! -x $ATF_BIN/atf-report ; then
 317             AC_MSG_WARN([atf-run/atf-report not found, assuming they are in your path])
 318         fi
 319
 320         AC_SUBST(ATF_CFLAGS)
 321         AC_SUBST(ATF_LDFLAGS)
 322         AC_SUBST(ATF_BIN)
 323     fi
 324 fi
 325
 326 AM_CONDITIONAL(HAVE_ATF, test "$atf_pcp" != "")
 327 AM_COND_IF([HAVE_ATF], [AC_DEFINE([HAVE_ATF], [1], [ATF framework specified?])])
 328 AC_SUBST(DISTCHECK_ATF_CONFIGURE_FLAG)
 329
 330 ###
 331 ### Path fun.  Older versions of DHCP were installed in /usr/sbin, so we
 332 ### need to look there and potentially overwrite by default (but not if
 333 ### the user configures an alternate value).  LOCALSTATEDIR is totally
 334 ### braindead.  No one uses /usr/local/var/db/ nor /usr/local/var/run, and
 335 ### they would be insane for suggesting it.  We need to look in /var/for
 336 ### 'db' and 'state/dhcp' for db files, and /var/run for pid files by
 337 ### default.
 338 ###
 339 AC_PREFIX_PROGRAM(dhcpd)
 340
 341 # XXX - isn't there SOME WAY to default autoconf to /var instead of
 342 # /usr/local/var/no/one/has/this/please/stop/trying?
 343 case "$localstatedir" in
 344         '${prefix}/var')
 345                 localstatedir=/var
 346                 ;;
 347 esac
 348
 349 # Allow specification of alternate state files
 350 AC_ARG_WITH(srv-lease-file,
 351         AS_HELP_STRING([--with-srv-lease-file=PATH],[File for dhcpd leases
 352                         (default is LOCALSTATEDIR/db/dhcpd.leases)]),
 353         AC_DEFINE_UNQUOTED([_PATH_DHCPD_DB], ["$withval"],
 354                            [File for dhcpd leases.]))
 355
 356 AC_MSG_CHECKING([for dhcpd.leases location])
 357 if [[ "x$with_srv_lease_file" = "x" ]] ; then
 358         if [[ -d "${localstatedir}/db" ]] ; then
 359                 with_srv_lease_file="${localstatedir}/db/dhcpd.leases"
 360         elif [[ -d "${localstatedir}/state" ]] ; then
 361                 if [[ -d "${localstatedir}/state/dhcp" ]] ; then
 362                         with_srv_lease_file="${localstatedir}/state/dhcp/dhcpd.leases"
 363                 else
 364                         with_srv_lease_file="${localstatedir}/state/dhcpd.leases"
 365                 fi
 366         elif [[ -d "${localstatedir}/lib" ]] ; then
 367                 if [[ -d "${localstatedir}/lib/dhcp" ]] ; then
 368                         with_srv_lease_file="${localstatedir}/lib/dhcp/dhcpd.leases"
 369                 else
 370                         with_srv_lease_file="${localstatedir}/lib/dhcpd.leases"
 371                 fi
 372         elif [[ -d "${localstatedir}/etc" ]] ; then
 373                 with_srv_lease_file="${localstatedir}/etc/dhcpd.leases"
 374         else
 375                 with_srv_lease_file="/etc/dhcpd.leases"
 376         fi
 377 fi
 378 AC_MSG_RESULT($with_srv_lease_file)
 379
 380 AC_ARG_WITH(srv6-lease-file,
 381         AS_HELP_STRING([--with-srv6-lease-file=PATH],[File for dhcpd6 leases
 382                         (default is LOCALSTATEDIR/db/dhcpd6.leases)]),
 383         AC_DEFINE_UNQUOTED([_PATH_DHCPD6_DB], ["$withval"],
 384                            [File for dhcpd6 leases.]))
 385
 386 AC_MSG_CHECKING([for dhcpd6.leases location])
 387 if [[ "x$with_srv6_lease_file" = "x" ]] ; then
 388         if [[ -d "${localstatedir}/db" ]] ; then
 389                 with_srv6_lease_file="${localstatedir}/db/dhcpd6.leases"
 390         elif [[ -d "${localstatedir}/state" ]] ; then
 391                 if [[ -d "${localstatedir}/state/dhcp" ]] ; then
 392                         with_srv6_lease_file="${localstatedir}/state/dhcp/dhcpd6.leases"
 393                 else
 394                         with_srv6_lease_file="${localstatedir}/state/dhcpd6.leases"
 395                 fi
 396         elif [[ -d "${localstatedir}/lib" ]] ; then
 397                 if [[ -d "${localstatedir}/lib/dhcp" ]] ; then
 398                         with_srv6_lease_file="${localstatedir}/lib/dhcp/dhcpd6.leases"
 399                 else
 400                         with_srv6_lease_file="${localstatedir}/lib/dhcpd6.leases"
 401                 fi
 402         elif [[ -d "${localstatedir}/etc" ]] ; then
 403                 with_srv6_lease_file="${localstatedir}/etc/dhcpd6.leases"
 404         else
 405                 with_srv6_lease_file="/etc/dhcpd6.leases"
 406         fi
 407 fi
 408 AC_MSG_RESULT($with_srv6_lease_file)
 409
 410 AC_ARG_WITH(cli-lease-file,
 411         AS_HELP_STRING([--with-cli-lease-file=PATH],[File for dhclient leases
 412                         (default is LOCALSTATEDIR/db/dhclient.leases)]),
 413         AC_DEFINE_UNQUOTED([_PATH_DHCLIENT_DB], ["$withval"],
 414                            [File for dhclient leases.]))
 415
 416 AC_MSG_CHECKING([for dhclient.leases location])
 417 if [[ "x$with_cli_lease_file" = "x" ]] ; then
 418         if [[ -d "${localstatedir}/db" ]] ; then
 419                 with_cli_lease_file="${localstatedir}/db/dhclient.leases"
 420         elif [[ -d "${localstatedir}/state" ]] ; then
 421                 if [[ -d "${localstatedir}/state/dhcp" ]] ; then
 422                         with_cli_lease_file="${localstatedir}/state/dhcp/dhclient.leases"
 423                 else
 424                         with_cli_lease_file="${localstatedir}/state/dhclient.leases"
 425                 fi
 426         elif [[ -d "${localstatedir}/lib" ]] ; then
 427                 if [[ -d "${localstatedir}/lib/dhcp" ]] ; then
 428                         with_cli_lease_file="${localstatedir}/lib/dhcp/dhclient.leases"
 429                 else
 430                         with_cli_lease_file="${localstatedir}/lib/dhclient.leases"
 431                 fi
 432         elif [[ -d "${localstatedir}/etc" ]] ; then
 433                 with_cli_lease_file="${localstatedir}/etc/dhclient.leases"
 434         else
 435                 with_cli_lease_file="/etc/dhclient.leases"
 436         fi
 437 fi
 438 AC_MSG_RESULT($with_cli_lease_file)
 439
 440 AC_ARG_WITH(cli6-lease-file,
 441         AS_HELP_STRING([--with-cli6-lease-file=PATH],[File for dhclient6 leases
 442                         (default is LOCALSTATEDIR/db/dhclient6.leases)]),
 443         AC_DEFINE_UNQUOTED([_PATH_DHCLIENT6_DB], ["$withval"],
 444                            [File for dhclient6 leases.]))
 445
 446 AC_MSG_CHECKING([for dhclient6.leases location])
 447 if [[ "x$with_cli6_lease_file" = "x" ]] ; then
 448         if [[ -d "${localstatedir}/db" ]] ; then
 449                 with_cli6_lease_file="${localstatedir}/db/dhclient6.leases"
 450         elif [[ -d "${localstatedir}/state" ]] ; then
 451                 if [[ -d "${localstatedir}/state/dhcp" ]] ; then
 452                         with_cli6_lease_file="${localstatedir}/state/dhcp/dhclient6.leases"
 453                 else
 454                         with_cli6_lease_file="${localstatedir}/state/dhclient6.leases"
 455                 fi
 456         elif [[ -d "${localstatedir}/lib" ]] ; then
 457                 if [[ -d "${localstatedir}/lib/dhcp" ]] ; then
 458                         with_cli6_lease_file="${localstatedir}/lib/dhcp/dhclient6.leases"
 459                 else
 460                         with_cli6_lease_file="${localstatedir}/lib/dhclient6.leases"
 461                 fi
 462         elif [[ -d "${localstatedir}/etc" ]] ; then
 463                 with_cli6_lease_file="${localstatedir}/etc/dhclient6.leases"
 464         else
 465                 with_cli6_lease_file="/etc/dhclient6.leases"
 466         fi
 467 fi
 468 AC_MSG_RESULT($with_cli6_lease_file)
 469
 470 AC_ARG_WITH(srv-pid-file,
 471         AS_HELP_STRING([--with-srv-pid-file=PATH],[File for dhcpd process information
 472                         (default is LOCALSTATEDIR/run/dhcpd.pid)]),
 473         AC_DEFINE_UNQUOTED([_PATH_DHCPD_PID], ["$withval"],
 474                            [File for dhcpd process information.]))
 475 AC_ARG_WITH(srv6-pid-file,
 476         AS_HELP_STRING([--with-srv6-pid-file=PATH],[File for dhcpd6 process information
 477                         (default is LOCALSTATEDIR/run/dhcpd6.pid)]),
 478         AC_DEFINE_UNQUOTED([_PATH_DHCPD6_PID], ["$withval"],
 479                            [File for dhcpd6 process information.]))
 480 AC_ARG_WITH(cli-pid-file,
 481         AS_HELP_STRING([--with-cli-pid-file=PATH],[File for dhclient process information
 482                         (default is LOCALSTATEDIR/run/dhclient.pid)]),
 483         AC_DEFINE_UNQUOTED([_PATH_DHCLIENT_PID], ["$withval"],
 484                            [File for dhclient process information.]))
 485 AC_ARG_WITH(cli6-pid-file,
 486         AS_HELP_STRING([--with-cli6-pid-file=PATH],[File for dhclient6 process information
 487                         (default is LOCALSTATEDIR/run/dhclient6.pid)]),
 488         AC_DEFINE_UNQUOTED([_PATH_DHCLIENT6_PID], ["$withval"],
 489                            [File for dhclient6 process information.]))
 490 AC_ARG_WITH(relay-pid-file,
 491         AS_HELP_STRING([--with-relay-pid-file=PATH],[File for dhcrelay process information
 492                         (default is LOCALSTATEDIR/run/dhcrelay.pid)]),
 493         AC_DEFINE_UNQUOTED([_PATH_DHCRELAY_PID], ["$withval"],
 494                            [File for dhcrelay process information.]))
 495 AC_ARG_WITH(relay6-pid-file,
 496         AS_HELP_STRING([--with-relay6-pid-file=PATH],[File for dhcrelay6 process information
 497                         (default is LOCALSTATEDIR/run/dhcrelay6.pid)]),
 498         AC_DEFINE_UNQUOTED([_PATH_DHCRELAY6_PID], ["$withval"],
 499                            [File for dhcrelay6 process information.]))
 500
 501 # Check basic types.
 502 AC_TYPE_INT8_T
 503 AC_TYPE_INT16_T
 504 AC_TYPE_INT32_T
 505 AC_TYPE_INT64_T
 506
 507 # Some systems need the u_intX_t types defined across.
 508 AC_CHECK_TYPE([u_int8_t], [], [
 509   AC_TYPE_UINT8_T
 510   AC_DEFINE(u_int8_t, [uint8_t], [Define a type for 8-bit unsigned
 511                                   integers.])
 512 ])
 513 AC_CHECK_TYPE([u_int16_t], [], [
 514   AC_TYPE_UINT16_T
 515   AC_DEFINE(u_int16_t, [uint16_t], [Define a type for 16-bit unsigned
 516                                     integers.])
 517 ])
 518 AC_CHECK_TYPE([u_int32_t], [], [
 519   AC_TYPE_UINT32_T
 520   AC_DEFINE(u_int32_t, [uint32_t], [Define a type for 32-bit unsigned
 521                                     integers.])
 522 ])
 523 AC_CHECK_TYPE([u_int64_t], [], [
 524   AC_TYPE_UINT64_T
 525   AC_DEFINE(u_int64_t, [uint64_t], [Define a type for 64-bit unsigned
 526                                     integers.])
 527 ])
 528
 529 # see if ifaddrs.h is available
 530 AC_CHECK_HEADERS(ifaddrs.h)
 531
 532 # figure out what IPv4 interface code to use
 533 AC_CHECK_HEADERS(linux/types.h)  # needed for linux/filter.h on old systems
 534
 535 AC_CHECK_HEADER(linux/filter.h, DO_LPF=1, ,
 536 [
 537 #ifdef HAVE_LINUX_TYPES_H
 538 #include <linux/types.h>
 539 #endif
 540 ])
 541 if test -n "$DO_LPF"
 542 then
 543         AC_DEFINE([HAVE_LPF], [1],
 544                   [Define to 1 to use the Linux Packet Filter interface code.])
 545 else
 546         AC_CHECK_HEADER(sys/dlpi.h, DO_DLPI=1)
 547         if test -n "$DO_DLPI"
 548         then
 549                 AC_DEFINE([HAVE_DLPI], [1],
 550                           [Define to 1 to use DLPI interface code.])
 551         else
 552                 AC_CHECK_HEADER(net/bpf.h, DO_BPF=1)
 553                 if test -n "$DO_BPF"
 554                 then
 555                         AC_DEFINE([HAVE_BPF], [1],
 556                                    [Define to 1 to use the
 557                                    Berkeley Packet Filter interface code.])
 558                 fi
 559         fi
 560 fi
 561
 562 # SIOCGLIFCONF uses some transport structures.  Trick is not all platforms
 563 # use the same structures.  We like to use 'struct lifconf' and 'struct
 564 # lifreq', but we'll use these other structures if they're present.  HPUX
 565 # does not define 'struct lifnum', but does use SIOCGLIFNUM - they use an
 566 # int value.
 567 #
 568 AC_MSG_CHECKING([for struct lifnum])
 569 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ #include <sys/types.h>
 570   #include <sys/socket.h>
 571   #include <net/if.h>
 572 ]], [[ struct lifnum a;
 573 ]])],[AC_MSG_RESULT(yes)
 574          AC_DEFINE([ISC_PLATFORM_HAVELIFNUM], [1],
 575                    [Define to 1 if the system has 'struct lifnum'.])],[AC_MSG_RESULT(no)])
 576
 577 AC_MSG_CHECKING([for struct if_laddrconf])
 578 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ #include <sys/types.h>
 579   #include <net/if6.h>
 580 ]], [[ struct if_laddrconf a;
 581 ]])],[AC_MSG_RESULT(yes)
 582          AC_DEFINE([ISC_PLATFORM_HAVEIF_LADDRCONF], [1],
 583                    [Define to 1 if the system has 'struct if_laddrconf'.])],[AC_MSG_RESULT(no)])
 584
 585 AC_MSG_CHECKING([for struct if_laddrreq])
 586 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 587  #include <net/if6.h>
 588 ]], [[ struct if_laddrreq a;
 589 ]])],[AC_MSG_RESULT(yes)
 590          AC_DEFINE([ISC_PLATFORM_HAVEIF_LADDRREQ], [1],
 591                    [Define to 1 if the system has 'struct if_laddrreq'.])],[AC_MSG_RESULT(no)])
 592
 593 #
 594 # check for GCC noreturn attribute
 595 #
 596 AC_MSG_CHECKING(for GCC noreturn attribute)
 597 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[void foo() __attribute__((noreturn));]])],[AC_MSG_RESULT(yes)
 598          AC_DEFINE([ISC_DHCP_NORETURN], [__attribute__((noreturn))],
 599                    [Define to the string for a noreturn attribute.])],[AC_MSG_RESULT(no)
 600          AC_DEFINE([ISC_DHCP_NORETURN], [],
 601                    [Define to the string for a noreturn attribute.])])
 602
 603 # Look for optional headers.
 604 AC_CHECK_HEADERS(sys/socket.h net/if_dl.h net/if6.h regex.h)
 605
 606 # Solaris needs some libraries for functions
 607 AC_SEARCH_LIBS(socket, [socket])
 608 AC_SEARCH_LIBS(inet_ntoa, [nsl])
 609
 610 AC_SEARCH_LIBS(inet_aton, [socket nsl], ,
 611         AC_DEFINE([NEED_INET_ATON], [1],
 612                   [Define to 1 if the inet_aton() function is missing.]))
 613
 614 # Check for a standalone regex library.
 615 AC_SEARCH_LIBS(regcomp, [regex])
 616
 617 AC_CHECK_FUNCS(strlcat)
 618
 619 # For HP/UX we need -lipv6 for if_nametoindex, perhaps others.
 620 AC_SEARCH_LIBS(if_nametoindex, [ipv6])
 621
 622 # check for /dev/random (declares HAVE_DEV_RANDOM)
 623 AC_MSG_CHECKING(for random device)
 624 AC_ARG_WITH(randomdev,
 625         AS_HELP_STRING([--with-randomdev=PATH],[Path for random device
 626                        (default is /dev/random)]),
 627         use_randomdev="$withval", use_randomdev="unspec")
 628 if test "$use_randomdev" = "unspec"; then
 629         if test "$cross_compiling" = "yes"; then
 630                 AC_MSG_RESULT(unspecified)
 631                 AC_MSG_ERROR([ need --with-randomdev=PATH or --with-randomdev=no])
 632         fi
 633         use_randomdev="/dev/random"
 634 elif test "$use_randomdev" = "yes"; then
 635         use_randomdev="/dev/random"
 636 fi
 637 if test "$use_randomdev" = "no"; then
 638         AC_MSG_RESULT(disabled)
 639         BINDCONFIG="$BINDCONFIG --with-randomdev=no"
 640 else
 641         if test "$cross_compiling" = "yes"; then
 642                 AC_MSG_RESULT($use_randomdev (unchecked))
 643         else
 644                 AC_MSG_RESULT($use_randomdev)
 645                 AC_CHECK_FILE($use_randomdev,
 646                     AC_DEFINE([HAVE_DEV_RANDOM], [1],
 647                         [Define to 1 if you have the /dev/random or other configured file.]),
 648                     AC_MSG_ERROR(cannot find $use_randomdev))
 649         fi
 650         BINDCONFIG="$BINDCONFIG --with-randomdev=$use_randomdev"
 651 fi
 652
 653 BINDIOMUX="--disable-kqueue --disable-epoll --disable-devpoll"
 654 # check kqueue/epoll/devpoll alternative to select
 655 AC_ARG_ENABLE(kqueue,
 656         AS_HELP_STRING([--enable-kqueue],[use BSD kqueue (default is no)]),
 657         want_kqueue="$enableval", want_kqueue="no")
 658 if test "$want_kqueue" = "yes"; then
 659         BINDIOMUX="--enable-kqueue"
 660         AC_MSG_WARN([--enable-kqueue is not supported: it may lead to issues such as server looping])
 661 fi
 662 AC_ARG_ENABLE(epoll,
 663         AS_HELP_STRING([--enable-epoll],[use Linux epoll (default is no)]),
 664         want_epoll="$enableval", want_epoll="no")
 665 if test "$want_epoll" = "yes"; then
 666         BINDIOMUX="--enable-epoll"
 667         AC_MSG_WARN([--enable-epoll is not supported: it may lead to issues such as server looping])
 668 fi
 669 AC_ARG_ENABLE(devpoll,
 670         AS_HELP_STRING([--enable-devpoll],[use /dev/poll (default is no)]),
 671         want_devpoll="$enableval", want_devpoll="no")
 672 if test "$want_devpoll" = "yes"; then
 673         BINDIOMUX="--enable-devpoll"
 674         AC_MSG_WARN([--enable-devpoll is not supported: it may lead to issues such as server looping])
 675 fi
 676 AC_SUBST(BINDIOMUX)
 677
 678 # general extra bind configure arguments
 679 AC_ARG_WITH(bind-extra-config,
 680         AS_HELP_STRING([--with-bind-extra-config],[configure bind librairies
 681                        with some extra options (default is none)]),
 682         use_xbindconfig="$withval", use_xbindconfig="")
 683 case "$use_xbindconfig" in
 684 yes|no|'')
 685         ;;
 686 *)
 687         BINDCONFIG="$BINDCONFIG $use_xbindconfig"
 688         AC_MSG_WARN([Most options to bind configure are not supported when used by ISC DHCP])
 689         ;;
 690 esac
 691
 692 # see if there is a "sa_len" field in our interface information structure
 693 AC_CHECK_MEMBER(struct sockaddr.sa_len,
 694         AC_DEFINE([HAVE_SA_LEN], [],
 695                   [Define to 1 if the sockaddr structure has a length field.]),
 696         ,
 697         [#include <sys/socket.h>])
 698
 699 # figure out pointer size
 700 SAVE_CFLAGS="$CFLAGS"
 701 CFLAGS="$CFLAGS -I$srcdir"
 702 AC_CHECK_SIZEOF(struct iaddr *, , [
 703 #include "includes/inet.h"
 704 #include <stdio.h>
 705 ])
 706 CFLAGS="$SAVE_CFLAGS"
 707
 708 # Solaris does not have the msg_control or msg_controlen members
 709 # in the msghdr structure unless you define:
 710 #
 711 #   _XOPEN_SOURCE, _XOPEN_SOURCE_EXTENDED, and __EXTENSIONS__
 712 #
 713 # See the "standards" man page for details.
 714 #
 715 # We check for the msg_control member, and if it is not found, we check
 716 # again with the appropriate defines added to the CFLAGS. (In order to
 717 # do this we have to remove the check from the cache, which is what the
 718 # "unset" is for.)
 719 AC_CHECK_MEMBER(struct msghdr.msg_control,,
 720         [CFLAGS="$CFLAGS -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 721          CFLAGS="$CFLAGS -D__EXTENSIONS__"
 722          unset ac_cv_member_struct_msghdr_msg_control
 723          AC_CHECK_MEMBER(struct msghdr.msg_control,,
 724                 [AC_MSG_ERROR([Missing msg_control member in
 725                                msg_control structure.])],
 726                 [
 727 #include <sys/types.h>
 728 #include <sys/socket.h>
 729                 ])
 730         ],
 731         [
 732 #include <sys/types.h>
 733 #include <sys/socket.h>
 734         ])
 735
 736 AC_CHECK_MEMBER(struct tpacket_auxdata.tp_vlan_tci,
 737     [AC_DEFINE([VLAN_TCI_PRESENT], [1], [tpacket_auxdata.tp_vlan_tci present])]
 738     ,, [#include <linux/if_packet.h>])
 739
 740 # bind/Makefile.in is not from automake so we need 2 variables for bind dir
 741 BINDSUBDIR=
 742 BINDDIR=
 743 BINDSRCDIR=
 744 BINDLIBIRSDIR=
 745 BINDLIBDNSDIR=
 746 BINDLIBISCCFGDIR=
 747 BINDLIBISCDIR=
 748 DISTCHECK_LIBBIND_CONFIGURE_FLAG=
 749 AC_ARG_WITH(libbind,
 750         AS_HELP_STRING([--with-libbind=PATH],[bind includes and libraries are in PATH]),
 751         use_libbind="$withval", use_libbind="no")
 752 case "$use_libbind" in
 753 yes)
 754         AC_MSG_ERROR([PATH is required in --with-libbind=PATH])
 755         ;;
 756 no)
 757         BINDSUBDIR="\${top_srcdir}/bind"
 758         my_abs_srcdir=`cd $srcdir && pwd`
 759         BINDDIR="${my_abs_srcdir}/bind"
 760         if test ! -d "$srcdir/bind"; then
 761                 AC_MSG_ERROR([Where to find or build bind includes and libraries must be specified])
 762         fi
 763         if test -d "$srcdir/bind/bind9"; then
 764                 BINDSRCDIR="${my_abs_srcdir}/bind/bind9"
 765         else
 766                 if test ! -f "$srcdir/bind/version.tmp"; then
 767                         AC_MSG_ERROR([Cannot find $srcdir/bind/version.tmp])
 768                 fi
 769                 . "$srcdir/bind/version.tmp"
 770                 bindversion=${MAJORVER}.${MINORVER}.${PATCHVER}${RELEASETYPE}${RELEASEVER}
 771                 BINDSRCDIR="${my_abs_srcdir}/bind/bind-$bindversion"
 772         fi
 773         AC_CONFIG_FILES([$srcdir/bind/Makefile])
 774
 775         BINDLIBIRSDIR="$BINDSRCDIR/lib/irs"
 776         BINDLIBDNSDIR="$BINDSRCDIR/lib/dns"
 777         BINDLIBISCCFGDIR="$BINDSRCDIR/lib/isccfg"
 778         BINDLIBISCDIR="$BINDSRCDIR/lib/isc"
 779         ;;
 780 *)
 781         if test ! -d "$use_libbind"; then
 782                 AC_MSG_ERROR([Cannot find bind directory at $use_libbind])
 783         fi
 784         if test ! -d "$use_libbind/include" -o \
 785                 ! -f "$use_libbind/include/isc/buffer.h"
 786         then
 787                 AC_MSG_ERROR([Cannot find bind includes at $use_libbind/include])
 788         fi
 789         if test ! -d "$use_libbind/lib" -o \
 790                 \( ! -f "$use_libbind/lib/libisc.a" -a \
 791                    ! -f "$use_libbind/lib/libisc.la" \)
 792         then
 793                 AC_MSG_ERROR([Cannot find bind libraries at $use_libbind/lib])
 794         fi
 795         BINDDIR="$use_libbind"
 796         BINDLIBIRSDIR="$BINDDIR/lib"
 797         BINDLIBDNSDIR="$BINDDIR/lib"
 798         BINDLIBISCCFGDIR="$BINDDIR/lib"
 799         BINDLIBISCDIR="$BINDDIR/lib"
 800         DISTCHECK_LIBBIND_CONFIGURE_FLAG="--with-libbind=$use_libbind"
 801         ;;
 802 esac
 803 AC_SUBST(BINDSUBDIR)
 804 AC_SUBST(BINDDIR)
 805 AC_SUBST(BINDSRCDIR)
 806 AC_SUBST(BINDLIBIRSDIR)
 807 AC_SUBST(BINDLIBDNSDIR)
 808 AC_SUBST(BINDLIBISCCFGDIR)
 809 AC_SUBST(BINDLIBISCDIR)
 810 AC_SUBST(DISTCHECK_LIBBIND_CONFIGURE_FLAG)
 811 AM_CONDITIONAL(HAVE_BINDDIR, test "$use_libbind" = "no")
 812
 813 #
 814 # GNU libtool support
 815 #
 816 case "$build_os" in
 817         sunos*)
 818                 # Just set the maximum command line length for sunos
 819                 # as it otherwise takes a exceptionally long time to
 820                 # work it out. Required for libtool.
 821
 822                 lt_cv_sys_max_cmd_len=4096
 823                 ;;
 824 esac
 825
 826 want_libtool="no"
 827 @BEGIN WITH LIBTOOL
 828 LT_INIT
 829 want_libtool="yes"
 830 @END WITH LIBTOOL
 831
 832 BINDLT=
 833 DISTCHECK_LIBTOOL_CONFIGURE_FLAG=
 834 AC_ARG_ENABLE(libtool,
 835         AS_HELP_STRING([--enable-libtool],
 836 @BEGIN WITH LIBTOOL
 837 [use GNU libtool for dynamic shared libraries (default is yes).]),
 838 @END WITH LIBTOOL
 839 @BEGIN WITHOUT LIBTOOL
 840 [use GNU libtool for dynamic shared libraries (default is no).]),
 841 @END WITHOUT LIBTOOL
 842         want_libtool="$enableval")
 843
 844 if test "$use_libbind" != "no"; then
 845         if test "$want_libtool" = "yes" -a \
 846                 ! -f "$use_libbind/lib/libisc.la"
 847         then
 848                 AC_MSG_ERROR([Cannot find dynamic libraries at $use_libbind/lib])
 849         fi
 850         if test "$want_libtool" = "no" -a \
 851                 ! -f "$use_libbind/lib/libisc.a"
 852         then
 853                 AC_MSG_ERROR([Cannot find static libraries at $use_libbind/lib])
 854         fi
 855 fi
 856
 857 @BEGIN WITH LIBTOOL
 858 if test "$want_libtool" = "no"; then
 859         AC_MSG_ERROR([libtool configure is used but libtool is disabled?])
 860 fi
 861
 862 DHLIBS=LTLIBRARIES
 863 A=la
 864 BINDLT="--with-libtool --disable-symtable"
 865 DISTCHECK_LIBTOOL_CONFIGURE_FLAG="--enable-libtool"
 866 @END WITH LIBTOOL
 867
 868 @BEGIN WITHOUT LIBTOOL
 869 if test "$want_libtool" = "yes"; then
 870         AC_MSG_WARN([legacy configure is used but libtool is enabled. Trying to recover...])
 871         # expand $ac_configure_args
 872         eval "set my_configure_args $ac_configure_args"
 873         shift
 874         cd $srcdir; exec ./config+lt "$@"
 875         AC_MSG_ERROR([Recovering failed])
 876 fi
 877
 878 DHLIBS=LIBRARIES
 879 A=a
 880 @END WITHOUT LIBTOOL
 881
 882 AC_SUBST(DHLIBS)
 883 AC_SUBST(A)
 884 AC_SUBST(BINDLT)
 885 AC_SUBST(DISTCHECK_LIBTOOL_CONFIGURE_FLAG)
 886
 887 # quoting in Makefile.am.in
 888 Q=@
 889 AC_SUBST(Q)
 890
 891 # install bind includes and libraries
 892
 893 want_install_bind="no"
 894 @BEGIN WITH LIBTOOL
 895 want_install_bind="yes"
 896 @END WITH LIBTOOL
 897 if test "$want_libtool" = "yes"; then
 898         want_install_bind="yes"
 899 fi
 900 if test "$use_libbind" != "no"; then
 901         want_install_bind="no"
 902 fi
 903 AC_ARG_ENABLE(bind_install,
 904         AS_HELP_STRING([--enable-bind-install],
 905 @BEGIN WITH LIBTOOL
 906 [install bind includes and libraries.]),
 907 @END WITH LIBTOOL
 908 @BEGIN WITHOUT LIBTOOL
 909 [install bind includes and libraries (default is no).]),
 910 @END WITHOUT LIBTOOL
 911         want_install_bind="$enableval")
 912 if test "$want_install_bind" = "yes"; then
 913         if test "$use_libbind" != "no"; then
 914                 AC_MSG_WARN([--enable-bind-install does nothing when --with-libbind is set])
 915         fi
 916 elif test "$want_libtool" = "yes" -a "$use_libbind" = "no"; then
 917         AC_MSG_WARN([embedded dynamic bind libraries must be installed])
 918 fi
 919 AM_CONDITIONAL(INSTALL_BIND, test "$want_install_bind" = "yes")
 920
 921 # OpenLDAP support.
 922 AC_ARG_WITH(ldap,
 923     AS_HELP_STRING([--with-ldap],[enable OpenLDAP support in dhcpd (default is no)]),
 924     [ldap=$withval],
 925     [ldap=no])
 926
 927 # OpenLDAP with SSL support.
 928 AC_ARG_WITH(ldapcrypto,
 929     AS_HELP_STRING([--with-ldapcrypto],[enable OpenLDAP crypto support in dhcpd (default is no)]),
 930     [ldapcrypto=$withval],
 931     [ldapcrypto=no])
 932
 933 # Gssapi to allow LDAP to authenticate with a keytab
 934 AC_ARG_WITH(ldap-gssapi,
 935     AC_HELP_STRING([--with-ldap-gssapi],
 936                    [enable krb5/gssapi authentication for OpenLDAP in dhcpd (default is no)]),
 937     [ldap_gssapi=$withval],
 938     [ldap_gssapi=no])
 939
 940
 941 # LDAP CASA auth support.
 942 AC_ARG_WITH(ldapcasa,
 943     AC_HELP_STRING([--with-ldapcasa],
 944                    [enable LDAP CASA auth support in dhcpd (default is no)]),
 945     [ldapcasa=$withval],
 946     [ldapcasa=no])
 947
 948 # OpenLDAP support is disabled by default, if enabled then SSL support is an
 949 # extra optional that is also disabled by default.  Enabling LDAP SSL support
 950 # implies enabling LDAP support. Similarly, KRB5 support implies LDAP support,
 951 # but doesn't include SSL. The two are not dependant.
 952 if test x$ldap = xyes || test x$ldapcrypto = xyes || test x$ldap_gssapi = xyes; then
 953     saved_LIBS="$LIBS"
 954     LIBS=""
 955     AC_SEARCH_LIBS(ldap_initialize, [ldap], ,
 956                    AC_MSG_FAILURE([*** Cannot find ldap_initialize with -lldap - do you need to install an OpenLDAP2 Devel package?]))
 957     AC_SEARCH_LIBS(ber_pvt_opt_on, [lber], ,
 958                    AC_MSG_FAILURE([*** Cannot find ber_pvt_opt_on with -llber - do you need to install an OpenLDAP2 Devel package?]))
 959     if test x$ldap_gssapi = xyes ; then
 960     AC_SEARCH_LIBS(krb5_init_context, [krb5], ,
 961           AC_MSG_FAILURE([*** Cannot find krb5_init_context with -lkrb5 - do you need to install a Kerberos Devel package?]))
 962     fi
 963
 964     # Create LDAP_LIBS which we specify them explicitly rather than lumping them in with LIBS
 965     AC_SUBST(LDAP_LIBS, [$LIBS])
 966     LIBS="$saved_LIBS"
 967
 968
 969     AC_CHECK_HEADERS([ldap.h])
 970     AC_CHECK_FUNCS([inet_pton inet_ntop])
 971
 972
 973     LDAP_CFLAGS="-DLDAP_CONFIGURATION"
 974
 975     if test x$ldapcasa = xyes ; then
 976     AC_CHECK_HEADERS([micasa_mgmd.h],[
 977            LDAP_CFLAGS="$LDAP_CFLAGS -DLDAP_CASA_AUTH"
 978     ], AC_MSG_FAILURE([*** Cannot find micasa_mgmd.h for ldap casa auth support]))
 979     fi
 980
 981     if test x$ldapcrypto = xyes ; then
 982     LDAP_CFLAGS="$LDAP_CFLAGS -DLDAP_USE_SSL"
 983     fi
 984
 985     if test x$ldap_gssapi = xyes; then
 986     LDAP_CFLAGS="$LDAP_CFLAGS -DLDAP_USE_GSSAPI"
 987     fi
 988
 989     AC_SUBST(LDAP_CFLAGS, [$LDAP_CFLAGS])
 990 fi
 991
 992 # Append selected warning levels to CFLAGS before substitution (but after
 993 # AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[],[]) & etc).
 994 CFLAGS="$CFLAGS $STD_CWARNINGS"
 995
 996 # Try to add the bind and dhcp include directories
 997 CFLAGS="$CFLAGS -I\$(top_srcdir)/includes -I$BINDDIR/include"
 998
 999 case "$host" in
1000 *-darwin*)
1001     CFLAGS="$CFLAGS -D__APPLE_USE_RFC_3542";;
1002 *-solaris*)
1003     # As of Solaris 11, ethernet dev files are in /dev/net
1004     AC_CHECK_FILE(/dev/net,
1005                     [AC_DEFINE([USE_DEV_NET], [1],
1006                         [Define to 1 if ethernet devices are in /dev/net])])
1007     ;;
1008 esac
1009
1010 AC_C_FLEXIBLE_ARRAY_MEMBER
1011
1012 AC_CONFIG_FILES([
1013   Makefile
1014   client/Makefile
1015   client/tests/Makefile
1016   common/Makefile.am
1017   common/Makefile
1018   common/tests/Makefile
1019   dhcpctl/Makefile.am
1020   dhcpctl/Makefile
1021   includes/Makefile
1022   omapip/Makefile.am
1023   omapip/Makefile
1024   relay/Makefile
1025   server/Makefile
1026   tests/Makefile.am
1027   tests/Makefile
1028   tests/unittest.sh
1029   server/tests/Makefile
1030   doc/devel/doxyfile
1031 ])
1032 AC_OUTPUT
1033
1034 @BEGIN WITH LIBTOOL
1035 AC_MSG_NOTICE([postconfig: run automake in $srcdir])
1036 (cd $srcdir; automake)
1037 AC_MSG_NOTICE([postconfig: rerun config.status])
1038 sh ./config.status
1039 @END WITH LIBTOOL
1040
1041 if test "$enable_dhcpv4o6" = "yes"; then
1042         DHCP_VERSIONS="DHCPv4, DHCPv6 and DHCPv4-over-DHCPv6"
1043 elif test "$enable_dhcpv6" != "no"; then
1044         DHCP_VERSIONS="DHCPv4 and DHCPv6"
1045 else
1046         DHCP_VERSIONS="DHCPv4"
1047 fi
1048
1049 cat > config.report << END
1050
1051      ISC DHCP source configure results:
1052     -=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
1053
1054 Package:
1055   Name:          $PACKAGE_NAME
1056   Version:       $PACKAGE_VERSION
1057
1058 C Compiler:      $CC
1059
1060 Flags:
1061   DEFS:          $DEFS
1062   CFLAGS:        $CFLAGS
1063
1064 DHCP versions:   $DHCP_VERSIONS
1065
1066 Features:
1067   debug:         $enable_debug
1068   failover:      $enable_failover
1069   execute:       $enable_execute
1070   binary-leases: $enable_binary_leases
1071   dhcpv6:        $enable_dhcpv6
1072   delayed-ack:   $enable_delayed_ack
1073
1074 Developer:
1075   ATF unittests : $atf_path
1076
1077 END
1078 # TODO: Add Perl system tests
1079
1080 if test "$atf_path" != "no"
1081 then
1082 echo "ATF_CFLAGS  : $ATF_CFLAGS" >> config.report
1083 echo "ATF_LDFLAGS : $ATF_LDFLAGS" >> config.report
1084 echo "ATF_BIN : $ATF_BIN" >> config.report
1085 echo
1086 fi
1087
1088 cat config.report
1089
1090 echo
1091 echo Now you can type "make" to build ISC DHCP
1092 echo