meta/recipes-kernel/linux/kernel-devsrc.bb

   1 SUMMARY = "Linux kernel Development Source"
   2 DESCRIPTION = "Development source linux kernel. When built, this recipe packages the \
   3 source of the preferred virtual/kernel provider and makes it available for full kernel \
   4 development or external module builds"
   5
   6 SECTION = "kernel"
   7
   8 LICENSE = "GPL-2.0-only"
   9
  10 inherit linux-kernel-base
  11
  12 # Whilst not a module, this ensures we don't get multilib extended (which would make no sense)
  13 inherit module-base
  14
  15 # We need the kernel to be staged (unpacked, patched and configured) before
  16 # we can grab the source and make the source package. We also need the bits from
  17 # ${B} not to change while we install, so virtual/kernel must finish do_compile.
  18 do_install[depends] += "virtual/kernel:do_shared_workdir"
  19 # Need the source, not just the output of populate_sysroot
  20 do_install[depends] += "virtual/kernel:do_install"
  21
  22 # There's nothing to do here, except install the source where we can package it
  23 do_fetch[noexec] = "1"
  24 do_unpack[noexec] = "1"
  25 do_patch[noexec] = "1"
  26 do_configure[noexec] = "1"
  27 do_compile[noexec] = "1"
  28 deltask do_populate_sysroot
  29
  30 S = "${STAGING_KERNEL_DIR}"
  31 B = "${STAGING_KERNEL_BUILDDIR}"
  32
  33 PACKAGE_ARCH = "${MACHINE_ARCH}"
  34
  35 KERNEL_BUILD_ROOT="${nonarch_base_libdir}/modules/"
  36
  37 do_install() {
  38     kerneldir=${D}${KERNEL_BUILD_ROOT}${KERNEL_VERSION}
  39     install -d $kerneldir
  40
  41     # create the directory structure
  42     rm -f $kerneldir/build
  43     rm -f $kerneldir/source
  44     mkdir -p $kerneldir/build
  45
  46     # for compatibility with some older variants of this package, we
  47     # create  a /usr/src/kernel symlink to /lib/modules/<version>/source
  48     mkdir -p ${D}/usr/src
  49     (
  50         cd ${D}/usr/src
  51         ln -rs ${D}${KERNEL_BUILD_ROOT}${KERNEL_VERSION}/source kernel
  52     )
  53
  54     # for on target purposes, we unify build and source
  55     (
  56         cd $kerneldir
  57         ln -s build source
  58     )
  59
  60     # first copy everything
  61     (
  62         cd ${S}
  63         cp --parents $(find  -type f -name "Makefile*" -o -name "Kconfig*") $kerneldir/build
  64         cp --parents $(find  -type f -name "Build" -o -name "Build.include") $kerneldir/build
  65     )
  66
  67     # then drop all but the needed Makefiles/Kconfig files
  68     rm -rf $kerneldir/build/scripts
  69     rm -rf $kerneldir/build/include
  70
  71     # now copy in parts from the build that we'll need later
  72     (
  73         cd ${B}
  74
  75         if [ -s Module.symvers ]; then
  76             cp Module.symvers $kerneldir/build
  77         fi
  78         cp System.map* $kerneldir/build
  79         if [ -s Module.markers ]; then
  80             cp Module.markers $kerneldir/build
  81         fi
  82
  83         cp -a .config $kerneldir/build
  84
  85         # This scripts copy blow up QA, so for now, we require a more
  86         # complex 'make scripts' to restore these, versus copying them
  87         # here. Left as a reference to indicate that we know the scripts must
  88         # be dealt with.
  89         # cp -a scripts $kerneldir/build
  90
  91         # although module.lds can be regenerated on target via 'make modules_prepare'
  92         # there are several places where 'makes scripts prepare' is done, and that won't
  93         # regenerate the file. So we copy it onto the target as a migration to using
  94         # modules_prepare
  95         cp -a --parents scripts/module.lds $kerneldir/build/ 2>/dev/null || :
  96
  97         if [ -d arch/${ARCH}/scripts ]; then
  98             cp -a arch/${ARCH}/scripts $kerneldir/build/arch/${ARCH}
  99         fi
 100         if [ -f arch/${ARCH}/*lds ]; then
 101             cp -a arch/${ARCH}/*lds $kerneldir/build/arch/${ARCH}
 102         fi
 103
 104         rm -f $kerneldir/build/scripts/*.o
 105         rm -f $kerneldir/build/scripts/*/*.o
 106
 107         if [ "${ARCH}" = "powerpc" ]; then
 108             if [ -e arch/powerpc/lib/crtsavres.S ] ||
 109                    [ -e arch/powerpc/lib/crtsavres.o ]; then
 110                 cp -a --parents arch/powerpc/lib/crtsavres.[So] $kerneldir/build/
 111             fi
 112         fi
 113
 114         if [ "${ARCH}" = "arm64" -o "${ARCH}" = "riscv" ]; then
 115             if [ -e arch/${ARCH}/kernel/vdso/vdso.lds ]; then
 116                 cp -a --parents arch/${ARCH}/kernel/vdso/vdso.lds $kerneldir/build/
 117             fi
 118         fi
 119         if [ "${ARCH}" = "powerpc" ]; then
 120             cp -a --parents arch/powerpc/kernel/vdso32/vdso32.lds $kerneldir/build 2>/dev/null || :
 121             cp -a --parents arch/powerpc/kernel/vdso64/vdso64.lds $kerneldir/build 2>/dev/null || :
 122             # v5.19+
 123             cp -a --parents arch/powerpc/kernel/vdso/vdso*.lds $kerneldir/build 2>/dev/null || :
 124         fi
 125
 126         cp -a include $kerneldir/build/include
 127
 128         # we don't usually copy generated files, since they can be rebuilt on the target,
 129         # but without this file, we get a forced syncconfig run in v5.8+, which prompts and
 130         # breaks workflows.
 131         cp -a --parents include/generated/autoconf.h $kerneldir/build 2>/dev/null || :
 132
 133         if [ -e $kerneldir/include/generated/.vdso-offsets.h.cmd ] ||
 134              [ -e $kerneldir/build/include/generated/.vdso-offsets.h.cmd ] ||
 135              [ -e $kerneldir/build/include/generated/.vdso32-offsets.h.cmd ] ; then
 136             rm -f $kerneldir/include/generated/.vdso-offsets.h.cmd
 137             rm -f $kerneldir/build/include/generated/.vdso-offsets.h.cmd
 138             rm -f $kerneldir/build/include/generated/.vdso32-offsets.h.cmd
 139         fi
 140     )
 141
 142     # now grab the chunks from the source tree that we need
 143     (
 144         cd ${S}
 145
 146         cp -a scripts $kerneldir/build
 147
 148         # for v6.1+ (otherwise we are missing multiple default targets)
 149         cp -a --parents Kbuild $kerneldir/build 2>/dev/null || :
 150
 151         # For v6.6+ the debian packing is moved out to seperate rules file
 152         # Remove as we else would ned to RDEPEND on make
 153         rm $kerneldir/build/scripts/package/debian/rules 2>/dev/null || :
 154
 155         # if our build dir had objtool, it will also be rebuilt on target, so
 156         # we copy what is required for that build
 157         if [ -f ${B}/tools/objtool/objtool ]; then
 158             # these are a few files associated with objtool, since we'll need to
 159             # rebuild it
 160             cp -a --parents tools/build/Build.include $kerneldir/build/
 161             cp -a --parents tools/build/Build $kerneldir/build/
 162             cp -a --parents tools/build/fixdep.c $kerneldir/build/
 163             cp -a --parents tools/scripts/utilities.mak $kerneldir/build/
 164
 165             # extra files, just in case
 166             cp -a --parents tools/objtool/* $kerneldir/build/
 167             cp -a --parents tools/lib/* $kerneldir/build/
 168             cp -a --parents tools/lib/subcmd/* $kerneldir/build/
 169
 170             cp -a --parents tools/include/* $kerneldir/build/
 171
 172             cp -a --parents $(find tools/arch/${ARCH}/ -type f) $kerneldir/build/
 173         fi
 174
 175         if [ "${ARCH}" = "arm64" ]; then
 176             # arch/arm64/include/asm/xen references arch/arm
 177             cp -a --parents arch/arm/include/asm/xen $kerneldir/build/
 178             # arch/arm64/include/asm/opcodes.h references arch/arm
 179             cp -a --parents arch/arm/include/asm/opcodes.h $kerneldir/build/
 180
 181             # v6.1+
 182             cp -a --parents arch/arm64/kernel/asm-offsets.c $kerneldir/build/
 183
 184             cp -a --parents arch/arm64/kernel/vdso/*gettimeofday.* $kerneldir/build/
 185             cp -a --parents arch/arm64/kernel/vdso/sigreturn.S $kerneldir/build/
 186             cp -a --parents arch/arm64/kernel/vdso/note.S $kerneldir/build/
 187             cp -a --parents arch/arm64/kernel/vdso/gen_vdso_offsets.sh $kerneldir/build/
 188
 189             cp -a --parents arch/arm64/kernel/module.lds $kerneldir/build/ 2>/dev/null || :
 190
 191             # 5.13+ needs these tools
 192             cp -a --parents arch/arm64/tools/gen-cpucaps.awk $kerneldir/build/ 2>/dev/null || :
 193             cp -a --parents arch/arm64/tools/cpucaps $kerneldir/build/ 2>/dev/null || :
 194
 195             # 5.19+
 196             cp -a --parents arch/arm64/tools/gen-sysreg.awk $kerneldir/build/   2>/dev/null || :
 197             cp -a --parents arch/arm64/tools/sysreg $kerneldir/build/   2>/dev/null || :
 198
 199             if [ -e $kerneldir/build/arch/arm64/tools/gen-cpucaps.awk ]; then
 200                  sed -i -e "s,#!.*awk.*,#!${USRBINPATH}/env awk," $kerneldir/build/arch/arm64/tools/gen-cpucaps.awk
 201             fi
 202             if [ -e $kerneldir/build/arch/arm64/tools/gen-sysreg.awk ]; then
 203                  sed -i -e "s,#!.*awk.*,#!${USRBINPATH}/env awk," $kerneldir/build/arch/arm64/tools/gen-sysreg.awk
 204             fi
 205         fi
 206
 207         if [ "${ARCH}" = "powerpc" ]; then
 208             # 5.0 needs these files, but don't error if they aren't present in the source
 209             cp -a --parents arch/${ARCH}/kernel/syscalls/syscall.tbl $kerneldir/build/ 2>/dev/null || :
 210             cp -a --parents arch/${ARCH}/kernel/syscalls/syscalltbl.sh $kerneldir/build/ 2>/dev/null || :
 211             cp -a --parents arch/${ARCH}/kernel/syscalls/syscallhdr.sh $kerneldir/build/ 2>/dev/null || :
 212             cp -a --parents arch/${ARCH}/kernel/vdso32/* $kerneldir/build/ 2>/dev/null || :
 213             cp -a --parents arch/${ARCH}/kernel/vdso64/* $kerneldir/build/ 2>/dev/null || :
 214
 215             # v5.19+
 216             cp -a --parents arch/powerpc/kernel/vdso/*.S $kerneldir/build 2>/dev/null || :
 217             cp -a --parents arch/powerpc/kernel/vdso/*gettimeofday.* $kerneldir/build 2>/dev/null || :
 218             cp -a --parents arch/powerpc/kernel/vdso/gen_vdso*_offsets.sh $kerneldir/build/ 2>/dev/null || :
 219
 220             # v6,1+
 221             cp -a --parents arch/powerpc/kernel/asm-offsets.c $kerneldir/build/ 2>/dev/null || :
 222             cp -a --parents arch/powerpc/kernel/head_booke.h $kerneldir/build/ 2>/dev/null || :
 223         fi
 224         if [ "${ARCH}" = "riscv" ]; then
 225             cp -a --parents arch/riscv/kernel/vdso/*gettimeofday.* $kerneldir/build/
 226             cp -a --parents arch/riscv/kernel/vdso/note.S $kerneldir/build/
 227             # v6.1+
 228             cp -a --parents arch/riscv/kernel/asm-offsets.c $kerneldir/build/
 229             if [ -e arch/riscv/kernel/vdso/gen_vdso_offsets.sh ]; then
 230                     cp -a --parents arch/riscv/kernel/vdso/gen_vdso_offsets.sh $kerneldir/build/
 231             fi
 232             cp -a --parents arch/riscv/kernel/vdso/* $kerneldir/build/ 2>/dev/null || :
 233             if [ -e arch/riscv/kernel/compat_vdso/gen_compat_vdso_offsets.sh ]; then
 234                 cp -a --parents arch/riscv/kernel/compat_vdso/gen_compat_vdso_offsets.sh $kerneldir/build/
 235             fi
 236             cp -a --parents arch/riscv/kernel/compat_vdso/* $kerneldir/build/ 2>/dev/null || :
 237         fi
 238
 239         # include the machine specific headers for ARM variants, if available.
 240         if [ "${ARCH}" = "arm" ]; then
 241             cp -a --parents arch/${ARCH}/mach-*/include $kerneldir/build/
 242
 243             # include a few files for 'make prepare'
 244             cp -a --parents arch/arm/tools/gen-mach-types $kerneldir/build/
 245             cp -a --parents arch/arm/tools/mach-types $kerneldir/build/
 246
 247             # 5.19+
 248             cp -a --parents arch/arm/tools/gen-sysreg.awk $kerneldir/build/     2>/dev/null || :
 249
 250             # ARM syscall table tools only exist for kernels v4.10 or later
 251             SYSCALL_TOOLS=$(find arch/arm/tools -name "syscall*")
 252             if [ -n "$SYSCALL_TOOLS" ] ; then
 253                 cp -a --parents $SYSCALL_TOOLS $kerneldir/build/
 254             fi
 255
 256             cp -a --parents arch/arm/kernel/module.lds $kerneldir/build/ 2>/dev/null || :
 257             # v6.1+
 258             cp -a --parents arch/arm/kernel/asm-offsets.c $kerneldir/build/ 2>/dev/null || :
 259             cp -a --parents arch/arm/kernel/signal.h $kerneldir/build/ 2>/dev/null || :
 260         fi
 261
 262         if [ -d arch/${ARCH}/include ]; then
 263             cp -a --parents arch/${ARCH}/include $kerneldir/build/
 264         fi
 265
 266         cp -a include $kerneldir/build
 267
 268         cp -a --parents lib/vdso/* $kerneldir/build/ 2>/dev/null || :
 269
 270         cp -a --parents tools/include/tools/le_byteshift.h $kerneldir/build/
 271         cp -a --parents tools/include/tools/be_byteshift.h $kerneldir/build/
 272
 273         # required for generate missing syscalls prepare phase
 274         cp -a --parents $(find arch/x86 -type f -name "syscall_32.tbl") $kerneldir/build
 275         cp -a --parents $(find arch/arm -type f -name "*.tbl") $kerneldir/build 2>/dev/null || :
 276
 277         if [ "${ARCH}" = "x86" ]; then
 278             # files for 'make prepare' to succeed with kernel-devel
 279             cp -a --parents $(find arch/x86 -type f -name "syscall_32.tbl") $kerneldir/build/ 2>/dev/null || :
 280             cp -a --parents $(find arch/x86 -type f -name "syscalltbl.sh") $kerneldir/build/ 2>/dev/null || :
 281             cp -a --parents $(find arch/x86 -type f -name "syscallhdr.sh") $kerneldir/build/ 2>/dev/null || :
 282             cp -a --parents $(find arch/x86 -type f -name "syscall_64.tbl") $kerneldir/build/ 2>/dev/null || :
 283             cp -a --parents arch/x86/tools/relocs_32.c $kerneldir/build/
 284             cp -a --parents arch/x86/tools/relocs_64.c $kerneldir/build/
 285             cp -a --parents arch/x86/tools/relocs.c $kerneldir/build/
 286             cp -a --parents arch/x86/tools/relocs_common.c $kerneldir/build/
 287             cp -a --parents arch/x86/tools/relocs.h $kerneldir/build/
 288             cp -a --parents arch/x86/tools/gen-insn-attr-x86.awk $kerneldir/build/ 2>/dev/null || :
 289             cp -a --parents arch/x86/purgatory/purgatory.c $kerneldir/build/
 290
 291             # 4.18 + have unified the purgatory files, so we ignore any errors if
 292             # these files are not present
 293             cp -a --parents arch/x86/purgatory/sha256.h $kerneldir/build/ 2>/dev/null || :
 294             cp -a --parents arch/x86/purgatory/sha256.c $kerneldir/build/ 2>/dev/null || :
 295
 296             cp -a --parents arch/x86/purgatory/stack.S $kerneldir/build/
 297             cp -a --parents arch/x86/purgatory/string.c $kerneldir/build/ 2>/dev/null || :
 298             cp -a --parents arch/x86/purgatory/setup-x86_64.S $kerneldir/build/
 299             cp -a --parents arch/x86/purgatory/entry64.S $kerneldir/build/
 300             cp -a --parents arch/x86/boot/string.h $kerneldir/build/
 301             cp -a --parents arch/x86/boot/string.c $kerneldir/build/
 302             cp -a --parents arch/x86/boot/compressed/string.c $kerneldir/build/ 2>/dev/null || :
 303             cp -a --parents arch/x86/boot/ctype.h $kerneldir/build/
 304
 305             # objtool requires these files
 306             cp -a --parents arch/x86/lib/inat.c $kerneldir/build/ 2>/dev/null || :
 307             cp -a --parents arch/x86/lib/insn.c $kerneldir/build/ 2>/dev/null || :
 308
 309             # v6.1+
 310             cp -a --parents arch/x86/kernel/asm-offsets* $kerneldir/build || :
 311             # for capabilities.h, vmx.h
 312             cp -a --parents arch/x86/kvm/vmx/*.h $kerneldir/build || :
 313             # for lapic.h, hyperv.h ....
 314             cp -a --parents arch/x86/kvm/*.h $kerneldir/build || :
 315         fi
 316
 317         # moved from arch/mips to all arches for v6.1+
 318         cp -a --parents kernel/time/timeconst.bc $kerneldir/build 2>/dev/null || :
 319         cp -a --parents kernel/bounds.c $kerneldir/build 2>/dev/null || :
 320
 321         if [ "${ARCH}" = "mips" ]; then
 322             cp -a --parents arch/mips/Kbuild.platforms $kerneldir/build/
 323             cp --parents $(find  -type f -name "Platform") $kerneldir/build
 324             cp --parents arch/mips/boot/tools/relocs* $kerneldir/build
 325             cp -a --parents arch/mips/kernel/asm-offsets.c $kerneldir/build
 326             cp -a --parents Kbuild $kerneldir/build
 327             cp -a --parents arch/mips/kernel/syscalls/*.sh $kerneldir/build 2>/dev/null || :
 328             cp -a --parents arch/mips/kernel/syscalls/*.tbl $kerneldir/build 2>/dev/null || :
 329             cp -a --parents arch/mips/tools/elf-entry.c $kerneldir/build 2>/dev/null || :
 330         fi
 331
 332         if [ "${ARCH}" = "loongarch" ]; then
 333             cp -a --parents arch/loongarch/kernel/asm-offsets.c $kerneldir/build
 334             cp -a --parents Kbuild $kerneldir/build
 335             cp -a --parents arch/loongarch/vdso/*.S $kerneldir/build 2>/dev/null || :
 336             cp -a --parents arch/loongarch/vdso/*gettimeofday.* $kerneldir/build 2>/dev/null || :
 337             cp -a --parents arch/loongarch/vdso/*getcpu.* $kerneldir/build 2>/dev/null || :
 338             cp -a --parents arch/loongarch/vdso/gen_vdso*_offsets.sh $kerneldir/build/ 2>/dev/null || :
 339         fi
 340
 341         # required to build scripts/selinux/genheaders/genheaders
 342         cp -a --parents security/selinux/include/* $kerneldir/build/
 343
 344         # copy any localversion files
 345         cp -a localversion* $kerneldir/build/ 2>/dev/null || :
 346     )
 347
 348     # Make sure the Makefile and version.h have a matching timestamp so that
 349     # external modules can be built
 350     touch -r $kerneldir/build/Makefile $kerneldir/build/include/generated/uapi/linux/version.h
 351
 352     # This fixes a warning that the compilers don't match when building a module
 353     # Change: CONFIG_CC_VERSION_TEXT="x86_64-poky-linux-gcc (GCC) 12.2.0" to "gcc (GCC) 12.2.0"
 354     #         #define CONFIG_CC_VERSION_TEXT "x86_64-poky-linux-gcc (GCC) 12.2.0" to "gcc (GCC) 12.2.0"
 355     sed -i 's/CONFIG_CC_VERSION_TEXT=".*\(gcc.*\)"/CONFIG_CC_VERSION_TEXT="\1"/' "$kerneldir/build/.config"
 356     sed -i 's/#define CONFIG_CC_VERSION_TEXT ".*\(gcc.*\)"/#define CONFIG_CC_VERSION_TEXT "\1"/' $kerneldir/build/include/generated/autoconf.h
 357     sed -i 's/CONFIG_CC_VERSION_TEXT=".*\(gcc.*\)"/CONFIG_CC_VERSION_TEXT="\1"/' $kerneldir/build/include/config/auto.conf
 358
 359     # make sure these are at least as old as the .config, or rebuilds will trigger
 360     touch -r $kerneldir/build/.config $kerneldir/build/include/generated/autoconf.h 2>/dev/null || :
 361     touch -r $kerneldir/build/.config $kerneldir/build/include/config/auto.conf* 2>/dev/null || :
 362
 363     if [ -e "$kerneldir/build/include/config/auto.conf.cmd" ]; then
 364         sed -i 's/ifneq "$(CC)" ".*-linux-.*gcc.*$/ifneq "$(CC)" "gcc"/' "$kerneldir/build/include/config/auto.conf.cmd"
 365         sed -i 's/ifneq "$(LD)" ".*-linux-.*ld.bfd.*$/ifneq "$(LD)" "ld"/' "$kerneldir/build/include/config/auto.conf.cmd"
 366         sed -i 's/ifneq "$(AR)" ".*-linux-.*ar.*$/ifneq "$(AR)" "ar"/' "$kerneldir/build/include/config/auto.conf.cmd"
 367         sed -i 's/ifneq "$(OBJCOPY)" ".*-linux-.*objcopy.*$/ifneq "$(OBJCOPY)" "objcopy"/' "$kerneldir/build/include/config/auto.conf.cmd"
 368         if [ "${ARCH}" = "powerpc" ]; then
 369             sed -i 's/ifneq "$(NM)" ".*-linux-.*nm.*$/ifneq "$(NM)" "nm --synthetic"/' "$kerneldir/build/include/config/auto.conf.cmd"
 370         else
 371             sed -i 's/ifneq "$(NM)" ".*-linux-.*nm.*$/ifneq "$(NM)" "nm"/' "$kerneldir/build/include/config/auto.conf.cmd"
 372         fi
 373         sed -i 's/ifneq "$(HOSTCXX)" ".*$/ifneq "$(HOSTCXX)" "g++"/' "$kerneldir/build/include/config/auto.conf.cmd"
 374         sed -i 's/ifneq "$(HOSTCC)" ".*$/ifneq "$(HOSTCC)" "gcc"/' "$kerneldir/build/include/config/auto.conf.cmd"
 375         sed -i 's/ifneq "$(CC_VERSION_TEXT)".*\(gcc.*\)"/ifneq "$(CC_VERSION_TEXT)" "\1"/' "$kerneldir/build/include/config/auto.conf.cmd"
 376         sed -i 's/ifneq "$(srctree)" ".*"/ifneq "$(srctree)" "."/' "$kerneldir/build/include/config/auto.conf.cmd"
 377         # we don't build against the defconfig, so make sure it isn't the trigger for syncconfig
 378         sed -i 's/ifneq "$(KBUILD_DEFCONFIG)".*"\(.*\)"/ifneq "\1" "\1"/' "$kerneldir/build/include/config/auto.conf.cmd"
 379     fi
 380
 381     # make the scripts python3 safe. We won't be running these, and if they are
 382     # left as /usr/bin/python rootfs assembly will fail, since we only have python3
 383     # in the RDEPENDS (and the python3 package does not include /usr/bin/python)
 384     for ss in $(find $kerneldir/build/scripts -type f -name '*'); do
 385         sed -i 's,/usr/bin/python2,/usr/bin/env python3,' "$ss"
 386         sed -i 's,/usr/bin/env python2,/usr/bin/env python3,' "$ss"
 387         sed -i 's,/usr/bin/python,/usr/bin/env python3,' "$ss"
 388     done
 389
 390     chown -R root:root ${D}
 391 }
 392
 393 # Ensure we don't race against "make scripts" during cpio
 394 do_install[lockfiles] = "${TMPDIR}/kernel-scripts.lock"
 395
 396 FILES:${PN} = "${KERNEL_BUILD_ROOT} ${KERNEL_SRC_PATH}"
 397 FILES:${PN}-dbg += "${KERNEL_BUILD_ROOT}*/build/scripts/*/.debug/*"
 398
 399 RDEPENDS:${PN} = "bc python3-core flex bison ${TCLIBC}-utils gawk"
 400 # 4.15+ needs these next two RDEPENDS
 401 RDEPENDS:${PN} += "openssl-dev util-linux"
 402 # and x86 needs a bit more for 4.15+
 403 RDEPENDS:${PN} += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-dev', '', d)}"
 404 # powerpc needs elfutils on 6.3+
 405 RDEPENDS:${PN} += "${@bb.utils.contains('ARCH', 'powerpc', 'elfutils-dev', '', d)}"
 406 # 5.8+ needs gcc-plugins libmpc-dev
 407 RDEPENDS:${PN} += "gcc-plugins libmpc-dev"
 408 # 5.13+ needs grep for powerpc
 409 RDEPENDS:${PN}:append:powerpc = " grep"