meta/recipes-support/gnutls/gnutls_3.6.14.bb

   1 SUMMARY = "GNU Transport Layer Security Library"
   2 DESCRIPTION = "a secure communications library implementing the SSL, \
   3 TLS and DTLS protocols and technologies around them."
   4 HOMEPAGE = "https://gnutls.org/"
   5 BUGTRACKER = "https://savannah.gnu.org/support/?group=gnutls"
   6
   7 LICENSE = "GPLv3+ & LGPLv2.1+"
   8 LICENSE_${PN} = "LGPLv2.1+"
   9 LICENSE_${PN}-xx = "LGPLv2.1+"
  10 LICENSE_${PN}-bin = "GPLv3+"
  11 LICENSE_${PN}-openssl = "GPLv3+"
  12
  13 LIC_FILES_CHKSUM = "file://LICENSE;md5=71391c8e0c1cfe68077e7fce3b586283 \
  14                     file://doc/COPYING;md5=c678957b0c8e964aa6c70fd77641a71e \
  15                     file://doc/COPYING.LESSER;md5=a6f89e2100d9b6cdffcea4f398e37343"
  16
  17 DEPENDS = "nettle gmp virtual/libiconv libunistring"
  18 DEPENDS_append_libc-musl = " argp-standalone"
  19
  20 SHRT_VER = "${@d.getVar('PV').split('.')[0]}.${@d.getVar('PV').split('.')[1]}"
  21
  22 SRC_URI = "https://www.gnupg.org/ftp/gcrypt/gnutls/v${SHRT_VER}/gnutls-${PV}.tar.xz \
  23            file://arm_eabi.patch \
  24            file://0001-Modied-the-license-to-GPLv2.1-to-keep-with-LICENSE-f.patch \
  25            file://CVE-2020-24659.patch \
  26            file://CVE-2021-20231.patch \
  27            file://CVE-2021-20232.patch \
  28            file://CVE-2022-2509.patch \
  29 "
  30
  31 SRC_URI[sha256sum] = "5630751adec7025b8ef955af4d141d00d252a985769f51b4059e5affa3d39d63"
  32
  33 inherit autotools texinfo pkgconfig gettext lib_package gtk-doc
  34
  35 PACKAGECONFIG ??= "libidn"
  36
  37 # You must also have CONFIG_SECCOMP enabled in the kernel for
  38 # seccomp to work.
  39 PACKAGECONFIG[seccomp] = "ac_cv_libseccomp=yes,ac_cv_libseccomp=no,libseccomp"
  40 PACKAGECONFIG[libidn] = "--with-idn,--without-idn,libidn2"
  41 PACKAGECONFIG[libtasn1] = "--with-included-libtasn1=no,--with-included-libtasn1,libtasn1"
  42 PACKAGECONFIG[p11-kit] = "--with-p11-kit,--without-p11-kit,p11-kit"
  43 PACKAGECONFIG[tpm] = "--with-tpm,--without-tpm,trousers"
  44
  45 EXTRA_OECONF = " \
  46     --enable-doc \
  47     --disable-libdane \
  48     --disable-guile \
  49     --disable-rpath \
  50     --enable-local-libopts \
  51     --enable-openssl-compatibility \
  52     --with-libpthread-prefix=${STAGING_DIR_HOST}${prefix} \
  53     --with-default-trust-store-file=${sysconfdir}/ssl/certs/ca-certificates.crt \
  54 "
  55
  56 # Otherwise the tools try and use HOSTTOOLS_DIR/bash as a shell.
  57 export POSIX_SHELL="${base_bindir}/sh"
  58
  59 LDFLAGS_append_libc-musl = " -largp"
  60
  61 do_configure_prepend() {
  62         for dir in . lib; do
  63                 rm -f ${dir}/aclocal.m4 ${dir}/m4/libtool.m4 ${dir}/m4/lt*.m4
  64         done
  65 }
  66
  67 PACKAGES =+ "${PN}-openssl ${PN}-xx"
  68
  69 FILES_${PN}-dev += "${bindir}/gnutls-cli-debug"
  70 FILES_${PN}-openssl = "${libdir}/libgnutls-openssl.so.*"
  71 FILES_${PN}-xx = "${libdir}/libgnutlsxx.so.*"
  72
  73 BBCLASSEXTEND = "native nativesdk"