m4/pdns_with_lua.m4

   1 AC_DEFUN([PDNS_WITH_LUA],[
   2   AC_MSG_CHECKING([whether we will be linking in Lua])
   3   AC_ARG_WITH([lua],
   4     [AS_HELP_STRING([--with-lua], [build Lua Bindings @<:@default=auto@:>@])],
   5     [with_lua=$withval],
   6     [with_lua=auto]
   7   )
   8   AC_MSG_RESULT([$with_lua])
   9
  10   AS_IF([test "x$with_lua" != "xno"],[
  11     AS_IF([test "x$with_lua" = "xyes" -o "x$with_lua" = "xauto"],
  12       [for LUAPC in lua5.3 lua-5.3 lua53 lua5.2 lua-5.2 lua52 lua5.1 lua-5.1 lua51 lua; do
  13          PKG_CHECK_MODULES([LUA], $LUAPC >= 5.1, [
  14            AC_DEFINE([HAVE_LUA], [1], [Define to 1 if you have lua])
  15            with_lua=yes
  16          ], [LUAPC=""]) # otherwise pkg_check will fail
  17          if test "x$LUA_LIBS" != "x"; then break; fi
  18        done
  19       ],
  20       [LUAPC="$with_lua"
  21         PKG_CHECK_MODULES([LUA], $LUAPC >= 5.1, [
  22           AC_DEFINE([HAVE_LUA], [1], [Define to 1 if you have lua])
  23           with_lua=yes
  24         ])
  25     ])
  26     AC_MSG_CHECKING([for chosen LUA])
  27     AS_IF([test "x$LUAPC" = "x"], [
  28       AS_IF([test "x$with_lua" = "xyes"],
  29         [AC_MSG_ERROR([cannot find lua])],
  30         [AC_MSG_RESULT([not found])]
  31       )],
  32       [AC_MSG_RESULT([$LUAPC])
  33        AC_CHECK_HEADER([lua.hpp], [ have_lua_hpp=y ])
  34        AM_CONDITIONAL([HAVE_LUA_HPP], [ test x"$have_lua_hpp" = "xy" ])
  35       ])
  36     ])
  37   AM_CONDITIONAL([LUA], [test "x$with_lua" = "xyes"])
  38 ])