]> git.ipfire.org Git - people/ms/strongswan.git/blob - configure.in
Stub plugin for Maemo specific extensions added.
[people/ms/strongswan.git] / configure.in
1 dnl configure.in for linux strongSwan
2 dnl Copyright (C) 2006 Martin Willi
3 dnl Hochschule fuer Technik Rapperswil
4 dnl
5 dnl This program is free software; you can redistribute it and/or modify it
6 dnl under the terms of the GNU General Public License as published by the
7 dnl Free Software Foundation; either version 2 of the License, or (at your
8 dnl option) any later version. See <http://www.fsf.org/copyleft/gpl.txt>.
9 dnl
10 dnl This program is distributed in the hope that it will be useful, but
11 dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12 dnl or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
13 dnl for more details.
14
15 dnl ===========================
16 dnl initialize & set some vars
17 dnl ===========================
18
19 AC_INIT(strongSwan,4.5.0rc1)
20 AM_INIT_AUTOMAKE(tar-ustar)
21 AC_CONFIG_MACRO_DIR([m4/config])
22 PKG_PROG_PKG_CONFIG
23
24 dnl =================================
25 dnl check --enable-xxx & --with-xxx
26 dnl =================================
27
28 m4_include(m4/macros/with.m4)
29
30 ARG_WITH_SUBST([default-pkcs11], [/usr/lib/opensc-pkcs11.so], [set the default PKCS11 library])
31 ARG_WITH_SUBST([random-device], [/dev/random], [set the device to read real random data from])
32 ARG_WITH_SUBST([urandom-device], [/dev/urandom], [set the device to read pseudo random data from])
33 ARG_WITH_SUBST([strongswan-conf], [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
34 ARG_WITH_SUBST([resolv-conf], [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
35 ARG_WITH_SUBST([piddir], [/var/run], [set path for PID and UNIX socket files])
36 ARG_WITH_SUBST([ipsecdir], [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
37 ARG_WITH_SUBST([plugindir], [${ipsecdir%/}/plugins], [set the installation path of plugins])
38 ARG_WITH_SUBST([nm-ca-dir], [/usr/share/ca-certificates], [directory the NM plugin uses to look up trusted root certificates])
39 ARG_WITH_SUBST([linux-headers], [\${top_srcdir}/src/include], [set directory of linux header files to use])
40 ARG_WITH_SUBST([routing-table], [220], [set routing table to use for IPsec routes])
41 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
42
43 ARG_WITH_SET([capabilities], [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
44 ARG_WITH_SET([mpz_powm_sec], [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
45
46 AC_ARG_WITH(
47 [xauth-module],
48 AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
49 [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
50 )
51
52 AC_ARG_WITH(
53 [user],
54 AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
55 [AC_DEFINE_UNQUOTED(IPSEC_USER, "$withval") AC_SUBST(ipsecuser, "$withval")],
56 [AC_SUBST(ipsecuser, "root")]
57 )
58
59 AC_ARG_WITH(
60 [group],
61 AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
62 [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval") AC_SUBST(ipsecgroup, "$withval")],
63 [AC_SUBST(ipsecgroup, "root")]
64 )
65
66 m4_include(m4/macros/enable-disable.m4)
67
68 ARG_ENABL_SET([curl], [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
69 ARG_ENABL_SET([ldap], [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
70 ARG_DISBL_SET([aes], [disable AES software implementation plugin.])
71 ARG_DISBL_SET([des], [disable DES/3DES software implementation plugin.])
72 ARG_ENABL_SET([blowfish], [enable Blowfish software implementation plugin.])
73 ARG_ENABL_SET([md4], [enable MD4 software implementation plugin.])
74 ARG_DISBL_SET([md5], [disable MD5 software implementation plugin.])
75 ARG_DISBL_SET([sha1], [disable SHA1 software implementation plugin.])
76 ARG_DISBL_SET([sha2], [disable SHA256/SHA384/SHA512 software implementation plugin.])
77 ARG_DISBL_SET([fips-prf], [disable FIPS PRF software implementation plugin.])
78 ARG_DISBL_SET([gmp], [disable GNU MP (libgmp) based crypto implementation plugin.])
79 ARG_DISBL_SET([random], [disable RNG implementation on top of /dev/(u)random.])
80 ARG_DISBL_SET([x509], [disable X509 certificate implementation plugin.])
81 ARG_DISBL_SET([revocation], [disable X509 CRL/OCSP revocation check plugin.])
82 ARG_DISBL_SET([pubkey], [disable RAW public key support plugin.])
83 ARG_DISBL_SET([pkcs1], [disable PKCS1 key decoding plugin.])
84 ARG_DISBL_SET([pgp], [disable PGP key decoding plugin.])
85 ARG_DISBL_SET([dnskey], [disable DNS RR key decoding plugin.])
86 ARG_DISBL_SET([pem], [disable PEM decoding plugin.])
87 ARG_DISBL_SET([hmac], [disable HMAC crypto implementation plugin.])
88 ARG_DISBL_SET([xcbc], [disable xcbc crypto implementation plugin.])
89 ARG_ENABL_SET([test-vectors], [enable plugin providing crypto test vectors.])
90 ARG_ENABL_SET([mysql], [enable MySQL database support. Requires libmysqlclient_r.])
91 ARG_ENABL_SET([sqlite], [enable SQLite database support. Requires libsqlite3.])
92 ARG_DISBL_SET([stroke], [disable charons stroke (pluto compatibility) configuration backend.])
93 ARG_ENABL_SET([medsrv], [enable mediation server web frontend and daemon plugin.])
94 ARG_ENABL_SET([medcli], [enable mediation client configuration database plugin.])
95 ARG_ENABL_SET([smp], [enable SMP configuration and control interface. Requires libxml.])
96 ARG_ENABL_SET([sql], [enable SQL database configuration backend.])
97 ARG_ENABL_SET([smartcard], [enable smartcard support.])
98 ARG_ENABL_SET([cisco-quirks], [enable support of Cisco VPN client.])
99 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
100 ARG_ENABL_SET([lock-profiler], [enable lock/mutex profiling code.])
101 ARG_ENABL_SET([unit-tests], [enable unit tests on IKEv2 daemon startup.])
102 ARG_ENABL_SET([load-tester], [enable load testing plugin for IKEv2 daemon.])
103 ARG_ENABL_SET([eap-sim], [enable SIM authentication module for EAP.])
104 ARG_ENABL_SET([eap-sim-file], [enable EAP-SIM backend based on a triplet file.])
105 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
106 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
107 ARG_ENABL_SET([eap-simaka-reauth], [enable EAP-SIM/AKA reauthentication data storage plugin.])
108 ARG_ENABL_SET([eap-identity], [enable EAP module providing EAP-Identity helper.])
109 ARG_ENABL_SET([eap-md5], [enable EAP MD5 (CHAP) authentication module.])
110 ARG_ENABL_SET([eap-gtc], [enable PAM based EAP GTC authentication module.])
111 ARG_ENABL_SET([eap-aka], [enable EAP AKA authentication module.])
112 ARG_ENABL_SET([eap-aka-3gpp2], [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
113 ARG_ENABL_SET([eap-mschapv2], [enable EAP MS-CHAPv2 authentication module.])
114 ARG_ENABL_SET([eap-tls], [enable EAP TLS authentication module.])
115 ARG_ENABL_SET([eap-ttls], [enable EAP TTLS authentication module.])
116 ARG_ENABL_SET([eap-tnc], [enable EAP TNC trusted network connect module.])
117 ARG_ENABL_SET([eap-radius], [enable RADIUS proxy authentication module.])
118 ARG_ENABL_SET([tnc-imc], [enable TNC IMC module.])
119 ARG_ENABL_SET([tnc-imv], [enable TNC IMV module.])
120 ARG_ENABL_SET([tnccs-11], [enable TNCCS 1.1 protocol module.])
121 ARG_ENABL_SET([tnccs-20], [enable TNCCS 2.0 protocol module.])
122 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
123 ARG_ENABL_SET([kernel-pfkey], [enable the PF_KEY kernel interface.])
124 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
125 ARG_ENABL_SET([kernel-klips], [enable the KLIPS kernel interface.])
126 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
127 ARG_ENABL_SET([socket-raw], [enable raw socket implementation of charon, enforced if pluto is enabled])
128 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
129 ARG_ENABL_SET([farp], [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
130 ARG_ENABL_SET([nat-transport], [enable NAT traversal with IPsec transport mode in pluto.])
131 ARG_DISBL_SET([vendor-id], [disable the sending of the strongSwan vendor ID in pluto.])
132 ARG_DISBL_SET([xauth-vid], [disable the sending of the XAUTH vendor ID.])
133 ARG_ENABL_SET([dumm], [enable the DUMM UML test framework.])
134 ARG_ENABL_SET([fast], [enable libfast (FastCGI Application Server w/ templates.])
135 ARG_ENABL_SET([manager], [enable web management console (proof of concept).])
136 ARG_ENABL_SET([mediation], [enable IKEv2 Mediation Extension.])
137 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
138 ARG_DISBL_SET([load-warning], [disable the charon/pluto plugin load option warning in starter.])
139 ARG_DISBL_SET([pluto], [disable the IKEv1 keying daemon pluto.])
140 ARG_DISBL_SET([xauth], [disable xauth plugin.])
141 ARG_DISBL_SET([threads], [disable the use of threads in pluto. Charon always uses threads.])
142 ARG_DISBL_SET([charon], [disable the IKEv2 keying daemon charon.])
143 ARG_DISBL_SET([tools], [disable additional utilities (openac, scepclient and pki).])
144 ARG_DISBL_SET([scripts], [disable additional utilities (found in directory scripts).])
145 ARG_DISBL_SET([updown], [disable updown firewall script plugin.])
146 ARG_DISBL_SET([attr], [disable strongswan.conf based configuration attribute plugin.])
147 ARG_ENABL_SET([attr-sql], [enable SQL based configuration attribute plugin.])
148 ARG_ENABL_SET([dhcp], [enable DHCP based attribute provider plugin.])
149 ARG_DISBL_SET([resolve], [disable resolve DNS handler plugin.])
150 ARG_ENABL_SET([padlock], [enables VIA Padlock crypto plugin.])
151 ARG_ENABL_SET([openssl], [enables the OpenSSL crypto plugin.])
152 ARG_ENABL_SET([gcrypt], [enables the libgcrypt plugin.])
153 ARG_ENABL_SET([agent], [enables the ssh-agent signing plugin.])
154 ARG_ENABL_SET([pkcs11], [enables the PKCS11 token support plugin.])
155 ARG_ENABL_SET([ctr], [enables the Counter Mode wrapper crypto plugin.])
156 ARG_ENABL_SET([ccm], [enables the CCM AEAD wrapper crypto plugin.])
157 ARG_ENABL_SET([gcm], [enables the GCM AEAD wrapper crypto plugin.])
158 ARG_ENABL_SET([addrblock], [enables RFC 3779 address block constraint support.])
159 ARG_ENABL_SET([uci], [enable OpenWRT UCI configuration plugin.])
160 ARG_ENABL_SET([android], [enable Android specific plugin.])
161 ARG_ENABL_SET([maemo], [enable Maemo specific plugin.])
162 ARG_ENABL_SET([nm], [enable NetworkManager plugin.])
163 ARG_ENABL_SET([ha], [enable high availability cluster plugin.])
164 ARG_ENABL_SET([led], [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
165 ARG_ENABL_SET([vstr], [enforce using the Vstr string library to replace glibc-like printf hooks.])
166 ARG_ENABL_SET([monolithic], [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
167
168 dnl =========================
169 dnl set up compiler and flags
170 dnl =========================
171
172 if test -z "$CFLAGS"; then
173 CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign -Wno-strict-aliasing"
174 fi
175 AC_PROG_CC
176 AC_LIB_PREFIX
177 AC_C_BIGENDIAN
178
179 dnl =========================
180 dnl check required programs
181 dnl =========================
182
183 AC_PROG_INSTALL
184 AC_PROG_LIBTOOL
185 AC_PROG_EGREP
186 AC_PROG_AWK
187 AC_PROG_LEX
188 AC_PROG_YACC
189 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
190 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
191
192 dnl because gperf is not needed by end-users we just report it but do not abort on failure
193 AC_MSG_CHECKING([gperf version >= 3.0.0])
194 if test -x "$GPERF"; then
195 if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
196 AC_MSG_RESULT([yes])
197 else
198 AC_MSG_RESULT([no])
199 fi
200 else
201 AC_MSG_RESULT([not found])
202 fi
203
204 dnl translate user/group to numercial ids
205 AC_MSG_CHECKING([for uid of user "$ipsecuser"])
206 ipsecuid=`id -u $ipsecuser 2>/dev/null`
207 if test -n "$ipsecuid"; then
208 AC_MSG_RESULT([$ipsecuid])
209 AC_SUBST(ipsecuid)
210 else
211 AC_MSG_ERROR([not found])
212 fi
213 AC_MSG_CHECKING([for gid of group "$ipsecgroup"])
214 ipsecgid=`$EGREP "^$ipsecgroup:" /etc/group | $AWK -F: '{ print $3 }'`
215 if test -n "$ipsecgid"; then
216 AC_MSG_RESULT([$ipsecgid])
217 AC_SUBST(ipsecgid)
218 else
219 AC_MSG_ERROR([not found])
220 fi
221
222 dnl =========================
223 dnl dependency calculation
224 dnl =========================
225
226 if test x$eap_aka_3gpp2 = xtrue; then
227 gmp=true;
228 fi
229
230 if test x$eap_aka = xtrue; then
231 fips_prf=true;
232 simaka=true;
233 fi
234
235 if test x$eap_sim = xtrue; then
236 fips_prf=true;
237 simaka=true;
238 fi
239
240 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue; then
241 tls=true;
242 fi
243
244 if test x$fips_prf = xtrue; then
245 if test x$openssl = xfalse; then
246 sha1=true;
247 fi
248 fi
249
250 if test x$smp = xtrue; then
251 xml=true
252 fi
253
254 if test x$manager = xtrue; then
255 fast=true
256 fi
257
258 if test x$medsrv = xtrue; then
259 mediation=true
260 fast=true
261 fi
262
263 if test x$medcli = xtrue; then
264 mediation=true
265 fi
266
267 if test x$pluto = xtrue; then
268 if test x$socket_raw = xfalse; then
269 AC_MSG_NOTICE([Enforcing --enable-socket-raw, as pluto is enabled])
270 socket_raw=true
271 if test x$socket_default_given = xfalse; then
272 socket_default=false
273 fi
274 fi
275 fi
276
277 dnl ===========================================
278 dnl check required libraries and header files
279 dnl ===========================================
280
281 AC_HEADER_STDBOOL
282 AC_FUNC_ALLOCA
283
284 dnl libraries needed on some platforms but not on others
285 dnl ====================================================
286 saved_LIBS=$LIBS
287
288 dnl FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
289 LIBS=""
290 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
291 AC_SUBST(DLLIB)
292
293 dnl glibc's backtrace() can be replicated on FreeBSD with libexecinfo
294 LIBS=""
295 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
296 AC_CHECK_FUNCS(backtrace)
297 AC_SUBST(BTLIB)
298
299 dnl OpenSolaris needs libsocket and libnsl for socket()
300 LIBS=""
301 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
302 [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
303 )
304 AC_SUBST(SOCKLIB)
305
306 dnl FreeBSD has clock_gettime in libc, Linux needs librt
307 LIBS=""
308 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
309 AC_CHECK_FUNCS(clock_gettime)
310 AC_SUBST(RTLIB)
311
312 dnl Android has pthread_* functions in bionic (libc), others need libpthread
313 LIBS=""
314 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
315 AC_SUBST(PTHREADLIB)
316
317 LIBS=$saved_LIBS
318 dnl ======================
319
320 AC_MSG_CHECKING(for dladdr)
321 AC_TRY_COMPILE(
322 [#define _GNU_SOURCE
323 #include <dlfcn.h>],
324 [Dl_info* info = 0;
325 dladdr(0, info);],
326 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR])],
327 [AC_MSG_RESULT([no])]
328 )
329
330 dnl check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
331 saved_LIBS=$LIBS
332 LIBS=$PTHREADLIB
333 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
334 AC_TRY_RUN(
335 [#include <pthread.h>
336 int main() { pthread_condattr_t attr;
337 pthread_condattr_init(&attr);
338 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}],
339 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])],
340 [AC_MSG_RESULT([no])],
341 dnl Check existence of pthread_condattr_setclock if cross-compiling
342 [AC_MSG_RESULT([unknown]);
343 AC_CHECK_FUNCS(pthread_condattr_setclock,
344 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])]
345 )]
346 )
347 dnl check if we actually are able to configure attributes on cond vars
348 AC_CHECK_FUNCS(pthread_condattr_init)
349 dnl instead of pthread_condattr_setclock Android has this function
350 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
351 dnl check if we can cancel threads
352 AC_CHECK_FUNCS(pthread_cancel)
353 dnl check if native rwlocks are available
354 AC_CHECK_FUNCS(pthread_rwlock_init)
355 LIBS=$saved_LIBS
356
357 AC_CHECK_FUNCS(prctl)
358
359 AC_CHECK_FUNCS(mallinfo)
360
361 AC_CHECK_HEADERS(sys/sockio.h)
362 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
363
364 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
365 [
366 #include <sys/types.h>
367 #include <sys/socket.h>
368 ])
369
370 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
371 [
372 #include <sys/types.h>
373 #ifdef HAVE_NET_PFKEYV2_H
374 #include <net/pfkeyv2.h>
375 #else
376 #include <stdint.h>
377 #include <linux/pfkeyv2.h>
378 #endif
379 ])
380
381 AC_MSG_CHECKING([for in6addr_any])
382 AC_TRY_COMPILE(
383 [#include <sys/types.h>
384 #include <sys/socket.h>
385 #include <netinet/in.h>],
386 [struct in6_addr in6;
387 in6 = in6addr_any;],
388 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6ADDR_ANY])],
389 [AC_MSG_RESULT([no])]
390 )
391
392 AC_MSG_CHECKING([for in6_pktinfo])
393 AC_TRY_COMPILE(
394 [#define _GNU_SOURCE
395 #include <sys/types.h>
396 #include <sys/socket.h>
397 #include <netinet/in.h>],
398 [struct in6_pktinfo pi;
399 if (pi.ipi6_ifindex)
400 {
401 return 0;
402 }],
403 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6_PKTINFO])],
404 [AC_MSG_RESULT([no])]
405 )
406
407 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
408 AC_TRY_COMPILE(
409 [#include <sys/types.h>
410 #ifdef HAVE_NETIPSEC_IPSEC_H
411 #include <netipsec/ipsec.h>
412 #elif defined(HAVE_NETINET6_IPSEC_H)
413 #include <netinet6/ipsec.h>
414 #else
415 #include <stdint.h>
416 #include <linux/ipsec.h>
417 #endif],
418 [int mode = IPSEC_MODE_BEET;
419 return mode;],
420 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_MODE_BEET])],
421 [AC_MSG_RESULT([no])]
422 )
423
424 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
425 AC_TRY_COMPILE(
426 [#include <sys/types.h>
427 #ifdef HAVE_NETIPSEC_IPSEC_H
428 #include <netipsec/ipsec.h>
429 #elif defined(HAVE_NETINET6_IPSEC_H)
430 #include <netinet6/ipsec.h>
431 #else
432 #include <stdint.h>
433 #include <linux/ipsec.h>
434 #endif],
435 [int dir = IPSEC_DIR_FWD;
436 return dir;],
437 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_DIR_FWD])],
438 [AC_MSG_RESULT([no])]
439 )
440
441 AC_MSG_CHECKING([for gcc atomic operations])
442 AC_TRY_RUN(
443 [
444 int main() {
445 volatile int ref = 1;
446 __sync_fetch_and_add (&ref, 1);
447 __sync_sub_and_fetch (&ref, 1);
448 /* Make sure test fails if operations are not supported */
449 __sync_val_compare_and_swap(&ref, 1, 0);
450 return ref;
451 }
452 ],
453 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS)],
454 [AC_MSG_RESULT([no])],
455 [AC_MSG_RESULT([no])])
456
457 dnl check for the new register_printf_specifier function with len argument,
458 dnl or the deprecated register_printf_function without
459 AC_CHECK_FUNC(
460 [register_printf_specifier],
461 [AC_DEFINE(HAVE_PRINTF_SPECIFIER)],
462 [AC_CHECK_FUNC(
463 [register_printf_function],
464 [AC_DEFINE(HAVE_PRINTF_FUNCTION)],
465 [
466 AC_MSG_NOTICE([printf does not support custom format specifiers!])
467 vstr=true
468 ]
469 )]
470 )
471
472 if test x$vstr = xtrue; then
473 AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
474 AC_DEFINE(USE_VSTR)
475 fi
476
477 if test x$gmp = xtrue; then
478 saved_LIBS=$LIBS
479 AC_HAVE_LIBRARY([gmp],,[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
480 AC_MSG_CHECKING([mpz_powm_sec])
481 if test x$mpz_powm_sec = xyes; then
482 AC_TRY_COMPILE(
483 [#include "gmp.h"],
484 [
485 void *x = mpz_powm_sec;
486 ],
487 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_MPZ_POWM_SEC)], [AC_MSG_RESULT([no])]
488 )
489 else
490 AC_MSG_RESULT([disabled])
491 fi
492 LIBS=$saved_LIBS
493 AC_MSG_CHECKING([gmp.h version >= 4.1.4])
494 AC_TRY_COMPILE(
495 [#include "gmp.h"],
496 [
497 #if (__GNU_MP_VERSION*100 + __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
498 #error bad gmp
499 #endif
500 ],
501 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
502 )
503 fi
504
505 if test x$ldap = xtrue; then
506 AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
507 AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
508 AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
509 fi
510
511 if test x$curl = xtrue; then
512 AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
513 AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
514 fi
515
516 if test x$xml = xtrue; then
517 PKG_CHECK_MODULES(xml, [libxml-2.0])
518 AC_SUBST(xml_CFLAGS)
519 AC_SUBST(xml_LIBS)
520 fi
521
522 if test x$dumm = xtrue; then
523 PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
524 AC_SUBST(gtk_CFLAGS)
525 AC_SUBST(gtk_LIBS)
526 AC_CHECK_PROGS(RUBY, ruby)
527 AC_MSG_CHECKING([for Ruby header files])
528 if test -n "$RUBY"; then
529 RUBYDIR=`($RUBY -rmkmf -e 'print Config::CONFIG[["archdir"]] || $archdir') 2>/dev/null`
530 if test -n "$RUBYDIR"; then
531 dirs="$RUBYDIR"
532 RUBYINCLUDE=none
533 for i in $dirs; do
534 if test -r $i/ruby.h; then
535 AC_MSG_RESULT([$i])
536 RUBYINCLUDE="-I$i"
537 break;
538 fi
539 done
540 if test x"$RUBYINCLUDE" = xnone; then
541 AC_MSG_ERROR([ruby.h not found])
542 fi
543 AC_SUBST(RUBYINCLUDE)
544 else
545 AC_MSG_ERROR([unable to determine ruby configuration])
546 fi
547 else
548 AC_MSG_ERROR([don't know how to run ruby])
549 fi
550 fi
551
552 if test x$fast = xtrue; then
553 AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
554 AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
555 AC_HAVE_LIBRARY([z],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver dependency zlib not found!])])
556 dnl autoconf does not like CamelCase!? How to fix this?
557 dnl AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
558
559 AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
560 AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
561 fi
562
563 if test x$mysql = xtrue; then
564 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
565 if test x$MYSQLCONFIG = x; then
566 AC_MSG_ERROR([mysql_config not found!])
567 fi
568 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
569 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
570 fi
571
572 if test x$sqlite = xtrue; then
573 AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
574 AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
575 AC_MSG_CHECKING([sqlite3_prepare_v2])
576 AC_TRY_COMPILE(
577 [#include <sqlite3.h>],
578 [
579 void *test = sqlite3_prepare_v2;
580 ],
581 [AC_MSG_RESULT([yes])]; AC_DEFINE_UNQUOTED(HAVE_SQLITE3_PREPARE_V2, 1), [AC_MSG_RESULT([no])])
582 AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
583 AC_TRY_COMPILE(
584 [#include <sqlite3.h>],
585 [
586 #if SQLITE_VERSION_NUMBER < 3003001
587 #error bad sqlite
588 #endif
589 ],
590 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
591 fi
592
593 if test x$openssl = xtrue; then
594 AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
595 AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
596 fi
597
598 if test x$gcrypt = xtrue; then
599 AC_HAVE_LIBRARY([gcrypt],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
600 AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
601 AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
602 AC_TRY_COMPILE(
603 [#include <gcrypt.h>],
604 [enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;],
605 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA])],
606 [AC_MSG_RESULT([no])]
607 )
608 fi
609
610 if test x$tnccs_11 = xtrue -o x$tnc_imc = xtrue -o x$tnc_imv = xtrue; then
611 AC_CHECK_HEADER([libtnc.h],,[AC_MSG_ERROR([libtnc header libtnc.h not found!])])
612 fi
613
614 if test x$uci = xtrue; then
615 AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
616 AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
617 fi
618
619 if test x$android = xtrue; then
620 AC_HAVE_LIBRARY([cutils],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])])
621 AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
622 dnl we have to force the use of libdl here because the autodetection
623 dnl above does not work correctly when cross-compiling for android.
624 DLLIB="-ldl"
625 AC_SUBST(DLLIB)
626 fi
627
628 if test x$nm = xtrue; then
629 PKG_CHECK_EXISTS([libnm-glib],
630 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-glib libnm-glib-vpn])],
631 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_glib libnm_glib_vpn])]
632 )
633 AC_SUBST(nm_CFLAGS)
634 AC_SUBST(nm_LIBS)
635 fi
636
637 if test x$eap_gtc = xtrue; then
638 AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
639 AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
640 fi
641
642 if test x$capabilities = xnative; then
643 AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
644 dnl Linux requires the following for capset(), Android does not have it,
645 dnl but defines capset() in unistd.h instead.
646 AC_CHECK_HEADERS([sys/capability.h])
647 AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
648 AC_DEFINE(CAPABILITIES_NATIVE)
649 fi
650
651 if test x$capabilities = xlibcap; then
652 AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
653 AC_CHECK_HEADER([sys/capability.h],
654 [AC_DEFINE(HAVE_SYS_CAPABILITY_H)],
655 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
656 AC_DEFINE(CAPABILITIES_LIBCAP)
657 fi
658
659 if test x$integrity_test = xtrue; then
660 AC_MSG_CHECKING([for dladdr()])
661 AC_TRY_COMPILE(
662 [#define _GNU_SOURCE
663 #include <dlfcn.h>],
664 [Dl_info info; dladdr(main, &info);],
665 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
666 AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
667 )
668 AC_MSG_CHECKING([for dl_iterate_phdr()])
669 AC_TRY_COMPILE(
670 [#define _GNU_SOURCE
671 #include <link.h>],
672 [dl_iterate_phdr((void*)0, (void*)0);],
673 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
674 AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
675 )
676 fi
677
678 dnl ==============================================
679 dnl collect plugin list for strongSwan components
680 dnl ==============================================
681
682 m4_include(m4/macros/add-plugin.m4)
683
684 # plugin lists for all components
685 libcharon_plugins=
686 pluto_plugins=
687 pool_plugins=
688 openac_plugins=
689 scepclient_plugins=
690 pki_plugins=
691 scripts_plugins=
692 manager_plugins=
693 medsrv_plugins=
694
695 # location specific lists for checksumming,
696 # for src/libcharon, src/pluto, src/libhydra and src/libstrongswan
697 c_plugins=
698 p_plugins=
699 h_plugins=
700 s_plugins=
701
702 ADD_PLUGIN([test-vectors], [s libcharon pluto openac scepclient pki])
703 ADD_PLUGIN([curl], [s libcharon pluto scepclient])
704 ADD_PLUGIN([ldap], [s libcharon pluto scepclient])
705 ADD_PLUGIN([mysql], [s libcharon pluto pool manager medsrv])
706 ADD_PLUGIN([sqlite], [s libcharon pluto pool manager medsrv])
707 ADD_PLUGIN([aes], [s libcharon pluto openac scepclient pki scripts])
708 ADD_PLUGIN([des], [s libcharon pluto openac scepclient pki scripts])
709 ADD_PLUGIN([blowfish], [s libcharon pluto openac scepclient pki scripts])
710 ADD_PLUGIN([sha1], [s libcharon pluto openac scepclient pki scripts medsrv])
711 ADD_PLUGIN([sha2], [s libcharon pluto openac scepclient pki scripts medsrv])
712 ADD_PLUGIN([md4], [s libcharon openac manager scepclient pki])
713 ADD_PLUGIN([md5], [s libcharon pluto openac scepclient pki])
714 ADD_PLUGIN([random], [s libcharon pluto openac scepclient pki scripts medsrv])
715 ADD_PLUGIN([x509], [s libcharon pluto openac scepclient pki scripts])
716 ADD_PLUGIN([revocation], [s libcharon])
717 ADD_PLUGIN([pubkey], [s libcharon])
718 ADD_PLUGIN([pkcs1], [s libcharon pluto openac scepclient pki scripts manager medsrv])
719 ADD_PLUGIN([pgp], [s libcharon pluto])
720 ADD_PLUGIN([dnskey], [s pluto])
721 ADD_PLUGIN([pem], [s libcharon pluto openac scepclient pki scripts manager medsrv])
722 ADD_PLUGIN([padlock], [s libcharon])
723 ADD_PLUGIN([openssl], [s libcharon pluto openac scepclient pki scripts manager medsrv])
724 ADD_PLUGIN([gcrypt], [s libcharon pluto openac scepclient pki scripts manager medsrv])
725 ADD_PLUGIN([fips-prf], [s libcharon])
726 ADD_PLUGIN([gmp], [s libcharon pluto openac scepclient pki scripts manager medsrv])
727 ADD_PLUGIN([agent], [s libcharon])
728 ADD_PLUGIN([pkcs11], [s libcharon pki])
729 ADD_PLUGIN([xcbc], [s libcharon])
730 ADD_PLUGIN([hmac], [s libcharon pluto scripts])
731 ADD_PLUGIN([ctr], [s libcharon scripts])
732 ADD_PLUGIN([ccm], [s libcharon scripts])
733 ADD_PLUGIN([gcm], [s libcharon scripts])
734 ADD_PLUGIN([xauth], [p pluto])
735 ADD_PLUGIN([attr], [h libcharon pluto])
736 ADD_PLUGIN([attr-sql], [h libcharon pluto])
737 ADD_PLUGIN([kernel-pfkey], [h libcharon pluto])
738 ADD_PLUGIN([kernel-pfroute], [h libcharon pluto])
739 ADD_PLUGIN([kernel-klips], [h libcharon pluto])
740 ADD_PLUGIN([kernel-netlink], [h libcharon pluto])
741 ADD_PLUGIN([resolve], [h libcharon pluto])
742 ADD_PLUGIN([load-tester], [c libcharon])
743 ADD_PLUGIN([socket-default], [c libcharon])
744 ADD_PLUGIN([socket-raw], [c libcharon])
745 ADD_PLUGIN([socket-dynamic], [c libcharon])
746 ADD_PLUGIN([farp], [c libcharon])
747 ADD_PLUGIN([stroke], [c libcharon])
748 ADD_PLUGIN([smp], [c libcharon])
749 ADD_PLUGIN([sql], [c libcharon])
750 ADD_PLUGIN([updown], [c libcharon])
751 ADD_PLUGIN([eap-identity], [c libcharon])
752 ADD_PLUGIN([eap-sim], [c libcharon])
753 ADD_PLUGIN([eap-sim-file], [c libcharon])
754 ADD_PLUGIN([eap-simaka-sql], [c libcharon])
755 ADD_PLUGIN([eap-simaka-pseudonym], [c libcharon])
756 ADD_PLUGIN([eap-simaka-reauth], [c libcharon])
757 ADD_PLUGIN([eap-aka], [c libcharon])
758 ADD_PLUGIN([eap-aka-3gpp2], [c libcharon])
759 ADD_PLUGIN([eap-md5], [c libcharon])
760 ADD_PLUGIN([eap-gtc], [c libcharon])
761 ADD_PLUGIN([eap-mschapv2], [c libcharon])
762 ADD_PLUGIN([eap-radius], [c libcharon])
763 ADD_PLUGIN([eap-tls], [c libcharon])
764 ADD_PLUGIN([eap-ttls], [c libcharon])
765 ADD_PLUGIN([eap-tnc], [c libcharon])
766 ADD_PLUGIN([tnc-imc], [c libcharon])
767 ADD_PLUGIN([tnc-imv], [c libcharon])
768 ADD_PLUGIN([tnccs-11], [c libcharon])
769 ADD_PLUGIN([tnccs-20], [c libcharon])
770 ADD_PLUGIN([medsrv], [c libcharon])
771 ADD_PLUGIN([medcli], [c libcharon])
772 ADD_PLUGIN([nm], [c libcharon])
773 ADD_PLUGIN([dhcp], [c libcharon])
774 ADD_PLUGIN([android], [c libcharon])
775 ADD_PLUGIN([ha], [c libcharon])
776 ADD_PLUGIN([led], [c libcharon])
777 ADD_PLUGIN([maemo], [c libcharon])
778 ADD_PLUGIN([uci], [c libcharon])
779 ADD_PLUGIN([addrblock], [c libcharon])
780 ADD_PLUGIN([unit-tester], [c libcharon])
781
782 AC_SUBST(libcharon_plugins)
783 AC_SUBST(pluto_plugins)
784 AC_SUBST(pool_plugins)
785 AC_SUBST(openac_plugins)
786 AC_SUBST(scepclient_plugins)
787 AC_SUBST(pki_plugins)
788 AC_SUBST(scripts_plugins)
789 AC_SUBST(manager_plugins)
790 AC_SUBST(medsrv_plugins)
791
792 AC_SUBST(c_plugins)
793 AC_SUBST(p_plugins)
794 AC_SUBST(h_plugins)
795 AC_SUBST(s_plugins)
796
797 dnl =========================
798 dnl set Makefile.am vars
799 dnl =========================
800
801 dnl libstrongswan plugins
802 dnl =====================
803 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
804 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
805 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
806 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
807 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
808 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
809 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
810 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
811 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
812 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
813 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
814 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
815 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
816 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
817 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
818 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
819 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
820 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
821 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
822 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
823 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
824 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
825 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
826 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
827 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
828 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
829 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
830 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
831 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
832 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
833 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
834 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
835
836 dnl charon plugins
837 dnl ==============
838 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
839 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
840 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
841 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
842 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
843 AM_CONDITIONAL(USE_ANDROID, test x$android = xtrue)
844 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
845 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
846 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
847 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
848 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
849 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tests = xtrue)
850 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
851 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
852 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
853 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
854 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
855 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
856 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
857 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
858 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
859 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
860 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
861 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
862 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
863 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
864 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
865 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
866 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
867 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
868 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
869 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
870 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
871 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
872 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
873 AM_CONDITIONAL(USE_SOCKET_RAW, test x$socket_raw = xtrue)
874 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
875 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
876 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
877
878 dnl hydra plugins
879 dnl =============
880 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
881 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
882 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
883 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
884 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
885 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
886 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
887
888 dnl pluto plugins
889 dnl =============
890 AM_CONDITIONAL(USE_XAUTH, test x$xauth = xtrue)
891
892 dnl other options
893 dnl =============
894 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
895 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
896 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
897 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
898 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
899 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
900 AM_CONDITIONAL(USE_XAUTH_VID, test x$xauth_vid = xtrue)
901 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
902 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
903 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
904 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
905 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
906 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
907 AM_CONDITIONAL(USE_PLUTO, test x$pluto = xtrue)
908 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
909 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
910 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
911 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
912 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pluto = xtrue -o x$tools = xtrue)
913 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$pluto = xtrue)
914 AM_CONDITIONAL(USE_FILE_CONFIG, test x$pluto = xtrue -o x$stroke = xtrue)
915 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
916 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
917 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
918 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
919 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
920
921 dnl ==============================
922 dnl set global definitions
923 dnl ==============================
924
925 if test x$mediation = xtrue; then
926 AC_DEFINE(ME)
927 fi
928 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
929 AC_DEFINE(CAPABILITIES)
930 fi
931 if test x$monolithic = xtrue; then
932 AC_DEFINE(MONOLITHIC)
933 fi
934
935
936 dnl ==============================
937 dnl build Makefiles
938 dnl ==============================
939
940 AC_OUTPUT(
941 Makefile
942 man/Makefile
943 src/Makefile
944 src/include/Makefile
945 src/libstrongswan/Makefile
946 src/libstrongswan/plugins/aes/Makefile
947 src/libstrongswan/plugins/des/Makefile
948 src/libstrongswan/plugins/blowfish/Makefile
949 src/libstrongswan/plugins/md4/Makefile
950 src/libstrongswan/plugins/md5/Makefile
951 src/libstrongswan/plugins/sha1/Makefile
952 src/libstrongswan/plugins/sha2/Makefile
953 src/libstrongswan/plugins/fips_prf/Makefile
954 src/libstrongswan/plugins/gmp/Makefile
955 src/libstrongswan/plugins/random/Makefile
956 src/libstrongswan/plugins/hmac/Makefile
957 src/libstrongswan/plugins/xcbc/Makefile
958 src/libstrongswan/plugins/x509/Makefile
959 src/libstrongswan/plugins/revocation/Makefile
960 src/libstrongswan/plugins/pubkey/Makefile
961 src/libstrongswan/plugins/pkcs1/Makefile
962 src/libstrongswan/plugins/pgp/Makefile
963 src/libstrongswan/plugins/dnskey/Makefile
964 src/libstrongswan/plugins/pem/Makefile
965 src/libstrongswan/plugins/curl/Makefile
966 src/libstrongswan/plugins/ldap/Makefile
967 src/libstrongswan/plugins/mysql/Makefile
968 src/libstrongswan/plugins/sqlite/Makefile
969 src/libstrongswan/plugins/padlock/Makefile
970 src/libstrongswan/plugins/openssl/Makefile
971 src/libstrongswan/plugins/gcrypt/Makefile
972 src/libstrongswan/plugins/agent/Makefile
973 src/libstrongswan/plugins/pkcs11/Makefile
974 src/libstrongswan/plugins/ctr/Makefile
975 src/libstrongswan/plugins/ccm/Makefile
976 src/libstrongswan/plugins/gcm/Makefile
977 src/libstrongswan/plugins/test_vectors/Makefile
978 src/libhydra/Makefile
979 src/libhydra/plugins/attr/Makefile
980 src/libhydra/plugins/attr_sql/Makefile
981 src/libhydra/plugins/kernel_klips/Makefile
982 src/libhydra/plugins/kernel_netlink/Makefile
983 src/libhydra/plugins/kernel_pfkey/Makefile
984 src/libhydra/plugins/kernel_pfroute/Makefile
985 src/libhydra/plugins/resolve/Makefile
986 src/libfreeswan/Makefile
987 src/libsimaka/Makefile
988 src/libtls/Makefile
989 src/pluto/Makefile
990 src/pluto/plugins/xauth/Makefile
991 src/whack/Makefile
992 src/charon/Makefile
993 src/libcharon/Makefile
994 src/libcharon/plugins/eap_aka/Makefile
995 src/libcharon/plugins/eap_aka_3gpp2/Makefile
996 src/libcharon/plugins/eap_identity/Makefile
997 src/libcharon/plugins/eap_md5/Makefile
998 src/libcharon/plugins/eap_gtc/Makefile
999 src/libcharon/plugins/eap_sim/Makefile
1000 src/libcharon/plugins/eap_sim_file/Makefile
1001 src/libcharon/plugins/eap_simaka_sql/Makefile
1002 src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1003 src/libcharon/plugins/eap_simaka_reauth/Makefile
1004 src/libcharon/plugins/eap_mschapv2/Makefile
1005 src/libcharon/plugins/eap_tls/Makefile
1006 src/libcharon/plugins/eap_ttls/Makefile
1007 src/libcharon/plugins/eap_tnc/Makefile
1008 src/libcharon/plugins/eap_radius/Makefile
1009 src/libcharon/plugins/tnc_imc/Makefile
1010 src/libcharon/plugins/tnc_imv/Makefile
1011 src/libcharon/plugins/tnccs_11/Makefile
1012 src/libcharon/plugins/tnccs_20/Makefile
1013 src/libcharon/plugins/socket_default/Makefile
1014 src/libcharon/plugins/socket_raw/Makefile
1015 src/libcharon/plugins/socket_dynamic/Makefile
1016 src/libcharon/plugins/farp/Makefile
1017 src/libcharon/plugins/smp/Makefile
1018 src/libcharon/plugins/sql/Makefile
1019 src/libcharon/plugins/medsrv/Makefile
1020 src/libcharon/plugins/medcli/Makefile
1021 src/libcharon/plugins/nm/Makefile
1022 src/libcharon/plugins/addrblock/Makefile
1023 src/libcharon/plugins/uci/Makefile
1024 src/libcharon/plugins/ha/Makefile
1025 src/libcharon/plugins/led/Makefile
1026 src/libcharon/plugins/android/Makefile
1027 src/libcharon/plugins/maemo/Makefile
1028 src/libcharon/plugins/stroke/Makefile
1029 src/libcharon/plugins/updown/Makefile
1030 src/libcharon/plugins/dhcp/Makefile
1031 src/libcharon/plugins/unit_tester/Makefile
1032 src/libcharon/plugins/load_tester/Makefile
1033 src/stroke/Makefile
1034 src/ipsec/Makefile
1035 src/starter/Makefile
1036 src/_updown/Makefile
1037 src/_updown_espmark/Makefile
1038 src/_copyright/Makefile
1039 src/openac/Makefile
1040 src/scepclient/Makefile
1041 src/pki/Makefile
1042 src/dumm/Makefile
1043 src/dumm/ext/extconf.rb
1044 src/libfast/Makefile
1045 src/manager/Makefile
1046 src/medsrv/Makefile
1047 src/checksum/Makefile
1048 scripts/Makefile
1049 testing/Makefile
1050 )