rules.d/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 install_data(
   4         'README',
   5         install_dir : udevrulesdir)
   6
   7 rules = files(
   8         '60-autosuspend.rules',
   9         '60-block.rules',
  10         '60-cdrom_id.rules',
  11         '60-drm.rules',
  12         '60-evdev.rules',
  13         '60-fido-id.rules',
  14         '60-input-id.rules',
  15         '60-persistent-alsa.rules',
  16         '60-persistent-input.rules',
  17         '60-persistent-storage.rules',
  18         '60-persistent-storage-tape.rules',
  19         '60-persistent-v4l.rules',
  20         '60-sensor.rules',
  21         '60-serial.rules',
  22         '70-camera.rules',
  23         '70-joystick.rules',
  24         '70-mouse.rules',
  25         '70-touchpad.rules',
  26         '75-net-description.rules',
  27         '75-probe_mtd.rules',
  28         '78-sound-card.rules',
  29         '80-net-setup-link.rules',
  30         '81-net-dhcp.rules')
  31
  32 if conf.get('HAVE_KMOD') == 1
  33         rules += files('80-drivers.rules')
  34 endif
  35
  36 if dmi_arches.contains(host_machine.cpu_family())
  37         rules += files('70-memory.rules')
  38 endif
  39
  40 install_data(rules,
  41              install_dir : udevrulesdir)
  42
  43 all_rules = rules
  44
  45 rules_in = ['50-udev-default.rules',
  46             '64-btrfs.rules',
  47             '99-systemd.rules']
  48
  49 foreach file : rules_in
  50         all_rules += custom_target(
  51                 file,
  52                 input : file + '.in',
  53                 output: file,
  54                 command : [jinja2_cmdline, '@INPUT@', '@OUTPUT@'],
  55                 install : true,
  56                 install_dir : udevrulesdir)
  57 endforeach