configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  23 AC_ARG_WITH(gd, dnl
  24   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  25             [dnl
  26 case "$with_gd" in
  27 yes|''|no) ;;
  28 *) libgd_include="-I$withval/include"
  29    libgd_ldflags="-L$withval/lib" ;;
  30 esac
  31 ])
  32 AC_ARG_WITH(gd-include, dnl
  33   --with-gd-include=DIR   find libgd include files in DIR,
  34             [dnl
  35 case "$with_gd_include" in
  36 ''|no) ;;
  37 *) libgd_include="-I$withval" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH(gd-lib, dnl
  41   --with-gd-lib=DIR       find libgd library files in DIR,
  42             [dnl
  43 case "$with_gd_lib" in
  44 ''|no) ;;
  45 *) libgd_ldflags="-L$withval" ;;
  46 esac
  47 ])
  48
  49 if test -n "$libgd_include"; then
  50   config_vars="$config_vars
  51 CFLAGS-memusagestat.c = $libgd_include"
  52 fi
  53 if test -n "$libgd_ldflags"; then
  54   config_vars="$config_vars
  55 libgd-LDFLAGS = $libgd_ldflags"
  56 fi
  57
  58 dnl Arguments to specify presence of other packages/features.
  59 AC_ARG_WITH(fp, dnl
  60 [  --with-fp              if using floating-point hardware [default=yes]],
  61             with_fp=$withval, with_fp=yes)
  62 AC_SUBST(with_fp)
  63 AC_ARG_WITH(binutils, dnl
  64   --with-binutils=PATH    specify location of binutils (as and ld),
  65             path_binutils=$withval, path_binutils='')
  66 AC_ARG_WITH(elf, dnl
  67   --with-elf              if using the ELF object format,
  68             elf=$withval, elf=no)
  69 AC_ARG_WITH(xcoff, dnl
  70   --with-xcoff            if using the XCOFF object format,
  71             xcoff=$withval, xcoff=no)
  72 AC_ARG_WITH(cvs, dnl
  73 [  --without-cvs           if CVS should not be used],
  74             with_cvs=$withval, with_cvs=yes)
  75 if test "$with_cvs" = yes; then
  76   if test -d $srcdir/CVS && grep :pserver: $srcdir/CVS/Root > /dev/null
  77   then
  78     with_cvs=no
  79   fi
  80 fi
  81 AC_SUBST(with_cvs)
  82
  83 AC_ARG_WITH(headers, dnl
  84 [  --with-headers=PATH     location of system headers to use
  85                           [e.g. /usr/src/linux/include]
  86                           [default=compiler default]],
  87             sysheaders=$withval, sysheaders='')
  88
  89 AC_ARG_ENABLE(sanity-checks, dnl
  90 [  --disable-sanity-checks really do not use threads (should not be used
  91                           except in special situations) [default=yes]],
  92               enable_sanity=$enableval, enable_sanity=yes)
  93
  94 dnl Arguments to enable or disable building the static, shared, profiled,
  95 dnl and -fomit-frame-pointer libraries.
  96 dnl I've disabled this for now since we cannot build glibc without static
  97 dnl libraries built in the moment.
  98 dnl AC_ARG_ENABLE(static, dnl
  99 dnl [  --enable-static         build static library [default=yes]],
 100 dnl           static=$enableval, static=yes)
 101 static=yes
 102 AC_ARG_ENABLE(shared, dnl
 103 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 104               shared=$enableval, shared=default)
 105 AC_ARG_ENABLE(profile, dnl
 106 [  --enable-profile        build profiled library [default=yes]],
 107               profile=$enableval, profile=yes)
 108 AC_ARG_ENABLE(omitfp, dnl
 109 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 110               omitfp=$enableval, omitfp=no)
 111 AC_ARG_ENABLE(bounded, dnl
 112 [  --enable-bounded        build with runtime bounds checking [default=no]],
 113               bounded=$enableval, bounded=no)
 114 AC_ARG_ENABLE(versioning, dnl
 115 [  --disable-versioning    do not include versioning information in the
 116                           library objects [default=yes if supported]],
 117              enable_versioning=$enableval, enable_versioning=yes)
 118
 119 AC_ARG_ENABLE(oldest-abi, dnl
 120 [  --enable-oldest-abi=ABI configure the oldest ABI supported [e.g. 2.2]
 121                           [default=glibc default]],
 122             oldest_abi=$enableval, oldest_abi=no)
 123 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 124   oldest_abi=default
 125 else
 126   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 127 fi
 128 AC_SUBST(oldest_abi)
 129
 130 dnl Generic infrastructure for drop-in additions to libc.
 131 AC_ARG_ENABLE(add-ons, dnl
 132 [  --enable-add-ons[=DIR1,DIR2]...
 133                           configure and build add-ons in DIR1,DIR2,...
 134                           search for add-ons if no parameter given],
 135   [case "$enableval" in
 136     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 137          test "$add_ons" = "*" && add_ons= ;;
 138     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 139    esac],
 140   [add_ons=])
 141
 142 dnl Let the user avoid using TLS.  Don't know why but...
 143 AC_ARG_WITH(tls, dnl
 144 [  --without-tls           prevent support for TLS],
 145             usetls=$withval, usetls=yes)
 146
 147 AC_CONFIG_SUBDIRS($add_ons)
 148 add_ons_pfx=
 149 if test x"$add_ons" != x; then
 150   for f in $add_ons; do
 151     # Some sanity checks
 152     if test "$f" = "crypt"; then
 153       AC_MSG_ERROR([
 154 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 155 *** part of glibc and using the old add-on will not work with this
 156 *** release.  Start again with fresh sources and without the old
 157 *** \`crypt' add-on.])
 158     fi
 159     if test "$f" = "localedata"; then
 160       AC_MSG_ERROR([
 161 *** It seems that you're using an old \`localedata' add-on.  localedata
 162 *** is now part of glibc and using the old add-on will not work with
 163 *** this release.  Start again with fresh sources and without the old
 164 *** \`localedata' add-on.])
 165     fi
 166     # Test whether such a subdir really exists.
 167     if test -d $srcdir/$f; then
 168       add_ons_pfx="$add_ons_pfx $f/"
 169     else
 170       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 171     fi
 172   done
 173 fi
 174
 175 dnl On some platforms we cannot use dynamic loading.  We must provide
 176 dnl static NSS modules.
 177 AC_ARG_ENABLE(static-nss, dnl
 178 [  --enable-static-nss     build static NSS modules [default=no]],
 179               static_nss=$enableval, static_nss=no)
 180 dnl Enable static NSS also if we build no shared objects.
 181 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 182   AC_DEFINE(DO_STATIC_NSS)
 183 fi
 184
 185 AC_ARG_ENABLE(force-install,
 186 [  --disable-force-install don't force installation of files from this package,
 187                           even if they are older than the installed files],
 188               force_install=$enableval, force_install=yes)
 189 AC_SUBST(force_install)
 190
 191 dnl On some platforms we allow dropping compatibility with all kernel
 192 dnl versions.
 193 AC_ARG_ENABLE(kernel,
 194 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 195                            than VERSION],
 196               minimum_kernel=$enableval)
 197 dnl Prevent unreasonable values.
 198 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 199   # Better nothing than this.
 200   minimum_kernel=""
 201 else
 202   if test "$minimum_kernel" = current; then
 203     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 204   fi
 205 fi
 206
 207 dnl For the development we sometimes want gcc to issue even more warnings.
 208 dnl This is not the default since many of the extra warnings are not
 209 dnl appropriate.
 210 AC_ARG_ENABLE(all-warnings,
 211 [  --enable-all-warnings   enable all useful warnings gcc can issue],
 212               all_warnings=$enableval)
 213 AC_SUBST(all_warnings)
 214
 215 AC_CANONICAL_HOST
 216
 217 # The way shlib-versions is used to generate soversions.mk uses a
 218 # fairly simplistic model for name recognition that can't distinguish
 219 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 220 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 221 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 222 case "$host_os" in
 223 linux*)
 224   ;;
 225 gnu*)
 226   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 227   ;;
 228 esac
 229
 230 # We keep the original values in `$config_*' and never modify them, so we
 231 # can write them unchanged into config.make.  Everything else uses
 232 # $machine, $vendor, and $os, and changes them whenever convenient.
 233 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 234
 235 # Don't allow vendor == "unknown"
 236 test "$config_vendor" = unknown && config_vendor=
 237 config_os="`echo $config_os | sed 's/^unknown-//'`"
 238
 239 # Some configurations imply other options.
 240 case "$host_os" in
 241 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 242   # These systems always use GNU tools.
 243   gnu_ld=yes gnu_as=yes ;;
 244 esac
 245 case "$host_os" in
 246 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 247 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 248   ;;
 249 gnu* | linux* | sysv4* | solaris2* | irix6*)
 250   # These systems (almost) always use the ELF format.
 251   elf=yes
 252   ;;
 253 aix*)
 254   # These systems are always xcoff
 255   xcoff=yes
 256   elf=no
 257   ;;
 258 esac
 259
 260 machine=$config_machine
 261 vendor=$config_vendor
 262 os=$config_os
 263
 264 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 265 # Unify this here.
 266 if test "$machine" = rs6000; then
 267   machine="powerpc"
 268 fi
 269
 270 ###
 271 ### I put this here to prevent those annoying emails from people who cannot
 272 ### read and try to compile glibc on unsupported platforms.  --drepper
 273 ###
 274 ### By using the undocumented --enable-hacker-mode option for configure
 275 ### one can skip this test to make the configuration not fail for unsupported
 276 ### platforms.
 277 ###
 278 if test -z "$enable_hacker_mode"; then
 279   case "$machine-$host_os" in
 280   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 281     ;;
 282   *)
 283     echo "*** The GNU C library is currently not available for this platform."
 284     echo "*** So far nobody cared to port it and if there is no volunteer it"
 285     echo "*** might never happen.  So, if you have interest to see glibc on"
 286     echo "*** this platform visit"
 287     echo "***   http://www.gnu.org/software/libc/porting.html"
 288     echo "*** and join the group of porters"
 289     exit 1
 290     ;;
 291   esac
 292 fi
 293
 294 dnl We need to use [ and ] for other purposes for a while now.
 295 changequote(,)dnl
 296 # Expand the configuration machine name into a subdirectory by architecture
 297 # type and particular chip.
 298 case "$machine" in
 299 a29k | am29000) base_machine=a29k machine=a29k ;;
 300 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 301 arm*)           base_machine=arm machine=arm/arm32/$machine ;;
 302 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 303 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 304 hppa*64*)       base_machine=hppa machine=hppa/hppa64 ;;
 305 hppa*)          base_machine=hppa machine=hppa/hppa1.1 ;;
 306 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 307 ia64)           base_machine=ia64 machine=ia64 ;;
 308 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 309 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 310 m88???)         base_machine=m88k machine=m88k/$machine ;;
 311 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 312 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 313 mips*)          base_machine=mips machine=mips/$machine ;;
 314 s390)           base_machine=s390 machine=s390/s390-32 ;;
 315 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 316 sh3*)           base_machine=sh machine=sh/sh3 ;;
 317 sh4*)           base_machine=sh machine=sh/sh4 ;;
 318 sparc | sparcv[67])
 319                 base_machine=sparc machine=sparc/sparc32 ;;
 320 sparcv8 | supersparc | hypersparc)
 321                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 322 sparcv8plus | sparcv8plusa | sparcv9)
 323                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 324 sparcv8plusb | sparcv9b)
 325                 base_machine=sparc machine=sparc/sparc32/sparcv9b ;;
 326 sparc64 | ultrasparc)
 327                 base_machine=sparc machine=sparc/sparc64 ;;
 328 sparc64b | ultrasparc3)
 329                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 330 thumb*)         base_machine=thumb machine=arm/thumb/$machine ;;
 331 *)              base_machine=$machine ;;
 332 esac
 333 changequote([,])dnl
 334 AC_SUBST(base_machine)
 335
 336 if test "$base_machine" = "i386"; then
 337   AC_DEFINE(USE_REGPARMS)
 338 fi
 339
 340 # Compute the list of sysdep directories for this configuration.
 341 # This can take a while to compute.
 342 sysdep_dir=$srcdir/sysdeps
 343 AC_MSG_CHECKING(sysdep dirs)
 344 dnl We need to use [ and ] for other purposes for a while now.
 345 changequote(,)dnl
 346 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 347 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 348
 349 case "$os" in
 350 gnu*)
 351   base_os=mach/hurd ;;
 352 netbsd* | 386bsd* | freebsd* | bsdi*)
 353   base_os=unix/bsd/bsd4.4 ;;
 354 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 355   base_os=unix/bsd ;;
 356 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 357   base_os=unix/sysv ;;
 358 irix6*)
 359   base_os=unix/sysv/irix6/$os ;;
 360 solaris[2-9]*)
 361   base_os=unix/sysv/sysv4 ;;
 362 hpux*)
 363   base_os=unix/sysv/hpux/$os ;;
 364 aix4.3*)
 365   base_os=unix/sysv/aix/aix4.3 ;;
 366 none)
 367   base_os=standalone ;;
 368 *)
 369   base_os='' ;;
 370 esac
 371
 372 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 373 tail=$os
 374 ostry=$os
 375 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 376   ostry="$ostry /$o"
 377   tail=$o
 378 done
 379 o=`echo $tail | sed 's/[0-9]*$//'`
 380 if test $o != $tail; then
 381   ostry="$ostry /$o"
 382 fi
 383 # For linux-gnu, try linux-gnu, then linux.
 384 o=`echo $tail | sed 's/-.*$//'`
 385 if test $o != $tail; then
 386   ostry="$ostry /$o"
 387 fi
 388
 389 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 390 base=
 391 tail=$base_os
 392 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 393   set $b
 394   base="$base /$1"
 395   tail="$2"
 396 done
 397
 398 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 399 mach=
 400 tail=$machine
 401 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 402   set $m
 403   # Prepend the machine's FPU directory unless --without-fp.
 404   if test "$with_fp" = yes; then
 405     mach="$mach /$1/fpu"
 406   fi
 407   mach="$mach /$1"
 408   tail="$2"
 409 done
 410
 411 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 412 changequote([,])dnl
 413
 414 # Find what sysdep directories exist.
 415 sysnames=
 416 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 417 for d in $add_ons_pfx ''; do
 418   for b in $base ''; do
 419     for m0 in $mach ''; do
 420       for v in /$vendor ''; do
 421         test "$v" = / && continue
 422         for o in /$ostry ''; do
 423           test "$o" = / && continue
 424           for m in $mach ''; do
 425             if test "$m0$b$v$o$m"; then
 426               try="${d}sysdeps$m0$b$v$o$m"
 427               test -n "$enable_debug_configure" &&
 428               echo "$0 [DEBUG]: try $try" >&2
 429               if test -d $srcdir/$try; then
 430                 sysnames="$sysnames $try"
 431                 { test -n "$o" || test -n "$b"; } && os_used=t
 432                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 433               fi
 434             fi
 435           done
 436         done
 437       done
 438     done
 439   done
 440 done
 441 IFS="$ac_save_ifs"
 442
 443 if test -z "$os_used" && test "$os" != none; then
 444   AC_MSG_ERROR(Operating system $os is not supported.)
 445 fi
 446 if test -z "$machine_used" && test "$machine" != none; then
 447   AC_MSG_ERROR(The $machine is not supported.)
 448 fi
 449
 450 # We have now validated the configuration.
 451
 452
 453 # If using ELF, look for an `elf' subdirectory of each machine directory.
 454 # We prepend these rather than inserting them whereever the machine appears
 455 # because things specified by the machine's ELF ABI should override
 456 # OS-specific things, and should always be the same for any OS on the
 457 # machine (otherwise what's the point of an ABI?).
 458 if test "$elf" = yes; then
 459   elf_dirs=
 460   for d in $add_ons_pfx ''; do
 461     for m in $mach; do
 462       if test -d $srcdir/${d}sysdeps$m/elf; then
 463         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 464       fi
 465     done
 466   done
 467   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 468 fi
 469
 470
 471 # Expand the list of system names into a full list of directories
 472 # from each element's parent name and Implies file (if present).
 473 set $sysnames
 474 names=
 475 while test $# -gt 0; do
 476   name=$1
 477   shift
 478
 479   case " $names " in *" $name "*)
 480     # Already in the list.
 481     continue
 482   esac
 483
 484   # Report each name as we discover it, so there is no long pause in output.
 485   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 486
 487   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 488
 489   case $name in
 490     /*) xsrcdir= ;;
 491     *)  xsrcdir=$srcdir/ ;;
 492   esac
 493   test -n "$enable_debug_configure" &&
 494   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 495
 496   if test -f $xsrcdir$name/Implies; then
 497     # Collect more names from the `Implies' file (removing comments).
 498     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 499     implied=
 500     for x in $implied_candidate; do
 501       found=no
 502       if test -d $xsrcdir$name_base/$x; then
 503         implied="$implied $name_base/$x";
 504         found=yes
 505       fi
 506       for d in $add_ons_pfx ''; do
 507         try="${d}sysdeps/$x"
 508         case $d in
 509          /*) try_srcdir= ;;
 510          *) try_srcdir=$srcdir/ ;;
 511         esac
 512         test -n "$enable_debug_configure" &&
 513          echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
 514         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 515         then
 516           implied="$implied $try"
 517           found=yes
 518         fi
 519       done
 520       if test $found = no; then
 521         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 522       fi
 523     done
 524   else
 525     implied=
 526   fi
 527
 528   # Add NAME to the list of names.
 529   names="$names $name"
 530
 531   # Find the parent of NAME, using the empty string if it has none.
 532 changequote(,)dnl
 533   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 534 changequote([,])dnl
 535
 536   # Add the names implied by NAME, and NAME's parent (if it has one), to
 537   # the list of names to be processed (the argument list).  We prepend the
 538   # implied names to the list and append the parent.  We want implied
 539   # directories to come before further directories inferred from the
 540   # configuration components; this ensures that for sysv4, unix/common
 541   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 542   # after sysv4).
 543   sysnames="`echo $implied $* $parent`"
 544   test -n "$sysnames" && set $sysnames
 545 done
 546
 547 # Add the default directories.
 548 default_sysnames=sysdeps/generic
 549 if test "$elf" = yes; then
 550   default_sysnames="sysdeps/generic/elf $default_sysnames"
 551 fi
 552 sysnames="$names $default_sysnames"
 553 AC_SUBST(sysnames)
 554 # The other names were emitted during the scan.
 555 AC_MSG_RESULT($default_sysnames)
 556
 557
 558 ### Locate tools.
 559
 560 AC_PROG_INSTALL
 561 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 562   # The makefiles need to use a different form to find it in $srcdir.
 563   INSTALL='\$(..)./scripts/install-sh -c'
 564 fi
 565 AC_PROG_LN_S
 566
 567 # We need the physical current working directory.  We cannot use the
 568 # "pwd -P" shell builtin since that's not portable.  Instead we try to
 569 # find a pwd binary.  Note that assigning to the PWD environment
 570 # variable might have some interesting side effects, so we don't do
 571 # that.
 572 AC_PATH_PROG(PWD_P, pwd, no)
 573 if test "$PWD_P" = no; then
 574   AC_MSG_ERROR(*** A pwd binary could not be found.)
 575 fi
 576
 577 # These programs are version sensitive.
 578 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 579 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 580   [version \([egcygnustpi-]*[0-9.]*\)],
 581   [*gcc-2.9[5-9].*|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|3.[0-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]|sgicc-*],
 582   critic_missing=gcc)
 583 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 584   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 585   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 586
 587
 588 if test -n "$critic_missing"; then
 589 AC_MSG_ERROR([
 590 *** These critical programs are missing or too old:$critic_missing
 591 *** Check the INSTALL file for required versions.])
 592 fi
 593
 594
 595 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 596   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 597   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 598   MSGFMT=: aux_missing="$aux_missing msgfmt")
 599 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 600   [GNU texinfo.* \([0-9][0-9.]*\)],
 601   [4.*],
 602   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 603 AC_CHECK_PROG_VER(SED, sed, --version,
 604   [GNU sed version \([0-9]*\.[0-9.]*\)],
 605   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 606   SED=: aux_missing="$aux_missing sed")
 607
 608 AC_PROG_CC_LOCAL
 609 AC_CANONICAL_BUILD
 610 if test $host != $build; then
 611   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 612 fi
 613 AC_SUBST(cross_compiling)
 614 AC_PROG_CPP
 615 LIBC_PROG_BINUTILS
 616 AC_CHECK_TOOL(MIG, mig)
 617
 618 # Accept binutils 2.10.1 or newer (and also any ia64 2.9 version)
 619 # XXX Commented out because it filters out too many good versions.
 620 # XXX --drepper
 621 # AC_CHECK_PROG_VER(AS, $AS, --version,
 622 #   [GNU assembler.* \([0-9]*\.[0-9.]*\(-ia64-[0-9]*\)*\)],
 623 #   [2.10.[1-9]* | 2.1[1-9]* | 2.9-ia64-*], AS=: critic_missing=t)
 624
 625 test -n "$aux_missing" && AC_MSG_WARN([
 626 *** These auxiliary programs are missing or too old:$aux_missing
 627 *** some features will be disabled.
 628 *** Check the INSTALL file for required versions.])
 629
 630 # glibcbug.in wants to know the compiler version.
 631 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 632 AC_SUBST(CCVERSION)
 633
 634 # if using special system headers, find out the compiler's sekrit
 635 # header directory and add that to the list.  NOTE: Only does the right
 636 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 637 if test -n "$sysheaders"; then
 638   ccheaders=`$CC -print-file-name=include`
 639   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 640 fi
 641 AC_SUBST(SYSINCLUDES)
 642
 643 # check if ranlib is necessary
 644 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 645 cat > conftest.c <<EOF
 646 int a;
 647 char b;
 648 void c(void) {}
 649 EOF
 650 $CC $CFLAGS -c conftest.c
 651 $AR cr conftest.a conftest.c
 652 cp conftest.a conftest2.a
 653 $RANLIB conftest.a
 654 if cmp -s conftest.a conftest2.a; then
 655   libc_cv_ranlib_necessary=no
 656 else
 657   libc_cv_ranlib_necessary=yes
 658 fi
 659 rm -rf conftest*])
 660 if test "$libc_cv_ranlib_necessary" = no; then
 661  RANLIB=:
 662 fi
 663
 664 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 665 # since this would lead to problems installing/building glibc.
 666 # LD_LIBRARY_PATH contains the current directory if one of the following
 667 # is true:
 668 # - one of the terminals (":" and ";") is the first or last sign
 669 # - two terminals occur directly after each other
 670 # - the path contains an element with a dot in it
 671 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 672 changequote(,)dnl
 673 case ${LD_LIBRARY_PATH} in
 674   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 675     ld_library_path_setting="contains current directory"
 676     ;;
 677   *)
 678     ld_library_path_setting="ok"
 679     ;;
 680 esac
 681 changequote([,])dnl
 682 AC_MSG_RESULT($ld_library_path_setting)
 683 if test "$ld_library_path_setting" != "ok"; then
 684 AC_MSG_ERROR([
 685 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 686 *** building glibc. Please change the environment variable
 687 *** and run configure again.])
 688 fi
 689
 690 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
 691 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
 692   libc_cv_gcc_static_libgcc=
 693 else
 694   libc_cv_gcc_static_libgcc=-static-libgcc
 695 fi])
 696 AC_SUBST(libc_cv_gcc_static_libgcc)
 697
 698 AC_PATH_PROG(BASH, bash, no)
 699 if test "$BASH" != no &&
 700    $BASH -c 'test "$BASH_VERSINFO" \
 701              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 702   libc_cv_have_bash2=yes
 703 else
 704   libc_cv_have_bash2=no
 705 fi
 706 AC_SUBST(libc_cv_have_bash2)
 707
 708 dnl We need a ksh compatible shell for tzselect.
 709 if test "$BASH" = no; then
 710   AC_PATH_PROG(KSH, ksh, no)
 711   if test "$KSH" = no; then
 712     libc_cv_have_ksh=no
 713   else
 714     libc_cv_have_ksh=yes
 715   fi
 716 else
 717   KSH="$BASH"
 718   AC_SUBST(KSH)
 719   libc_cv_have_ksh=yes
 720 fi
 721 AC_SUBST(libc_cv_have_ksh)
 722
 723 AC_PROG_AWK
 724 AC_PATH_PROG(PERL, perl, no)
 725 if test "$PERL" != no &&
 726    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 727   PERL=no
 728 fi
 729 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 730              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 731 if test "$INSTALL_INFO" != "no"; then
 732 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 733  [mkdir conftest.d
 734   # There is a hard ^_ on the next line.  I am open to better ideas.
 735   (echo '\1f'
 736   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 737   echo '* Menu:') >conftest.d/dir
 738   (echo 'INFO-DIR-SECTION i-d-s works'
 739   echo 'START-INFO-DIR-ENTRY'
 740   echo '* Prog: (prog).   Program.'
 741   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 742   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 743   then
 744     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 745     then libc_cv_old_debian_install_info=no
 746     else libc_cv_old_debian_install_info=yes
 747     fi
 748   else libc_cv_old_debian_install_info=no testfailed=t
 749   fi
 750   rm -fr conftest.d])
 751 if test -n "$testfailed"
 752 then AC_MSG_WARN([install-info errored out, check config.log])
 753 fi
 754 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 755 fi
 756 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 757
 758 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
 759
 760 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 761 echo '#include <stddef.h>
 762 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 763 if eval "$ac_cpp conftest.c 2>/dev/null" \
 764 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 765   libc_cv_signed_size_t=no
 766 else
 767   libc_cv_signed_size_t=yes
 768 fi
 769 rm -f conftest*])
 770 if test $libc_cv_signed_size_t = yes; then
 771   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 772   cat >> confdefs.h <<\EOF
 773 #undef __SIZE_TYPE__
 774 #define __SIZE_TYPE__ unsigned
 775 EOF
 776 fi
 777
 778 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 779 AC_TRY_COMPILE(dnl
 780 [#define __need_size_t
 781 #define __need_wchar_t
 782 #include <stddef.h>
 783 #define __need_NULL
 784 #include <stddef.h>], [size_t size; wchar_t wchar;
 785 #ifdef offsetof
 786 #error stddef.h ignored __need_*
 787 #endif
 788 if (&size == NULL || &wchar == NULL) abort ();],
 789                libc_cv_friendly_stddef=yes,
 790                libc_cv_friendly_stddef=no)])
 791 if test $libc_cv_friendly_stddef = yes; then
 792   config_vars="$config_vars
 793 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 794 fi
 795
 796 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 797                libc_cv_need_minus_P, [dnl
 798 cat > conftest.S <<EOF
 799 #include "confdefs.h"
 800 /* Nothing whatsoever.  */
 801 EOF
 802 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 803   libc_cv_need_minus_P=no
 804 else
 805   libc_cv_need_minus_P=yes
 806 fi
 807 rm -f conftest*])
 808 if test $libc_cv_need_minus_P = yes; then
 809   config_vars="$config_vars
 810 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 811 fi
 812
 813 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 814 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 815 cat > conftest.s <<EOF
 816 .text
 817 EOF
 818 libc_cv_dot_text=
 819 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 820   libc_cv_dot_text=.text
 821 fi
 822 rm -f conftest*])
 823 if test -z "$libc_cv_dot_text"; then
 824   AC_MSG_RESULT(no)
 825 else
 826   AC_MSG_RESULT(yes)
 827 fi
 828
 829 AC_CACHE_CHECK(for assembler global-symbol directive,
 830                libc_cv_asm_global_directive, [dnl
 831 libc_cv_asm_global_directive=UNKNOWN
 832 for ac_globl in .globl .global .EXPORT; do
 833   cat > conftest.s <<EOF
 834         ${libc_cv_dot_text}
 835         ${ac_globl} foo
 836 foo:
 837 EOF
 838   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 839     libc_cv_asm_global_directive=${ac_globl}
 840   fi
 841   rm -f conftest*
 842   test $libc_cv_asm_global_directive != UNKNOWN && break
 843 done])
 844 if test $libc_cv_asm_global_directive = UNKNOWN; then
 845   AC_MSG_ERROR(cannot determine asm global directive)
 846 else
 847   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 848 fi
 849
 850 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 851 cat > conftest.s <<EOF
 852 ${libc_cv_dot_text}
 853 foo:
 854 .set glibc_conftest_frobozz,foo
 855 $libc_cv_asm_global_directive glibc_conftest_frobozz
 856 EOF
 857 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 858 # (but it doesn't work), so we must do a linking check to be sure.
 859 cat > conftest1.c <<\EOF
 860 extern int glibc_conftest_frobozz;
 861 main () { printf ("%d\n", glibc_conftest_frobozz); }
 862 EOF
 863 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 864             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 865   libc_cv_asm_set_directive=yes
 866 else
 867   libc_cv_asm_set_directive=no
 868 fi
 869 rm -f conftest*])
 870 if test $libc_cv_asm_set_directive = yes; then
 871   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 872 fi
 873
 874 # The Aix ld uses global .symbol_names instead of symbol_names.
 875 case "$os" in
 876 aix4.3*)
 877   AC_DEFINE(HAVE_ASM_GLOBAL_DOT_NAME)
 878 esac
 879
 880 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 881 [cat > conftest.s <<EOF
 882 ${libc_cv_dot_text}
 883 _sym:
 884 .symver _sym,sym@VERS
 885 EOF
 886 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 887   libc_cv_asm_symver_directive=yes
 888 else
 889   libc_cv_asm_symver_directive=no
 890 fi
 891 rm -f conftest*])
 892 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 893 if test $libc_cv_asm_symver_directive = yes; then
 894   cat > conftest.s <<EOF
 895 ${libc_cv_dot_text}
 896 _sym:
 897 .symver _sym,sym@VERS
 898 EOF
 899   cat > conftest.map <<EOF
 900 VERS_1 {
 901         global: sym;
 902 };
 903
 904 VERS_2 {
 905         global: sym;
 906 } VERS_1;
 907 EOF
 908   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 909     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 910                                         -nostartfiles -nostdlib
 911                                         -Wl,--version-script,conftest.map
 912                        1>&AC_FD_CC]);
 913     then
 914       libc_cv_ld_version_script_option=yes
 915     else
 916       libc_cv_ld_version_script_option=no
 917     fi
 918   else
 919     libc_cv_ld_version_script_option=no
 920   fi
 921 else
 922   libc_cv_ld_version_script_option=no
 923 fi
 924 rm -f conftest*])
 925 if test $shared != no &&
 926    test $libc_cv_asm_symver_directive = yes &&
 927    test $libc_cv_ld_version_script_option = yes &&
 928    test $enable_versioning = yes; then
 929   VERSIONING=yes
 930   AC_DEFINE(DO_VERSIONING)
 931 else
 932   VERSIONING=no
 933 fi
 934 AC_SUBST(VERSIONING)
 935
 936 if test $elf = yes && test $shared != no && test $VERSIONING = no; then
 937   echo "\
 938 *** WARNING: You should not compile GNU libc without versioning. Not using
 939 *** versioning will introduce incompatibilities so that old binaries
 940 *** will not run anymore.
 941 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 942 fi
 943 if test $elf = yes; then
 944   AC_CACHE_CHECK(for .previous assembler directive,
 945                  libc_cv_asm_previous_directive, [dnl
 946   cat > conftest.s <<EOF
 947 .section foo_section
 948 .previous
 949 EOF
 950   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 951     libc_cv_asm_previous_directive=yes
 952   else
 953     libc_cv_asm_previous_directive=no
 954   fi
 955   rm -f conftest*])
 956   if test $libc_cv_asm_previous_directive = yes; then
 957     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 958   else
 959     AC_CACHE_CHECK(for .popsection assembler directive,
 960                    libc_cv_asm_popsection_directive, [dnl
 961     cat > conftest.s <<EOF
 962 .pushsection foo_section
 963 .popsection
 964 EOF
 965     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 966       libc_cv_asm_popsection_directive=yes
 967     else
 968       libc_cv_asm_popsection_directive=no
 969     fi
 970     rm -f conftest*])
 971     if test $libc_cv_asm_popsection_directive = yes; then
 972       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 973     fi
 974   fi
 975   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
 976                  libc_cv_asm_protected_directive, [dnl
 977   cat > conftest.s <<EOF
 978 .protected foo
 979 foo:
 980 .hidden bar
 981 bar:
 982 EOF
 983   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 984     libc_cv_asm_protected_directive=yes
 985   else
 986     libc_cv_asm_protected_directive=no
 987   fi
 988   rm -f conftest*])
 989   AC_SUBST(libc_cv_asm_protected_directive)
 990   AC_DEFINE(HAVE_PROTECTED)
 991   AC_DEFINE(HAVE_HIDDEN)
 992
 993   if test $libc_cv_asm_protected_directive = yes; then
 994     AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
 995                  libc_cv_visibility_attribute,
 996                  [cat > conftest.c <<EOF
 997                   int foo __attribute__ ((visibility ("hidden"))) = 1;
 998                   int bar __attribute__ ((visibility ("protected"))) = 1;
 999 EOF
1000                   libc_cv_visibility_attribute=no
1001                   if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
1002                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1003                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1004                         libc_cv_visibility_attribute=yes
1005                       fi
1006                     fi
1007                   fi
1008                   rm -f conftest.[cs]
1009                  ])
1010     if test $libc_cv_visibility_attribute = yes; then
1011       AC_DEFINE(HAVE_VISIBILITY_ATTRIBUTE)
1012     fi
1013   fi
1014
1015   if test $libc_cv_visibility_attribute = yes -a $gnu_ld = yes; then
1016     AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1017                  libc_cv_have_sdata_section,
1018                  [echo "int i;" > conftest.c
1019                   libc_cv_have_sdata_section=no
1020                   if ${CC-cc} -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1021                      | grep '\.sdata' >/dev/null; then
1022                     libc_cv_have_sdata_section=yes
1023                   fi
1024                   rm -f conftest.c conftest.so
1025                  ])
1026     if test $libc_cv_have_sdata_section = yes; then
1027       AC_DEFINE(HAVE_SDATA_SECTION)
1028     fi
1029   fi
1030
1031   AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1032                  libc_cv_initfinit_array, [dnl
1033   cat > conftest.c <<EOF
1034 int _start (void) { return 0; }
1035 int __start (void) { return 0; }
1036 int foo (void) { return 1; }
1037 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1038 EOF
1039   if AC_TRY_COMMAND([${CC-cc} -o conftest conftest.c
1040                      -static -nostartfiles -nostdlib 1>&AC_FD_CC])
1041   then
1042     if readelf -S conftest | fgrep INIT_ARRAY > /dev/null; then
1043       libc_cv_initfinit_array=yes
1044     else
1045       libc_cv_initfinit_array=no
1046     fi
1047   else
1048     libc_cv_initfinit_array=no
1049   fi
1050   rm -f conftest*])
1051   AC_SUBST(libc_cv_initfinit_array)
1052   if test $libc_cv_initfinit_array = yes; then
1053     AC_DEFINE(HAVE_INITFINI_ARRAY)
1054   fi
1055
1056   AC_CACHE_CHECK(for -z nodelete option,
1057                  libc_cv_z_nodelete, [dnl
1058   cat > conftest.c <<EOF
1059 int _start (void) { return 42; }
1060 EOF
1061   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c
1062                      -nostartfiles -nostdlib
1063                      -Wl,--enable-new-dtags,-z,nodelete 1>&AC_FD_CC])
1064   then
1065     libc_cv_z_nodelete=yes
1066   else
1067     libc_cv_z_nodelete=no
1068   fi
1069   rm -f conftest*])
1070   AC_SUBST(libc_cv_z_nodelete)
1071
1072   AC_CACHE_CHECK(for -z nodlopen option,
1073                  libc_cv_z_nodlopen, [dnl
1074   cat > conftest.c <<EOF
1075 int _start (void) { return 42; }
1076 EOF
1077   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c
1078                         -nostartfiles -nostdlib
1079                         -Wl,--enable-new-dtags,-z,nodlopen 1>&AC_FD_CC])
1080   then
1081     libc_cv_z_nodlopen=yes
1082   else
1083     libc_cv_z_nodlopen=no
1084   fi
1085   rm -f conftest*])
1086   AC_SUBST(libc_cv_z_nodlopen)
1087
1088   AC_CACHE_CHECK(for -z initfirst option,
1089                  libc_cv_z_initfirst, [dnl
1090   cat > conftest.c <<EOF
1091 int _start (void) { return 42; }
1092 EOF
1093   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c
1094                         -nostartfiles -nostdlib
1095                         -Wl,--enable-new-dtags,-z,initfirst 1>&AC_FD_CC])
1096   then
1097     libc_cv_z_initfirst=yes
1098   else
1099     libc_cv_z_initfirst=no
1100   fi
1101   rm -f conftest*])
1102   AC_SUBST(libc_cv_z_initfirst)
1103
1104   AC_CACHE_CHECK(for -Bgroup option,
1105                  libc_cv_Bgroup, [dnl
1106   cat > conftest.c <<EOF
1107 int _start (void) { return 42; }
1108 EOF
1109   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,-Bgroup -nostdlib 1>&AC_FD_CC])
1110   then
1111     libc_cv_Bgroup=yes
1112   else
1113     libc_cv_Bgroup=no
1114   fi
1115   rm -f conftest*])
1116   AC_SUBST(libc_cv_Bgroup)
1117
1118   AC_CACHE_CHECK(for -z combreloc,
1119                  libc_cv_z_combreloc, [dnl
1120   cat > conftest.c <<EOF
1121 extern int bar (int);
1122 extern int mumble;
1123 int foo (void) { return bar (mumble); }
1124 EOF
1125   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c
1126                         -nostdlib -nostartfiles
1127                         -Wl,-z,combreloc 1>&AC_FD_CC])
1128   then
1129 dnl The following test is a bit weak.  We must use a tool which can test
1130 dnl cross-platform since the gcc used can be a cross compiler.  Without
1131 dnl introducing new options this is not easily doable.  Instead use a tool
1132 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1133 dnl look for a section named .rel.dyn.
1134     if readelf -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1135       libc_cv_z_combreloc=yes
1136     else
1137       libc_cv_z_combreloc=no
1138     fi
1139   else
1140     libc_cv_z_combreloc=no
1141   fi
1142   rm -f conftest*])
1143   if test "$libc_cv_z_combreloc" = yes; then
1144     AC_DEFINE(HAVE_Z_COMBRELOC)
1145   fi
1146 fi
1147 AC_SUBST(libc_cv_z_combreloc)
1148
1149 if test $elf != yes; then
1150   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
1151                  [AC_TRY_COMPILE(, [asm (".section .init");
1152                                     asm (".section .fini");
1153                                     asm ("${libc_cv_dot_text}");],
1154                                  libc_cv_have_initfini=yes,
1155                                  libc_cv_have_initfini=no)])
1156   AC_SUBST(libc_cv_have_initfini)dnl
1157   if test $libc_cv_have_initfini = yes; then
1158     AC_DEFINE(HAVE_INITFINI)
1159   fi
1160 fi
1161
1162 if test $elf = yes -a $gnu_ld = yes; then
1163   AC_CACHE_CHECK(whether cc puts quotes around section names,
1164                  libc_cv_have_section_quotes,
1165                  [cat > conftest.c <<EOF
1166                   static const int foo
1167                   __attribute__ ((section ("bar"))) = 1;
1168 EOF
1169                   if ${CC-cc} -S conftest.c -o conftest.s; then
1170                     if grep '\.section.*"bar"' conftest.s >/dev/null; then
1171                       libc_cv_have_section_quotes=yes
1172                     else
1173                       libc_cv_have_section_quotes=no
1174                     fi
1175                   else
1176                     libc_cv_have_section_quotes=unknown
1177                   fi
1178                   rm -f conftest.[cs]
1179                  ])
1180   if test $libc_cv_have_section_quotes = yes; then
1181     AC_DEFINE(HAVE_SECTION_QUOTES)
1182   fi
1183 fi
1184
1185 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
1186 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
1187 [cat > conftest.$ac_ext <<EOF
1188 dnl This sometimes fails to find confdefs.h, for some reason.
1189 dnl [#]line __oline__ "[$]0"
1190 [#]line __oline__ "configure"
1191 #include "confdefs.h"
1192 void underscore_test(void) {
1193 return; }
1194 EOF
1195 if AC_TRY_EVAL(ac_compile); then
1196   if grep _underscore_test conftest* >/dev/null; then
1197     ifelse([$1], , :, [rm -f conftest*
1198     $1])
1199   else
1200     ifelse([$2], , , [rm -f conftest*
1201     $2])
1202   fi
1203 else
1204   echo "configure: failed program was:" >&AC_FD_CC
1205   cat conftest.$ac_ext >&AC_FD_CC
1206   ifelse([$2], , , [rm -f conftest*
1207   $2])
1208 fi
1209 rm -f conftest*])
1210
1211 if test $elf = yes; then
1212   libc_cv_asm_underscores=no
1213 else
1214   if test $ac_cv_prog_cc_works = yes; then
1215     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1216                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
1217                                 libc_cv_asm_underscores=yes,
1218                                 libc_cv_asm_underscores=no)])
1219   else
1220     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1221                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
1222                                             libc_cv_asm_underscores=no)])
1223   fi
1224 fi
1225 if test $libc_cv_asm_underscores = no; then
1226   AC_DEFINE(NO_UNDERSCORES)
1227 fi
1228
1229 if test $elf = yes; then
1230   libc_cv_weak_symbols=yes
1231 fi
1232
1233 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1234                [dnl
1235 cat > conftest.s <<EOF
1236 ${libc_cv_dot_text}
1237 ${libc_cv_asm_global_directive} foo
1238 foo:
1239 .weak foo
1240 .weak bar; bar = foo
1241 EOF
1242 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1243   libc_cv_asm_weak_directive=yes
1244 else
1245   libc_cv_asm_weak_directive=no
1246 fi
1247 rm -f conftest*])
1248
1249 if test $libc_cv_asm_weak_directive = no; then
1250   AC_CACHE_CHECK(for assembler .weakext directive,
1251                  libc_cv_asm_weakext_directive,
1252                  [dnl
1253 cat > conftest.s <<EOF
1254 ${libc_cv_dot_text}
1255 ${libc_cv_asm_global_directive} foo
1256 foo:
1257 .weakext bar foo
1258 .weakext baz
1259 ${libc_cv_asm_global_directive} baz
1260 baz:
1261 EOF
1262   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1263     libc_cv_asm_weakext_directive=yes
1264   else
1265     libc_cv_asm_weakext_directive=no
1266   fi
1267   rm -f conftest*])
1268
1269 fi # no .weak
1270
1271 if test $libc_cv_asm_weak_directive = yes; then
1272   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1273 elif test $libc_cv_asm_weakext_directive = yes; then
1274   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1275 fi
1276
1277 dnl The standard hppa assembler uses `;' to start comments and `!'
1278 dnl as a line separator.  CRIS uses `;' to start comments and `@' for
1279 dnl line separator.
1280 case "${host_cpu}-${host_os}" in
1281   cris*)
1282     libc_cv_asm_line_sep='@'
1283     AC_DEFINE_UNQUOTED(ASM_LINE_SEP, $libc_cv_asm_line_sep)
1284     ;;
1285   hppa*linux*)
1286   AC_CACHE_CHECK(for assembler line separator,
1287                  libc_cv_asm_line_sep, [dnl
1288   cat > conftest.s <<EOF
1289  nop ; is_old_puffin
1290 EOF
1291   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
1292     libc_cv_asm_line_sep='!'
1293   else
1294     if test -z "$enable_hacker_mode"; then
1295       echo "*** You need a newer assembler to compile glibc"
1296       rm -f conftest*
1297       exit 1
1298     fi
1299     libc_cv_asm_line_sep=';'
1300   fi
1301   rm -f conftest*])
1302   AC_DEFINE_UNQUOTED(ASM_LINE_SEP, $libc_cv_asm_line_sep)
1303   ;;
1304 esac
1305
1306 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1307 cat > conftest.c <<\EOF
1308 _start () {}
1309 int __eh_pc;
1310 __throw () {}
1311 EOF
1312 dnl No \ in command here because it ends up inside ''.
1313 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1314                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1315                             -o conftest conftest.c 1>&AC_FD_CC]); then
1316   libc_cv_ld_no_whole_archive=yes
1317 else
1318   libc_cv_ld_no_whole_archive=no
1319 fi
1320 rm -f conftest*])
1321 if test $libc_cv_ld_no_whole_archive = yes; then
1322   no_whole_archive=-Wl,--no-whole-archive
1323 fi
1324 AC_SUBST(no_whole_archive)dnl
1325
1326 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1327 cat > conftest.c <<\EOF
1328 _start () {}
1329 int __eh_pc;
1330 __throw () {}
1331 EOF
1332 dnl No \ in command here because it ends up inside ''.
1333 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1334                             -nostdlib -nostartfiles -fexceptions
1335                             -o conftest conftest.c 1>&AC_FD_CC]); then
1336   libc_cv_gcc_exceptions=yes
1337 else
1338   libc_cv_gcc_exceptions=no
1339 fi
1340 rm -f conftest*])
1341 if test $libc_cv_gcc_exceptions = yes; then
1342   exceptions=-fexceptions
1343 fi
1344 AC_SUBST(exceptions)dnl
1345
1346 if test "$base_machine" = alpha ; then
1347 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1348 cat > conftest.c <<\EOF
1349 foo () { }
1350 EOF
1351 dnl
1352 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1353 then
1354   libc_cv_gcc_alpha_ng_prefix=yes
1355 else
1356   libc_cv_gcc_alpha_ng_prefix=no
1357 fi
1358 rm -f conftest* ])
1359 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1360   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1361 else
1362   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1363 fi
1364 fi
1365
1366 if test "$host_cpu" = powerpc ; then
1367 # Check for a bug present in at least versions 2.8.x of GCC
1368 # and versions 1.0.x of EGCS.
1369 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1370 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1371                libc_cv_c_asmcr0_bug='no',
1372                libc_cv_c_asmcr0_bug='yes')])
1373 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1374   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1375 fi
1376 fi
1377
1378 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1379 [cat > conftest.c <<EOF
1380 #line __oline__ "configure"
1381 static char *__EH_FRAME_BEGIN__;
1382 _start ()
1383 {
1384 #ifdef CHECK__register_frame
1385   __register_frame (__EH_FRAME_BEGIN__);
1386   __deregister_frame (__EH_FRAME_BEGIN__);
1387 #endif
1388 #ifdef CHECK__register_frame_info
1389   __register_frame_info (__EH_FRAME_BEGIN__);
1390   __deregister_frame_info (__EH_FRAME_BEGIN__);
1391 #endif
1392 }
1393 int __eh_pc;
1394 __throw () {}
1395 /* FIXME: this is fragile.  */
1396 malloc () {}
1397 strcmp () {}
1398 strlen () {}
1399 memcpy () {}
1400 memset () {}
1401 free () {}
1402 abort () {}
1403 __bzero () {}
1404 EOF
1405 dnl No \ in command here because it ends up inside ''.
1406 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1407                             -nostdlib -nostartfiles
1408                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1409   libc_cv_gcc_dwarf2_unwind_info=static
1410 else
1411   libc_cv_gcc_dwarf2_unwind_info=no
1412 fi
1413 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1414                             -nostdlib -nostartfiles
1415                             -o conftest conftest.c -lgcc -lgcc_eh >&AC_FD_CC]); then
1416   if ${CC-cc} $CFLAGS -DCHECK__register_frame_info -nostdlib -nostartfiles \
1417      -o conftest conftest.c -lgcc -lgcc_eh -v 2>&1 >/dev/null \
1418      | grep -q -- --eh-frame-hdr; then
1419     libc_cv_gcc_dwarf2_unwind_info=no_registry_needed
1420   else
1421     libc_cv_gcc_dwarf2_unwind_info=static
1422   fi
1423 else
1424   libc_cv_gcc_dwarf2_unwind_info=no
1425 fi
1426 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1427   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1428                               -nostdlib -nostartfiles
1429                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1430     libc_cv_gcc_dwarf2_unwind_info=yes
1431   else
1432     libc_cv_gcc_dwarf2_unwind_info=no
1433   fi
1434 fi
1435 rm -f conftest*])
1436 case $libc_cv_gcc_dwarf2_unwind_info in
1437 yes)
1438   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1439   ;;
1440 static)
1441   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1442   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1443   ;;
1444 esac
1445
1446 dnl Check whether compiler understands __builtin_expect.
1447 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1448 [cat > conftest.c <<EOF
1449 #line __oline__ "configure"
1450 int foo (int a)
1451 {
1452   a = __builtin_expect (a, 10);
1453   return a == 10 ? 0 : 1;
1454 }
1455 EOF
1456 dnl No \ in command here because it ends up inside ''.
1457 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1458                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1459   libc_cv_gcc_builtin_expect=yes
1460 else
1461   libc_cv_gcc_builtin_expect=no
1462 fi
1463 rm -f conftest*])
1464 if test "$libc_cv_gcc_builtin_expect" = yes; then
1465   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1466 fi
1467
1468 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1469 cat > conftest.c <<\EOF
1470 void zero (void *x)
1471 {
1472   __builtin_memset (x, 0, 1000);
1473 }
1474 EOF
1475 dnl
1476 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1477 then
1478   libc_cv_gcc_builtin_memset=no
1479 else
1480   libc_cv_gcc_builtin_memset=yes
1481 fi
1482 rm -f conftest* ])
1483 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1484   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1485 fi
1486
1487 dnl Check whether the compiler supports subtraction of local labels.
1488 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1489 [cat > conftest.c <<EOF
1490 changequote(,)dnl
1491 #line __oline__ "configure"
1492 int foo (int a)
1493 {
1494   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1495   void *p = &&l1 + ar[a];
1496   goto *p;
1497  l1:
1498   return 1;
1499  l2:
1500   return 2;
1501 }
1502 changequote([,])dnl
1503 EOF
1504 dnl No \ in command here because it ends up inside ''.
1505 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1506                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1507   libc_cv_gcc_subtract_local_labels=yes
1508 else
1509   libc_cv_gcc_subtract_local_labels=no
1510 fi
1511 rm -f conftest*])
1512 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1513   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1514 fi
1515
1516 dnl Check whether we have the gd library available.
1517 AC_MSG_CHECKING(for libgd)
1518 if test "$with_gd" != "no"; then
1519   old_CFLAGS="$CFLAGS"
1520   CFLAGS="$CFLAGS $libgd_include"
1521   old_LDFLAGS="$LDFLAGS"
1522   LDFLAGS="$LDFLAGS $libgd_ldflags"
1523   old_LIBS="$LIBS"
1524   LIBS="$LIBS -lgd -lpng -lz -lm"
1525   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1526   CFLAGS="$old_CFLAGS"
1527   LDFLAGS="$old_LDFLAGS"
1528   LIBS="$old_LIBS"
1529 else
1530   LIBGD=no
1531 fi
1532 AC_MSG_RESULT($LIBGD)
1533 AC_SUBST(LIBGD)
1534
1535 dnl check for the size of 'long double'.
1536 AC_CHECK_SIZEOF(long double, 0)
1537 sizeof_long_double=$ac_cv_sizeof_long_double
1538 AC_SUBST(sizeof_long_double)
1539
1540 ### End of automated tests.
1541 ### Now run sysdeps configure fragments.
1542
1543 # sysdeps configure fragments may set these with files to be linked below.
1544 libc_link_dests=
1545 libc_link_sources=
1546
1547 # They also can set these variables.
1548 use_ldconfig=no
1549 ldd_rewrite_script=no
1550 libc_cv_sysconfdir=$sysconfdir
1551 libc_cv_gcc_unwind_find_fde=no
1552
1553 # Iterate over all the sysdep directories we will use, running their
1554 # configure fragments, and looking for a uname implementation.
1555 uname=
1556 for dir in $sysnames; do
1557   case $dir in
1558     /*) dest=$dir ;;
1559     *)  dest=$srcdir/$dir ;;
1560   esac
1561   if test -r $dest/configure; then
1562     AC_MSG_RESULT(running configure fragment for $dest)
1563     . $dest/configure
1564   fi
1565 [
1566   if test -z "$uname"; then
1567     if test -r $dest/uname.c ||
1568        test -r $dest/uname.S ||
1569        { test -r $dest/syscalls.list &&
1570          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1571       uname=$dir
1572     fi
1573   fi
1574 ]dnl
1575 done
1576
1577 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1578   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1579 fi
1580 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1581
1582 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1583
1584 # If we will use the generic uname implementation, we must figure out what
1585 # it will say by examining the system, and write the results in config-name.h.
1586 if test "$uname" = "sysdeps/generic"; then
1587
1588 changequote(,)dnl
1589   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1590 changequote([,])dnl
1591   if test $uname_sysname != $config_os; then
1592     config_release=`echo $config_os | sed s/$uname_sysname//`
1593   fi
1594 dnl
1595 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1596     if test -r /vmunix; then
1597       kernel_id=`strings /vmunix | grep UNIX`
1598     elif test -r /dynix; then
1599       kernel_id=`strings /dynix | grep DYNIX`
1600     else
1601       kernel_id=
1602     fi
1603 ])dnl
1604
1605   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1606 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1607 changequote(,)dnl
1608   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1609 changequote([,])dnl
1610   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1611          != x$config_release; then
1612     # The configuration release is a substring of the kernel release.
1613     libc_cv_uname_release=$kernel_release
1614   elif test x$config_release != x; then
1615     libc_cv_uname_release=$config_release
1616   elif test x$kernel_release != x; then
1617     libc_cv_uname_release=$kernel_release
1618   else
1619     libc_cv_uname_release=unknown
1620   fi])
1621   uname_release="$libc_cv_uname_release"
1622
1623   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1624 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1625 changequote(,)dnl
1626   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1627 changequote([,])dnl
1628   if test -n "$kernel_version"; then
1629     libc_cv_uname_version="$kernel_version"
1630   else
1631     libc_cv_uname_version=unknown
1632   fi])
1633   uname_version="$libc_cv_uname_version"
1634
1635 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1636   config_uname=config-name.h:config-name.in
1637 else
1638   # For non-generic uname, we don't need to create config-name.h at all.
1639   config_uname=
1640 fi
1641
1642 dnl This is tested by existing code and it's simpler to avoid changing it.
1643 AC_DEFINE(USE_IN_LIBIO)
1644
1645 # Test for old glibc 2.0.x headers so that they can be removed properly
1646 # Search only in includedir.
1647 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1648 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1649 then
1650   old_glibc_headers=yes
1651 else
1652   old_glibc_headers=no
1653 fi
1654 AC_MSG_RESULT($old_glibc_headers)
1655 if test ${old_glibc_headers} = yes; then
1656   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1657   AC_MSG_WARN(*** be removed.)
1658 fi
1659 AC_SUBST(old_glibc_headers)
1660
1661 AC_SUBST(libc_cv_slibdir)
1662 AC_SUBST(libc_cv_localedir)
1663 AC_SUBST(libc_cv_sysconfdir)
1664 AC_SUBST(libc_cv_rootsbindir)
1665
1666 AC_SUBST(use_ldconfig)
1667 AC_SUBST(ldd_rewrite_script)
1668
1669 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(xcoff)
1670 if test $gnu_ld = yes; then
1671   AC_DEFINE(HAVE_GNU_LD)
1672 fi
1673 if test $gnu_as = yes; then
1674   AC_DEFINE(HAVE_GNU_AS)
1675 fi
1676 if test $elf = yes; then
1677   AC_DEFINE(HAVE_ELF)
1678 fi
1679 if test $xcoff = yes; then
1680   AC_DEFINE(HAVE_XCOFF)
1681 fi
1682
1683 AC_SUBST(static)
1684 AC_SUBST(shared)
1685 if test $shared = default; then
1686   if test $gnu_ld = yes; then
1687     shared=$elf
1688   else
1689     # For now we do not assume shared libs are available.  In future more
1690     # tests might become available.
1691     shared=no
1692   fi
1693 fi
1694
1695 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1696 [pic_default=yes
1697 cat > conftest.c <<EOF
1698 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1699 # error PIC is default.
1700 #endif
1701 EOF
1702 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1703   pic_default=no
1704 fi
1705 rm -f conftest.*])
1706 AC_SUBST(pic_default)
1707
1708 AC_SUBST(profile)
1709 AC_SUBST(omitfp)
1710 AC_SUBST(bounded)
1711 AC_SUBST(static_nss)
1712 AC_SUBST(nopic_initfini)
1713
1714 AC_SUBST(DEFINES)
1715
1716 case "$add_ons" in
1717   *door*) linux_doors=yes ;;
1718   *) linux_doors=no ;;
1719 esac
1720 AC_SUBST(linux_doors)
1721
1722 dnl See sysdeps/mach/configure.in for this variable.
1723 AC_SUBST(mach_interface_list)
1724
1725 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1726   config_makefile=
1727 else
1728   config_makefile=Makefile
1729 fi
1730
1731 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1732 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1733 AC_SUBST(VERSION)
1734 AC_SUBST(RELEASE)
1735
1736 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1737 case $CONFIG_FILES in *config.make*)
1738 echo "$config_vars" >> config.make;;
1739 esac
1740 test -d bits || mkdir bits], [config_vars='$config_vars'])