m4/boost.m4

   1 # boost.m4: Locate Boost headers and libraries for autoconf-based projects.
   2 # Copyright (C) 2007-2011, 2014  Benoit Sigoure <tsuna@lrde.epita.fr>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # Additional permission under section 7 of the GNU General Public
  10 # License, version 3 ("GPLv3"):
  11 #
  12 # If you convey this file as part of a work that contains a
  13 # configuration script generated by Autoconf, you may do so under
  14 # terms of your choice.
  15 #
  16 # This program is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 m4_define([_BOOST_SERIAL], [m4_translit([
  25 # serial 30
  26 ], [#
  27 ], [])])
  28
  29 # Original sources can be found at http://github.com/tsuna/boost.m4
  30 # You can fetch the latest version of the script by doing:
  31 #   wget http://github.com/tsuna/boost.m4/raw/master/build-aux/boost.m4
  32
  33 # ------ #
  34 # README #
  35 # ------ #
  36
  37 # This file provides several macros to use the various Boost libraries.
  38 # The first macro is BOOST_REQUIRE.  It will simply check if it's possible to
  39 # find the Boost headers of a given (optional) minimum version and it will
  40 # define BOOST_CPPFLAGS accordingly.  It will add an option --with-boost to
  41 # your configure so that users can specify non standard locations.
  42 # If the user's environment contains BOOST_ROOT and --with-boost was not
  43 # specified, --with-boost=$BOOST_ROOT is implicitly used.
  44 # For more README and documentation, go to http://github.com/tsuna/boost.m4
  45 # Note: THESE MACROS ASSUME THAT YOU USE LIBTOOL.  If you don't, don't worry,
  46 # simply read the README, it will show you what to do step by step.
  47
  48 m4_pattern_forbid([^_?(BOOST|Boost)_])
  49
  50
  51 # _BOOST_SED_CPP(SED-PROGRAM, PROGRAM,
  52 #                [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
  53 # --------------------------------------------------------
  54 # Same as AC_EGREP_CPP, but leave the result in conftest.i.
  55 #
  56 # SED-PROGRAM is *not* overquoted, as in AC_EGREP_CPP.  It is expanded
  57 # in double-quotes, so escape your double quotes.
  58 #
  59 # It could be useful to turn this into a macro which extracts the
  60 # value of any macro.
  61 m4_define([_BOOST_SED_CPP],
  62 [AC_LANG_PUSH([C++])dnl
  63 AC_LANG_PREPROC_REQUIRE()dnl
  64 AC_REQUIRE([AC_PROG_SED])dnl
  65 AC_LANG_CONFTEST([AC_LANG_SOURCE([[$2]])])
  66 AS_IF([dnl eval is necessary to expand ac_cpp.
  67 dnl Ultrix and Pyramid sh refuse to redirect output of eval, so use subshell.
  68 dnl Beware of Windows end-of-lines, for instance if we are running
  69 dnl some Windows programs under Wine.  In that case, boost/version.hpp
  70 dnl is certainly using "\r\n", but the regular Unix shell will only
  71 dnl strip `\n' with backquotes, not the `\r'.  This results in
  72 dnl boost_cv_lib_version='1_37\r' for instance, which breaks
  73 dnl everything else.
  74 dnl Cannot use 'dnl' after [$4] because a trailing dnl may break AC_CACHE_CHECK
  75 dnl
  76 dnl Beware that GCC 5, when expanding macros, may embed # line directives
  77 dnl a within single line:
  78 dnl
  79 dnl # 1 "conftest.cc"
  80 dnl # 1 "<built-in>"
  81 dnl # 1 "<command-line>"
  82 dnl # 1 "conftest.cc"
  83 dnl # 1 "/opt/local/include/boost/version.hpp" 1 3
  84 dnl # 2 "conftest.cc" 2
  85 dnl boost-lib-version =
  86 dnl # 2 "conftest.cc" 3
  87 dnl                    "1_56"
  88 dnl
  89 dnl So get rid of the # and empty lines, and glue the remaining ones together.
  90 (eval "$ac_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD |
  91   grep -v '#' |
  92   grep -v '^[[[:space:]]]*$' |
  93   tr -d '\r' |
  94   tr -s '\n' ' ' |
  95   $SED -n -e "$1" >conftest.i 2>&1],
  96   [$3],
  97   [$4])
  98 rm -rf conftest*
  99 AC_LANG_POP([C++])dnl
 100 ])# _BOOST_SED_CPP
 101
 102
 103
 104 # BOOST_REQUIRE([VERSION], [ACTION-IF-NOT-FOUND])
 105 # -----------------------------------------------
 106 # Look for Boost.  If version is given, it must either be a literal of the form
 107 # "X.Y.Z" where X, Y and Z are integers (the ".Z" part being optional) or a
 108 # variable "$var".
 109 # Defines the value BOOST_CPPFLAGS.  This macro only checks for headers with
 110 # the required version, it does not check for any of the Boost libraries.
 111 # On # success, defines HAVE_BOOST.  On failure, calls the optional
 112 # ACTION-IF-NOT-FOUND action if one was supplied.
 113 # Otherwise aborts with an error message.
 114 AC_DEFUN_ONCE([BOOST_REQUIRE],
 115 [AC_REQUIRE([AC_PROG_CXX])dnl
 116 AC_REQUIRE([AC_PROG_GREP])dnl
 117 echo "$as_me: this is boost.m4[]_BOOST_SERIAL" >&AS_MESSAGE_LOG_FD
 118 boost_save_IFS=$IFS
 119 boost_version_req=$1
 120 IFS=.
 121 set x $boost_version_req 0 0 0
 122 IFS=$boost_save_IFS
 123 shift
 124 boost_version_req=`expr "$[1]" '*' 100000 + "$[2]" '*' 100 + "$[3]"`
 125 boost_version_req_string=$[1].$[2].$[3]
 126 AC_ARG_WITH([boost],
 127    [AS_HELP_STRING([--with-boost=DIR],
 128                    [prefix of Boost $1 @<:@guess@:>@])])dnl
 129 AC_ARG_VAR([BOOST_ROOT],[Location of Boost installation])dnl
 130 # If BOOST_ROOT is set and the user has not provided a value to
 131 # --with-boost, then treat BOOST_ROOT as if it the user supplied it.
 132 if test x"$BOOST_ROOT" != x; then
 133   if test x"$with_boost" = x; then
 134     AC_MSG_NOTICE([Detected BOOST_ROOT; continuing with --with-boost=$BOOST_ROOT])
 135     with_boost=$BOOST_ROOT
 136   else
 137     AC_MSG_NOTICE([Detected BOOST_ROOT=$BOOST_ROOT, but overridden by --with-boost=$with_boost])
 138   fi
 139 fi
 140 AC_SUBST([DISTCHECK_CONFIGURE_FLAGS],
 141          ["$DISTCHECK_CONFIGURE_FLAGS '--with-boost=$with_boost'"])dnl
 142 boost_save_CPPFLAGS=$CPPFLAGS
 143   AC_CACHE_CHECK([for Boost headers version >= $boost_version_req_string],
 144     [boost_cv_inc_path],
 145     [boost_cv_inc_path=no
 146 AC_LANG_PUSH([C++])dnl
 147 m4_pattern_allow([^BOOST_VERSION$])dnl
 148     AC_LANG_CONFTEST([AC_LANG_PROGRAM([[#include <boost/version.hpp>
 149 #if !defined BOOST_VERSION
 150 # error BOOST_VERSION is not defined
 151 #elif BOOST_VERSION < $boost_version_req
 152 # error Boost headers version < $boost_version_req
 153 #endif
 154 ]])])
 155     # If the user provided a value to --with-boost, use it and only it.
 156     case $with_boost in #(
 157       ''|yes) set x '' /opt/local/include /usr/local/include /opt/include \
 158                  /usr/include C:/Boost/include;; #(
 159       *)      set x "$with_boost/include" "$with_boost";;
 160     esac
 161     shift
 162     for boost_dir
 163     do
 164     # Without --layout=system, Boost (or at least some versions) installs
 165     # itself in <prefix>/include/boost-<version>.  This inner loop helps to
 166     # find headers in such directories.
 167     #
 168     # Any ${boost_dir}/boost-x_xx directories are searched in reverse version
 169     # order followed by ${boost_dir}.  The final '.' is a sentinel for
 170     # searching $boost_dir" itself.  Entries are whitespace separated.
 171     #
 172     # I didn't indent this loop on purpose (to avoid over-indented code)
 173     boost_layout_system_search_list=`cd "$boost_dir" 2>/dev/null \
 174         && ls -1 | "${GREP}" '^boost-' | sort -rn -t- -k2 \
 175         && echo .`
 176     for boost_inc in $boost_layout_system_search_list
 177     do
 178       if test x"$boost_inc" != x.; then
 179         boost_inc="$boost_dir/$boost_inc"
 180       else
 181         boost_inc="$boost_dir" # Uses sentinel in boost_layout_system_search_list
 182       fi
 183       if test x"$boost_inc" != x; then
 184         # We are going to check whether the version of Boost installed
 185         # in $boost_inc is usable by running a compilation that
 186         # #includes it.  But if we pass a -I/some/path in which Boost
 187         # is not installed, the compiler will just skip this -I and
 188         # use other locations (either from CPPFLAGS, or from its list
 189         # of system include directories).  As a result we would use
 190         # header installed on the machine instead of the /some/path
 191         # specified by the user.  So in that precise case (trying
 192         # $boost_inc), make sure the version.hpp exists.
 193         #
 194         # Use test -e as there can be symlinks.
 195         test -e "$boost_inc/boost/version.hpp" || continue
 196         CPPFLAGS="$CPPFLAGS -I$boost_inc"
 197       fi
 198       AC_COMPILE_IFELSE([], [boost_cv_inc_path=yes], [boost_cv_version=no])
 199       if test x"$boost_cv_inc_path" = xyes; then
 200         if test x"$boost_inc" != x; then
 201           boost_cv_inc_path=$boost_inc
 202         fi
 203         break 2
 204       fi
 205     done
 206     done
 207 AC_LANG_POP([C++])dnl
 208     ])
 209     case $boost_cv_inc_path in #(
 210       no)
 211         boost_errmsg="cannot find Boost headers version >= $boost_version_req_string"
 212         m4_if([$2], [],  [AC_MSG_ERROR([$boost_errmsg])],
 213                         [AC_MSG_NOTICE([$boost_errmsg])])
 214         $2
 215         ;;#(
 216       yes)
 217         BOOST_CPPFLAGS=
 218         ;;#(
 219       *)
 220         AC_SUBST([BOOST_CPPFLAGS], ["-I$boost_cv_inc_path"])dnl
 221         ;;
 222     esac
 223   if test x"$boost_cv_inc_path" != xno; then
 224   AC_DEFINE([HAVE_BOOST], [1],
 225             [Defined if the requested minimum BOOST version is satisfied])
 226   AC_CACHE_CHECK([for Boost's header version],
 227     [boost_cv_lib_version],
 228     [m4_pattern_allow([^BOOST_LIB_VERSION$])dnl
 229      _BOOST_SED_CPP([[/^boost-lib-version = /{s///;s/[\" ]//g;p;q;}]],
 230                     [#include <boost/version.hpp>
 231 boost-lib-version = BOOST_LIB_VERSION],
 232     [boost_cv_lib_version=`cat conftest.i`])])
 233     # e.g. "134" for 1_34_1 or "135" for 1_35
 234     boost_major_version=`echo "$boost_cv_lib_version" | sed 's/_//;s/_.*//'`
 235     case $boost_major_version in #(
 236       '' | *[[!0-9]]*)
 237         AC_MSG_ERROR([invalid value: boost_major_version='$boost_major_version'])
 238         ;;
 239     esac
 240 fi
 241 CPPFLAGS=$boost_save_CPPFLAGS
 242 ])# BOOST_REQUIRE
 243
 244
 245 # BOOST_STATIC()
 246 # --------------
 247 # Add the "--enable-static-boost" configure argument. If this argument is given
 248 # on the command line, static versions of the libraries will be looked up.
 249 AC_DEFUN([BOOST_STATIC],
 250   [AC_ARG_ENABLE([static-boost],
 251      [AS_HELP_STRING([--enable-static-boost],
 252                [Prefer the static boost libraries over the shared ones [no]])],
 253      [enable_static_boost=yes],
 254      [enable_static_boost=no])])# BOOST_STATIC
 255
 256
 257 # BOOST_FIND_HEADER([HEADER-NAME], [ACTION-IF-NOT-FOUND], [ACTION-IF-FOUND])
 258 # --------------------------------------------------------------------------
 259 # Wrapper around AC_CHECK_HEADER for Boost headers.  Useful to check for
 260 # some parts of the Boost library which are only made of headers and don't
 261 # require linking (such as Boost.Foreach).
 262 #
 263 # Default ACTION-IF-NOT-FOUND: Fail with a fatal error unless Boost couldn't be
 264 # found in the first place, in which case by default a notice is issued to the
 265 # user.  Presumably if we haven't died already it's because it's OK to not have
 266 # Boost, which is why only a notice is issued instead of a hard error.
 267 #
 268 # Default ACTION-IF-FOUND: define the preprocessor symbol HAVE_<HEADER-NAME> in
 269 # case of success # (where HEADER-NAME is written LIKE_THIS, e.g.,
 270 # HAVE_BOOST_FOREACH_HPP).
 271 AC_DEFUN([BOOST_FIND_HEADER],
 272 [AC_REQUIRE([BOOST_REQUIRE])dnl
 273 if test x"$boost_cv_inc_path" = xno; then
 274   m4_default([$2], [AC_MSG_NOTICE([Boost not available, not searching for $1])])
 275 else
 276 AC_LANG_PUSH([C++])dnl
 277 boost_save_CPPFLAGS=$CPPFLAGS
 278 CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
 279 AC_CHECK_HEADER([$1],
 280   [m4_default([$3], [AC_DEFINE(AS_TR_CPP([HAVE_$1]), [1],
 281                                [Define to 1 if you have <$1>])])],
 282   [m4_default([$2], [AC_MSG_ERROR([cannot find $1])])])
 283 CPPFLAGS=$boost_save_CPPFLAGS
 284 AC_LANG_POP([C++])dnl
 285 fi
 286 ])# BOOST_FIND_HEADER
 287
 288
 289 # BOOST_FIND_LIBS([COMPONENT-NAME], [CANDIDATE-LIB-NAMES],
 290 #                 [PREFERRED-RT-OPT], [HEADER-NAME], [CXX-TEST],
 291 #                 [CXX-PROLOGUE], [CXX-POST-INCLUDE-PROLOGUE],
 292 #                 [ERROR_ON_UNUSABLE])
 293 # --------------------------------------------------------------
 294 # Look for the Boost library COMPONENT-NAME (e.g., `thread', for
 295 # libboost_thread) under the possible CANDIDATE-LIB-NAMES (e.g.,
 296 # "thread_win32 thread").  Check that HEADER-NAME works and check that
 297 # libboost_LIB-NAME can link with the code CXX-TEST.  The optional
 298 # argument CXX-PROLOGUE can be used to include some C++ code before
 299 # the `main' function. The CXX-POST-INCLUDE-PROLOGUE can be used to
 300 # include some code before the `main' function, but after the
 301 # `#include <HEADER-NAME>'.
 302 #
 303 # Invokes BOOST_FIND_HEADER([HEADER-NAME]) (see above).
 304 #
 305 # Boost libraries typically come compiled with several flavors (with different
 306 # runtime options) so PREFERRED-RT-OPT is the preferred suffix.  A suffix is one
 307 # or more of the following letters: sgdpn (in that order).  s = static
 308 # runtime, d = debug build, g = debug/diagnostic runtime, p = STLPort build,
 309 # n = (unsure) STLPort build without iostreams from STLPort (it looks like `n'
 310 # must always be used along with `p').  Additionally, PREFERRED-RT-OPT can
 311 # start with `mt-' to indicate that there is a preference for multi-thread
 312 # builds.  Some sample values for PREFERRED-RT-OPT: (nothing), mt, d, mt-d, gdp
 313 # ...  If you want to make sure you have a specific version of Boost
 314 # (eg, >= 1.33) you *must* invoke BOOST_REQUIRE before this macro.
 315 #
 316 # ERROR_ON_UNUSABLE can be set to "no" if the caller does not want their
 317 # configure to fail
 318 AC_DEFUN([BOOST_FIND_LIBS],
 319 [AC_REQUIRE([BOOST_REQUIRE])dnl
 320 AC_REQUIRE([_BOOST_FIND_COMPILER_TAG])dnl
 321 AC_REQUIRE([BOOST_STATIC])dnl
 322 AC_REQUIRE([_BOOST_GUESS_WHETHER_TO_USE_MT])dnl
 323 if test x"$boost_cv_inc_path" = xno; then
 324   AC_MSG_NOTICE([Boost not available, not searching for the Boost $1 library])
 325 else
 326 dnl The else branch is huge and wasn't indented on purpose.
 327 AC_LANG_PUSH([C++])dnl
 328 AS_VAR_PUSHDEF([Boost_lib], [boost_cv_lib_$1])dnl
 329 AS_VAR_PUSHDEF([Boost_lib_LDFLAGS], [boost_cv_lib_$1_LDFLAGS])dnl
 330 AS_VAR_PUSHDEF([Boost_lib_LDPATH], [boost_cv_lib_$1_LDPATH])dnl
 331 AS_VAR_PUSHDEF([Boost_lib_LIBS], [boost_cv_lib_$1_LIBS])dnl
 332 AS_IF([test x"$8" = "xno"], [not_found_header='true'])
 333 BOOST_FIND_HEADER([$4], [$not_found_header])
 334 boost_save_CPPFLAGS=$CPPFLAGS
 335 CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
 336 AC_CACHE_CHECK([for the Boost $1 library], [Boost_lib],
 337                [_BOOST_FIND_LIBS($@)])
 338 case $Boost_lib in #(
 339   (yes) _AC_MSG_LOG_CONFTEST
 340     AC_DEFINE(AS_TR_CPP([HAVE_BOOST_$1]), [1], [Defined if the Boost $1 library is available])dnl
 341     AC_SUBST(AS_TR_CPP([BOOST_$1_LDFLAGS]), [$Boost_lib_LDFLAGS])dnl
 342     AC_SUBST(AS_TR_CPP([BOOST_$1_LDPATH]), [$Boost_lib_LDPATH])dnl
 343     AC_SUBST([BOOST_LDPATH], [$Boost_lib_LDPATH])dnl
 344     AC_SUBST(AS_TR_CPP([BOOST_$1_LIBS]), [$Boost_lib_LIBS])dnl
 345     ;;
 346   (no) _AC_MSG_LOG_CONFTEST
 347     AS_IF([test x"$8" != "xno"], [
 348       AC_MSG_ERROR([cannot find flags to link with the Boost $1 library (libboost-$1)])
 349     ])
 350     ;;
 351 esac
 352 CPPFLAGS=$boost_save_CPPFLAGS
 353 AS_VAR_POPDEF([Boost_lib])dnl
 354 AS_VAR_POPDEF([Boost_lib_LDFLAGS])dnl
 355 AS_VAR_POPDEF([Boost_lib_LDPATH])dnl
 356 AS_VAR_POPDEF([Boost_lib_LIBS])dnl
 357 AC_LANG_POP([C++])dnl
 358 fi
 359 ])
 360
 361
 362 # BOOST_FIND_LIB([LIB-NAME],
 363 #                [PREFERRED-RT-OPT], [HEADER-NAME], [CXX-TEST],
 364 #                [CXX-PROLOGUE], [CXX-POST-INCLUDE-PROLOGUE],
 365 #                [ERROR_ON_UNUSABLE])
 366 # --------------------------------------------------------------
 367 # Backward compatibility wrapper for BOOST_FIND_LIBS.
 368 # ERROR_ON_UNUSABLE can be set to "no" if the caller does not want their
 369 # configure to fail
 370 AC_DEFUN([BOOST_FIND_LIB],
 371 [BOOST_FIND_LIBS([$1], $@)])
 372
 373
 374 # _BOOST_FIND_LIBS([LIB-NAME], [CANDIDATE-LIB-NAMES],
 375 #                 [PREFERRED-RT-OPT], [HEADER-NAME], [CXX-TEST],
 376 #                 [CXX-PROLOGUE], [CXX-POST-INCLUDE-PROLOGUE],
 377 #                 [ERROR_ON_UNUSABLE])
 378 # --------------------------------------------------------------
 379 # Real implementation of BOOST_FIND_LIBS: rely on these local macros:
 380 # Boost_lib, Boost_lib_LDFLAGS, Boost_lib_LDPATH, Boost_lib_LIBS
 381 #
 382 # The algorithm is as follows: first look for a given library name
 383 # according to the user's PREFERRED-RT-OPT.  For each library name, we
 384 # prefer to use the ones that carry the tag (toolset name).  Each
 385 # library is searched through the various standard paths were Boost is
 386 # usually installed.  If we can't find the standard variants, we try
 387 # to enforce -mt (for instance on MacOSX, libboost_thread.dylib
 388 # doesn't exist but there's -obviously- libboost_thread-mt.dylib).
 389 #
 390 # ERROR_ON_UNUSABLE can be set to "no" if the caller does not want their
 391 # configure to fail
 392 AC_DEFUN([_BOOST_FIND_LIBS],
 393 [Boost_lib=no
 394   case "$3" in #(
 395     (mt | mt-) boost_mt=-mt; boost_rtopt=;; #(
 396     (mt* | mt-*) boost_mt=-mt; boost_rtopt=`expr "X$3" : 'Xmt-*\(.*\)'`;; #(
 397     (*) boost_mt=; boost_rtopt=$3;;
 398   esac
 399   if test $enable_static_boost = yes; then
 400     boost_rtopt="s$boost_rtopt"
 401   fi
 402   # Find the proper debug variant depending on what we've been asked to find.
 403   case $boost_rtopt in #(
 404     (*d*) boost_rt_d=$boost_rtopt;; #(
 405     (*[[sgpn]]*) # Insert the `d' at the right place (in between `sg' and `pn')
 406       boost_rt_d=`echo "$boost_rtopt" | sed 's/\(s*g*\)\(p*n*\)/\1\2/'`;; #(
 407     (*) boost_rt_d='-d';;
 408   esac
 409   # If the PREFERRED-RT-OPT are not empty, prepend a `-'.
 410   test -n "$boost_rtopt" && boost_rtopt="-$boost_rtopt"
 411   $boost_guess_use_mt && boost_mt=-mt
 412   # Look for the abs path the static archive.
 413   # $libext is computed by Libtool but let's make sure it's non empty.
 414   test -z "$libext" &&
 415     AC_MSG_ERROR([the libext variable is empty, did you invoke Libtool?])
 416   boost_save_ac_objext=$ac_objext
 417   # Generate the test file.
 418   AC_LANG_CONFTEST([AC_LANG_PROGRAM([$7
 419 #include <$4>
 420 $6], [$5])])
 421 dnl Optimization hacks: compiling C++ is slow, especially with Boost.  What
 422 dnl we're trying to do here is guess the right combination of link flags
 423 dnl (LIBS / LDFLAGS) to use a given library.  This can take several
 424 dnl iterations before it succeeds and is thus *very* slow.  So what we do
 425 dnl instead is that we compile the code first (and thus get an object file,
 426 dnl typically conftest.o).  Then we try various combinations of link flags
 427 dnl until we succeed to link conftest.o in an executable.  The problem is
 428 dnl that the various TRY_LINK / COMPILE_IFELSE macros of Autoconf always
 429 dnl remove all the temporary files including conftest.o.  So the trick here
 430 dnl is to temporarily change the value of ac_objext so that conftest.o is
 431 dnl preserved accross tests.  This is obviously fragile and I will burn in
 432 dnl hell for not respecting Autoconf's documented interfaces, but in the
 433 dnl mean time, it optimizes the macro by a factor of 5 to 30.
 434 dnl Another small optimization: the first argument of AC_COMPILE_IFELSE left
 435 dnl empty because the test file is generated only once above (before we
 436 dnl start the for loops).
 437   AC_COMPILE_IFELSE([],
 438     [ac_objext=do_not_rm_me_plz],
 439     [AS_IF([test x"$8" != x"no"], [
 440        AC_MSG_ERROR([cannot compile a test that uses Boost $1])
 441      ])
 442     ])
 443   ac_objext=$boost_save_ac_objext
 444   boost_failed_libs=
 445 # Don't bother to ident the following nested for loops, only the 2
 446 # innermost ones matter.
 447 for boost_lib_ in $2; do
 448 for boost_tag_ in -$boost_cv_lib_tag ''; do
 449 for boost_ver_ in -$boost_cv_lib_version ''; do
 450 for boost_mt_ in $boost_mt -mt ''; do
 451 for boost_rtopt_ in $boost_rtopt '' -d; do
 452   for boost_full_suffix in \
 453     $boost_last_suffix \
 454     x$boost_tag_$boost_mt_$boost_rtopt_$boost_ver_ \
 455     x$boost_tag_$boost_rtopt_$boost_ver_ \
 456     x$boost_tag_$boost_mt_$boost_ver_ \
 457     x$boost_tag_$boost_ver_
 458   do
 459     boost_real_suffix=`echo "$boost_full_suffix" | sed 's/^x//'`
 460     boost_lib="boost_$boost_lib_$boost_real_suffix"
 461     # Avoid testing twice the same lib
 462     case $boost_failed_libs in #(
 463       (*@$boost_lib@*) continue;;
 464     esac
 465     # If with_boost is empty, we'll search in /lib first, which is not quite
 466     # right so instead we'll try to a location based on where the headers are.
 467     boost_tmp_lib=$with_boost
 468     test x"$with_boost" = x && boost_tmp_lib=${boost_cv_inc_path%/include}
 469     for boost_ldpath in "$boost_tmp_lib/lib" '' \
 470              /opt/local/lib* /usr/local/lib* /opt/lib* /usr/lib* \
 471              "$with_boost" C:/Boost/lib /lib*
 472     do
 473       # Don't waste time with directories that don't exist.
 474       if test x"$boost_ldpath" != x && test ! -e "$boost_ldpath"; then
 475         continue
 476       fi
 477       boost_save_LDFLAGS=$LDFLAGS
 478       # Are we looking for a static library?
 479       case $boost_ldpath:$boost_rtopt_ in #(
 480         (*?*:*s*) # Yes (Non empty boost_ldpath + s in rt opt)
 481           Boost_lib_LIBS="$boost_ldpath/lib$boost_lib.$libext"
 482           test -e "$Boost_lib_LIBS" || continue;; #(
 483         (*) # No: use -lboost_foo to find the shared library.
 484           Boost_lib_LIBS="-l$boost_lib";;
 485       esac
 486       boost_save_LIBS=$LIBS
 487       LIBS="$Boost_lib_LIBS $LIBS"
 488       test x"$boost_ldpath" != x && LDFLAGS="$LDFLAGS -L$boost_ldpath"
 489 dnl First argument of AC_LINK_IFELSE left empty because the test file is
 490 dnl generated only once above (before we start the for loops).
 491       _BOOST_AC_LINK_IFELSE([],
 492                             [Boost_lib=yes], [Boost_lib=no])
 493       ac_objext=$boost_save_ac_objext
 494       LDFLAGS=$boost_save_LDFLAGS
 495       LIBS=$boost_save_LIBS
 496       if test x"$Boost_lib" = xyes; then
 497         # Check or used cached result of whether or not using -R or
 498         # -rpath makes sense.  Some implementations of ld, such as for
 499         # Mac OSX, require -rpath but -R is the flag known to work on
 500         # other systems.  https://github.com/tsuna/boost.m4/issues/19
 501         AC_CACHE_VAL([boost_cv_rpath_link_ldflag],
 502           [case $boost_ldpath in
 503            '') # Nothing to do.
 504              boost_cv_rpath_link_ldflag=
 505              boost_rpath_link_ldflag_found=yes;;
 506            *)
 507             for boost_cv_rpath_link_ldflag in -Wl,-R, -Wl,-rpath,; do
 508               LDFLAGS="$boost_save_LDFLAGS -L$boost_ldpath $boost_cv_rpath_link_ldflag$boost_ldpath"
 509               LIBS="$Boost_lib_LIBS $boost_save_LIBS"
 510               _BOOST_AC_LINK_IFELSE([],
 511                 [boost_rpath_link_ldflag_found=yes
 512                 break],
 513                 [boost_rpath_link_ldflag_found=no])
 514             done
 515             ;;
 516           esac
 517           AS_IF([test "x$boost_rpath_link_ldflag_found" != "xyes"],
 518             [AC_MSG_ERROR([Unable to determine whether to use -R or -rpath])])
 519           LDFLAGS=$boost_save_LDFLAGS
 520           LIBS=$boost_save_LIBS
 521           ])
 522         test x"$boost_ldpath" != x &&
 523           Boost_lib_LDFLAGS="-L$boost_ldpath $boost_cv_rpath_link_ldflag$boost_ldpath"
 524         Boost_lib_LDPATH="$boost_ldpath"
 525         boost_last_suffix="$boost_full_suffix"
 526         break 7
 527       else
 528         boost_failed_libs="$boost_failed_libs@$boost_lib@"
 529       fi
 530     done
 531   done
 532 done
 533 done
 534 done
 535 done
 536 done # boost_lib_
 537 rm -f conftest.$ac_objext
 538 ])
 539
 540
 541
 542 # --------------------------------------- #
 543 # Checks for the various Boost libraries. #
 544 # --------------------------------------- #
 545
 546 # List of boost libraries: http://www.boost.org/libs/libraries.htm
 547 # The page http://beta.boost.org/doc/libs is useful: it gives the first release
 548 # version of each library (among other things).
 549
 550 # BOOST_DEFUN(LIBRARY, CODE)
 551 # --------------------------
 552 # Define BOOST_<LIBRARY-UPPERCASE> as a macro that runs CODE.
 553 #
 554 # Use indir to avoid the warning on underquoted macro name given to AC_DEFUN.
 555 m4_define([BOOST_DEFUN],
 556 [m4_indir([AC_DEFUN],
 557           m4_toupper([BOOST_$1]),
 558 [m4_pushdef([BOOST_Library], [$1])dnl
 559 $2
 560 m4_popdef([BOOST_Library])dnl
 561 ])
 562 ])
 563
 564
 565 # BOOST_ANY()
 566 # ------------
 567 # Look for Boost.Any
 568 BOOST_DEFUN([Any],
 569 [BOOST_FIND_HEADER([boost/any.hpp])])
 570
 571
 572 # BOOST_ARRAY()
 573 # -------------
 574 # Look for Boost.Array
 575 BOOST_DEFUN([Array],
 576 [BOOST_FIND_HEADER([boost/array.hpp])])
 577
 578
 579 # BOOST_ASIO()
 580 # ------------
 581 # Look for Boost.Asio (new in Boost 1.35).
 582 BOOST_DEFUN([Asio],
 583 [AC_REQUIRE([BOOST_SYSTEM])dnl
 584 BOOST_FIND_HEADER([boost/asio.hpp])])
 585
 586 # BOOST_BIMAP()
 587 # ------------
 588 # Look for Boost.Bimap
 589 BOOST_DEFUN([Bimap],
 590 [BOOST_FIND_HEADER([boost/bimap.hpp])])
 591
 592
 593 # BOOST_ASSIGN()
 594 # -------------
 595 # Look for Boost.Assign
 596 BOOST_DEFUN([Assign],
 597 [BOOST_FIND_HEADER([boost/assign.hpp])])
 598
 599
 600 # BOOST_ATOMIC([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
 601 # -------------------------------
 602 # Look for Boost.Atomic.  For the documentation of PREFERRED-RT-OPT, see the
 603 # documentation of BOOST_FIND_LIB above.
 604 BOOST_DEFUN([Atomic],
 605 [BOOST_FIND_LIB([atomic], [$1],
 606                 [boost/atomic.hpp],
 607                 [boost::atomic<int> a;],
 608                 [ ],
 609                 [#ifdef HAVE_UNISTD_H
 610 #include <unistd.h>
 611 #endif
 612 #ifdef HAVE_STDINT_H
 613 #include <stdint.h>
 614 #endif], [$2])
 615 ])# BOOST_ATOMIC
 616
 617
 618 # BOOST_BIND()
 619 # ------------
 620 # Look for Boost.Bind.
 621 BOOST_DEFUN([Bind],
 622 [BOOST_FIND_HEADER([boost/bind.hpp])])
 623
 624
 625 # BOOST_CAST()
 626 # ------------
 627 # Look for Boost.Cast
 628 BOOST_DEFUN([Cast],
 629 [BOOST_FIND_HEADER([boost/cast.hpp])])
 630
 631
 632 # BOOST_CHRONO([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
 633 # --------------
 634 # Look for Boost.Chrono.
 635 BOOST_DEFUN([Chrono],
 636 [# Do we have to check for Boost.System?  This link-time dependency was
 637 # added as of 1.35.0.  If we have a version <1.35, we must not attempt to
 638 # find Boost.System as it didn't exist by then.
 639 if test $boost_major_version -ge 135; then
 640   BOOST_SYSTEM([$1], [$2])
 641 fi # end of the Boost.System check.
 642 boost_filesystem_save_LIBS=$LIBS
 643 boost_filesystem_save_LDFLAGS=$LDFLAGS
 644 m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
 645 LIBS="$LIBS $BOOST_SYSTEM_LIBS"
 646 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
 647 BOOST_FIND_LIB([chrono], [$1],
 648                 [boost/chrono.hpp],
 649                 [boost::chrono::thread_clock d;], [], [], [$2])
 650 if test $enable_static_boost = yes && test $boost_major_version -ge 135; then
 651   BOOST_CHRONO_LIBS="$BOOST_CHRONO_LIBS $BOOST_SYSTEM_LIBS"
 652 fi
 653 LIBS=$boost_filesystem_save_LIBS
 654 LDFLAGS=$boost_filesystem_save_LDFLAGS
 655 ])# BOOST_CHRONO
 656
 657
 658 # BOOST_CONTEXT([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
 659 # -----------------------------------
 660 # Look for Boost.Context.  For the documentation of PREFERRED-RT-OPT, see the
 661 # documentation of BOOST_FIND_LIB above.
 662 #
 663 # * This library was introduced in Boost 1.51.0
 664 # * The signatures of make_fcontext() and jump_fcontext were changed in 1.56.0
 665 # * A dependency on boost_thread appears in 1.57.0
 666 # * The implementation details were moved to boost::context::detail in 1.61.0
 667 BOOST_DEFUN([Context],
 668 [boost_context_save_LIBS=$LIBS
 669  boost_context_save_LDFLAGS=$LDFLAGS
 670 if test $boost_major_version -ge 157; then
 671   BOOST_THREAD([$1], [$2])
 672   m4_pattern_allow([^BOOST_THREAD_(LIBS|LDFLAGS)$])dnl
 673   LIBS="$LIBS $BOOST_THREAD_LIBS"
 674   LDFLAGS="$LDFLAGS $BOOST_THREAD_LDFLAGS"
 675 fi
 676
 677 if test $boost_major_version -ge 161; then
 678 BOOST_FIND_LIB([context], [$1],
 679                 [boost/context/continuation.hpp], [[
 680 namespace ctx=boost::context;
 681 int a;
 682 ctx::continuation source=ctx::callcc(
 683     [&a](ctx::continuation && sink){
 684         a=0;
 685         int b=1;
 686         for(;;){
 687             sink=sink.resume();
 688             int next=a+b;
 689             a=b;
 690             b=next;
 691         }
 692         return std::move(sink);
 693     });
 694 for (int j=0;j<10;++j) {
 695     source=source.resume();
 696 }
 697 return a == 34;
 698 ]], [], [], [$2])
 699
 700 else
 701
 702 BOOST_FIND_LIB([context], [$1],
 703                 [boost/context/fcontext.hpp],[[
 704
 705 // creates a stack
 706 void * stack_pointer = new void*[4096];
 707 std::size_t const size = sizeof(void*[4096]);
 708
 709 #if BOOST_VERSION <= 105100
 710 ctx::make_fcontext(&fc, f);
 711 return ctx::jump_fcontext(&fcm, &fc, 3) == 6;
 712
 713 #else
 714
 715 fc = ctx::make_fcontext(stack_pointer, size, f);
 716 return ctx::jump_fcontext(&fcm, fc, 3) == 6;
 717
 718 #endif
 719
 720
 721 ]],[dnl
 722
 723 #include <boost/version.hpp>
 724 #if BOOST_VERSION <= 105100
 725
 726 namespace ctx = boost::ctx;
 727
 728 static ctx::fcontext_t fcm, fc;
 729
 730 static void f(intptr_t i) {
 731     ctx::jump_fcontext(&fc, &fcm, i * 2);
 732 }
 733
 734 #elif BOOST_VERSION <= 105500
 735
 736 namespace ctx = boost::context;
 737
 738 // context
 739 static ctx::fcontext_t fcm, *fc;
 740
 741 // context-function
 742 static void f(intptr_t i) {
 743     ctx::jump_fcontext(fc, &fcm, i * 2);
 744 }
 745
 746 #else
 747
 748 namespace ctx = boost::context;
 749
 750 // context
 751 static ctx::fcontext_t fcm, fc;
 752
 753 // context-function
 754 static void f(intptr_t i) {
 755     ctx::jump_fcontext(&fc, fcm, i * 2);
 756 }
 757 #endif
 758 ], [], [], [$2])
 759
 760 fi
 761
 762 LIBS=$boost_context_save_LIBS
 763 LDFLAGS=$boost_context_save_LDFLAGS
 764 ])# BOOST_CONTEXT
 765
 766
 767 # BOOST_CONVERSION()
 768 # ------------------
 769 # Look for Boost.Conversion (cast / lexical_cast)
 770 BOOST_DEFUN([Conversion],
 771 [BOOST_FIND_HEADER([boost/cast.hpp])
 772 BOOST_FIND_HEADER([boost/lexical_cast.hpp])
 773 ])# BOOST_CONVERSION
 774
 775
 776 # BOOST_COROUTINE([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
 777 # -----------------------------------
 778 # Look for Boost.Coroutine.  For the documentation of PREFERRED-RT-OPT, see the
 779 # documentation of BOOST_FIND_LIB above.  This library was introduced in Boost
 780 # 1.53.0
 781 BOOST_DEFUN([Coroutine],
 782 [
 783 boost_coroutine_save_LIBS=$LIBS
 784 boost_coroutine_save_LDFLAGS=$LDFLAGS
 785 # Link-time dependency from coroutine to context
 786 BOOST_CONTEXT([$1], [$2])
 787 # Starting from Boost 1.55 a dependency on Boost.System is added
 788 if test $boost_major_version -ge 155; then
 789   BOOST_SYSTEM([$1], [$2])
 790 fi
 791 m4_pattern_allow([^BOOST_(CONTEXT|SYSTEM)_(LIBS|LDFLAGS)])
 792 LIBS="$LIBS $BOOST_CONTEXT_LIBS $BOOST_SYSTEM_LIBS"
 793 LDFLAGS="$LDFLAGS $BOOST_CONTEXT_LDFLAGS"
 794
 795 # in 1.53 coroutine was a header only library
 796 if test $boost_major_version -eq 153; then
 797   AS_IF([test x"$2" = "xno"], [not_found_header='true'])
 798   BOOST_FIND_HEADER([boost/coroutine/coroutine.hpp], [$not_found_header])
 799 else
 800   BOOST_FIND_LIB([coroutine], [$1],
 801                   [boost/coroutine/coroutine.hpp],
 802                   [
 803   #include <boost/version.hpp>
 804   #if   BOOST_VERSION <= 105500
 805   boost::coroutines::coroutine<int(int)> coro; coro.get();
 806   #else
 807   boost::coroutines::asymmetric_coroutine<int>::pull_type coro; coro.get();
 808   #endif
 809   ], [], [], [$2])
 810 fi
 811 # Link-time dependency from coroutine to context, existed only in 1.53, in 1.54
 812 # coroutine doesn't use context from its headers but from its library.
 813 if test $boost_major_version -eq 153 || test $enable_static_boost = yes && test $boost_major_version -ge 154; then
 814   BOOST_COROUTINE_LIBS="$BOOST_COROUTINE_LIBS $BOOST_CONTEXT_LIBS"
 815   BOOST_COROUTINE_LDFLAGS="$BOOST_COROUTINE_LDFLAGS $BOOST_CONTEXT_LDFLAGS"
 816 fi
 817 if test $enable_static_boost = yes && test $boost_major_version -ge 155; then
 818   BOOST_COROUTINE_LIBS="$BOOST_COROUTINE_LIBS $BOOST_SYSTEM_LIBS"
 819   BOOST_COROUTINE_LDFLAGS="$BOOST_COROUTINE_LDFLAGS $BOOST_SYSTEM_LDFLAGS"
 820 fi
 821 LIBS=$boost_coroutine_save_LIBS
 822 LDFLAGS=$boost_coroutine_save_LDFLAGS
 823 ])# BOOST_COROUTINE
 824
 825
 826 # BOOST_CRC()
 827 # -----------
 828 # Look for Boost.CRC
 829 BOOST_DEFUN([CRC],
 830 [BOOST_FIND_HEADER([boost/crc.hpp])
 831 ])# BOOST_CRC
 832
 833
 834 # BOOST_DATE_TIME([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
 835 # -----------------------------------
 836 # Look for Boost.Date_Time.  For the documentation of PREFERRED-RT-OPT, see the
 837 # documentation of BOOST_FIND_LIB above.
 838 BOOST_DEFUN([Date_Time],
 839 [BOOST_FIND_LIB([date_time], [$1],
 840                 [boost/date_time/posix_time/posix_time.hpp],
 841                 [boost::posix_time::ptime t;], [], [], [$2])
 842 ])# BOOST_DATE_TIME
 843
 844
 845 # BOOST_EXCEPTION()
 846 # ------------
 847 # Look for Boost.Exception
 848 BOOST_DEFUN([Exception],
 849 [BOOST_FIND_HEADER([boost/exception/all.hpp])])
 850
 851
 852 # BOOST_FILESYSTEM([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
 853 # ------------------------------------
 854 # Look for Boost.Filesystem.  For the documentation of PREFERRED-RT-OPT, see
 855 # the documentation of BOOST_FIND_LIB above.
 856 # Do not check for boost/filesystem.hpp because this file was introduced in
 857 # 1.34.
 858 BOOST_DEFUN([Filesystem],
 859 [# Do we have to check for Boost.System?  This link-time dependency was
 860 # added as of 1.35.0.  If we have a version <1.35, we must not attempt to
 861 # find Boost.System as it didn't exist by then.
 862 if test $boost_major_version -ge 135; then
 863   BOOST_SYSTEM([$1], [$2])
 864 fi # end of the Boost.System check.
 865 boost_filesystem_save_LIBS=$LIBS
 866 boost_filesystem_save_LDFLAGS=$LDFLAGS
 867 m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
 868 LIBS="$LIBS $BOOST_SYSTEM_LIBS"
 869 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
 870 BOOST_FIND_LIB([filesystem], [$1],
 871                 [boost/filesystem/path.hpp], [boost::filesystem::path p;],
 872                 [], [], [$2])
 873 if test $enable_static_boost = yes && test $boost_major_version -ge 135; then
 874   BOOST_FILESYSTEM_LIBS="$BOOST_FILESYSTEM_LIBS $BOOST_SYSTEM_LIBS"
 875 fi
 876 LIBS=$boost_filesystem_save_LIBS
 877 LDFLAGS=$boost_filesystem_save_LDFLAGS
 878 ])# BOOST_FILESYSTEM
 879
 880
 881 # BOOST_FLYWEIGHT()
 882 # -----------------
 883 # Look for Boost.Flyweight.
 884 BOOST_DEFUN([Flyweight],
 885 [dnl There's a hidden dependency on pthreads.
 886 AC_REQUIRE([_BOOST_PTHREAD_FLAG])dnl
 887 BOOST_FIND_HEADER([boost/flyweight.hpp])
 888 AC_SUBST([BOOST_FLYWEIGHT_LIBS], [$boost_cv_pthread_flag])
 889 ])
 890
 891
 892 # BOOST_FOREACH()
 893 # ---------------
 894 # Look for Boost.Foreach.
 895 BOOST_DEFUN([Foreach],
 896 [BOOST_FIND_HEADER([boost/foreach.hpp])])
 897
 898
 899 # BOOST_FORMAT()
 900 # --------------
 901 # Look for Boost.Format.
 902 # Note: we can't check for boost/format/format_fwd.hpp because the header isn't
 903 # standalone.  It can't be compiled because it triggers the following error:
 904 # boost/format/detail/config_macros.hpp:88: error: 'locale' in namespace 'std'
 905 #                                                  does not name a type
 906 BOOST_DEFUN([Format],
 907 [BOOST_FIND_HEADER([boost/format.hpp])])
 908
 909
 910 # BOOST_FUNCTION()
 911 # ----------------
 912 # Look for Boost.Function
 913 BOOST_DEFUN([Function],
 914 [BOOST_FIND_HEADER([boost/function.hpp])])
 915
 916
 917 # BOOST_FUSION()
 918 # -----------------
 919 # Look for Boost.Fusion
 920 BOOST_DEFUN([Fusion],
 921 [BOOST_FIND_HEADER([boost/fusion/sequence.hpp])])
 922
 923
 924 # BOOST_GEOMETRY()
 925 # ----------------
 926 # Look for Boost.Geometry (new since 1.47.0).
 927 BOOST_DEFUN([Geometry],
 928 [BOOST_FIND_HEADER([boost/geometry.hpp])
 929 ])# BOOST_GEOMETRY
 930
 931
 932 # BOOST_GRAPH([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
 933 # -------------------------------
 934 # Look for Boost.Graphs.  For the documentation of PREFERRED-RT-OPT, see the
 935 # documentation of BOOST_FIND_LIB above.
 936 BOOST_DEFUN([Graph],
 937 [boost_graph_save_LIBS=$LIBS
 938 boost_graph_save_LDFLAGS=$LDFLAGS
 939 # Link-time dependency from graph to regex was added as of 1.40.0.
 940 if test $boost_major_version -ge 140; then
 941   BOOST_REGEX([$1], [$2])
 942   m4_pattern_allow([^BOOST_REGEX_(LIBS|LDFLAGS)$])dnl
 943   LIBS="$LIBS $BOOST_REGEX_LIBS"
 944   LDFLAGS="$LDFLAGS $BOOST_REGEX_LDFLAGS"
 945 fi
 946 BOOST_FIND_LIB([graph], [$1],
 947                 [boost/graph/adjacency_list.hpp], [boost::adjacency_list<> g;],
 948                 [], [], [$2])
 949 LIBS=$boost_graph_save_LIBS
 950 LDFLAGS=$boost_graph_save_LDFLAGS
 951 ])# BOOST_GRAPH
 952
 953
 954 # BOOST_HASH()
 955 # ------------
 956 # Look for Boost.Functional/Hash
 957 BOOST_DEFUN([Hash],
 958 [BOOST_FIND_HEADER([boost/functional/hash.hpp])])
 959
 960
 961 # BOOST_IOSTREAMS([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
 962 # -----------------------------------
 963 # Look for Boost.IOStreams.  For the documentation of PREFERRED-RT-OPT, see the
 964 # documentation of BOOST_FIND_LIB above.
 965 BOOST_DEFUN([IOStreams],
 966 [BOOST_FIND_LIB([iostreams], [$1],
 967                 [boost/iostreams/device/file_descriptor.hpp],
 968                 [boost::iostreams::file_descriptor fd; fd.close();],
 969                 [], [], [$2])
 970 ])# BOOST_IOSTREAMS
 971
 972
 973 # BOOST_ITERATOR()
 974 # ------------
 975 # Look for Boost.Iterator
 976 BOOST_DEFUN([Iterator],
 977 [BOOST_FIND_HEADER([boost/iterator/iterator_adaptor.hpp])])
 978
 979
 980 # BOOST_LAMBDA()
 981 # --------------
 982 # Look for Boost.Lambda
 983 BOOST_DEFUN([Lambda],
 984 [BOOST_FIND_HEADER([boost/lambda/lambda.hpp])])
 985
 986
 987 # BOOST_LOCALE([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
 988 # --------------
 989 # Look for Boost.Locale
 990 BOOST_DEFUN([Locale],
 991 [
 992 boost_locale_save_LIBS=$LIBS
 993 boost_locale_save_LDFLAGS=$LDFLAGS
 994 # require SYSTEM for boost-1.50.0 and up
 995 if test $boost_major_version -ge 150; then
 996   BOOST_SYSTEM([$1], [$2])
 997   m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
 998   LIBS="$LIBS $BOOST_SYSTEM_LIBS"
 999   LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
1000 fi # end of the Boost.System check.
1001 BOOST_FIND_LIB([locale], [$1],
1002     [boost/locale.hpp],
1003     [[boost::locale::generator gen; std::locale::global(gen(""));]], [], [], [$2])
1004 LIBS=$boost_locale_save_LIBS
1005 LDFLAGS=$boost_locale_save_LDFLAGS
1006 ])# BOOST_LOCALE
1007
1008 # BOOST_LOG([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1009 # -----------------------------
1010 # Look for Boost.Log.  For the documentation of PREFERRED-RT-OPT, see the
1011 # documentation of BOOST_FIND_LIB above.
1012 BOOST_DEFUN([Log],
1013 [boost_log_save_LIBS=$LIBS
1014 boost_log_save_LDFLAGS=$LDFLAGS
1015 BOOST_SYSTEM([$1], [$2])
1016 BOOST_FILESYSTEM([$1], [$2])
1017 BOOST_DATE_TIME([$1], [$2])
1018 m4_pattern_allow([^BOOST_(SYSTEM|FILESYSTEM|DATE_TIME)_(LIBS|LDFLAGS)$])dnl
1019 LIBS="$LIBS $BOOST_DATE_TIME_LIBS $BOOST_FILESYSTEM_LIBS $BOOST_SYSTEM_LIBS"
1020 LDFLAGS="$LDFLAGS $BOOST_DATE_TIME_LDFLAGS $BOOST_FILESYSTEM_LDFLAGS $BOOST_SYSTEM_LDFLAGS"
1021 BOOST_FIND_LIB([log], [$1],
1022     [boost/log/core/core.hpp],
1023     [boost::log::attribute a; a.get_value();], [], [], [$2])
1024 LIBS=$boost_log_save_LIBS
1025 LDFLAGS=$boost_log_save_LDFLAGS
1026 ])# BOOST_LOG
1027
1028
1029 # BOOST_LOG_SETUP([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1030 # -----------------------------------
1031 # Look for Boost.Log.  For the documentation of PREFERRED-RT-OPT, see the
1032 # documentation of BOOST_FIND_LIB above.
1033 BOOST_DEFUN([Log_Setup],
1034 [boost_log_setup_save_LIBS=$LIBS
1035 boost_log_setup_save_LDFLAGS=$LDFLAGS
1036 BOOST_LOG([$1])
1037 m4_pattern_allow([^BOOST_LOG_(LIBS|LDFLAGS)$])dnl
1038 LIBS="$LIBS $BOOST_LOG_LIBS"
1039 LDFLAGS="$LDFLAGS $BOOST_LOG_LDFLAGS"
1040 BOOST_FIND_LIB([log_setup], [$1],
1041     [boost/log/utility/setup/from_settings.hpp],
1042     [boost::log::basic_settings<char> bs; bs.empty();], [], [], [$2])
1043 LIBS=$boost_log_setup_save_LIBS
1044 LDFLAGS=$boost_log_setup_save_LDFLAGS
1045 ])# BOOST_LOG_SETUP
1046
1047
1048 # BOOST_MATH()
1049 # ------------
1050 # Look for Boost.Math
1051 # TODO: This library isn't header-only but it comes in multiple different
1052 # flavors that don't play well with BOOST_FIND_LIB (e.g, libboost_math_c99,
1053 # libboost_math_c99f, libboost_math_c99l, libboost_math_tr1,
1054 # libboost_math_tr1f, libboost_math_tr1l).  This macro must be fixed to do the
1055 # right thing anyway.
1056 BOOST_DEFUN([Math],
1057 [BOOST_FIND_HEADER([boost/math/special_functions.hpp])])
1058
1059
1060 # BOOST_MPI([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1061 # -------------------------------
1062 # Look for Boost MPI.  For the documentation of PREFERRED-RT-OPT, see the
1063 # documentation of BOOST_FIND_LIB above.  Uses MPICXX variable if it is
1064 # set, otherwise tries CXX
1065 #
1066 BOOST_DEFUN([MPI],
1067 [boost_save_CXX=${CXX}
1068 boost_save_CXXCPP=${CXXCPP}
1069 if test x"${MPICXX}" != x; then
1070   CXX=${MPICXX}
1071   CXXCPP="${MPICXX} -E"
1072 fi
1073 BOOST_FIND_LIB([mpi], [$1],
1074                [boost/mpi.hpp],
1075                [int argc = 0;
1076                 char **argv = 0;
1077                 boost::mpi::environment env(argc,argv);],
1078                [], [], [$2])
1079 CXX=${boost_save_CXX}
1080 CXXCPP=${boost_save_CXXCPP}
1081 ])# BOOST_MPI
1082
1083
1084 # BOOST_MPL()
1085 # ------------------
1086 # Look for Boost.MPL
1087 BOOST_DEFUN([MPL],
1088 [BOOST_FIND_HEADER([boost/mpl/for_each.hpp])])
1089
1090
1091 # BOOST_MULTIARRAY()
1092 # ------------------
1093 # Look for Boost.MultiArray
1094 BOOST_DEFUN([MultiArray],
1095 [BOOST_FIND_HEADER([boost/multi_array.hpp])])
1096
1097
1098 # BOOST_MULTIINDEXCCONTAINER()
1099 # ------------------
1100 # Look for Boost.MultiIndexContainer
1101 BOOST_DEFUN([MultiIndexContainer],
1102 [BOOST_FIND_HEADER([boost/multi_index_container.hpp])])
1103
1104
1105 # BOOST_NUMERIC_UBLAS()
1106 # --------------------------
1107 # Look for Boost.NumericUblas (Basic Linear Algebra)
1108 BOOST_DEFUN([Numeric_Ublas],
1109 [BOOST_FIND_HEADER([boost/numeric/ublas/vector.hpp])
1110 ])# BOOST_NUMERIC_UBLAS
1111
1112
1113 # BOOST_NUMERIC_CONVERSION()
1114 # --------------------------
1115 # Look for Boost.NumericConversion (policy-based numeric conversion)
1116 BOOST_DEFUN([Numeric_Conversion],
1117 [BOOST_FIND_HEADER([boost/numeric/conversion/converter.hpp])
1118 ])# BOOST_NUMERIC_CONVERSION
1119
1120
1121 # BOOST_OPTIONAL()
1122 # ----------------
1123 # Look for Boost.Optional
1124 BOOST_DEFUN([Optional],
1125 [BOOST_FIND_HEADER([boost/optional.hpp])])
1126
1127
1128 # BOOST_PREPROCESSOR()
1129 # --------------------
1130 # Look for Boost.Preprocessor
1131 BOOST_DEFUN([Preprocessor],
1132 [BOOST_FIND_HEADER([boost/preprocessor/repeat.hpp])])
1133
1134
1135 # BOOST_PROPERTY_TREE([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1136 # -----------------------------------------
1137 # Look for Boost.Property_Tree.  For the documentation of PREFERRED-RT-OPT,
1138 # see the documentation of BOOST_FIND_LIB above.
1139 BOOST_DEFUN([Property_Tree],
1140 [BOOST_FIND_LIB([property_tree], [$1],
1141                 [boost/property_tree/ptree.hpp],
1142                 [boost::property_tree::ptree pt; boost::property_tree::read_xml d("test", pt);],
1143                 [], [], [$2])
1144 ])# BOOST_PROPERTY_TREE
1145
1146
1147 # BOOST_RANDOM()
1148 # --------------------
1149 # Look for Boost.Random
1150 BOOST_DEFUN([Random],
1151 [BOOST_FIND_HEADER([boost/random/random_number_generator.hpp])])
1152
1153
1154 # BOOST_RANGE()
1155 # --------------------
1156 # Look for Boost.Range
1157 BOOST_DEFUN([Range],
1158 [BOOST_FIND_HEADER([boost/range/adaptors.hpp])])
1159
1160 # BOOST_UNORDERED()
1161 # -----------------
1162 # Look for Boost.Unordered
1163 BOOST_DEFUN([Unordered],
1164 [BOOST_FIND_HEADER([boost/unordered_map.hpp])])
1165
1166
1167 # BOOST_UUID()
1168 # ------------
1169 # Look for Boost.Uuid
1170 BOOST_DEFUN([Uuid],
1171 [BOOST_FIND_HEADER([boost/uuid/uuid.hpp])])
1172
1173
1174 # BOOST_PROGRAM_OPTIONS([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1175 # -----------------------------------------
1176 # Look for Boost.Program_options.  For the documentation of PREFERRED-RT-OPT,
1177 # see the documentation of BOOST_FIND_LIB above.
1178 BOOST_DEFUN([Program_Options],
1179 [BOOST_FIND_LIB([program_options], [$1],
1180                 [boost/program_options.hpp],
1181                 [boost::program_options::options_description d("test");],
1182                 [], [], [$2])
1183 ])# BOOST_PROGRAM_OPTIONS
1184
1185
1186
1187 # _BOOST_PYTHON_CONFIG(VARIABLE, FLAG)
1188 # ------------------------------------
1189 # Save VARIABLE, and define it via `python-config --FLAG`.
1190 # Substitute BOOST_PYTHON_VARIABLE.
1191 m4_define([_BOOST_PYTHON_CONFIG],
1192 [AC_SUBST([BOOST_PYTHON_$1],
1193           [`python-config --$2 2>/dev/null`])dnl
1194 boost_python_save_$1=$$1
1195 $1="$$1 $BOOST_PYTHON_$1"])
1196
1197
1198 # BOOST_PYTHON([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1199 # --------------------------------
1200 # Look for Boost.Python.  For the documentation of PREFERRED-RT-OPT,
1201 # see the documentation of BOOST_FIND_LIB above.
1202 BOOST_DEFUN([Python],
1203 [_BOOST_PYTHON_CONFIG([CPPFLAGS], [includes])
1204 _BOOST_PYTHON_CONFIG([LDFLAGS],   [ldflags])
1205 _BOOST_PYTHON_CONFIG([LIBS],      [libs])
1206 m4_pattern_allow([^BOOST_PYTHON_MODULE$])dnl
1207 BOOST_FIND_LIBS([python], [python python3], [$1],
1208                 [boost/python.hpp],
1209                 [], [BOOST_PYTHON_MODULE(empty) {}], [], [$2])
1210 CPPFLAGS=$boost_python_save_CPPFLAGS
1211 LDFLAGS=$boost_python_save_LDFLAGS
1212 LIBS=$boost_python_save_LIBS
1213 ])# BOOST_PYTHON
1214
1215
1216 # BOOST_REF()
1217 # -----------
1218 # Look for Boost.Ref
1219 BOOST_DEFUN([Ref],
1220 [BOOST_FIND_HEADER([boost/ref.hpp])])
1221
1222
1223 # BOOST_REGEX([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1224 # -------------------------------
1225 # Look for Boost.Regex.  For the documentation of PREFERRED-RT-OPT, see the
1226 # documentation of BOOST_FIND_LIB above.
1227 BOOST_DEFUN([Regex],
1228 [BOOST_FIND_LIB([regex], [$1],
1229                 [boost/regex.hpp],
1230                 [boost::regex exp("*"); boost::regex_match("foo", exp);],
1231                 [], [], [$2])
1232 ])# BOOST_REGEX
1233
1234
1235 # BOOST_SCOPE_EXIT()
1236 # ------------
1237 # Look for Boost.ScopeExit.
1238 BOOST_DEFUN([SCOPE_EXIT],
1239 [BOOST_FIND_HEADER([boost/scope_exit.hpp])])
1240
1241
1242 # BOOST_SERIALIZATION([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1243 # ---------------------------------------
1244 # Look for Boost.Serialization.  For the documentation of PREFERRED-RT-OPT, see
1245 # the documentation of BOOST_FIND_LIB above.
1246 BOOST_DEFUN([Serialization],
1247 [BOOST_FIND_LIB([serialization], [$1],
1248                 [boost/archive/text_oarchive.hpp],
1249                 [std::ostream* o = 0; // Cheap way to get an ostream...
1250                 boost::archive::text_oarchive t(*o);],
1251                 [], [], [$2])
1252 ])# BOOST_SERIALIZATION
1253
1254
1255 # BOOST_SIGNALS([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1256 # ---------------------------------
1257 # Look for Boost.Signals.  For the documentation of PREFERRED-RT-OPT, see the
1258 # documentation of BOOST_FIND_LIB above.
1259 BOOST_DEFUN([Signals],
1260 [BOOST_FIND_LIB([signals], [$1],
1261                 [boost/signal.hpp],
1262                 [boost::signal<void ()> s;],
1263                 [], [], [$2])
1264 ])# BOOST_SIGNALS
1265
1266
1267 # BOOST_SIGNALS2()
1268 # ----------------
1269 # Look for Boost.Signals2 (new since 1.39.0).
1270 BOOST_DEFUN([Signals2],
1271 [BOOST_FIND_HEADER([boost/signals2.hpp])
1272 ])# BOOST_SIGNALS2
1273
1274
1275 # BOOST_SMART_PTR()
1276 # -----------------
1277 # Look for Boost.SmartPtr
1278 BOOST_DEFUN([Smart_Ptr],
1279 [BOOST_FIND_HEADER([boost/scoped_ptr.hpp])
1280 BOOST_FIND_HEADER([boost/shared_ptr.hpp])
1281 ])
1282
1283
1284 # BOOST_STATICASSERT()
1285 # --------------------
1286 # Look for Boost.StaticAssert
1287 BOOST_DEFUN([StaticAssert],
1288 [BOOST_FIND_HEADER([boost/static_assert.hpp])])
1289
1290
1291 # BOOST_STRING_ALGO()
1292 # -------------------
1293 # Look for Boost.StringAlgo
1294 BOOST_DEFUN([String_Algo],
1295 [BOOST_FIND_HEADER([boost/algorithm/string.hpp])
1296 ])
1297
1298
1299 # BOOST_SYSTEM([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1300 # --------------------------------
1301 # Look for Boost.System.  For the documentation of PREFERRED-RT-OPT, see the
1302 # documentation of BOOST_FIND_LIB above.  This library was introduced in Boost
1303 # 1.35.0.
1304 BOOST_DEFUN([System],
1305 [BOOST_FIND_LIB([system], [$1],
1306                 [boost/system/error_code.hpp],
1307                 [boost::system::error_code e; e.clear();], [], [], [$2])
1308 ])# BOOST_SYSTEM
1309
1310
1311 # BOOST_TEST([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1312 # ------------------------------
1313 # Look for Boost.Test.  For the documentation of PREFERRED-RT-OPT, see the
1314 # documentation of BOOST_FIND_LIB above.
1315 BOOST_DEFUN([Test],
1316 [m4_pattern_allow([^BOOST_CHECK$])dnl
1317 BOOST_FIND_LIB([unit_test_framework], [$1],
1318                [boost/test/unit_test.hpp], [BOOST_CHECK(2 == 2);],
1319                [using boost::unit_test::test_suite;
1320                test_suite* init_unit_test_suite(int argc, char ** argv)
1321                { return NULL; }], [], [$2])
1322 ])# BOOST_TEST
1323
1324
1325 # BOOST_THREAD([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1326 # ---------------------------------
1327 # Look for Boost.Thread.  For the documentation of PREFERRED-RT-OPT, see the
1328 # documentation of BOOST_FIND_LIB above.
1329 BOOST_DEFUN([Thread],
1330 [dnl Having the pthread flag is required at least on GCC3 where
1331 dnl boost/thread.hpp would complain if we try to compile without
1332 dnl -pthread on GNU/Linux.
1333 AC_REQUIRE([_BOOST_PTHREAD_FLAG])dnl
1334 boost_thread_save_LIBS=$LIBS
1335 boost_thread_save_LDFLAGS=$LDFLAGS
1336 boost_thread_save_CPPFLAGS=$CPPFLAGS
1337 # Link-time dependency from thread to system was added as of 1.49.0.
1338 if test $boost_major_version -ge 149; then
1339 BOOST_SYSTEM([$1], [$2])
1340 fi # end of the Boost.System check.
1341 m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
1342 LIBS="$LIBS $BOOST_SYSTEM_LIBS $boost_cv_pthread_flag"
1343 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
1344 CPPFLAGS="$CPPFLAGS $boost_cv_pthread_flag"
1345
1346 # When compiling for the Windows platform, the threads library is named
1347 # differently.  This suffix doesn't exist in new versions of Boost, or
1348 # possibly new versions of GCC on mingw I am assuming it's Boost's change for
1349 # now and I am setting version to 1.48, for lack of knowledge as to when this
1350 # change occurred.
1351 if test $boost_major_version -lt 148; then
1352   case $host_os in
1353     (*mingw*) boost_thread_lib_ext=_win32;;
1354   esac
1355 fi
1356 BOOST_FIND_LIBS([thread], [thread$boost_thread_lib_ext],
1357                 [$1],
1358                 [boost/thread.hpp], [boost::thread t; boost::mutex m;], [], [], [$2])
1359
1360 case $host_os in
1361   (*mingw*) boost_thread_w32_socket_link=-lws2_32;;
1362 esac
1363
1364 BOOST_THREAD_LIBS="$BOOST_THREAD_LIBS $BOOST_SYSTEM_LIBS $boost_cv_pthread_flag $boost_thread_w32_socket_link"
1365 BOOST_THREAD_LDFLAGS="$BOOST_SYSTEM_LDFLAGS"
1366 BOOST_CPPFLAGS="$BOOST_CPPFLAGS $boost_cv_pthread_flag"
1367 LIBS=$boost_thread_save_LIBS
1368 LDFLAGS=$boost_thread_save_LDFLAGS
1369 CPPFLAGS=$boost_thread_save_CPPFLAGS
1370 ])# BOOST_THREAD
1371
1372 AU_ALIAS([BOOST_THREADS], [BOOST_THREAD])
1373
1374
1375 # BOOST_TOKENIZER()
1376 # -----------------
1377 # Look for Boost.Tokenizer
1378 BOOST_DEFUN([Tokenizer],
1379 [BOOST_FIND_HEADER([boost/tokenizer.hpp])])
1380
1381
1382 # BOOST_TRIBOOL()
1383 # ---------------
1384 # Look for Boost.Tribool
1385 BOOST_DEFUN([Tribool],
1386 [BOOST_FIND_HEADER([boost/logic/tribool_fwd.hpp])
1387 BOOST_FIND_HEADER([boost/logic/tribool.hpp])
1388 ])
1389
1390
1391 # BOOST_TUPLE()
1392 # -------------
1393 # Look for Boost.Tuple
1394 BOOST_DEFUN([Tuple],
1395 [BOOST_FIND_HEADER([boost/tuple/tuple.hpp])])
1396
1397
1398 # BOOST_TYPETRAITS()
1399 # --------------------
1400 # Look for Boost.TypeTraits
1401 BOOST_DEFUN([TypeTraits],
1402 [BOOST_FIND_HEADER([boost/type_traits.hpp])])
1403
1404
1405 # BOOST_UTILITY()
1406 # ---------------
1407 # Look for Boost.Utility (noncopyable, result_of, base-from-member idiom,
1408 # etc.)
1409 BOOST_DEFUN([Utility],
1410 [BOOST_FIND_HEADER([boost/utility.hpp])])
1411
1412
1413 # BOOST_VARIANT()
1414 # ---------------
1415 # Look for Boost.Variant.
1416 BOOST_DEFUN([Variant],
1417 [BOOST_FIND_HEADER([boost/variant/variant_fwd.hpp])
1418 BOOST_FIND_HEADER([boost/variant.hpp])])
1419
1420
1421 # BOOST_POINTER_CONTAINER()
1422 # ------------------------
1423 # Look for Boost.PointerContainer
1424 BOOST_DEFUN([Pointer_Container],
1425 [BOOST_FIND_HEADER([boost/ptr_container/ptr_deque.hpp])
1426 BOOST_FIND_HEADER([boost/ptr_container/ptr_list.hpp])
1427 BOOST_FIND_HEADER([boost/ptr_container/ptr_vector.hpp])
1428 BOOST_FIND_HEADER([boost/ptr_container/ptr_array.hpp])
1429 BOOST_FIND_HEADER([boost/ptr_container/ptr_set.hpp])
1430 BOOST_FIND_HEADER([boost/ptr_container/ptr_map.hpp])
1431 ])# BOOST_POINTER_CONTAINER
1432
1433
1434 # BOOST_WAVE([PREFERRED-RT-OPT], [ERROR_ON_UNUSABLE])
1435 # ------------------------------
1436 # NOTE: If you intend to use Wave/Spirit with thread support, make sure you
1437 # call BOOST_THREAD first.
1438 # Look for Boost.Wave.  For the documentation of PREFERRED-RT-OPT, see the
1439 # documentation of BOOST_FIND_LIB above.
1440 BOOST_DEFUN([Wave],
1441 [AC_REQUIRE([BOOST_FILESYSTEM])dnl
1442 AC_REQUIRE([BOOST_DATE_TIME])dnl
1443 boost_wave_save_LIBS=$LIBS
1444 boost_wave_save_LDFLAGS=$LDFLAGS
1445 m4_pattern_allow([^BOOST_((FILE)?SYSTEM|DATE_TIME|THREAD)_(LIBS|LDFLAGS)$])dnl
1446 LIBS="$LIBS $BOOST_SYSTEM_LIBS $BOOST_FILESYSTEM_LIBS $BOOST_DATE_TIME_LIBS \
1447 $BOOST_THREAD_LIBS"
1448 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS $BOOST_FILESYSTEM_LDFLAGS \
1449 $BOOST_DATE_TIME_LDFLAGS $BOOST_THREAD_LDFLAGS"
1450 BOOST_FIND_LIB([wave], [$1],
1451                 [boost/wave.hpp],
1452                 [boost::wave::token_id id; get_token_name(id);], [], [], [$2])
1453 LIBS=$boost_wave_save_LIBS
1454 LDFLAGS=$boost_wave_save_LDFLAGS
1455 ])# BOOST_WAVE
1456
1457
1458 # BOOST_XPRESSIVE()
1459 # -----------------
1460 # Look for Boost.Xpressive (new since 1.36.0).
1461 BOOST_DEFUN([Xpressive],
1462 [BOOST_FIND_HEADER([boost/xpressive/xpressive.hpp])])
1463
1464
1465 # ----------------- #
1466 # Internal helpers. #
1467 # ----------------- #
1468
1469
1470 # _BOOST_PTHREAD_FLAG()
1471 # ---------------------
1472 # Internal helper for BOOST_THREAD.  Computes boost_cv_pthread_flag
1473 # which must be used in CPPFLAGS and LIBS.
1474 #
1475 # Yes, we *need* to put the -pthread thing in CPPFLAGS because with GCC3,
1476 # boost/thread.hpp will trigger a #error if -pthread isn't used:
1477 #   boost/config/requires_threads.hpp:47:5: #error "Compiler threading support
1478 #   is not turned on. Please set the correct command line options for
1479 #   threading: -pthread (Linux), -pthreads (Solaris) or -mthreads (Mingw32)"
1480 #
1481 # Based on ACX_PTHREAD: http://autoconf-archive.cryp.to/acx_pthread.html
1482 AC_DEFUN([_BOOST_PTHREAD_FLAG],
1483 [AC_REQUIRE([AC_PROG_CXX])dnl
1484 AC_REQUIRE([AC_CANONICAL_HOST])dnl
1485 AC_LANG_PUSH([C++])dnl
1486 AC_CACHE_CHECK([for the flags needed to use pthreads], [boost_cv_pthread_flag],
1487 [ boost_cv_pthread_flag=
1488   # The ordering *is* (sometimes) important.  Some notes on the
1489   # individual items follow:
1490   # (none): in case threads are in libc; should be tried before -Kthread and
1491   #       other compiler flags to prevent continual compiler warnings
1492   # -lpthreads: AIX (must check this before -lpthread)
1493   # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
1494   # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
1495   # -llthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
1496   # -pthread: GNU Linux/GCC (kernel threads), BSD/GCC (userland threads)
1497   # -pthreads: Solaris/GCC
1498   # -mthreads: MinGW32/GCC, Lynx/GCC
1499   # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
1500   #      doesn't hurt to check since this sometimes defines pthreads too;
1501   #      also defines -D_REENTRANT)
1502   #      ... -mt is also the pthreads flag for HP/aCC
1503   # -lpthread: GNU Linux, etc.
1504   # --thread-safe: KAI C++
1505   case $host_os in #(
1506     *solaris*)
1507       # On Solaris (at least, for some versions), libc contains stubbed
1508       # (non-functional) versions of the pthreads routines, so link-based
1509       # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
1510       # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
1511       # a function called by this macro, so we could check for that, but
1512       # who knows whether they'll stub that too in a future libc.)  So,
1513       # we'll just look for -pthreads and -lpthread first:
1514       boost_pthread_flags="-pthreads -lpthread -mt -pthread";; #(
1515     *)
1516       boost_pthread_flags="-lpthreads -Kthread -kthread -llthread -pthread \
1517                            -pthreads -mthreads -lpthread --thread-safe -mt";;
1518   esac
1519   # Generate the test file.
1520   AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <pthread.h>],
1521     [pthread_t th; pthread_join(th, 0);
1522     pthread_attr_init(0); pthread_cleanup_push(0, 0);
1523     pthread_create(0,0,0,0); pthread_cleanup_pop(0);])])
1524   for boost_pthread_flag in '' $boost_pthread_flags; do
1525     boost_pthread_ok=false
1526 dnl Re-use the test file already generated.
1527     boost_pthreads__save_LIBS=$LIBS
1528     LIBS="$LIBS $boost_pthread_flag"
1529     AC_LINK_IFELSE([],
1530       [if grep ".*$boost_pthread_flag" conftest.err; then
1531          echo "This flag seems to have triggered warnings" >&AS_MESSAGE_LOG_FD
1532        else
1533          boost_pthread_ok=:; boost_cv_pthread_flag=$boost_pthread_flag
1534        fi])
1535     LIBS=$boost_pthreads__save_LIBS
1536     $boost_pthread_ok && break
1537   done
1538 ])
1539 AC_LANG_POP([C++])dnl
1540 ])# _BOOST_PTHREAD_FLAG
1541
1542
1543 # _BOOST_gcc_test(MAJOR, MINOR)
1544 # -----------------------------
1545 # Internal helper for _BOOST_FIND_COMPILER_TAG.
1546 m4_define([_BOOST_gcc_test],
1547 ["defined __GNUC__ && __GNUC__ == $1 && __GNUC_MINOR__ == $2 && !defined __ICC @ gcc$1$2"])dnl
1548
1549 # _BOOST_mingw_test(MAJOR, MINOR)
1550 # -----------------------------
1551 # Internal helper for _BOOST_FIND_COMPILER_TAG.
1552 m4_define([_BOOST_mingw_test],
1553 ["defined __GNUC__ && __GNUC__ == $1 && __GNUC_MINOR__ == $2 && !defined __ICC && \
1554   (defined WIN32 || defined WINNT || defined _WIN32 || defined __WIN32 \
1555          || defined __WIN32__ || defined __WINNT || defined __WINNT__) @ mgw$1$2"])dnl
1556
1557
1558 # _BOOST_FIND_COMPILER_TAG()
1559 # --------------------------
1560 # Internal.  When Boost is installed without --layout=system, each library
1561 # filename will hold a suffix that encodes the compiler used during the
1562 # build.  The Boost build system seems to call this a `tag'.
1563 AC_DEFUN([_BOOST_FIND_COMPILER_TAG],
1564 [AC_REQUIRE([AC_PROG_CXX])dnl
1565 AC_REQUIRE([AC_CANONICAL_HOST])dnl
1566 AC_CACHE_CHECK([for the toolset name used by Boost for $CXX],
1567                [boost_cv_lib_tag],
1568 [boost_cv_lib_tag=unknown
1569 if test x$boost_cv_inc_path != xno; then
1570   AC_LANG_PUSH([C++])dnl
1571   # The following tests are mostly inspired by boost/config/auto_link.hpp
1572   # The list is sorted to most recent/common to oldest compiler (in order
1573   # to increase the likelihood of finding the right compiler with the
1574   # least number of compilation attempt).
1575   # Beware that some tests are sensible to the order (for instance, we must
1576   # look for MinGW before looking for GCC3).
1577   # I used one compilation test per compiler with a #error to recognize
1578   # each compiler so that it works even when cross-compiling (let me know
1579   # if you know a better approach).
1580   # Known missing tags (known from Boost's tools/build/v2/tools/common.jam):
1581   #   como, edg, kcc, bck, mp, sw, tru, xlc
1582   # I'm not sure about my test for `il' (be careful: Intel's ICC pre-defines
1583   # the same defines as GCC's).
1584   for i in \
1585     "defined __clang__ && __clang_major__ == 8 && __clang_minor__ == 0 @ clang80" \
1586     "defined __clang__ && __clang_major__ == 7 && __clang_minor__ == 0 @ clang70" \
1587     "defined __clang__ && __clang_major__ == 6 && __clang_minor__ == 0 @ clang60" \
1588     "defined __clang__ && __clang_major__ == 5 && __clang_minor__ == 0 @ clang50" \
1589     "defined __clang__ && __clang_major__ == 4 && __clang_minor__ == 0 @ clang40" \
1590     "defined __clang__ && __clang_major__ == 3 && __clang_minor__ == 9 @ clang39" \
1591     "defined __clang__ && __clang_major__ == 3 && __clang_minor__ == 8 @ clang38" \
1592     "defined __clang__ && __clang_major__ == 3 && __clang_minor__ == 7 @ clang37" \
1593     _BOOST_mingw_test(9, 1) \
1594     _BOOST_gcc_test(9, 1) \
1595     _BOOST_mingw_test(9, 0) \
1596     _BOOST_gcc_test(9, 0) \
1597     _BOOST_mingw_test(8, 3) \
1598     _BOOST_gcc_test(8, 3) \
1599     _BOOST_mingw_test(8, 2) \
1600     _BOOST_gcc_test(8, 2) \
1601     _BOOST_mingw_test(8, 1) \
1602     _BOOST_gcc_test(8, 1) \
1603     _BOOST_mingw_test(8, 0) \
1604     _BOOST_gcc_test(8, 0) \
1605     _BOOST_mingw_test(7, 3) \
1606     _BOOST_gcc_test(7, 3) \
1607     _BOOST_mingw_test(7, 2) \
1608     _BOOST_gcc_test(7, 2) \
1609     _BOOST_mingw_test(7, 1) \
1610     _BOOST_gcc_test(7, 1) \
1611     _BOOST_mingw_test(7, 0) \
1612     _BOOST_gcc_test(7, 0) \
1613     _BOOST_mingw_test(6, 4) \
1614     _BOOST_gcc_test(6, 4) \
1615     _BOOST_mingw_test(6, 3) \
1616     _BOOST_gcc_test(6, 3) \
1617     _BOOST_mingw_test(6, 2) \
1618     _BOOST_gcc_test(6, 2) \
1619     _BOOST_mingw_test(6, 1) \
1620     _BOOST_gcc_test(6, 1) \
1621     _BOOST_mingw_test(6, 0) \
1622     _BOOST_gcc_test(6, 0) \
1623     _BOOST_mingw_test(5, 5) \
1624     _BOOST_gcc_test(5, 5) \
1625     _BOOST_mingw_test(5, 4) \
1626     _BOOST_gcc_test(5, 4) \
1627     _BOOST_mingw_test(5, 3) \
1628     _BOOST_gcc_test(5, 3) \
1629     _BOOST_mingw_test(5, 2) \
1630     _BOOST_gcc_test(5, 2) \
1631     _BOOST_mingw_test(5, 1) \
1632     _BOOST_gcc_test(5, 1) \
1633     _BOOST_mingw_test(5, 0) \
1634     _BOOST_gcc_test(5, 0) \
1635     _BOOST_mingw_test(4, 10) \
1636     _BOOST_gcc_test(4, 10) \
1637     _BOOST_mingw_test(4, 9) \
1638     _BOOST_gcc_test(4, 9) \
1639     _BOOST_mingw_test(4, 8) \
1640     _BOOST_gcc_test(4, 8) \
1641     _BOOST_mingw_test(4, 7) \
1642     _BOOST_gcc_test(4, 7) \
1643     _BOOST_mingw_test(4, 6) \
1644     _BOOST_gcc_test(4, 6) \
1645     _BOOST_mingw_test(4, 5) \
1646     _BOOST_gcc_test(4, 5) \
1647     _BOOST_mingw_test(4, 4) \
1648     _BOOST_gcc_test(4, 4) \
1649     _BOOST_mingw_test(4, 3) \
1650     _BOOST_gcc_test(4, 3) \
1651     _BOOST_mingw_test(4, 2) \
1652     _BOOST_gcc_test(4, 2) \
1653     _BOOST_mingw_test(4, 1) \
1654     _BOOST_gcc_test(4, 1) \
1655     _BOOST_mingw_test(4, 0) \
1656     _BOOST_gcc_test(4, 0) \
1657     "defined __GNUC__ && __GNUC__ == 3 && !defined __ICC \
1658      && (defined WIN32 || defined WINNT || defined _WIN32 || defined __WIN32 \
1659          || defined __WIN32__ || defined __WINNT || defined __WINNT__) @ mgw" \
1660     _BOOST_gcc_test(3, 4) \
1661     _BOOST_gcc_test(3, 3) \
1662     "defined _MSC_VER && _MSC_VER >= 1500 @ vc90" \
1663     "defined _MSC_VER && _MSC_VER == 1400 @ vc80" \
1664     _BOOST_gcc_test(3, 2) \
1665     "defined _MSC_VER && _MSC_VER == 1310 @ vc71" \
1666     _BOOST_gcc_test(3, 1) \
1667     _BOOST_gcc_test(3, 0) \
1668     "defined __BORLANDC__ @ bcb" \
1669     "defined __ICC && (defined __unix || defined __unix__) @ il" \
1670     "defined __ICL @ iw" \
1671     "defined _MSC_VER && _MSC_VER == 1300 @ vc7" \
1672     _BOOST_gcc_test(2, 95) \
1673     "defined __MWERKS__ && __MWERKS__ <= 0x32FF @ cw9" \
1674     "defined _MSC_VER && _MSC_VER < 1300 && !defined UNDER_CE @ vc6" \
1675     "defined _MSC_VER && _MSC_VER < 1300 && defined UNDER_CE @ evc4" \
1676     "defined __MWERKS__ && __MWERKS__ <= 0x31FF @ cw8"
1677   do
1678     boost_tag_test=`expr "X$i" : 'X\([[^@]]*\) @ '`
1679     boost_tag=`expr "X$i" : 'X[[^@]]* @ \(.*\)'`
1680     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1681 #if $boost_tag_test
1682 /* OK */
1683 #else
1684 # error $boost_tag_test
1685 #endif
1686 ]])], [boost_cv_lib_tag=$boost_tag; break], [])
1687   done
1688 AC_LANG_POP([C++])dnl
1689   case $boost_cv_lib_tag in #(
1690     # Some newer (>= 1.35?) versions of Boost seem to only use "gcc" as opposed
1691     # to "gcc41" for instance.
1692     *-gcc | *'-gcc ') :;; #(  Don't re-add -gcc: it's already in there.
1693     gcc*)
1694       boost_tag_x=
1695       case $host_os in #(
1696         darwin*)
1697           if test $boost_major_version -ge 136; then
1698             # The `x' added in r46793 of Boost.
1699             boost_tag_x=x
1700           fi;;
1701       esac
1702       # We can specify multiple tags in this variable because it's used by
1703       # BOOST_FIND_LIB that does a `for tag in -$boost_cv_lib_tag' ...
1704       boost_cv_lib_tag="$boost_tag_x$boost_cv_lib_tag -${boost_tag_x}gcc"
1705       ;; #(
1706     unknown)
1707       AC_MSG_WARN([[could not figure out which toolset name to use for $CXX]])
1708       boost_cv_lib_tag=
1709       ;;
1710   esac
1711 fi])dnl end of AC_CACHE_CHECK
1712 ])# _BOOST_FIND_COMPILER_TAG
1713
1714
1715 # _BOOST_GUESS_WHETHER_TO_USE_MT()
1716 # --------------------------------
1717 # Compile a small test to try to guess whether we should favor MT (Multi
1718 # Thread) flavors of Boost.  Sets boost_guess_use_mt accordingly.
1719 AC_DEFUN([_BOOST_GUESS_WHETHER_TO_USE_MT],
1720 [# Check whether we do better use `mt' even though we weren't ask to.
1721 AC_LANG_PUSH([C++])dnl
1722 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1723 #if defined _REENTRANT || defined _MT || defined __MT__
1724 /* use -mt */
1725 #else
1726 # error MT not needed
1727 #endif
1728 ]])], [boost_guess_use_mt=:], [boost_guess_use_mt=false])
1729 AC_LANG_POP([C++])dnl
1730 ])
1731
1732 # _BOOST_AC_LINK_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
1733 # -------------------------------------------------------------------
1734 # Fork of _AC_LINK_IFELSE that preserves conftest.o across calls.  Fragile,
1735 # will break when Autoconf changes its internals.  Requires that you manually
1736 # rm -f conftest.$ac_objext in between to really different tests, otherwise
1737 # you will try to link a conftest.o left behind by a previous test.
1738 # Used to aggressively optimize BOOST_FIND_LIB (see the big comment in this
1739 # macro).
1740 #
1741 # Don't use "break" in the actions, as it would short-circuit some code
1742 # this macro runs after the actions.
1743 m4_define([_BOOST_AC_LINK_IFELSE],
1744 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
1745 rm -f conftest$ac_exeext
1746 boost_save_ac_ext=$ac_ext
1747 boost_use_source=:
1748 # If we already have a .o, re-use it.  We change $ac_ext so that $ac_link
1749 # tries to link the existing object file instead of compiling from source.
1750 test -f conftest.$ac_objext && ac_ext=$ac_objext && boost_use_source=false &&
1751   _AS_ECHO_LOG([re-using the existing conftest.$ac_objext])
1752 AS_IF([_AC_DO_STDERR($ac_link) && {
1753          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
1754          test ! -s conftest.err
1755        } && test -s conftest$ac_exeext && {
1756          test "$cross_compiling" = yes ||
1757          $as_executable_p conftest$ac_exeext
1758 dnl FIXME: use AS_TEST_X instead when 2.61 is widespread enough.
1759        }],
1760       [$2],
1761       [if $boost_use_source; then
1762          _AC_MSG_LOG_CONFTEST
1763        fi
1764        $3])
1765 ac_objext=$boost_save_ac_objext
1766 ac_ext=$boost_save_ac_ext
1767 dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
1768 dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
1769 dnl as it would interfere with the next link command.
1770 rm -f core conftest.err conftest_ipa8_conftest.oo \
1771       conftest$ac_exeext m4_ifval([$1], [conftest.$ac_ext])[]dnl
1772 ])# _BOOST_AC_LINK_IFELSE
1773
1774 # Local Variables:
1775 # mode: autoconf
1776 # End: