libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GNU Offloading and Multi Processing Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 # We would like our source tree to be readonly. However when releases or
  19 # pre-releases are generated, the flex/bison generated files as well as the
  20 # various formats of manuals need to be included along with the rest of the
  21 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  22 # just that.
  23 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  24 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  25    [put copies of generated files in source dir intended for creating source
  26     tarballs for users without texinfo bison or flex.],
  27    permit yes|no)
  28 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  29 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  30
  31
  32 # -------
  33 # -------
  34
  35 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  36 #
  37 # You will slowly go insane if you do not grok the following fact:  when
  38 # building this library, the top-level /target/ becomes the library's /host/.
  39 #
  40 # configure then causes --target to default to --host, exactly like any
  41 # other package using autoconf.  Therefore, 'target' and 'host' will
  42 # always be the same.  This makes sense both for native and cross compilers
  43 # just think about it for a little while.  :-)
  44 #
  45 # Also, if this library is being configured as part of a cross compiler, the
  46 # top-level configure script will pass the "real" host as $with_cross_host.
  47 #
  48 # Do not delete or change the following two lines.  For why, see
  49 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  50 AC_CANONICAL_SYSTEM
  51 target_alias=${target_alias-$host_alias}
  52
  53 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  54 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  55 #  1.9.0:  minimum required version
  56 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  57 #              of other PACKAGE_* variables will, however, and there's nothing
  58 #              we can do about that; they come from AC_INIT).
  59 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  60 #            file in the top srcdir, etc, etc), so stop complaining.
  61 #  no-dist:  we don't want 'dist' and related rules.
  62 #  -Wall:  turns on all automake warnings...
  63 #  -Wno-portability:  ...except this one, since GNU make is required.
  64 #  -Wno-override: ... and this one, since we do want this in testsuite.
  65 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  66 AM_ENABLE_MULTILIB(, ..)
  67
  68 # Calculate toolexeclibdir
  69 # Also toolexecdir, though it's only used in toolexeclibdir
  70 case ${enable_version_specific_runtime_libs} in
  71   yes)
  72     # Need the gcc compiler version to know where to install libraries
  73     # and header files if --enable-version-specific-runtime-libs option
  74     # is selected.
  75     toolexecdir='$(libdir)/gcc/$(target_alias)'
  76     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  77     ;;
  78   no)
  79     if test -n "$with_cross_host" &&
  80        test x"$with_cross_host" != x"no"; then
  81       # Install a library built with a cross compiler in tooldir, not libdir.
  82       toolexecdir='$(exec_prefix)/$(target_alias)'
  83       toolexeclibdir='$(toolexecdir)/lib'
  84     else
  85       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  86       toolexeclibdir='$(libdir)'
  87     fi
  88     multi_os_directory=`$CC -print-multi-os-directory`
  89     case $multi_os_directory in
  90       .) ;; # Avoid trailing /.
  91       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  92     esac
  93     ;;
  94 esac
  95 AC_SUBST(toolexecdir)
  96 AC_SUBST(toolexeclibdir)
  97
  98 # Check the compiler.
  99 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 100 # We must force CC to /not/ be precious variables; otherwise
 101 # the wrong, non-multilib-adjusted value will be used in multilibs.
 102 # As a side effect, we have to subst CFLAGS ourselves.
 103
 104 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 105 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 106 AC_PROG_CC
 107 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108
 109 AC_SUBST(CFLAGS)
 110
 111 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 112 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 113 # in both places for now and restore CFLAGS at the end of config.
 114 save_CFLAGS="$CFLAGS"
 115
 116 # Add -Wall -Werror if we are using GCC.
 117 if test "x$GCC" = "xyes"; then
 118   XCFLAGS="$XCFLAGS -Wall -Werror"
 119 fi
 120
 121 # Find other programs we need.
 122 AC_CHECK_TOOL(AR, ar)
 123 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 124 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 125 AC_PROG_MAKE_SET
 126 AC_PROG_INSTALL
 127
 128 # See if makeinfo has been installed and is modern enough
 129 # that we can use it.
 130 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 131                    [GNU texinfo.* \([0-9][0-9.]*\)],
 132                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 133 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 134
 135
 136 # Configure libtool
 137 AM_PROG_LIBTOOL
 138 ACX_LT_HOST_FLAGS
 139 AC_SUBST(enable_shared)
 140 AC_SUBST(enable_static)
 141
 142 AM_MAINTAINER_MODE
 143
 144 # Create a spec file, so that compile/link tests don't fail
 145 test -f libgfortran.spec || touch libgfortran.spec
 146 FCFLAGS="$FCFLAGS -L."
 147
 148 # We need gfortran to compile parts of the library
 149 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 150 #AC_PROG_FC(gfortran)
 151 case `echo $GFORTRAN` in
 152   -* | no* )
 153     FC=no ;;
 154   *)
 155     set dummy $GFORTRAN; ac_word=$2
 156     if test -x "$ac_word"; then
 157       FC="$GFORTRAN"
 158     else
 159       FC=no
 160     fi ;;
 161 esac
 162 AC_PROG_FC(gfortran)
 163 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 164
 165 # For libtool versioning info, format is CURRENT:REVISION:AGE
 166 libtool_VERSION=1:0:0
 167 AC_SUBST(libtool_VERSION)
 168
 169 # Check header files.
 170 AC_STDC_HEADERS
 171 AC_HEADER_TIME
 172 ACX_HEADER_STRING
 173 AC_CHECK_HEADERS(pthread.h unistd.h semaphore.h sys/loadavg.h sys/sysctl.h sys/time.h)
 174
 175 GCC_HEADER_STDINT(gstdint.h)
 176
 177 XPCFLAGS=""
 178 case "$host" in
 179   *-*-rtems*)
 180     # RTEMS supports Pthreads, but the library is not available at GCC build time.
 181     ;;
 182   nvptx*-*-*)
 183     # NVPTX does not support Pthreads, has its own code replacement.
 184     libgomp_use_pthreads=no
 185     # NVPTX is an accelerator-only target
 186     libgomp_offloaded_only=yes
 187     ;;
 188   *)
 189     # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 190     # In case the pthread.h system header is not found, this test will fail.
 191     CFLAGS="$CFLAGS -pthread"
 192     AC_LINK_IFELSE(
 193      [AC_LANG_PROGRAM(
 194       [#include <pthread.h>
 195        void *g(void *d) { return NULL; }],
 196       [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 197      [XPCFLAGS=" -Wc,-pthread"],
 198      [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 199       AC_LINK_IFELSE(
 200        [AC_LANG_PROGRAM(
 201         [#include <pthread.h>
 202          void *g(void *d) { return NULL; }],
 203         [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 204        [],
 205        [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 206 esac
 207
 208 if test x$libgomp_use_pthreads != xno; then
 209   AC_DEFINE(LIBGOMP_USE_PTHREADS, 1,
 210             [Define to 1 if libgomp should use POSIX threads.])
 211 fi
 212
 213 if test x$libgomp_offloaded_only = xyes; then
 214   AC_DEFINE(LIBGOMP_OFFLOADED_ONLY, 1,
 215             [Define to 1 if building libgomp for an accelerator-only target.])
 216 fi
 217
 218 m4_include([plugin/configfrag.ac])
 219
 220 # Check for functions needed.
 221 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 222
 223 # Check for broken semaphore implementation on darwin.
 224 # sem_init returns: sem_init error: Function not implemented.
 225 case "$host" in
 226   *-darwin*)
 227     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 228         Define if the POSIX Semaphores do not work on your system.)
 229     ;;
 230 esac
 231
 232 # RTEMS specific checks
 233 case "$host" in
 234   *-*-rtems*)
 235     AC_CHECK_TYPES([struct _Mutex_Control],[],[],[#include <sys/lock.h>])
 236     ;;
 237 esac
 238
 239 GCC_LINUX_FUTEX(:)
 240
 241 # Check for pthread_{,attr_}[sg]etaffinity_np.
 242 AC_LINK_IFELSE(
 243  [AC_LANG_PROGRAM(
 244   [#define _GNU_SOURCE
 245    #include <pthread.h>],
 246   [cpu_set_t cpuset;
 247    pthread_attr_t attr;
 248    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 249    if (CPU_ISSET (0, &cpuset))
 250      CPU_SET (1, &cpuset);
 251    else
 252      CPU_ZERO (&cpuset);
 253    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 254    pthread_attr_init (&attr);
 255    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 256    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 257   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 258 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 259
 260 # At least for glibc, clock_gettime is in librt.  But don't pull that
 261 # in if it still doesn't give us the function we want.
 262 if test $ac_cv_func_clock_gettime = no; then
 263   AC_CHECK_LIB(rt, clock_gettime,
 264     [LIBS="-lrt $LIBS"
 265      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 266                [Define to 1 if you have the `clock_gettime' function.])])
 267 fi
 268
 269 # See if we support thread-local storage.
 270 GCC_CHECK_TLS
 271
 272 # See if we have emulated thread-local storage.
 273 GCC_CHECK_EMUTLS
 274
 275 # See what sort of export controls are available.
 276 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 277 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 278 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 279 LIBGOMP_ENABLE_SYMVERS
 280
 281 if test $enable_symvers = gnu; then
 282   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 283             [Define to 1 if GNU symbol versioning is used for libgomp.])
 284 fi
 285
 286 # Get target configury.
 287 . ${srcdir}/configure.tgt
 288 CFLAGS="$save_CFLAGS $XCFLAGS"
 289
 290 # Check for __sync_val_compare_and_swap, but only after the target has
 291 # had a chance to set XCFLAGS.
 292 LIBGOMP_CHECK_SYNC_BUILTINS
 293
 294 XCFLAGS="$XCFLAGS$XPCFLAGS"
 295
 296 # Add CET specific flags if CET is enabled
 297 GCC_CET_FLAGS(CET_FLAGS)
 298 XCFLAGS="$XCFLAGS $CET_FLAGS"
 299 FCFLAGS="$FCFLAGS $CET_FLAGS"
 300
 301 AC_SUBST(config_path)
 302 AC_SUBST(XCFLAGS)
 303 AC_SUBST(XLDFLAGS)
 304
 305 # Cleanup and exit.
 306 CFLAGS="$save_CFLAGS"
 307 AC_CACHE_SAVE
 308
 309 if test ${multilib} = yes; then
 310   multilib_arg="--enable-multilib"
 311 else
 312   multilib_arg=
 313 fi
 314
 315 # Set up the set of libraries that we need to link against for libgomp.
 316 # Note that the GOMP_SELF_SPEC in gcc.c may force -pthread,
 317 # which will force linkage against -lpthread (or equivalent for the system).
 318 # That's not 100% ideal, but about the best we can do easily.
 319 if test $enable_shared = yes; then
 320   link_gomp="-lgomp %{static: $LIBS}"
 321 else
 322   link_gomp="-lgomp $LIBS"
 323 fi
 324 AC_SUBST(link_gomp)
 325
 326 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 327
 328 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 329 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 330 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 331 # need to copy this macro to our acinclude.m4.
 332 save_CFLAGS="$CFLAGS"
 333 for i in $config_path; do
 334   if test -f $srcdir/config/$i/omp-lock.h; then
 335     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 336     break
 337   fi
 338 done
 339
 340 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 341   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 342 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 343 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 344 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 345 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 346   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 347 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 348 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 349 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 350
 351 # If the lock fits in an integer, then arrange for Fortran to use that
 352 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 353 # Except that we don't have a way at present to multi-lib the installed
 354 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 355 # actual target.
 356 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 357 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 358 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 359   OMP_LOCK_KIND=8
 360 fi
 361 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 362   OMP_NEST_LOCK_KIND=8
 363 fi
 364 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 365 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 366 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 367   OMP_LOCK_25_KIND=8
 368 fi
 369 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 370   OMP_NEST_LOCK_25_KIND=8
 371 fi
 372
 373 AC_SUBST(OMP_LOCK_SIZE)
 374 AC_SUBST(OMP_LOCK_ALIGN)
 375 AC_SUBST(OMP_NEST_LOCK_SIZE)
 376 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 377 AC_SUBST(OMP_LOCK_KIND)
 378 AC_SUBST(OMP_NEST_LOCK_KIND)
 379 AC_SUBST(OMP_LOCK_25_SIZE)
 380 AC_SUBST(OMP_LOCK_25_ALIGN)
 381 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 382 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 383 AC_SUBST(OMP_LOCK_25_KIND)
 384 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 385 CFLAGS="$save_CFLAGS"
 386
 387 # Determine what GCC version number to use in filesystem paths.
 388 GCC_BASE_VER
 389
 390 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 391 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 392 AC_CONFIG_FILES([testsuite/libgomp-test-support.pt.exp:testsuite/libgomp-test-support.exp.in])
 393 AC_OUTPUT