rules.d/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 install_data(
   4         'README',
   5         install_dir : udevrulesdir)
   6
   7 rules = files('''
   8         60-autosuspend.rules
   9         60-block.rules
  10         60-cdrom_id.rules
  11         60-drm.rules
  12         60-evdev.rules
  13         60-fido-id.rules
  14         60-input-id.rules
  15         60-persistent-alsa.rules
  16         60-persistent-input.rules
  17         60-persistent-storage.rules
  18         60-persistent-storage-tape.rules
  19         60-persistent-v4l.rules
  20         60-sensor.rules
  21         60-serial.rules
  22         70-joystick.rules
  23         70-mouse.rules
  24         70-touchpad.rules
  25         75-net-description.rules
  26         75-probe_mtd.rules
  27         78-sound-card.rules
  28         80-net-setup-link.rules
  29 '''.split())
  30
  31 if conf.get('HAVE_KMOD') == 1
  32         rules += files('80-drivers.rules')
  33 endif
  34
  35 if dmi_arches.contains(host_machine.cpu_family())
  36         rules += files('70-memory.rules')
  37 endif
  38
  39 install_data(rules,
  40              install_dir : udevrulesdir)
  41
  42 all_rules = rules
  43
  44 rules_in = '''
  45         50-udev-default.rules
  46         64-btrfs.rules
  47         99-systemd.rules
  48 '''.split()
  49
  50 foreach file : rules_in
  51         gen = configure_file(
  52                 input : file + '.in',
  53                 output : file,
  54                 configuration : substs)
  55         install_data(gen,
  56                      install_dir : udevrulesdir)
  57         all_rules += gen
  58 endforeach