meta/recipes-kernel/linux/kernel-devsrc.bb

   1 SUMMARY = "Linux kernel Development Source"
   2 DESCRIPTION = "Development source linux kernel. When built, this recipe packages the \
   3 source of the preferred virtual/kernel provider and makes it available for full kernel \
   4 development or external module builds"
   5
   6 SECTION = "kernel"
   7
   8 LICENSE = "GPLv2"
   9
  10 inherit linux-kernel-base
  11
  12 # Whilst not a module, this ensures we don't get multilib extended (which would make no sense)
  13 inherit module-base
  14
  15 # We need the kernel to be staged (unpacked, patched and configured) before
  16 # we can grab the source and make the source package. We also need the bits from
  17 # ${B} not to change while we install, so virtual/kernel must finish do_compile.
  18 do_install[depends] += "virtual/kernel:do_shared_workdir"
  19 # Need the source, not just the output of populate_sysroot
  20 do_install[depends] += "virtual/kernel:do_install"
  21
  22 # There's nothing to do here, except install the source where we can package it
  23 do_fetch[noexec] = "1"
  24 do_unpack[noexec] = "1"
  25 do_patch[noexec] = "1"
  26 do_configure[noexec] = "1"
  27 do_compile[noexec] = "1"
  28 deltask do_populate_sysroot
  29
  30 S = "${STAGING_KERNEL_DIR}"
  31 B = "${STAGING_KERNEL_BUILDDIR}"
  32
  33 PACKAGE_ARCH = "${MACHINE_ARCH}"
  34
  35 KERNEL_BUILD_ROOT="${nonarch_base_libdir}/modules/"
  36
  37 do_install() {
  38     kerneldir=${D}${KERNEL_BUILD_ROOT}${KERNEL_VERSION}
  39     install -d $kerneldir
  40
  41     # create the directory structure
  42     rm -f $kerneldir/build
  43     rm -f $kerneldir/source
  44     mkdir -p $kerneldir/build
  45
  46     # for compatibility with some older variants of this package, we
  47     # create  a /usr/src/kernel symlink to /lib/modules/<version>/source
  48     mkdir -p ${D}/usr/src
  49     (
  50         cd ${D}/usr/src
  51         lnr ${D}${KERNEL_BUILD_ROOT}${KERNEL_VERSION}/source kernel
  52     )
  53
  54     # for on target purposes, we unify build and source
  55     (
  56         cd $kerneldir
  57         ln -s build source
  58     )
  59
  60     # first copy everything
  61     (
  62         cd ${S}
  63         cp --parents $(find  -type f -name "Makefile*" -o -name "Kconfig*") $kerneldir/build
  64         cp --parents $(find  -type f -name "Build" -o -name "Build.include") $kerneldir/build
  65     )
  66
  67     # then drop all but the needed Makefiles/Kconfig files
  68     rm -rf $kerneldir/build/scripts
  69     rm -rf $kerneldir/build/include
  70
  71     # now copy in parts from the build that we'll need later
  72     (
  73         cd ${B}
  74
  75         cp Module.symvers $kerneldir/build
  76         cp System.map* $kerneldir/build
  77         if [ -s Module.markers ]; then
  78             cp Module.markers $kerneldir/build
  79         fi
  80
  81         cp -a .config $kerneldir/build
  82
  83         # This scripts copy blow up QA, so for now, we require a more
  84         # complex 'make scripts' to restore these, versus copying them
  85         # here. Left as a reference to indicate that we know the scripts must
  86         # be dealt with.
  87         # cp -a scripts $kerneldir/build
  88
  89         # although module.lds can be regenerated on target via 'make modules_prepare'
  90         # there are several places where 'makes scripts prepare' is done, and that won't
  91         # regenerate the file. So we copy it onto the target as a migration to using
  92         # modules_prepare
  93         cp -a --parents scripts/module.lds $kerneldir/build/ 2>/dev/null || :
  94
  95         if [ -d arch/${ARCH}/scripts ]; then
  96             cp -a arch/${ARCH}/scripts $kerneldir/build/arch/${ARCH}
  97         fi
  98         if [ -f arch/${ARCH}/*lds ]; then
  99             cp -a arch/${ARCH}/*lds $kerneldir/build/arch/${ARCH}
 100         fi
 101
 102         rm -f $kerneldir/build/scripts/*.o
 103         rm -f $kerneldir/build/scripts/*/*.o
 104
 105         if [ "${ARCH}" = "powerpc" ]; then
 106             if [ -e arch/powerpc/lib/crtsavres.S ] ||
 107                    [ -e arch/powerpc/lib/crtsavres.o ]; then
 108                 cp -a --parents arch/powerpc/lib/crtsavres.[So] $kerneldir/build/
 109             fi
 110         fi
 111
 112         if [ "${ARCH}" = "arm64" ]; then
 113             cp -a --parents arch/arm64/kernel/vdso/vdso.lds $kerneldir/build/
 114         fi
 115
 116         cp -a include $kerneldir/build/include
 117
 118         # we don't usually copy generated files, since they can be rebuilt on the target,
 119         # but without this file, we get a forced syncconfig run in v5.8+, which prompts and
 120         # breaks workflows.
 121         cp -a --parents include/generated/autoconf.h $kerneldir/build 2>/dev/null || :
 122     )
 123
 124     # now grab the chunks from the source tree that we need
 125     (
 126         cd ${S}
 127
 128         cp -a scripts $kerneldir/build
 129
 130         # if our build dir had objtool, it will also be rebuilt on target, so
 131         # we copy what is required for that build
 132         if [ -f ${B}/tools/objtool/objtool ]; then
 133             # these are a few files associated with objtool, since we'll need to
 134             # rebuild it
 135             cp -a --parents tools/build/Build.include $kerneldir/build/
 136             cp -a --parents tools/build/Build $kerneldir/build/
 137             cp -a --parents tools/build/fixdep.c $kerneldir/build/
 138             cp -a --parents tools/scripts/utilities.mak $kerneldir/build/
 139
 140             # extra files, just in case
 141             cp -a --parents tools/objtool/* $kerneldir/build/
 142             cp -a --parents tools/lib/* $kerneldir/build/
 143             cp -a --parents tools/lib/subcmd/* $kerneldir/build/
 144
 145             cp -a --parents tools/include/* $kerneldir/build/
 146
 147             cp -a --parents $(find tools/arch/${ARCH}/ -type f) $kerneldir/build/
 148         fi
 149
 150         if [ "${ARCH}" = "arm64" ]; then
 151             # arch/arm64/include/asm/xen references arch/arm
 152             cp -a --parents arch/arm/include/asm/xen $kerneldir/build/
 153             # arch/arm64/include/asm/opcodes.h references arch/arm
 154             cp -a --parents arch/arm/include/asm/opcodes.h $kerneldir/build/
 155
 156             cp -a --parents arch/arm64/kernel/vdso/*gettimeofday.* $kerneldir/build/
 157             cp -a --parents arch/arm64/kernel/vdso/sigreturn.S $kerneldir/build/
 158             cp -a --parents arch/arm64/kernel/vdso/note.S $kerneldir/build/
 159             cp -a --parents arch/arm64/kernel/vdso/gen_vdso_offsets.sh $kerneldir/build/
 160
 161             cp -a --parents arch/arm64/kernel/module.lds $kerneldir/build/ 2>/dev/null || :
 162         fi
 163
 164         if [ "${ARCH}" = "powerpc" ]; then
 165             # 5.0 needs these files, but don't error if they aren't present in the source
 166             cp -a --parents arch/${ARCH}/kernel/syscalls/syscall.tbl $kerneldir/build/ 2>/dev/null || :
 167             cp -a --parents arch/${ARCH}/kernel/syscalls/syscalltbl.sh $kerneldir/build/ 2>/dev/null || :
 168             cp -a --parents arch/${ARCH}/kernel/syscalls/syscallhdr.sh $kerneldir/build/ 2>/dev/null || :
 169         fi
 170
 171         # include the machine specific headers for ARM variants, if available.
 172         if [ "${ARCH}" = "arm" ]; then
 173             cp -a --parents arch/${ARCH}/mach-*/include $kerneldir/build/
 174
 175             # include a few files for 'make prepare'
 176             cp -a --parents arch/arm/tools/gen-mach-types $kerneldir/build/
 177             cp -a --parents arch/arm/tools/mach-types $kerneldir/build/
 178
 179             # ARM syscall table tools only exist for kernels v4.10 or later
 180             SYSCALL_TOOLS=$(find arch/arm/tools -name "syscall*")
 181             if [ -n "$SYSCALL_TOOLS" ] ; then
 182                 cp -a --parents $SYSCALL_TOOLS $kerneldir/build/
 183             fi
 184
 185             cp -a --parents arch/arm/kernel/module.lds $kerneldir/build/
 186         fi
 187
 188         if [ -d arch/${ARCH}/include ]; then
 189             cp -a --parents arch/${ARCH}/include $kerneldir/build/
 190         fi
 191
 192         cp -a include $kerneldir/build
 193
 194         cp -a --parents lib/vdso/* $kerneldir/build/ 2>/dev/null || :
 195
 196         cp -a --parents tools/include/tools/le_byteshift.h $kerneldir/build/
 197         cp -a --parents tools/include/tools/be_byteshift.h $kerneldir/build/
 198
 199         # required for generate missing syscalls prepare phase
 200         cp -a --parents $(find arch/x86 -type f -name "syscall_32.tbl") $kerneldir/build
 201         cp -a --parents $(find arch/arm -type f -name "*.tbl") $kerneldir/build 2>/dev/null || :
 202
 203         if [ "${ARCH}" = "x86" ]; then
 204             # files for 'make prepare' to succeed with kernel-devel
 205             cp -a --parents $(find arch/x86 -type f -name "syscall_32.tbl") $kerneldir/build/
 206             cp -a --parents $(find arch/x86 -type f -name "syscalltbl.sh") $kerneldir/build/
 207             cp -a --parents $(find arch/x86 -type f -name "syscallhdr.sh") $kerneldir/build/
 208             cp -a --parents $(find arch/x86 -type f -name "syscall_64.tbl") $kerneldir/build/
 209             cp -a --parents arch/x86/tools/relocs_32.c $kerneldir/build/
 210             cp -a --parents arch/x86/tools/relocs_64.c $kerneldir/build/
 211             cp -a --parents arch/x86/tools/relocs.c $kerneldir/build/
 212             cp -a --parents arch/x86/tools/relocs_common.c $kerneldir/build/
 213             cp -a --parents arch/x86/tools/relocs.h $kerneldir/build/
 214             cp -a --parents arch/x86/tools/gen-insn-attr-x86.awk $kerneldir/build/ 2>/dev/null || :
 215             cp -a --parents arch/x86/purgatory/purgatory.c $kerneldir/build/
 216
 217             # 4.18 + have unified the purgatory files, so we ignore any errors if
 218             # these files are not present
 219             cp -a --parents arch/x86/purgatory/sha256.h $kerneldir/build/ 2>/dev/null || :
 220             cp -a --parents arch/x86/purgatory/sha256.c $kerneldir/build/ 2>/dev/null || :
 221
 222             cp -a --parents arch/x86/purgatory/stack.S $kerneldir/build/
 223             cp -a --parents arch/x86/purgatory/string.c $kerneldir/build/ 2>/dev/null || :
 224             cp -a --parents arch/x86/purgatory/setup-x86_64.S $kerneldir/build/
 225             cp -a --parents arch/x86/purgatory/entry64.S $kerneldir/build/
 226             cp -a --parents arch/x86/boot/string.h $kerneldir/build/
 227             cp -a --parents arch/x86/boot/string.c $kerneldir/build/
 228             cp -a --parents arch/x86/boot/compressed/string.c $kerneldir/build/ 2>/dev/null || :
 229             cp -a --parents arch/x86/boot/ctype.h $kerneldir/build/
 230
 231             # objtool requires these files
 232             cp -a --parents arch/x86/lib/inat.c $kerneldir/build/ 2>/dev/null || :
 233             cp -a --parents arch/x86/lib/insn.c $kerneldir/build/ 2>/dev/null || :
 234         fi
 235
 236         if [ "${ARCH}" = "mips" ]; then
 237             cp -a --parents arch/mips/Kbuild.platforms $kerneldir/build/
 238             cp --parents $(find  -type f -name "Platform") $kerneldir/build
 239             cp --parents arch/mips/boot/tools/relocs* $kerneldir/build
 240             cp -a --parents arch/mips/kernel/asm-offsets.c $kerneldir/build
 241             cp -a --parents kernel/time/timeconst.bc $kerneldir/build
 242             cp -a --parents kernel/bounds.c $kerneldir/build
 243             cp -a --parents Kbuild $kerneldir/build
 244             cp -a --parents arch/mips/kernel/syscalls/*.sh $kerneldir/build 2>/dev/null || :
 245             cp -a --parents arch/mips/kernel/syscalls/*.tbl $kerneldir/build 2>/dev/null || :
 246             cp -a --parents arch/mips/tools/elf-entry.c $kerneldir/build 2>/dev/null || :
 247         fi
 248
 249         # required to build scripts/selinux/genheaders/genheaders
 250         cp -a --parents security/selinux/include/* $kerneldir/build/
 251
 252         # copy any localversion files
 253         cp -a localversion* $kerneldir/build/ 2>/dev/null || :
 254     )
 255
 256     # Make sure the Makefile and version.h have a matching timestamp so that
 257     # external modules can be built
 258     touch -r $kerneldir/build/Makefile $kerneldir/build/include/generated/uapi/linux/version.h
 259
 260     # Copy .config to include/config/auto.conf so "make prepare" is unnecessary.
 261     cp $kerneldir/build/.config $kerneldir/build/include/config/auto.conf
 262
 263     # make sure these are at least as old as the .config, or rebuilds will trigger
 264     touch -r $kerneldir/build/.config $kerneldir/build/include/generated/autoconf.h 2>/dev/null || :
 265     touch -r $kerneldir/build/.config $kerneldir/build/include/config/auto.conf* 2>/dev/null || :
 266
 267     if [ -e "$kerneldir/build/include/config/auto.conf.cmd" ]; then
 268         sed -i 's/ifneq "$(CC)" ".*-linux-.*gcc.*$/ifneq "$(CC)" "gcc"/' "$kerneldir/build/include/config/auto.conf.cmd"
 269         sed -i 's/ifneq "$(LD)" ".*-linux-.*ld.bfd.*$/ifneq "$(LD)" "ld"/' "$kerneldir/build/include/config/auto.conf.cmd"
 270         sed -i 's/ifneq "$(HOSTCXX)" ".*$/ifneq "$(HOSTCXX)" "g++"/' "$kerneldir/build/include/config/auto.conf.cmd"
 271         sed -i 's/ifneq "$(HOSTCC)" ".*$/ifneq "$(HOSTCC)" "gcc"/' "$kerneldir/build/include/config/auto.conf.cmd"
 272         sed -i 's/ifneq "$(CC_VERSION_TEXT)".*\(gcc.*\)"/ifneq "$(CC_VERSION_TEXT)" "\1"/' "$kerneldir/build/include/config/auto.conf.cmd"
 273         sed -i 's/ifneq "$(srctree)" ".*"/ifneq "$(srctree)" "."/' "$kerneldir/build/include/config/auto.conf.cmd"
 274         # we don't build against the defconfig, so make sure it isn't the trigger for syncconfig
 275         sed -i 's/ifneq "$(KBUILD_DEFCONFIG)".*"\(.*\)"/ifneq "\1" "\1"/' "$kerneldir/build/include/config/auto.conf.cmd"
 276     fi
 277
 278     # make the scripts python3 safe. We won't be running these, and if they are
 279     # left as /usr/bin/python rootfs assembly will fail, since we only have python3
 280     # in the RDEPENDS (and the python3 package does not include /usr/bin/python)
 281     for ss in $(find $kerneldir/build/scripts -type f -name '*'); do
 282         sed -i 's,/usr/bin/python2,/usr/bin/env python3,' "$ss"
 283         sed -i 's,/usr/bin/env python2,/usr/bin/env python3,' "$ss"
 284         sed -i 's,/usr/bin/python,/usr/bin/env python3,' "$ss"
 285     done
 286
 287     chown -R root:root ${D}
 288 }
 289
 290 # Ensure we don't race against "make scripts" during cpio
 291 do_install[lockfiles] = "${TMPDIR}/kernel-scripts.lock"
 292
 293 FILES_${PN} = "${KERNEL_BUILD_ROOT} ${KERNEL_SRC_PATH}"
 294 FILES_${PN}-dbg += "${KERNEL_BUILD_ROOT}*/build/scripts/*/.debug/*"
 295
 296 RDEPENDS_${PN} = "bc python3 flex bison ${TCLIBC}-utils"
 297 # 4.15+ needs these next two RDEPENDS
 298 RDEPENDS_${PN} += "openssl-dev util-linux"
 299 # and x86 needs a bit more for 4.15+
 300 RDEPENDS_${PN} += "${@bb.utils.contains('ARCH', 'x86', 'elfutils', '', d)}"
 301 # 5.8+ needs gcc-plugins libmpc-dev
 302 RDEPENDS_${PN} += "gcc-plugins libmpc-dev"