m4/pdns_with_geo.m4

   1 AC_DEFUN([PDNS_CHECK_GEOIP], [
   2   PKG_CHECK_MODULES([GEOIP], [geoip], AC_DEFINE([HAVE_GEOIP], [1], [Define this if you have GeoIP]), [have_geoip=0])
   3   AC_ARG_WITH([maxminddb_incdir],
   4     AS_HELP_STRING([--with-maxminddb-includedir],[path to maxminddb include directory @<:@default=auto@:>@]),
   5     [with_maxminddb_incdir=$withval],
   6     [with_maxminddb_incdir=auto]
   7   )
   8   AC_ARG_WITH([maxminddb_libdir],
   9     AS_HELP_STRING([--with-maxminddb-libdir],[path to maxminddb library directory @<:@default=auto@:>@]),
  10     [with_maxminddb_libdir=$withval],
  11     [with_maxminddb_libdir=auto],
  12   )
  13
  14   PKG_CHECK_MODULES([MMDB], [libmaxminddb], [
  15     AC_DEFINE([HAVE_MMDB], [1], [Define this if you have Maxmind DB])
  16   ], [
  17     AS_IF([test "x$with_maxminddb_incdir" = "xauto"], [
  18       AC_CHECK_HEADER([maxminddb.h], [have_mmdb=1], [have_mmdb=0])
  19     ], [
  20       OLD_CFLAGS="$CFLAGS"
  21       CFLAGS="$CFLAGS -I$with_maxminddb_incdir"
  22       AC_CHECK_HEADER([maxminddb.h], [have_mmdb=1], [have_mmdb=0])
  23       CFLAGS="$OLD_CFLAGS"
  24     ])
  25
  26     AS_IF([test "$have_mmdb" = "1"], [
  27       AS_IF([test "x$with_maxminddb_libdir" = "xauto"], [
  28         AC_CHECK_LIB([maxminddb], [MMDB_open], [
  29           AC_DEFINE([HAVE_MMDB], [1], [Define this if you have Maxmind DB])
  30           MMDB_LIBS="-lmaxminddb"
  31         ])
  32       ], [
  33         OLD_LDFLAGS="$LDFLAGS"
  34         LDFLAGS="$LDFLAGS -L$with_maxminddb_libdir"
  35         AC_CHECK_LIB([maxminddb], [MMDB_open], [
  36           AC_DEFINE([HAVE_MMDB], [1], [Define this if you have Maxmind DB])
  37           MMDB_CFLAGS="-I$with_maxminddb_incdir"
  38           MMDB_LIBS="-L$with_maxminddb_libdir -lmaxminddb"
  39         ])
  40       ])
  41     ])
  42   ])
  43
  44   PKG_CHECK_MODULES([YAML], [yaml-cpp >= 0.5],[],
  45     AC_MSG_ERROR([Could not find yaml-cpp])
  46   )
  47 ])