meta/recipes-kernel/wireless-regdb/wireless-regdb_2024.01.23.bb

   1 SUMMARY = "Wireless Central Regulatory Domain Database"
   2 HOMEPAGE = "https://wireless.wiki.kernel.org/en/developers/regulatory/crda"
   3 SECTION = "net"
   4 LICENSE = "ISC"
   5 LIC_FILES_CHKSUM = "file://LICENSE;md5=07c4f6dea3845b02a18dc00c8c87699c"
   6
   7 SRC_URI = "https://www.kernel.org/pub/software/network/${BPN}/${BP}.tar.xz"
   8 SRC_URI[sha256sum] = "c8a61c9acf76fa7eb4239e89f640dee3e87098d9f69b4d3518c9c60fc6d20c55"
   9
  10 inherit bin_package allarch
  11
  12 do_install() {
  13     install -d -m0755 ${D}${nonarch_libdir}/crda
  14     install -d -m0755 ${D}${sysconfdir}/wireless-regdb/pubkeys
  15     install -m 0644 regulatory.bin ${D}${nonarch_libdir}/crda/regulatory.bin
  16     install -m 0644 wens.key.pub.pem ${D}${sysconfdir}/wireless-regdb/pubkeys/wens.key.pub.pem
  17
  18     install -m 0644 -D regulatory.db ${D}${nonarch_base_libdir}/firmware/regulatory.db
  19     install -m 0644 regulatory.db.p7s ${D}${nonarch_base_libdir}/firmware/regulatory.db.p7s
  20 }
  21
  22 # Install static regulatory DB in /lib/firmware for kernel to load.
  23 # This requires Linux kernel >= v4.15.
  24 # For kernel <= v4.14, inherit the kernel_wireless_regdb.bbclass
  25 # (in meta-networking) in kernel's recipe.
  26 PACKAGES = "${PN}-static ${PN}"
  27 RCONFLICTS:${PN} = "${PN}-static"
  28
  29 FILES:${PN}-static = " \
  30     ${nonarch_base_libdir}/firmware/regulatory.db \
  31     ${nonarch_base_libdir}/firmware/regulatory.db.p7s \
  32 "
  33
  34 # Native users might want to use the source of regulatory DB.
  35 # This is for example used by Linux kernel <= v4.14 and
  36 # kernel_wireless_regdb.bbclass in meta-networking.
  37 do_install:append:class-native() {
  38     install -m 0644 -D db.txt ${D}${libdir}/crda/db.txt
  39 }
  40
  41 RSUGGESTS:${PN} = "crda"
  42
  43 BBCLASSEXTEND = "native"