m4/pdns_check_libcrypto_ecdsa.m4

   1 AC_DEFUN([PDNS_CHECK_LIBCRYPTO_ECDSA], [
   2   AC_REQUIRE([PDNS_CHECK_LIBCRYPTO])
   3
   4   # Set the environment correctly for a possibly non-default OpenSSL path that was found by/supplied to PDNS_CHECK_LIBCRYPTO
   5   save_CPPFLAGS="$CPPFLAGS"
   6   save_LDFLAGS="$LDFLAGS"
   7   save_LIBS="$LIBS"
   8
   9   CPPFLAGS="$LIBCRYPTO_INCLUDES $CPPFLAGS"
  10   LDFLAGS="$LIBCRYPTO_LDFLAGS $LDFLAGS"
  11   LIBS="$LIBCRYPTO_LIBS $LIBS"
  12
  13   # Find the headers we need for ECDSA
  14   libcrypto_ecdsa=yes
  15   AC_CHECK_HEADER([$ssldir/include/openssl/ecdsa.h], [
  16     AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [ : ], [
  17       libcrypto_ecdsa=no
  18     ], [AC_INCLUDES_DEFAULT
  19 #include <$ssldir/include/openssl/evp.h>
  20     ])
  21   ], [
  22     libcrypto_ecdsa=no
  23   ])
  24
  25   AS_IF([test "x$libcrypto_ecdsa" = "xyes"], [
  26     AC_DEFINE([HAVE_LIBCRYPTO_ECDSA], [1], [define to 1 if OpenSSL ecdsa support is available.])
  27   ])
  28
  29   # Restore variables
  30   CPPFLAGS="$save_CPPFLAGS"
  31   LDFLAGS="$save_LDFLAGS"
  32   LIBS="$save_LIBS"
  33 ])