meta/recipes-graphics/xinput-calibrator/xinput-calibrator_git.bb

   1 SUMMARY = "Touchscreen calibration program for X11"
   2 HOMEPAGE = "http://www.freedesktop.org/wiki/Software/xinput_calibrator"
   3 LICENSE = "MIT"
   4 LIC_FILES_CHKSUM = "file://src/calibrator.cpp;endline=22;md5=1bcba08f67cdb56f34021557898e4b5a"
   5 DEPENDS = "virtual/libx11 libxi libxrandr"
   6
   7 PV = "0.7.5+git"
   8 PR = "r6"
   9
  10 inherit autotools pkgconfig features_check
  11 # depends on virtual/libx11
  12 REQUIRED_DISTRO_FEATURES = "x11"
  13
  14 SRCREV = "18ec53f1cada39f905614ebfaffed5c7754ecf46"
  15 SRC_URI = "git://github.com/kreijack/xinput_calibrator.git;branch=libinput;protocol=https \
  16            file://30xinput_calibrate.sh \
  17            file://Allow-xinput_calibrator_pointercal.sh-to-be-run-as-n.patch \
  18            file://0001-calibrator.hh-Include-string-to-get-std-string.patch \
  19            "
  20
  21 S = "${WORKDIR}/git"
  22
  23 # force native X11 ui as we don't have gtk+ in DEPENDS
  24 EXTRA_OECONF += "--with-gui=x11"
  25
  26 do_install:append() {
  27     install -d ${D}${bindir}
  28     install -m 0755 ${S}/scripts/xinput_calibrator_pointercal.sh ${D}${bindir}/xinput_calibrator_once.sh
  29
  30     install -d ${D}${sysconfdir}/X11/Xsession.d/
  31     install -m 0755 ${WORKDIR}/30xinput_calibrate.sh ${D}${sysconfdir}/X11/Xsession.d/
  32
  33     install -d ${D}${sysconfdir}/xdg/autostart
  34     sed -e 's,^Exec=.*,Exec=${bindir}/xinput_calibrator_once.sh,' ${S}/scripts/xinput_calibrator.desktop > ${D}${sysconfdir}/xdg/autostart/xinput_calibrator.desktop
  35 }
  36
  37 FILES:${PN} += "${sysconfdir}/xdg/autostart"
  38 RDEPENDS:${PN} = "xinput formfactor"
  39 RRECOMMENDS:${PN} = "pointercal-xinput"