meta/recipes-multimedia/libtiff/tiff_4.6.0.bb

   1 SUMMARY = "Provides support for the Tag Image File Format (TIFF)"
   2 DESCRIPTION = "Library provides support for the Tag Image File Format \
   3 (TIFF), a widely used format for storing image data.  This library \
   4 provide means to easily access and create TIFF image files."
   5 HOMEPAGE = "http://www.libtiff.org/"
   6 LICENSE = "BSD-2-Clause"
   7 LIC_FILES_CHKSUM = "file://LICENSE.md;md5=a3e32d664d6db1386b4689c8121531c3"
   8
   9 CVE_PRODUCT = "libtiff"
  10
  11 SRC_URI = "http://download.osgeo.org/libtiff/tiff-${PV}.tar.gz \
  12            file://CVE-2023-6277-At-image-reading-compare-data-size-of-some-tags-data.patch \
  13            file://CVE-2023-6277-At-image-reading-compare-data-size-of-some-tags-data-2.patch \
  14            file://CVE-2023-6277-Apply-1-suggestion-s-to-1-file-s.patch \
  15            file://CVE-2023-6228.patch \
  16            "
  17
  18 SRC_URI[sha256sum] = "88b3979e6d5c7e32b50d7ec72fb15af724f6ab2cbf7e10880c360a77e4b5d99a"
  19
  20 # exclude betas
  21 UPSTREAM_CHECK_REGEX = "tiff-(?P<pver>\d+(\.\d+)+).tar"
  22
  23 CVE_STATUS[CVE-2015-7313] = "fixed-version: Tested with check from https://security-tracker.debian.org/tracker/CVE-2015-7313 and already 4.3.0 doesn't have the issue"
  24
  25 inherit autotools multilib_header
  26
  27 CACHED_CONFIGUREVARS = "ax_cv_check_gl_libgl=no"
  28
  29 PACKAGECONFIG ?= "cxx jpeg zlib lzma \
  30                   strip-chopping extrasample-as-alpha check-ycbcr-subsampling"
  31
  32 PACKAGECONFIG[cxx] = "--enable-cxx,--disable-cxx,,"
  33 PACKAGECONFIG[jbig] = "--enable-jbig,--disable-jbig,jbig,"
  34 PACKAGECONFIG[jpeg] = "--enable-jpeg,--disable-jpeg,jpeg,"
  35 PACKAGECONFIG[zlib] = "--enable-zlib,--disable-zlib,zlib,"
  36 PACKAGECONFIG[lzma] = "--enable-lzma,--disable-lzma,xz,"
  37 PACKAGECONFIG[webp] = "--enable-webp,--disable-webp,libwebp,"
  38 PACKAGECONFIG[zstd] = "--enable-zstd,--disable-zstd,zstd,"
  39 PACKAGECONFIG[libdeflate] = "--enable-libdeflate,--disable-libdeflate,libdeflate,"
  40
  41 # Convert single-strip uncompressed images to multiple strips of specified
  42 # size (default: 8192) to reduce memory usage
  43 PACKAGECONFIG[strip-chopping] = "--enable-strip-chopping,--disable-strip-chopping,,"
  44
  45 # Treat a fourth sample with no EXTRASAMPLE_ value as being ASSOCALPHA
  46 PACKAGECONFIG[extrasample-as-alpha] = "--enable-extrasample-as-alpha,--disable-extrasample-as-alpha,,"
  47
  48 # Control picking up YCbCr subsample info. Disable to support files lacking
  49 # the tag
  50 PACKAGECONFIG[check-ycbcr-subsampling] = "--enable-check-ycbcr-subsampling,--disable-check-ycbcr-subsampling,,"
  51
  52 # Support a mechanism allowing reading large strips (usually one strip files)
  53 # in chunks when using TIFFReadScanline. Experimental 4.0+ feature
  54 PACKAGECONFIG[chunky-strip-read] = "--enable-chunky-strip-read,--disable-chunky-strip-read,,"
  55
  56 PACKAGES =+ "tiffxx tiff-utils"
  57 FILES:tiffxx = "${libdir}/libtiffxx.so.*"
  58 FILES:tiff-utils = "${bindir}/*"
  59
  60 do_install:append() {
  61     oe_multilib_header tiffconf.h
  62 }
  63
  64 BBCLASSEXTEND = "native nativesdk"