pdns/dnsdistdist/configure.ac

   1 AC_PREREQ([2.69])
   2
   3 AC_INIT([dnsdist], m4_esyscmd(build-aux/gen-version))
   4 AM_INIT_AUTOMAKE([foreign tar-ustar dist-bzip2 no-dist-gzip parallel-tests 1.11 subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_MACRO_DIR([m4])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_PROG_CC
   9 AC_PROG_CXX
  10 AC_LANG([C++])
  11
  12 AC_DEFINE([DNSDIST], [1],
  13   [This is dnsdist]
  14 )
  15
  16 LT_PREREQ([2.2.2])
  17 LT_INIT([disable-static])
  18
  19 CFLAGS="-g -O3 -Wall -Wextra -Wshadow -Wno-unused-parameter -fvisibility=hidden $CFLAGS"
  20 CXXFLAGS="-g -O3 -Wall -Wextra -Wshadow -Wno-unused-parameter -Wmissing-declarations -Wredundant-decls -fvisibility=hidden $CXXFLAGS"
  21
  22 PDNS_WITH_LIBSODIUM
  23 PDNS_CHECK_DNSTAP([auto])
  24 PDNS_CHECK_RAGEL([dnslabeltext.cc], [www.dnsdist.org])
  25 PDNS_WITH_LIBEDIT
  26 PDNS_CHECK_CLOCK_GETTIME
  27
  28 PDNS_CHECK_OS
  29 PTHREAD_SET_NAME
  30 PDNS_CHECK_NETWORK_LIBS
  31 PDNS_CHECK_PTHREAD_NP
  32 PDNS_CHECK_SECURE_MEMSET
  33 AC_FUNC_STRERROR_R
  34
  35 BOOST_REQUIRE([1.42])
  36
  37 PDNS_ENABLE_UNIT_TESTS
  38 PDNS_WITH_RE2
  39 DNSDIST_ENABLE_DNSCRYPT
  40 PDNS_WITH_EBPF
  41 PDNS_WITH_NET_SNMP
  42 PDNS_WITH_LIBCAP
  43
  44 AX_AVAILABLE_SYSTEMD
  45 AX_CHECK_SYSTEMD_FEATURES
  46 AM_CONDITIONAL([HAVE_SYSTEMD], [ test x"$systemd" = "xy" ])
  47 PDNS_WITH_SERVICE_USER([dnsdist])
  48
  49 dnl the *_r functions are in posix so we can use them unconditionally, but the ext/yahttp code is
  50 dnl using the defines.
  51 AC_CHECK_FUNCS_ONCE([localtime_r gmtime_r getrandom])
  52 AC_SUBST([YAHTTP_CFLAGS], ['-I$(top_srcdir)/ext/yahttp'])
  53 AC_SUBST([YAHTTP_LIBS], ['$(top_builddir)/ext/yahttp/yahttp/libyahttp.la'])
  54 AC_SUBST([IPCRYPT_CFLAGS], ['-I$(top_srcdir)/ext/ipcrypt'])
  55 AC_SUBST([IPCRYPT_LIBS], ['$(top_builddir)/ext/ipcrypt/libipcrypt.la'])
  56
  57 PDNS_WITH_LUA([mandatory])
  58 AS_IF([test "x$LUAPC" = "xluajit"], [
  59   # export all symbols with default visibility, to be able to use the Lua FFI interface
  60   AC_MSG_NOTICE([Adding -rdynamic to export all symbols for the Lua FFI interface])
  61   LDFLAGS="$LDFLAGS -rdynamic"
  62 ])
  63 PDNS_CHECK_LUA_HPP
  64
  65 AM_CONDITIONAL([HAVE_GNUTLS], [false])
  66 AM_CONDITIONAL([HAVE_LIBSSL], [false])
  67 AM_CONDITIONAL([HAVE_LMDB], [false])
  68 AM_CONDITIONAL([HAVE_CDB], [false])
  69
  70 PDNS_CHECK_LIBCRYPTO
  71
  72 PDNS_ENABLE_DNS_OVER_TLS
  73 DNSDIST_ENABLE_DNS_OVER_HTTPS
  74
  75 AS_IF([test "x$enable_dns_over_tls" != "xno" -o "x$enable_dns_over_https" != "xno"], [
  76   PDNS_WITH_LIBSSL
  77 ])
  78
  79 AS_IF([test "x$enable_dns_over_tls" != "xno"], [
  80   PDNS_WITH_GNUTLS
  81
  82   AS_IF([test "x$HAVE_GNUTLS" != "x1" -a "x$HAVE_LIBSSL" != "x1"], [
  83     AC_MSG_ERROR([DNS over TLS support requested but neither GnuTLS nor OpenSSL are available])
  84   ])
  85 ])
  86
  87 PDNS_CHECK_LIBH2OEVLOOP
  88 AS_IF([test "x$enable_dns_over_https" != "xno"], [
  89   AS_IF([test "x$HAVE_LIBH2OEVLOOP" != "x1"], [
  90     AC_MSG_ERROR([DNS over HTTPS support requested but libh2o-evloop was not found])
  91   ])
  92
  93   AS_IF([test "x$HAVE_LIBSSL" != "x1"], [
  94     AC_MSG_ERROR([DNS over HTTPS support requested but OpenSSL was not found])
  95   ])
  96 ])
  97
  98 PDNS_WITH_NGHTTP2
  99
 100 DNSDIST_WITH_CDB
 101 PDNS_CHECK_LMDB
 102 PDNS_ENABLE_IPCIPHER
 103
 104 AX_CXX_COMPILE_STDCXX_17([noext], [mandatory])
 105
 106 AC_MSG_CHECKING([whether we will enable compiler security checks])
 107 AC_ARG_ENABLE([hardening],
 108   [AS_HELP_STRING([--disable-hardening], [disable compiler security checks @<:@default=no@:>@])],
 109   [enable_hardening=$enableval],
 110   [enable_hardening=yes]
 111 )
 112 AC_MSG_RESULT([$enable_hardening])
 113
 114 AS_IF([test "x$enable_hardening" != "xno"], [
 115   AC_CC_PIE
 116   AC_CC_STACK_PROTECTOR
 117   AC_CC_PARAM_SSP_BUFFER_SIZE([4])
 118   AC_CC_D_FORTIFY_SOURCE
 119   AC_LD_RELRO
 120 ])
 121
 122 PDNS_INIT_AUTO_VARS
 123
 124 PDNS_ENABLE_SANITIZERS
 125
 126 PDNS_CHECK_PYTHON_VENV
 127
 128 AM_CONDITIONAL([HAVE_MANPAGES], [test -e "$srcdir/dnsdist.1"])
 129 AM_COND_IF([HAVE_MANPAGES],[],[
 130   AM_COND_IF([HAVE_VENV],[],[
 131     AC_MSG_WARN([Python 3 and/or venv module are not available, documentation will not be built.])
 132   ])
 133 ])
 134
 135 LDFLAGS="$RELRO_LDFLAGS $LDFLAGS"
 136
 137 CFLAGS="$SANITIZER_FLAGS $PIE_CFLAGS $CFLAGS"
 138 CXXFLAGS="$SANITIZER_FLAGS $PIE_CFLAGS $CXXFLAGS"
 139
 140 CCVERSION=`$CC --version | head -1`
 141 CXXVERSION=`$CXX --version | head -1`
 142
 143 PROGRAM_LDFLAGS="$PIE_LDFLAGS $PROGRAM_LDFLAGS"
 144 AC_SUBST([PROGRAM_LDFLAGS])
 145
 146 AC_SUBST([AM_CPPFLAGS],
 147   ["AS_ESCAPE([-I$(top_builddir) -I$(top_srcdir)]) $THREADFLAGS $BOOST_CPPFLAGS"]
 148 )
 149
 150 AC_ARG_VAR(PACKAGEVERSION, [The version used in secpoll queries])
 151 AS_IF([test "x$PACKAGEVERSION" != "x"],
 152   [AC_DEFINE_UNQUOTED([PACKAGEVERSION], "$PACKAGEVERSION", [Set to the package version used for secpoll])]
 153 )
 154
 155 AC_CONFIG_FILES([Makefile
 156         ext/yahttp/Makefile
 157         ext/yahttp/yahttp/Makefile
 158         ext/ipcrypt/Makefile])
 159
 160 AC_OUTPUT
 161
 162 AC_MSG_NOTICE([])
 163 AC_MSG_NOTICE([Configuration summary])
 164 AC_MSG_NOTICE([=====================])
 165 AC_MSG_NOTICE([])
 166 AS_IF([test "x$ac_configure_args" != "x"],
 167   [summary_conf_opts=$ac_configure_args],
 168   [summary_conf_opts="(no options)"]
 169 )
 170 AC_MSG_NOTICE([dnsdist configured with: $summary_conf_opts])
 171 AC_MSG_NOTICE([])
 172 AC_MSG_NOTICE([CC: $CC ($CCVERSION)])
 173 AC_MSG_NOTICE([CXX: $CXX ($CXXVERSION)])
 174 AC_MSG_NOTICE([LD: $LD])
 175 AC_MSG_NOTICE([CFLAGS: $CFLAGS])
 176 AC_MSG_NOTICE([CPPFLAGS: $CPPFLAGS])
 177 AC_MSG_NOTICE([CXXFLAGS: $CXXFLAGS])
 178 AC_MSG_NOTICE([LDFLAGS: $LDFLAGS])
 179 AC_MSG_NOTICE([LIBS: $LIBS])
 180 AC_MSG_NOTICE([BOOST_CPPFLAGS: $BOOST_CPPFLAGS])
 181 AC_MSG_NOTICE([])
 182 AC_MSG_NOTICE([Features enabled])
 183 AC_MSG_NOTICE([----------------])
 184 AC_MSG_NOTICE([Lua: $LUAPC])
 185 AC_MSG_NOTICE([Protobuf: yes])
 186 AS_IF([test "x$systemd" != "xn"],
 187   [AC_MSG_NOTICE([systemd: yes])],
 188   [AC_MSG_NOTICE([systemd: no])]
 189 )
 190 AS_IF([test "x$HAVE_IPCIPHER" = "x1"],
 191   [AC_MSG_NOTICE([ipcipher: yes])],
 192   [AC_MSG_NOTICE([ipcipher: no])]
 193 )
 194 AS_IF([test "x$LIBEDIT_LIBS" != "x"],
 195   [AC_MSG_NOTICE([libedit: yes])],
 196   [AC_MSG_NOTICE([libedit: no])]
 197 )
 198 AS_IF([test "x$LIBSODIUM_LIBS" != "x"],
 199   [AC_MSG_NOTICE([libsodium: yes])],
 200   [AC_MSG_NOTICE([libsodium: no])]
 201 )
 202 AS_IF([test "x$enable_dnscrypt" != "xno"],
 203   [AC_MSG_NOTICE([DNSCrypt: yes])],
 204   [AC_MSG_NOTICE([DNSCrypt: no])]
 205 )
 206 AS_IF([test "x$FSTRM_LIBS" != "x"],
 207   [AC_MSG_NOTICE([dnstap: yes])],
 208   [AC_MSG_NOTICE([dnstap: no])]
 209 )
 210 AS_IF([test "x$RE2_LIBS" != "x"],
 211   [AC_MSG_NOTICE([re2: yes])],
 212   [AC_MSG_NOTICE([re2: no])]
 213 )
 214 AS_IF([test "x$NET_SNMP_LIBS" != "x"],
 215   [AC_MSG_NOTICE([SNMP: yes])],
 216   [AC_MSG_NOTICE([SNMP: no])]
 217 )
 218 AS_IF([test "x$enable_dns_over_tls" != "xno"],
 219   [AC_MSG_NOTICE([DNS over TLS: yes])],
 220   [AC_MSG_NOTICE([DNS over TLS: no])]
 221 )
 222 AS_IF([test "x$enable_dns_over_https" != "xno"],
 223   [AC_MSG_NOTICE([DNS over HTTPS (DoH): yes])],
 224   [AC_MSG_NOTICE([DNS over HTTPS (DoH): no])]
 225 )
 226 AS_IF([test "x$enable_dns_over_tls" != "xno"], [
 227   AS_IF([test "x$GNUTLS_LIBS" != "x"],
 228     [AC_MSG_NOTICE([GnuTLS: yes])],
 229     [AC_MSG_NOTICE([GnuTLS: no])]
 230   )]
 231 )
 232 AS_IF([test "x$enable_dns_over_tls" != "xno" -o "x$enable_dns_over_https" != "xno"], [
 233   AS_IF([test "x$LIBSSL_LIBS" != "x"],
 234     [AC_MSG_NOTICE([OpenSSL: yes])],
 235     [AC_MSG_NOTICE([OpenSSL: no])]
 236   )]
 237 )
 238 AS_IF([test "x$NGHTTP2_LIBS" != "x"],
 239   [AC_MSG_NOTICE([nghttp2: yes])],
 240   [AC_MSG_NOTICE([nghttp2: no])]
 241 )
 242 AS_IF([test "x$CDB_LIBS" != "x"],
 243   [AC_MSG_NOTICE([cdb: yes])],
 244   [AC_MSG_NOTICE([cdb: no])]
 245 )
 246 AS_IF([test "x$LMDB_LIBS" != "x"],
 247   [AC_MSG_NOTICE([lmdb: yes])],
 248   [AC_MSG_NOTICE([lmdb: no])]
 249 )
 250
 251 AC_MSG_NOTICE([])