m4/pdns_enable_remotebackend_zeromq.m4

   1 AC_DEFUN([PDNS_ENABLE_REMOTEBACKEND_ZEROMQ],[
   2   AC_MSG_CHECKING([whether to enable ZeroMQ connector in remotebackend])
   3   AC_ARG_ENABLE([remotebackend_zeromq],
   4     AS_HELP_STRING([--enable-remotebackend-zeromq],
   5       [enable ZeroMQ connector for remotebackend @<:@default=no@:>@]
   6     ),
   7     [enable_remotebackend_zeromq=$enableval],
   8     [enable_remotebackend_zeromq=no]
   9   )
  10
  11   AC_MSG_RESULT([$enable_remotebackend_zeromq])
  12
  13   AM_CONDITIONAL([REMOTEBACKEND_ZEROMQ],[test "x$enable_remotebackend_zeromq" != "xno"])
  14   AC_SUBST(REMOTEBACKEND_ZEROMQ)
  15
  16   AS_IF([test "x$enable_remotebackend_zeromq" != "xno"],
  17     [
  18       AS_IF([test "x$have_remotebackend" = "xyes"],
  19         [
  20           PKG_CHECK_MODULES([LIBZMQ], [libzmq],
  21             [
  22               AC_DEFINE([HAVE_LIBZMQ], [1], [Define to 1 if you have libzmq])
  23               AC_DEFINE([REMOTEBACKEND_ZEROMQ], [1], [Define to 1 if you have the ZeroMQ connector])
  24               REMOTEBACKEND_ZEROMQ=yes
  25             ],
  26             [AC_MSG_ERROR([Could not find libzmq])]
  27           )
  28
  29           old_CXXFLAGS="$CXXFLAGS"
  30           old_LDFLAGS="$LDFLAGS"
  31           CXXFLAGS="$CFLAGS $LIBZMQ_CFLAGS"
  32           LDFLAGS="$LDFLAGS $LIBZMQ_LIBS"
  33           AC_CHECK_LIB([zmq], [zmq_msg_send],
  34             [
  35               AC_DEFINE([HAVE_ZMQ_MSG_SEND], [1], [Define to 1 if the ZeroMQ 3.x or greater API is available])
  36             ]
  37           )
  38           CXXFLAGS="$old_CXXFLAGS"
  39           LDFLAGS="$old_LDFLAGS"
  40         ],
  41         [AC_MSG_ERROR([remotebackend \"zeromq\" selected but the \"remote\" backend itself is not selected. Please add \"remote\" to your modules or dynmodules list and re-run configure!])]
  42       )
  43     ]
  44   )
  45 ])