scripts/kernel-doc

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0
   3
   4 use warnings;
   5 use strict;
   6
   7 ## Copyright (c) 1998 Michael Zucchi, All Rights Reserved        ##
   8 ## Copyright (C) 2000, 1  Tim Waugh <twaugh@redhat.com>          ##
   9 ## Copyright (C) 2001  Simon Huggins                             ##
  10 ## Copyright (C) 2005-2012  Randy Dunlap                         ##
  11 ## Copyright (C) 2012  Dan Luedtke                               ##
  12 ##                                                               ##
  13 ## #define enhancements by Armin Kuster <akuster@mvista.com>     ##
  14 ## Copyright (c) 2000 MontaVista Software, Inc.                  ##
  15 #
  16 # Copyright (C) 2022 Tomasz Warniełło (POD)
  17
  18 use Pod::Usage qw/pod2usage/;
  19
  20 =head1 NAME
  21
  22 kernel-doc - Print formatted kernel documentation to stdout
  23
  24 =head1 SYNOPSIS
  25
  26  kernel-doc [-h] [-v] [-Werror] [-Wall] [-Wreturn] [-Wshort-desc[ription]] [-Wcontents-before-sections]
  27    [ -man |
  28      -rst [-sphinx-version VERSION] [-enable-lineno] |
  29      -none
  30    ]
  31    [
  32      -export |
  33      -internal |
  34      [-function NAME] ... |
  35      [-nosymbol NAME] ...
  36    ]
  37    [-no-doc-sections]
  38    [-export-file FILE] ...
  39    FILE ...
  40
  41 Run `kernel-doc -h` for details.
  42
  43 =head1 DESCRIPTION
  44
  45 Read C language source or header FILEs, extract embedded documentation comments,
  46 and print formatted documentation to standard output.
  47
  48 The documentation comments are identified by the "/**" opening comment mark.
  49
  50 See Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
  51
  52 =cut
  53
  54 # more perldoc at the end of the file
  55
  56 ## init lots of data
  57
  58 my $errors = 0;
  59 my $warnings = 0;
  60 my $anon_struct_union = 0;
  61
  62 # match expressions used to find embedded type information
  63 my $type_constant = '\b``([^\`]+)``\b';
  64 my $type_constant2 = '\%([-_\w]+)';
  65 my $type_func = '(\w+)\(\)';
  66 my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
  67 my $type_param_ref = '([\!~]?)\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
  68 my $type_fp_param = '\@(\w+)\(\)';  # Special RST handling for func ptr params
  69 my $type_fp_param2 = '\@(\w+->\S+)\(\)';  # Special RST handling for structs with func ptr params
  70 my $type_env = '(\$\w+)';
  71 my $type_enum = '\&(enum\s*([_\w]+))';
  72 my $type_struct = '\&(struct\s*([_\w]+))';
  73 my $type_typedef = '\&(typedef\s*([_\w]+))';
  74 my $type_union = '\&(union\s*([_\w]+))';
  75 my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
  76 my $type_fallback = '\&([_\w]+)';
  77 my $type_member_func = $type_member . '\(\)';
  78
  79 # Output conversion substitutions.
  80 #  One for each output format
  81
  82 # these are pretty rough
  83 my @highlights_man = (
  84                       [$type_constant, "\$1"],
  85                       [$type_constant2, "\$1"],
  86                       [$type_func, "\\\\fB\$1\\\\fP"],
  87                       [$type_enum, "\\\\fI\$1\\\\fP"],
  88                       [$type_struct, "\\\\fI\$1\\\\fP"],
  89                       [$type_typedef, "\\\\fI\$1\\\\fP"],
  90                       [$type_union, "\\\\fI\$1\\\\fP"],
  91                       [$type_param, "\\\\fI\$1\\\\fP"],
  92                       [$type_param_ref, "\\\\fI\$1\$2\\\\fP"],
  93                       [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
  94                       [$type_fallback, "\\\\fI\$1\\\\fP"]
  95                      );
  96 my $blankline_man = "";
  97
  98 # rst-mode
  99 my @highlights_rst = (
 100                        [$type_constant, "``\$1``"],
 101                        [$type_constant2, "``\$1``"],
 102                        # Note: need to escape () to avoid func matching later
 103                        [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
 104                        [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
 105                        [$type_fp_param, "**\$1\\\\(\\\\)**"],
 106                        [$type_fp_param2, "**\$1\\\\(\\\\)**"],
 107                        [$type_func, "\$1()"],
 108                        [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
 109                        [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
 110                        [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
 111                        [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
 112                        # in rst this can refer to any type
 113                        [$type_fallback, "\\:c\\:type\\:`\$1`"],
 114                        [$type_param_ref, "**\$1\$2**"]
 115                       );
 116 my $blankline_rst = "\n";
 117
 118 # read arguments
 119 if ($#ARGV == -1) {
 120         pod2usage(
 121                 -message => "No arguments!\n",
 122                 -exitval => 1,
 123                 -verbose => 99,
 124                 -sections => 'SYNOPSIS',
 125                 -output => \*STDERR,
 126         );
 127 }
 128
 129 my $kernelversion;
 130 my ($sphinx_major, $sphinx_minor, $sphinx_patch);
 131
 132 my $dohighlight = "";
 133
 134 my $verbose = 0;
 135 my $Werror = 0;
 136 my $Wreturn = 0;
 137 my $Wshort_desc = 0;
 138 my $Wcontents_before_sections = 0;
 139 my $output_mode = "rst";
 140 my $output_preformatted = 0;
 141 my $no_doc_sections = 0;
 142 my $enable_lineno = 0;
 143 my @highlights = @highlights_rst;
 144 my $blankline = $blankline_rst;
 145 my $modulename = "Kernel API";
 146
 147 use constant {
 148     OUTPUT_ALL          => 0, # output all symbols and doc sections
 149     OUTPUT_INCLUDE      => 1, # output only specified symbols
 150     OUTPUT_EXPORTED     => 2, # output exported symbols
 151     OUTPUT_INTERNAL     => 3, # output non-exported symbols
 152 };
 153 my $output_selection = OUTPUT_ALL;
 154 my $show_not_found = 0; # No longer used
 155
 156 my @export_file_list;
 157
 158 my @build_time;
 159 if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
 160     (my $seconds = `date -d"${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
 161     @build_time = gmtime($seconds);
 162 } else {
 163     @build_time = localtime;
 164 }
 165
 166 my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
 167                 'July', 'August', 'September', 'October',
 168                 'November', 'December')[$build_time[4]] .
 169   " " . ($build_time[5]+1900);
 170
 171 # Essentially these are globals.
 172 # They probably want to be tidied up, made more localised or something.
 173 # CAVEAT EMPTOR!  Some of the others I localised may not want to be, which
 174 # could cause "use of undefined value" or other bugs.
 175 my ($function, %function_table, %parametertypes, $declaration_purpose);
 176 my %nosymbol_table = ();
 177 my $declaration_start_line;
 178 my ($type, $declaration_name, $return_type);
 179 my ($newsection, $newcontents, $prototype, $brcount, %source_map);
 180
 181 if (defined($ENV{'KBUILD_VERBOSE'}) && $ENV{'KBUILD_VERBOSE'} =~ '1') {
 182         $verbose = 1;
 183 }
 184
 185 if (defined($ENV{'KCFLAGS'})) {
 186         my $kcflags = "$ENV{'KCFLAGS'}";
 187
 188         if ($kcflags =~ /(\s|^)-Werror(\s|$)/) {
 189                 $Werror = 1;
 190         }
 191 }
 192
 193 # reading this variable is for backwards compat just in case
 194 # someone was calling it with the variable from outside the
 195 # kernel's build system
 196 if (defined($ENV{'KDOC_WERROR'})) {
 197         $Werror = "$ENV{'KDOC_WERROR'}";
 198 }
 199 # other environment variables are converted to command-line
 200 # arguments in cmd_checkdoc in the build system
 201
 202 # Generated docbook code is inserted in a template at a point where
 203 # docbook v3.1 requires a non-zero sequence of RefEntry's; see:
 204 # https://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
 205 # We keep track of number of generated entries and generate a dummy
 206 # if needs be to ensure the expanded template can be postprocessed
 207 # into html.
 208 my $section_counter = 0;
 209
 210 my $lineprefix="";
 211
 212 # Parser states
 213 use constant {
 214     STATE_NORMAL        => 0,        # normal code
 215     STATE_NAME          => 1,        # looking for function name
 216     STATE_BODY_MAYBE    => 2,        # body - or maybe more description
 217     STATE_BODY          => 3,        # the body of the comment
 218     STATE_BODY_WITH_BLANK_LINE => 4, # the body, which has a blank line
 219     STATE_PROTO         => 5,        # scanning prototype
 220     STATE_DOCBLOCK      => 6,        # documentation block
 221     STATE_INLINE        => 7,        # gathering doc outside main block
 222 };
 223 my $state;
 224 my $in_doc_sect;
 225 my $leading_space;
 226
 227 # Inline documentation state
 228 use constant {
 229     STATE_INLINE_NA     => 0, # not applicable ($state != STATE_INLINE)
 230     STATE_INLINE_NAME   => 1, # looking for member name (@foo:)
 231     STATE_INLINE_TEXT   => 2, # looking for member documentation
 232     STATE_INLINE_END    => 3, # done
 233     STATE_INLINE_ERROR  => 4, # error - Comment without header was found.
 234                               # Spit a warning as it's not
 235                               # proper kernel-doc and ignore the rest.
 236 };
 237 my $inline_doc_state;
 238
 239 #declaration types: can be
 240 # 'function', 'struct', 'union', 'enum', 'typedef'
 241 my $decl_type;
 242
 243 # Name of the kernel-doc identifier for non-DOC markups
 244 my $identifier;
 245
 246 my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
 247 my $doc_end = '\*/';
 248 my $doc_com = '\s*\*\s*';
 249 my $doc_com_body = '\s*\* ?';
 250 my $doc_decl = $doc_com . '(\w+)';
 251 # @params and a strictly limited set of supported section names
 252 # Specifically:
 253 #   Match @word:
 254 #         @...:
 255 #         @{section-name}:
 256 # while trying to not match literal block starts like "example::"
 257 #
 258 my $doc_sect = $doc_com .
 259     '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:([^:].*)?$';
 260 my $doc_content = $doc_com_body . '(.*)';
 261 my $doc_block = $doc_com . 'DOC:\s*(.*)?';
 262 my $doc_inline_start = '^\s*/\*\*\s*$';
 263 my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
 264 my $doc_inline_end = '^\s*\*/\s*$';
 265 my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
 266 my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
 267 my $export_symbol_ns = '^\s*EXPORT_SYMBOL_NS(_GPL)?\s*\(\s*(\w+)\s*,\s*\w+\)\s*;';
 268 my $function_pointer = qr{([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)};
 269 my $attribute = qr{__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)}i;
 270
 271 my %parameterdescs;
 272 my %parameterdesc_start_lines;
 273 my @parameterlist;
 274 my %sections;
 275 my @sectionlist;
 276 my %section_start_lines;
 277 my $sectcheck;
 278 my $struct_actual;
 279
 280 my $contents = "";
 281 my $new_start_line = 0;
 282
 283 # the canonical section names. see also $doc_sect above.
 284 my $section_default = "Description";    # default section
 285 my $section_intro = "Introduction";
 286 my $section = $section_default;
 287 my $section_context = "Context";
 288 my $section_return = "Return";
 289
 290 my $undescribed = "-- undescribed --";
 291
 292 reset_state();
 293
 294 while ($ARGV[0] =~ m/^--?(.*)/) {
 295     my $cmd = $1;
 296     shift @ARGV;
 297     if ($cmd eq "man") {
 298         $output_mode = "man";
 299         @highlights = @highlights_man;
 300         $blankline = $blankline_man;
 301     } elsif ($cmd eq "rst") {
 302         $output_mode = "rst";
 303         @highlights = @highlights_rst;
 304         $blankline = $blankline_rst;
 305     } elsif ($cmd eq "none") {
 306         $output_mode = "none";
 307     } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
 308         $modulename = shift @ARGV;
 309     } elsif ($cmd eq "function") { # to only output specific functions
 310         $output_selection = OUTPUT_INCLUDE;
 311         $function = shift @ARGV;
 312         $function_table{$function} = 1;
 313     } elsif ($cmd eq "nosymbol") { # Exclude specific symbols
 314         my $symbol = shift @ARGV;
 315         $nosymbol_table{$symbol} = 1;
 316     } elsif ($cmd eq "export") { # only exported symbols
 317         $output_selection = OUTPUT_EXPORTED;
 318         %function_table = ();
 319     } elsif ($cmd eq "internal") { # only non-exported symbols
 320         $output_selection = OUTPUT_INTERNAL;
 321         %function_table = ();
 322     } elsif ($cmd eq "export-file") {
 323         my $file = shift @ARGV;
 324         push(@export_file_list, $file);
 325     } elsif ($cmd eq "v") {
 326         $verbose = 1;
 327     } elsif ($cmd eq "Werror") {
 328         $Werror = 1;
 329     } elsif ($cmd eq "Wreturn") {
 330         $Wreturn = 1;
 331     } elsif ($cmd eq "Wshort-desc" or $cmd eq "Wshort-description") {
 332         $Wshort_desc = 1;
 333     } elsif ($cmd eq "Wcontents-before-sections") {
 334         $Wcontents_before_sections = 1;
 335     } elsif ($cmd eq "Wall") {
 336         $Wreturn = 1;
 337         $Wshort_desc = 1;
 338         $Wcontents_before_sections = 1;
 339     } elsif (($cmd eq "h") || ($cmd eq "help")) {
 340                 pod2usage(-exitval => 0, -verbose => 2);
 341     } elsif ($cmd eq 'no-doc-sections') {
 342             $no_doc_sections = 1;
 343     } elsif ($cmd eq 'enable-lineno') {
 344             $enable_lineno = 1;
 345     } elsif ($cmd eq 'show-not-found') {
 346         $show_not_found = 1;  # A no-op but don't fail
 347     } elsif ($cmd eq "sphinx-version") {
 348         my $ver_string = shift @ARGV;
 349         if ($ver_string =~ m/^(\d+)(\.\d+)?(\.\d+)?/) {
 350             $sphinx_major = $1;
 351             if (defined($2)) {
 352                 $sphinx_minor = substr($2,1);
 353             } else {
 354                 $sphinx_minor = 0;
 355             }
 356             if (defined($3)) {
 357                 $sphinx_patch = substr($3,1)
 358             } else {
 359                 $sphinx_patch = 0;
 360             }
 361         } else {
 362             die "Sphinx version should either major.minor or major.minor.patch format\n";
 363         }
 364     } else {
 365         # Unknown argument
 366         pod2usage(
 367             -message => "Argument unknown!\n",
 368             -exitval => 1,
 369             -verbose => 99,
 370             -sections => 'SYNOPSIS',
 371             -output => \*STDERR,
 372             );
 373     }
 374     if ($#ARGV < 0){
 375         pod2usage(
 376             -message => "FILE argument missing\n",
 377             -exitval => 1,
 378             -verbose => 99,
 379             -sections => 'SYNOPSIS',
 380             -output => \*STDERR,
 381             );
 382     }
 383 }
 384
 385 # continue execution near EOF;
 386
 387 # The C domain dialect changed on Sphinx 3. So, we need to check the
 388 # version in order to produce the right tags.
 389 sub findprog($)
 390 {
 391         foreach(split(/:/, $ENV{PATH})) {
 392                 return "$_/$_[0]" if(-x "$_/$_[0]");
 393         }
 394 }
 395
 396 sub get_sphinx_version()
 397 {
 398         my $ver;
 399
 400         my $cmd = "sphinx-build";
 401         if (!findprog($cmd)) {
 402                 my $cmd = "sphinx-build3";
 403                 if (!findprog($cmd)) {
 404                         $sphinx_major = 1;
 405                         $sphinx_minor = 2;
 406                         $sphinx_patch = 0;
 407                         printf STDERR "Warning: Sphinx version not found. Using default (Sphinx version %d.%d.%d)\n",
 408                                $sphinx_major, $sphinx_minor, $sphinx_patch;
 409                         return;
 410                 }
 411         }
 412
 413         open IN, "$cmd --version 2>&1 |";
 414         while (<IN>) {
 415                 if (m/^\s*sphinx-build\s+([\d]+)\.([\d\.]+)(\+\/[\da-f]+)?$/) {
 416                         $sphinx_major = $1;
 417                         $sphinx_minor = $2;
 418                         $sphinx_patch = $3;
 419                         last;
 420                 }
 421                 # Sphinx 1.2.x uses a different format
 422                 if (m/^\s*Sphinx.*\s+([\d]+)\.([\d\.]+)$/) {
 423                         $sphinx_major = $1;
 424                         $sphinx_minor = $2;
 425                         $sphinx_patch = $3;
 426                         last;
 427                 }
 428         }
 429         close IN;
 430 }
 431
 432 # get kernel version from env
 433 sub get_kernel_version() {
 434     my $version = 'unknown kernel version';
 435
 436     if (defined($ENV{'KERNELVERSION'})) {
 437         $version = $ENV{'KERNELVERSION'};
 438     }
 439     return $version;
 440 }
 441
 442 #
 443 sub print_lineno {
 444     my $lineno = shift;
 445     if ($enable_lineno && defined($lineno)) {
 446         print ".. LINENO " . $lineno . "\n";
 447     }
 448 }
 449
 450 sub emit_warning {
 451     my $location = shift;
 452     my $msg = shift;
 453     print STDERR "$location: warning: $msg";
 454     ++$warnings;
 455 }
 456 ##
 457 # dumps section contents to arrays/hashes intended for that purpose.
 458 #
 459 sub dump_section {
 460     my $file = shift;
 461     my $name = shift;
 462     my $contents = join "\n", @_;
 463
 464     if ($name =~ m/$type_param/) {
 465         $name = $1;
 466         $parameterdescs{$name} = $contents;
 467         $sectcheck = $sectcheck . $name . " ";
 468         $parameterdesc_start_lines{$name} = $new_start_line;
 469         $new_start_line = 0;
 470     } elsif ($name eq "@\.\.\.") {
 471         $name = "...";
 472         $parameterdescs{$name} = $contents;
 473         $sectcheck = $sectcheck . $name . " ";
 474         $parameterdesc_start_lines{$name} = $new_start_line;
 475         $new_start_line = 0;
 476     } else {
 477         if (defined($sections{$name}) && ($sections{$name} ne "")) {
 478             # Only warn on user specified duplicate section names.
 479             if ($name ne $section_default) {
 480                 emit_warning("${file}:$.", "duplicate section name '$name'\n");
 481             }
 482             $sections{$name} .= $contents;
 483         } else {
 484             $sections{$name} = $contents;
 485             push @sectionlist, $name;
 486             $section_start_lines{$name} = $new_start_line;
 487             $new_start_line = 0;
 488         }
 489     }
 490 }
 491
 492 ##
 493 # dump DOC: section after checking that it should go out
 494 #
 495 sub dump_doc_section {
 496     my $file = shift;
 497     my $name = shift;
 498     my $contents = join "\n", @_;
 499
 500     if ($no_doc_sections) {
 501         return;
 502     }
 503
 504     return if (defined($nosymbol_table{$name}));
 505
 506     if (($output_selection == OUTPUT_ALL) ||
 507         (($output_selection == OUTPUT_INCLUDE) &&
 508          defined($function_table{$name})))
 509     {
 510         dump_section($file, $name, $contents);
 511         output_blockhead({'sectionlist' => \@sectionlist,
 512                           'sections' => \%sections,
 513                           'module' => $modulename,
 514                           'content-only' => ($output_selection != OUTPUT_ALL), });
 515     }
 516 }
 517
 518 ##
 519 # output function
 520 #
 521 # parameterdescs, a hash.
 522 #  function => "function name"
 523 #  parameterlist => @list of parameters
 524 #  parameterdescs => %parameter descriptions
 525 #  sectionlist => @list of sections
 526 #  sections => %section descriptions
 527 #
 528
 529 sub output_highlight {
 530     my $contents = join "\n",@_;
 531     my $line;
 532
 533 #   DEBUG
 534 #   if (!defined $contents) {
 535 #       use Carp;
 536 #       confess "output_highlight got called with no args?\n";
 537 #   }
 538
 539 #   print STDERR "contents b4:$contents\n";
 540     eval $dohighlight;
 541     die $@ if $@;
 542 #   print STDERR "contents af:$contents\n";
 543
 544     foreach $line (split "\n", $contents) {
 545         if (! $output_preformatted) {
 546             $line =~ s/^\s*//;
 547         }
 548         if ($line eq ""){
 549             if (! $output_preformatted) {
 550                 print $lineprefix, $blankline;
 551             }
 552         } else {
 553             if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
 554                 print "\\&$line";
 555             } else {
 556                 print $lineprefix, $line;
 557             }
 558         }
 559         print "\n";
 560     }
 561 }
 562
 563 ##
 564 # output function in man
 565 sub output_function_man(%) {
 566     my %args = %{$_[0]};
 567     my ($parameter, $section);
 568     my $count;
 569
 570     print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
 571
 572     print ".SH NAME\n";
 573     print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
 574
 575     print ".SH SYNOPSIS\n";
 576     if ($args{'functiontype'} ne "") {
 577         print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
 578     } else {
 579         print ".B \"" . $args{'function'} . "\n";
 580     }
 581     $count = 0;
 582     my $parenth = "(";
 583     my $post = ",";
 584     foreach my $parameter (@{$args{'parameterlist'}}) {
 585         if ($count == $#{$args{'parameterlist'}}) {
 586             $post = ");";
 587         }
 588         $type = $args{'parametertypes'}{$parameter};
 589         if ($type =~ m/$function_pointer/) {
 590             # pointer-to-function
 591             print ".BI \"" . $parenth . $1 . "\" " . " \") (" . $2 . ")" . $post . "\"\n";
 592         } else {
 593             $type =~ s/([^\*])$/$1 /;
 594             print ".BI \"" . $parenth . $type . "\" " . " \"" . $post . "\"\n";
 595         }
 596         $count++;
 597         $parenth = "";
 598     }
 599
 600     print ".SH ARGUMENTS\n";
 601     foreach $parameter (@{$args{'parameterlist'}}) {
 602         my $parameter_name = $parameter;
 603         $parameter_name =~ s/\[.*//;
 604
 605         print ".IP \"" . $parameter . "\" 12\n";
 606         output_highlight($args{'parameterdescs'}{$parameter_name});
 607     }
 608     foreach $section (@{$args{'sectionlist'}}) {
 609         print ".SH \"", uc $section, "\"\n";
 610         output_highlight($args{'sections'}{$section});
 611     }
 612 }
 613
 614 ##
 615 # output enum in man
 616 sub output_enum_man(%) {
 617     my %args = %{$_[0]};
 618     my ($parameter, $section);
 619     my $count;
 620
 621     print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
 622
 623     print ".SH NAME\n";
 624     print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
 625
 626     print ".SH SYNOPSIS\n";
 627     print "enum " . $args{'enum'} . " {\n";
 628     $count = 0;
 629     foreach my $parameter (@{$args{'parameterlist'}}) {
 630         print ".br\n.BI \"    $parameter\"\n";
 631         if ($count == $#{$args{'parameterlist'}}) {
 632             print "\n};\n";
 633             last;
 634         }
 635         else {
 636             print ", \n.br\n";
 637         }
 638         $count++;
 639     }
 640
 641     print ".SH Constants\n";
 642     foreach $parameter (@{$args{'parameterlist'}}) {
 643         my $parameter_name = $parameter;
 644         $parameter_name =~ s/\[.*//;
 645
 646         print ".IP \"" . $parameter . "\" 12\n";
 647         output_highlight($args{'parameterdescs'}{$parameter_name});
 648     }
 649     foreach $section (@{$args{'sectionlist'}}) {
 650         print ".SH \"$section\"\n";
 651         output_highlight($args{'sections'}{$section});
 652     }
 653 }
 654
 655 ##
 656 # output struct in man
 657 sub output_struct_man(%) {
 658     my %args = %{$_[0]};
 659     my ($parameter, $section);
 660
 661     print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
 662
 663     print ".SH NAME\n";
 664     print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
 665
 666     my $declaration = $args{'definition'};
 667     $declaration =~ s/\t/  /g;
 668     $declaration =~ s/\n/"\n.br\n.BI \"/g;
 669     print ".SH SYNOPSIS\n";
 670     print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
 671     print ".BI \"$declaration\n};\n.br\n\n";
 672
 673     print ".SH Members\n";
 674     foreach $parameter (@{$args{'parameterlist'}}) {
 675         ($parameter =~ /^#/) && next;
 676
 677         my $parameter_name = $parameter;
 678         $parameter_name =~ s/\[.*//;
 679
 680         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
 681         print ".IP \"" . $parameter . "\" 12\n";
 682         output_highlight($args{'parameterdescs'}{$parameter_name});
 683     }
 684     foreach $section (@{$args{'sectionlist'}}) {
 685         print ".SH \"$section\"\n";
 686         output_highlight($args{'sections'}{$section});
 687     }
 688 }
 689
 690 ##
 691 # output typedef in man
 692 sub output_typedef_man(%) {
 693     my %args = %{$_[0]};
 694     my ($parameter, $section);
 695
 696     print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
 697
 698     print ".SH NAME\n";
 699     print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
 700
 701     foreach $section (@{$args{'sectionlist'}}) {
 702         print ".SH \"$section\"\n";
 703         output_highlight($args{'sections'}{$section});
 704     }
 705 }
 706
 707 sub output_blockhead_man(%) {
 708     my %args = %{$_[0]};
 709     my ($parameter, $section);
 710     my $count;
 711
 712     print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
 713
 714     foreach $section (@{$args{'sectionlist'}}) {
 715         print ".SH \"$section\"\n";
 716         output_highlight($args{'sections'}{$section});
 717     }
 718 }
 719
 720 ##
 721 # output in restructured text
 722 #
 723
 724 #
 725 # This could use some work; it's used to output the DOC: sections, and
 726 # starts by putting out the name of the doc section itself, but that tends
 727 # to duplicate a header already in the template file.
 728 #
 729 sub output_blockhead_rst(%) {
 730     my %args = %{$_[0]};
 731     my ($parameter, $section);
 732
 733     foreach $section (@{$args{'sectionlist'}}) {
 734         next if (defined($nosymbol_table{$section}));
 735
 736         if ($output_selection != OUTPUT_INCLUDE) {
 737             print ".. _$section:\n\n";
 738             print "**$section**\n\n";
 739         }
 740         print_lineno($section_start_lines{$section});
 741         output_highlight_rst($args{'sections'}{$section});
 742         print "\n";
 743     }
 744 }
 745
 746 #
 747 # Apply the RST highlights to a sub-block of text.
 748 #
 749 sub highlight_block($) {
 750     # The dohighlight kludge requires the text be called $contents
 751     my $contents = shift;
 752     eval $dohighlight;
 753     die $@ if $@;
 754     return $contents;
 755 }
 756
 757 #
 758 # Regexes used only here.
 759 #
 760 my $sphinx_literal = '^[^.].*::$';
 761 my $sphinx_cblock = '^\.\.\ +code-block::';
 762
 763 sub output_highlight_rst {
 764     my $input = join "\n",@_;
 765     my $output = "";
 766     my $line;
 767     my $in_literal = 0;
 768     my $litprefix;
 769     my $block = "";
 770
 771     foreach $line (split "\n",$input) {
 772         #
 773         # If we're in a literal block, see if we should drop out
 774         # of it.  Otherwise pass the line straight through unmunged.
 775         #
 776         if ($in_literal) {
 777             if (! ($line =~ /^\s*$/)) {
 778                 #
 779                 # If this is the first non-blank line in a literal
 780                 # block we need to figure out what the proper indent is.
 781                 #
 782                 if ($litprefix eq "") {
 783                     $line =~ /^(\s*)/;
 784                     $litprefix = '^' . $1;
 785                     $output .= $line . "\n";
 786                 } elsif (! ($line =~ /$litprefix/)) {
 787                     $in_literal = 0;
 788                 } else {
 789                     $output .= $line . "\n";
 790                 }
 791             } else {
 792                 $output .= $line . "\n";
 793             }
 794         }
 795         #
 796         # Not in a literal block (or just dropped out)
 797         #
 798         if (! $in_literal) {
 799             $block .= $line . "\n";
 800             if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
 801                 $in_literal = 1;
 802                 $litprefix = "";
 803                 $output .= highlight_block($block);
 804                 $block = ""
 805             }
 806         }
 807     }
 808
 809     if ($block) {
 810         $output .= highlight_block($block);
 811     }
 812     foreach $line (split "\n", $output) {
 813         print $lineprefix . $line . "\n";
 814     }
 815 }
 816
 817 sub output_function_rst(%) {
 818     my %args = %{$_[0]};
 819     my ($parameter, $section);
 820     my $oldprefix = $lineprefix;
 821     my $start = "";
 822     my $is_macro = 0;
 823
 824     if ($sphinx_major < 3) {
 825         if ($args{'typedef'}) {
 826             print ".. c:type:: ". $args{'function'} . "\n\n";
 827             print_lineno($declaration_start_line);
 828             print "   **Typedef**: ";
 829             $lineprefix = "";
 830             output_highlight_rst($args{'purpose'});
 831             $start = "\n\n**Syntax**\n\n  ``";
 832             $is_macro = 1;
 833         } else {
 834             print ".. c:function:: ";
 835         }
 836     } else {
 837         if ($args{'typedef'} || $args{'functiontype'} eq "") {
 838             $is_macro = 1;
 839             print ".. c:macro:: ". $args{'function'} . "\n\n";
 840         } else {
 841             print ".. c:function:: ";
 842         }
 843
 844         if ($args{'typedef'}) {
 845             print_lineno($declaration_start_line);
 846             print "   **Typedef**: ";
 847             $lineprefix = "";
 848             output_highlight_rst($args{'purpose'});
 849             $start = "\n\n**Syntax**\n\n  ``";
 850         } else {
 851             print "``" if ($is_macro);
 852         }
 853     }
 854     if ($args{'functiontype'} ne "") {
 855         $start .= $args{'functiontype'} . " " . $args{'function'} . " (";
 856     } else {
 857         $start .= $args{'function'} . " (";
 858     }
 859     print $start;
 860
 861     my $count = 0;
 862     foreach my $parameter (@{$args{'parameterlist'}}) {
 863         if ($count ne 0) {
 864             print ", ";
 865         }
 866         $count++;
 867         $type = $args{'parametertypes'}{$parameter};
 868
 869         if ($type =~ m/$function_pointer/) {
 870             # pointer-to-function
 871             print $1 . $parameter . ") (" . $2 . ")";
 872         } else {
 873             print $type;
 874         }
 875     }
 876     if ($is_macro) {
 877         print ")``\n\n";
 878     } else {
 879         print ")\n\n";
 880     }
 881     if (!$args{'typedef'}) {
 882         print_lineno($declaration_start_line);
 883         $lineprefix = "   ";
 884         output_highlight_rst($args{'purpose'});
 885         print "\n";
 886     }
 887
 888     #
 889     # Put our descriptive text into a container (thus an HTML <div>) to help
 890     # set the function prototypes apart.
 891     #
 892     print ".. container:: kernelindent\n\n";
 893     $lineprefix = "  ";
 894     print $lineprefix . "**Parameters**\n\n";
 895     foreach $parameter (@{$args{'parameterlist'}}) {
 896         my $parameter_name = $parameter;
 897         $parameter_name =~ s/\[.*//;
 898         $type = $args{'parametertypes'}{$parameter};
 899
 900         if ($type ne "") {
 901             print $lineprefix . "``$type``\n";
 902         } else {
 903             print $lineprefix . "``$parameter``\n";
 904         }
 905
 906         print_lineno($parameterdesc_start_lines{$parameter_name});
 907
 908         $lineprefix = "    ";
 909         if (defined($args{'parameterdescs'}{$parameter_name}) &&
 910             $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
 911             output_highlight_rst($args{'parameterdescs'}{$parameter_name});
 912         } else {
 913             print $lineprefix . "*undescribed*\n";
 914         }
 915         $lineprefix = "  ";
 916         print "\n";
 917     }
 918
 919     output_section_rst(@_);
 920     $lineprefix = $oldprefix;
 921 }
 922
 923 sub output_section_rst(%) {
 924     my %args = %{$_[0]};
 925     my $section;
 926     my $oldprefix = $lineprefix;
 927
 928     foreach $section (@{$args{'sectionlist'}}) {
 929         print $lineprefix . "**$section**\n\n";
 930         print_lineno($section_start_lines{$section});
 931         output_highlight_rst($args{'sections'}{$section});
 932         print "\n";
 933     }
 934     print "\n";
 935 }
 936
 937 sub output_enum_rst(%) {
 938     my %args = %{$_[0]};
 939     my ($parameter);
 940     my $oldprefix = $lineprefix;
 941     my $count;
 942     my $outer;
 943
 944     if ($sphinx_major < 3) {
 945         my $name = "enum " . $args{'enum'};
 946         print "\n\n.. c:type:: " . $name . "\n\n";
 947     } else {
 948         my $name = $args{'enum'};
 949         print "\n\n.. c:enum:: " . $name . "\n\n";
 950     }
 951     print_lineno($declaration_start_line);
 952     $lineprefix = "  ";
 953     output_highlight_rst($args{'purpose'});
 954     print "\n";
 955
 956     print ".. container:: kernelindent\n\n";
 957     $outer = $lineprefix . "  ";
 958     $lineprefix = $outer . "  ";
 959     print $outer . "**Constants**\n\n";
 960     foreach $parameter (@{$args{'parameterlist'}}) {
 961         print $outer . "``$parameter``\n";
 962
 963         if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
 964             output_highlight_rst($args{'parameterdescs'}{$parameter});
 965         } else {
 966             print $lineprefix . "*undescribed*\n";
 967         }
 968         print "\n";
 969     }
 970     print "\n";
 971     $lineprefix = $oldprefix;
 972     output_section_rst(@_);
 973 }
 974
 975 sub output_typedef_rst(%) {
 976     my %args = %{$_[0]};
 977     my ($parameter);
 978     my $oldprefix = $lineprefix;
 979     my $name;
 980
 981     if ($sphinx_major < 3) {
 982         $name = "typedef " . $args{'typedef'};
 983     } else {
 984         $name = $args{'typedef'};
 985     }
 986     print "\n\n.. c:type:: " . $name . "\n\n";
 987     print_lineno($declaration_start_line);
 988     $lineprefix = "   ";
 989     output_highlight_rst($args{'purpose'});
 990     print "\n";
 991
 992     $lineprefix = $oldprefix;
 993     output_section_rst(@_);
 994 }
 995
 996 sub output_struct_rst(%) {
 997     my %args = %{$_[0]};
 998     my ($parameter);
 999     my $oldprefix = $lineprefix;
1000
1001     if ($sphinx_major < 3) {
1002         my $name = $args{'type'} . " " . $args{'struct'};
1003         print "\n\n.. c:type:: " . $name . "\n\n";
1004     } else {
1005         my $name = $args{'struct'};
1006         if ($args{'type'} eq 'union') {
1007             print "\n\n.. c:union:: " . $name . "\n\n";
1008         } else {
1009             print "\n\n.. c:struct:: " . $name . "\n\n";
1010         }
1011     }
1012     print_lineno($declaration_start_line);
1013     $lineprefix = "  ";
1014     output_highlight_rst($args{'purpose'});
1015     print "\n";
1016
1017     print ".. container:: kernelindent\n\n";
1018     print $lineprefix . "**Definition**::\n\n";
1019     my $declaration = $args{'definition'};
1020     $lineprefix = $lineprefix . "  ";
1021     $declaration =~ s/\t/$lineprefix/g;
1022     print $lineprefix . $args{'type'} . " " . $args{'struct'} . " {\n$declaration" . $lineprefix . "};\n\n";
1023
1024     $lineprefix = "  ";
1025     print $lineprefix . "**Members**\n\n";
1026     foreach $parameter (@{$args{'parameterlist'}}) {
1027         ($parameter =~ /^#/) && next;
1028
1029         my $parameter_name = $parameter;
1030         $parameter_name =~ s/\[.*//;
1031
1032         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
1033         $type = $args{'parametertypes'}{$parameter};
1034         print_lineno($parameterdesc_start_lines{$parameter_name});
1035         print $lineprefix . "``" . $parameter . "``\n";
1036         $lineprefix = "    ";
1037         output_highlight_rst($args{'parameterdescs'}{$parameter_name});
1038         $lineprefix = "  ";
1039         print "\n";
1040     }
1041     print "\n";
1042
1043     $lineprefix = $oldprefix;
1044     output_section_rst(@_);
1045 }
1046
1047 ## none mode output functions
1048
1049 sub output_function_none(%) {
1050 }
1051
1052 sub output_enum_none(%) {
1053 }
1054
1055 sub output_typedef_none(%) {
1056 }
1057
1058 sub output_struct_none(%) {
1059 }
1060
1061 sub output_blockhead_none(%) {
1062 }
1063
1064 ##
1065 # generic output function for all types (function, struct/union, typedef, enum);
1066 # calls the generated, variable output_ function name based on
1067 # functype and output_mode
1068 sub output_declaration {
1069     no strict 'refs';
1070     my $name = shift;
1071     my $functype = shift;
1072     my $func = "output_${functype}_$output_mode";
1073
1074     return if (defined($nosymbol_table{$name}));
1075
1076     if (($output_selection == OUTPUT_ALL) ||
1077         (($output_selection == OUTPUT_INCLUDE ||
1078           $output_selection == OUTPUT_EXPORTED) &&
1079          defined($function_table{$name})) ||
1080         ($output_selection == OUTPUT_INTERNAL &&
1081          !($functype eq "function" && defined($function_table{$name}))))
1082     {
1083         &$func(@_);
1084         $section_counter++;
1085     }
1086 }
1087
1088 ##
1089 # generic output function - calls the right one based on current output mode.
1090 sub output_blockhead {
1091     no strict 'refs';
1092     my $func = "output_blockhead_" . $output_mode;
1093     &$func(@_);
1094     $section_counter++;
1095 }
1096
1097 ##
1098 # takes a declaration (struct, union, enum, typedef) and
1099 # invokes the right handler. NOT called for functions.
1100 sub dump_declaration($$) {
1101     no strict 'refs';
1102     my ($prototype, $file) = @_;
1103     my $func = "dump_" . $decl_type;
1104     &$func(@_);
1105 }
1106
1107 sub dump_union($$) {
1108     dump_struct(@_);
1109 }
1110
1111 sub dump_struct($$) {
1112     my $x = shift;
1113     my $file = shift;
1114     my $decl_type;
1115     my $members;
1116     my $type = qr{struct|union};
1117     # For capturing struct/union definition body, i.e. "{members*}qualifiers*"
1118     my $qualifiers = qr{$attribute|__packed|__aligned|____cacheline_aligned_in_smp|____cacheline_aligned};
1119     my $definition_body = qr{\{(.*)\}\s*$qualifiers*};
1120     my $struct_members = qr{($type)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;};
1121
1122     if ($x =~ /($type)\s+(\w+)\s*$definition_body/) {
1123         $decl_type = $1;
1124         $declaration_name = $2;
1125         $members = $3;
1126     } elsif ($x =~ /typedef\s+($type)\s*$definition_body\s*(\w+)\s*;/) {
1127         $decl_type = $1;
1128         $declaration_name = $3;
1129         $members = $2;
1130     }
1131
1132     if ($members) {
1133         if ($identifier ne $declaration_name) {
1134             emit_warning("${file}:$.", "expecting prototype for $decl_type $identifier. Prototype was for $decl_type $declaration_name instead\n");
1135             return;
1136         }
1137
1138         # ignore members marked private:
1139         $members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1140         $members =~ s/\/\*\s*private:.*//gosi;
1141         # strip comments:
1142         $members =~ s/\/\*.*?\*\///gos;
1143         # strip attributes
1144         $members =~ s/\s*$attribute/ /gi;
1145         $members =~ s/\s*__aligned\s*\([^;]*\)/ /gos;
1146         $members =~ s/\s*__counted_by\s*\([^;]*\)/ /gos;
1147         $members =~ s/\s*__packed\s*/ /gos;
1148         $members =~ s/\s*CRYPTO_MINALIGN_ATTR/ /gos;
1149         $members =~ s/\s*____cacheline_aligned_in_smp/ /gos;
1150         $members =~ s/\s*____cacheline_aligned/ /gos;
1151         # unwrap struct_group():
1152         # - first eat non-declaration parameters and rewrite for final match
1153         # - then remove macro, outer parens, and trailing semicolon
1154         $members =~ s/\bstruct_group\s*\(([^,]*,)/STRUCT_GROUP(/gos;
1155         $members =~ s/\bstruct_group_(attr|tagged)\s*\(([^,]*,){2}/STRUCT_GROUP(/gos;
1156         $members =~ s/\b__struct_group\s*\(([^,]*,){3}/STRUCT_GROUP(/gos;
1157         $members =~ s/\bSTRUCT_GROUP(\(((?:(?>[^)(]+)|(?1))*)\))[^;]*;/$2/gos;
1158
1159         my $args = qr{([^,)]+)};
1160         # replace DECLARE_BITMAP
1161         $members =~ s/__ETHTOOL_DECLARE_LINK_MODE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, __ETHTOOL_LINK_MODE_MASK_NBITS)/gos;
1162         $members =~ s/DECLARE_PHY_INTERFACE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, PHY_INTERFACE_MODE_MAX)/gos;
1163         $members =~ s/DECLARE_BITMAP\s*\($args,\s*$args\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1164         # replace DECLARE_HASHTABLE
1165         $members =~ s/DECLARE_HASHTABLE\s*\($args,\s*$args\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1166         # replace DECLARE_KFIFO
1167         $members =~ s/DECLARE_KFIFO\s*\($args,\s*$args,\s*$args\)/$2 \*$1/gos;
1168         # replace DECLARE_KFIFO_PTR
1169         $members =~ s/DECLARE_KFIFO_PTR\s*\($args,\s*$args\)/$2 \*$1/gos;
1170         # replace DECLARE_FLEX_ARRAY
1171         $members =~ s/(?:__)?DECLARE_FLEX_ARRAY\s*\($args,\s*$args\)/$1 $2\[\]/gos;
1172         #replace DEFINE_DMA_UNMAP_ADDR
1173         $members =~ s/DEFINE_DMA_UNMAP_ADDR\s*\($args\)/dma_addr_t $1/gos;
1174         #replace DEFINE_DMA_UNMAP_LEN
1175         $members =~ s/DEFINE_DMA_UNMAP_LEN\s*\($args\)/__u32 $1/gos;
1176         my $declaration = $members;
1177
1178         # Split nested struct/union elements as newer ones
1179         while ($members =~ m/$struct_members/) {
1180                 my $newmember;
1181                 my $maintype = $1;
1182                 my $ids = $4;
1183                 my $content = $3;
1184                 foreach my $id(split /,/, $ids) {
1185                         $newmember .= "$maintype $id; ";
1186
1187                         $id =~ s/[:\[].*//;
1188                         $id =~ s/^\s*\**(\S+)\s*/$1/;
1189                         foreach my $arg (split /;/, $content) {
1190                                 next if ($arg =~ m/^\s*$/);
1191                                 if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1192                                         # pointer-to-function
1193                                         my $type = $1;
1194                                         my $name = $2;
1195                                         my $extra = $3;
1196                                         next if (!$name);
1197                                         if ($id =~ m/^\s*$/) {
1198                                                 # anonymous struct/union
1199                                                 $newmember .= "$type$name$extra; ";
1200                                         } else {
1201                                                 $newmember .= "$type$id.$name$extra; ";
1202                                         }
1203                                 } else {
1204                                         my $type;
1205                                         my $names;
1206                                         $arg =~ s/^\s+//;
1207                                         $arg =~ s/\s+$//;
1208                                         # Handle bitmaps
1209                                         $arg =~ s/:\s*\d+\s*//g;
1210                                         # Handle arrays
1211                                         $arg =~ s/\[.*\]//g;
1212                                         # The type may have multiple words,
1213                                         # and multiple IDs can be defined, like:
1214                                         #       const struct foo, *bar, foobar
1215                                         # So, we remove spaces when parsing the
1216                                         # names, in order to match just names
1217                                         # and commas for the names
1218                                         $arg =~ s/\s*,\s*/,/g;
1219                                         if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1220                                                 $type = $1;
1221                                                 $names = $2;
1222                                         } else {
1223                                                 $newmember .= "$arg; ";
1224                                                 next;
1225                                         }
1226                                         foreach my $name (split /,/, $names) {
1227                                                 $name =~ s/^\s*\**(\S+)\s*/$1/;
1228                                                 next if (($name =~ m/^\s*$/));
1229                                                 if ($id =~ m/^\s*$/) {
1230                                                         # anonymous struct/union
1231                                                         $newmember .= "$type $name; ";
1232                                                 } else {
1233                                                         $newmember .= "$type $id.$name; ";
1234                                                 }
1235                                         }
1236                                 }
1237                         }
1238                 }
1239                 $members =~ s/$struct_members/$newmember/;
1240         }
1241
1242         # Ignore other nested elements, like enums
1243         $members =~ s/(\{[^\{\}]*\})//g;
1244
1245         create_parameterlist($members, ';', $file, $declaration_name);
1246         check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1247
1248         # Adjust declaration for better display
1249         $declaration =~ s/([\{;])/$1\n/g;
1250         $declaration =~ s/\}\s+;/};/g;
1251         # Better handle inlined enums
1252         do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1253
1254         my @def_args = split /\n/, $declaration;
1255         my $level = 1;
1256         $declaration = "";
1257         foreach my $clause (@def_args) {
1258                 $clause =~ s/^\s+//;
1259                 $clause =~ s/\s+$//;
1260                 $clause =~ s/\s+/ /;
1261                 next if (!$clause);
1262                 $level-- if ($clause =~ m/(\})/ && $level > 1);
1263                 if (!($clause =~ m/^\s*#/)) {
1264                         $declaration .= "\t" x $level;
1265                 }
1266                 $declaration .= "\t" . $clause . "\n";
1267                 $level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1268         }
1269         output_declaration($declaration_name,
1270                            'struct',
1271                            {'struct' => $declaration_name,
1272                             'module' => $modulename,
1273                             'definition' => $declaration,
1274                             'parameterlist' => \@parameterlist,
1275                             'parameterdescs' => \%parameterdescs,
1276                             'parametertypes' => \%parametertypes,
1277                             'sectionlist' => \@sectionlist,
1278                             'sections' => \%sections,
1279                             'purpose' => $declaration_purpose,
1280                             'type' => $decl_type
1281                            });
1282     }
1283     else {
1284         print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1285         ++$errors;
1286     }
1287 }
1288
1289
1290 sub show_warnings($$) {
1291         my $functype = shift;
1292         my $name = shift;
1293
1294         return 0 if (defined($nosymbol_table{$name}));
1295
1296         return 1 if ($output_selection == OUTPUT_ALL);
1297
1298         if ($output_selection == OUTPUT_EXPORTED) {
1299                 if (defined($function_table{$name})) {
1300                         return 1;
1301                 } else {
1302                         return 0;
1303                 }
1304         }
1305         if ($output_selection == OUTPUT_INTERNAL) {
1306                 if (!($functype eq "function" && defined($function_table{$name}))) {
1307                         return 1;
1308                 } else {
1309                         return 0;
1310                 }
1311         }
1312         if ($output_selection == OUTPUT_INCLUDE) {
1313                 if (defined($function_table{$name})) {
1314                         return 1;
1315                 } else {
1316                         return 0;
1317                 }
1318         }
1319         die("Please add the new output type at show_warnings()");
1320 }
1321
1322 sub dump_enum($$) {
1323     my $x = shift;
1324     my $file = shift;
1325     my $members;
1326
1327     # ignore members marked private:
1328     $x =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1329     $x =~ s/\/\*\s*private:.*}/}/gosi;
1330
1331     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1332     # strip #define macros inside enums
1333     $x =~ s@#\s*((define|ifdef)\s+|endif)[^;]*;@@gos;
1334
1335     if ($x =~ /typedef\s+enum\s*\{(.*)\}\s*(\w*)\s*;/) {
1336         $declaration_name = $2;
1337         $members = $1;
1338     } elsif ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1339         $declaration_name = $1;
1340         $members = $2;
1341     }
1342
1343     if ($members) {
1344         if ($identifier ne $declaration_name) {
1345             if ($identifier eq "") {
1346                 emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n");
1347             } else {
1348                 emit_warning("${file}:$.", "expecting prototype for enum $identifier. Prototype was for enum $declaration_name instead\n");
1349             }
1350             return;
1351         }
1352         $declaration_name = "(anonymous)" if ($declaration_name eq "");
1353
1354         my %_members;
1355
1356         $members =~ s/\s+$//;
1357         $members =~ s/\([^;]*?[\)]//g;
1358
1359         foreach my $arg (split ',', $members) {
1360             $arg =~ s/^\s*(\w+).*/$1/;
1361             push @parameterlist, $arg;
1362             if (!$parameterdescs{$arg}) {
1363                 $parameterdescs{$arg} = $undescribed;
1364                 if (show_warnings("enum", $declaration_name)) {
1365                         emit_warning("${file}:$.", "Enum value '$arg' not described in enum '$declaration_name'\n");
1366                 }
1367             }
1368             $_members{$arg} = 1;
1369         }
1370
1371         while (my ($k, $v) = each %parameterdescs) {
1372             if (!exists($_members{$k})) {
1373                 if (show_warnings("enum", $declaration_name)) {
1374                      emit_warning("${file}:$.", "Excess enum value '$k' description in '$declaration_name'\n");
1375                 }
1376             }
1377         }
1378
1379         output_declaration($declaration_name,
1380                            'enum',
1381                            {'enum' => $declaration_name,
1382                             'module' => $modulename,
1383                             'parameterlist' => \@parameterlist,
1384                             'parameterdescs' => \%parameterdescs,
1385                             'sectionlist' => \@sectionlist,
1386                             'sections' => \%sections,
1387                             'purpose' => $declaration_purpose
1388                            });
1389     } else {
1390         print STDERR "${file}:$.: error: Cannot parse enum!\n";
1391         ++$errors;
1392     }
1393 }
1394
1395 my $typedef_type = qr { ((?:\s+[\w\*]+\b){1,8})\s* }x;
1396 my $typedef_ident = qr { \*?\s*(\w\S+)\s* }x;
1397 my $typedef_args = qr { \s*\((.*)\); }x;
1398
1399 my $typedef1 = qr { typedef$typedef_type\($typedef_ident\)$typedef_args }x;
1400 my $typedef2 = qr { typedef$typedef_type$typedef_ident$typedef_args }x;
1401
1402 sub dump_typedef($$) {
1403     my $x = shift;
1404     my $file = shift;
1405
1406     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1407
1408     # Parse function typedef prototypes
1409     if ($x =~ $typedef1 || $x =~ $typedef2) {
1410         $return_type = $1;
1411         $declaration_name = $2;
1412         my $args = $3;
1413         $return_type =~ s/^\s+//;
1414
1415         if ($identifier ne $declaration_name) {
1416             emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1417             return;
1418         }
1419
1420         create_parameterlist($args, ',', $file, $declaration_name);
1421
1422         output_declaration($declaration_name,
1423                            'function',
1424                            {'function' => $declaration_name,
1425                             'typedef' => 1,
1426                             'module' => $modulename,
1427                             'functiontype' => $return_type,
1428                             'parameterlist' => \@parameterlist,
1429                             'parameterdescs' => \%parameterdescs,
1430                             'parametertypes' => \%parametertypes,
1431                             'sectionlist' => \@sectionlist,
1432                             'sections' => \%sections,
1433                             'purpose' => $declaration_purpose
1434                            });
1435         return;
1436     }
1437
1438     while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1439         $x =~ s/\(*.\)\s*;$/;/;
1440         $x =~ s/\[*.\]\s*;$/;/;
1441     }
1442
1443     if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1444         $declaration_name = $1;
1445
1446         if ($identifier ne $declaration_name) {
1447             emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1448             return;
1449         }
1450
1451         output_declaration($declaration_name,
1452                            'typedef',
1453                            {'typedef' => $declaration_name,
1454                             'module' => $modulename,
1455                             'sectionlist' => \@sectionlist,
1456                             'sections' => \%sections,
1457                             'purpose' => $declaration_purpose
1458                            });
1459     }
1460     else {
1461         print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1462         ++$errors;
1463     }
1464 }
1465
1466 sub save_struct_actual($) {
1467     my $actual = shift;
1468
1469     # strip all spaces from the actual param so that it looks like one string item
1470     $actual =~ s/\s*//g;
1471     $struct_actual = $struct_actual . $actual . " ";
1472 }
1473
1474 sub create_parameterlist($$$$) {
1475     my $args = shift;
1476     my $splitter = shift;
1477     my $file = shift;
1478     my $declaration_name = shift;
1479     my $type;
1480     my $param;
1481
1482     # temporarily replace commas inside function pointer definition
1483     my $arg_expr = qr{\([^\),]+};
1484     while ($args =~ /$arg_expr,/) {
1485         $args =~ s/($arg_expr),/$1#/g;
1486     }
1487
1488     foreach my $arg (split($splitter, $args)) {
1489         # strip comments
1490         $arg =~ s/\/\*.*\*\///;
1491         # ignore argument attributes
1492         $arg =~ s/\sPOS0?\s/ /;
1493         # strip leading/trailing spaces
1494         $arg =~ s/^\s*//;
1495         $arg =~ s/\s*$//;
1496         $arg =~ s/\s+/ /;
1497
1498         if ($arg =~ /^#/) {
1499             # Treat preprocessor directive as a typeless variable just to fill
1500             # corresponding data structures "correctly". Catch it later in
1501             # output_* subs.
1502             push_parameter($arg, "", "", $file);
1503         } elsif ($arg =~ m/\(.+\)\s*\(/) {
1504             # pointer-to-function
1505             $arg =~ tr/#/,/;
1506             $arg =~ m/[^\(]+\(\*?\s*([\w\[\]\.]*)\s*\)/;
1507             $param = $1;
1508             $type = $arg;
1509             $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1510             save_struct_actual($param);
1511             push_parameter($param, $type, $arg, $file, $declaration_name);
1512         } elsif ($arg) {
1513             $arg =~ s/\s*:\s*/:/g;
1514             $arg =~ s/\s*\[/\[/g;
1515
1516             my @args = split('\s*,\s*', $arg);
1517             if ($args[0] =~ m/\*/) {
1518                 $args[0] =~ s/(\*+)\s*/ $1/;
1519             }
1520
1521             my @first_arg;
1522             if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1523                     shift @args;
1524                     push(@first_arg, split('\s+', $1));
1525                     push(@first_arg, $2);
1526             } else {
1527                     @first_arg = split('\s+', shift @args);
1528             }
1529
1530             unshift(@args, pop @first_arg);
1531             $type = join " ", @first_arg;
1532
1533             foreach $param (@args) {
1534                 if ($param =~ m/^(\*+)\s*(.*)/) {
1535                     save_struct_actual($2);
1536
1537                     push_parameter($2, "$type $1", $arg, $file, $declaration_name);
1538                 }
1539                 elsif ($param =~ m/(.*?):(\d+)/) {
1540                     if ($type ne "") { # skip unnamed bit-fields
1541                         save_struct_actual($1);
1542                         push_parameter($1, "$type:$2", $arg, $file, $declaration_name)
1543                     }
1544                 }
1545                 else {
1546                     save_struct_actual($param);
1547                     push_parameter($param, $type, $arg, $file, $declaration_name);
1548                 }
1549             }
1550         }
1551     }
1552 }
1553
1554 sub push_parameter($$$$$) {
1555         my $param = shift;
1556         my $type = shift;
1557         my $org_arg = shift;
1558         my $file = shift;
1559         my $declaration_name = shift;
1560
1561         if (($anon_struct_union == 1) && ($type eq "") &&
1562             ($param eq "}")) {
1563                 return;         # ignore the ending }; from anon. struct/union
1564         }
1565
1566         $anon_struct_union = 0;
1567         $param =~ s/[\[\)].*//;
1568
1569         if ($type eq "" && $param =~ /\.\.\.$/)
1570         {
1571             if (!$param =~ /\w\.\.\.$/) {
1572               # handles unnamed variable parameters
1573               $param = "...";
1574             }
1575             elsif ($param =~ /\w\.\.\.$/) {
1576               # for named variable parameters of the form `x...`, remove the dots
1577               $param =~ s/\.\.\.$//;
1578             }
1579             if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1580                 $parameterdescs{$param} = "variable arguments";
1581             }
1582         }
1583         elsif ($type eq "" && ($param eq "" or $param eq "void"))
1584         {
1585             $param="void";
1586             $parameterdescs{void} = "no arguments";
1587         }
1588         elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1589         # handle unnamed (anonymous) union or struct:
1590         {
1591                 $type = $param;
1592                 $param = "{unnamed_" . $param . "}";
1593                 $parameterdescs{$param} = "anonymous\n";
1594                 $anon_struct_union = 1;
1595         }
1596         elsif ($param =~ "__cacheline_group" )
1597         # handle cache group enforcing variables: they do not need be described in header files
1598         {
1599                 return; # ignore __cacheline_group_begin and __cacheline_group_end
1600         }
1601
1602         # warn if parameter has no description
1603         # (but ignore ones starting with # as these are not parameters
1604         # but inline preprocessor statements);
1605         # Note: It will also ignore void params and unnamed structs/unions
1606         if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1607                 $parameterdescs{$param} = $undescribed;
1608
1609                 if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1610                         emit_warning("${file}:$.", "Function parameter or struct member '$param' not described in '$declaration_name'\n");
1611                 }
1612         }
1613
1614         # strip spaces from $param so that it is one continuous string
1615         # on @parameterlist;
1616         # this fixes a problem where check_sections() cannot find
1617         # a parameter like "addr[6 + 2]" because it actually appears
1618         # as "addr[6", "+", "2]" on the parameter list;
1619         # but it's better to maintain the param string unchanged for output,
1620         # so just weaken the string compare in check_sections() to ignore
1621         # "[blah" in a parameter string;
1622         ###$param =~ s/\s*//g;
1623         push @parameterlist, $param;
1624         $org_arg =~ s/\s\s+/ /g;
1625         $parametertypes{$param} = $org_arg;
1626 }
1627
1628 sub check_sections($$$$$) {
1629         my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1630         my @sects = split ' ', $sectcheck;
1631         my @prms = split ' ', $prmscheck;
1632         my $err;
1633         my ($px, $sx);
1634         my $prm_clean;          # strip trailing "[array size]" and/or beginning "*"
1635
1636         foreach $sx (0 .. $#sects) {
1637                 $err = 1;
1638                 foreach $px (0 .. $#prms) {
1639                         $prm_clean = $prms[$px];
1640                         $prm_clean =~ s/\[.*\]//;
1641                         $prm_clean =~ s/$attribute//i;
1642                         # ignore array size in a parameter string;
1643                         # however, the original param string may contain
1644                         # spaces, e.g.:  addr[6 + 2]
1645                         # and this appears in @prms as "addr[6" since the
1646                         # parameter list is split at spaces;
1647                         # hence just ignore "[..." for the sections check;
1648                         $prm_clean =~ s/\[.*//;
1649
1650                         ##$prm_clean =~ s/^\**//;
1651                         if ($prm_clean eq $sects[$sx]) {
1652                                 $err = 0;
1653                                 last;
1654                         }
1655                 }
1656                 if ($err) {
1657                         if ($decl_type eq "function") {
1658                                 emit_warning("${file}:$.",
1659                                         "Excess function parameter " .
1660                                         "'$sects[$sx]' " .
1661                                         "description in '$decl_name'\n");
1662                         }
1663                         elsif (($decl_type eq "struct") or
1664                                ($decl_type eq "union")) {
1665                                 emit_warning("${file}:$.",
1666                                         "Excess $decl_type member " .
1667                                         "'$sects[$sx]' " .
1668                                         "description in '$decl_name'\n");
1669                         }
1670                 }
1671         }
1672 }
1673
1674 ##
1675 # Checks the section describing the return value of a function.
1676 sub check_return_section {
1677         my $file = shift;
1678         my $declaration_name = shift;
1679         my $return_type = shift;
1680
1681         # Ignore an empty return type (It's a macro)
1682         # Ignore functions with a "void" return type. (But don't ignore "void *")
1683         if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1684                 return;
1685         }
1686
1687         if (!defined($sections{$section_return}) ||
1688             $sections{$section_return} eq "") {
1689                 emit_warning("${file}:$.",
1690                         "No description found for return value of " .
1691                         "'$declaration_name'\n");
1692         }
1693 }
1694
1695 ##
1696 # takes a function prototype and the name of the current file being
1697 # processed and spits out all the details stored in the global
1698 # arrays/hashes.
1699 sub dump_function($$) {
1700     my $prototype = shift;
1701     my $file = shift;
1702     my $noret = 0;
1703
1704     print_lineno($new_start_line);
1705
1706     $prototype =~ s/^static +//;
1707     $prototype =~ s/^extern +//;
1708     $prototype =~ s/^asmlinkage +//;
1709     $prototype =~ s/^inline +//;
1710     $prototype =~ s/^__inline__ +//;
1711     $prototype =~ s/^__inline +//;
1712     $prototype =~ s/^__always_inline +//;
1713     $prototype =~ s/^noinline +//;
1714     $prototype =~ s/^__FORTIFY_INLINE +//;
1715     $prototype =~ s/__init +//;
1716     $prototype =~ s/__init_or_module +//;
1717     $prototype =~ s/__deprecated +//;
1718     $prototype =~ s/__flatten +//;
1719     $prototype =~ s/__meminit +//;
1720     $prototype =~ s/__must_check +//;
1721     $prototype =~ s/__weak +//;
1722     $prototype =~ s/__sched +//;
1723     $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1724     $prototype =~ s/__(?:re)?alloc_size\s*\(\s*\d+\s*(?:,\s*\d+\s*)?\) +//;
1725     $prototype =~ s/__diagnose_as\s*\(\s*\S+\s*(?:,\s*\d+\s*)*\) +//;
1726     my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1727     $prototype =~ s/__attribute_const__ +//;
1728     $prototype =~ s/__attribute__\s*\(\(
1729             (?:
1730                  [\w\s]++          # attribute name
1731                  (?:\([^)]*+\))?   # attribute arguments
1732                  \s*+,?            # optional comma at the end
1733             )+
1734           \)\)\s+//x;
1735
1736     # Yes, this truly is vile.  We are looking for:
1737     # 1. Return type (may be nothing if we're looking at a macro)
1738     # 2. Function name
1739     # 3. Function parameters.
1740     #
1741     # All the while we have to watch out for function pointer parameters
1742     # (which IIRC is what the two sections are for), C types (these
1743     # regexps don't even start to express all the possibilities), and
1744     # so on.
1745     #
1746     # If you mess with these regexps, it's a good idea to check that
1747     # the following functions' documentation still comes out right:
1748     # - parport_register_device (function pointer parameters)
1749     # - atomic_set (macro)
1750     # - pci_match_device, __copy_to_user (long return type)
1751     my $name = qr{[a-zA-Z0-9_~:]+};
1752     my $prototype_end1 = qr{[^\(]*};
1753     my $prototype_end2 = qr{[^\{]*};
1754     my $prototype_end = qr{\(($prototype_end1|$prototype_end2)\)};
1755     my $type1 = qr{[\w\s]+};
1756     my $type2 = qr{$type1\*+};
1757
1758     if ($define && $prototype =~ m/^()($name)\s+/) {
1759         # This is an object-like macro, it has no return type and no parameter
1760         # list.
1761         # Function-like macros are not allowed to have spaces between
1762         # declaration_name and opening parenthesis (notice the \s+).
1763         $return_type = $1;
1764         $declaration_name = $2;
1765         $noret = 1;
1766     } elsif ($prototype =~ m/^()($name)\s*$prototype_end/ ||
1767         $prototype =~ m/^($type1)\s+($name)\s*$prototype_end/ ||
1768         $prototype =~ m/^($type2+)\s*($name)\s*$prototype_end/)  {
1769         $return_type = $1;
1770         $declaration_name = $2;
1771         my $args = $3;
1772
1773         create_parameterlist($args, ',', $file, $declaration_name);
1774     } else {
1775         emit_warning("${file}:$.", "cannot understand function prototype: '$prototype'\n");
1776         return;
1777     }
1778
1779     if ($identifier ne $declaration_name) {
1780         emit_warning("${file}:$.", "expecting prototype for $identifier(). Prototype was for $declaration_name() instead\n");
1781         return;
1782     }
1783
1784     my $prms = join " ", @parameterlist;
1785     check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1786
1787     # This check emits a lot of warnings at the moment, because many
1788     # functions don't have a 'Return' doc section. So until the number
1789     # of warnings goes sufficiently down, the check is only performed in
1790     # -Wreturn mode.
1791     # TODO: always perform the check.
1792     if ($Wreturn && !$noret) {
1793             check_return_section($file, $declaration_name, $return_type);
1794     }
1795
1796     # The function parser can be called with a typedef parameter.
1797     # Handle it.
1798     if ($return_type =~ /typedef/) {
1799         output_declaration($declaration_name,
1800                            'function',
1801                            {'function' => $declaration_name,
1802                             'typedef' => 1,
1803                             'module' => $modulename,
1804                             'functiontype' => $return_type,
1805                             'parameterlist' => \@parameterlist,
1806                             'parameterdescs' => \%parameterdescs,
1807                             'parametertypes' => \%parametertypes,
1808                             'sectionlist' => \@sectionlist,
1809                             'sections' => \%sections,
1810                             'purpose' => $declaration_purpose
1811                            });
1812     } else {
1813         output_declaration($declaration_name,
1814                            'function',
1815                            {'function' => $declaration_name,
1816                             'module' => $modulename,
1817                             'functiontype' => $return_type,
1818                             'parameterlist' => \@parameterlist,
1819                             'parameterdescs' => \%parameterdescs,
1820                             'parametertypes' => \%parametertypes,
1821                             'sectionlist' => \@sectionlist,
1822                             'sections' => \%sections,
1823                             'purpose' => $declaration_purpose
1824                            });
1825     }
1826 }
1827
1828 sub reset_state {
1829     $function = "";
1830     %parameterdescs = ();
1831     %parametertypes = ();
1832     @parameterlist = ();
1833     %sections = ();
1834     @sectionlist = ();
1835     $sectcheck = "";
1836     $struct_actual = "";
1837     $prototype = "";
1838
1839     $state = STATE_NORMAL;
1840     $inline_doc_state = STATE_INLINE_NA;
1841 }
1842
1843 sub tracepoint_munge($) {
1844         my $file = shift;
1845         my $tracepointname = 0;
1846         my $tracepointargs = 0;
1847
1848         if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1849                 $tracepointname = $1;
1850         }
1851         if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1852                 $tracepointname = $1;
1853         }
1854         if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1855                 $tracepointname = $2;
1856         }
1857         $tracepointname =~ s/^\s+//; #strip leading whitespace
1858         if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1859                 $tracepointargs = $1;
1860         }
1861         if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1862                 emit_warning("${file}:$.", "Unrecognized tracepoint format: \n".
1863                              "$prototype\n");
1864         } else {
1865                 $prototype = "static inline void trace_$tracepointname($tracepointargs)";
1866                 $identifier = "trace_$identifier";
1867         }
1868 }
1869
1870 sub syscall_munge() {
1871         my $void = 0;
1872
1873         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1874 ##      if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1875         if ($prototype =~ m/SYSCALL_DEFINE0/) {
1876                 $void = 1;
1877 ##              $prototype = "long sys_$1(void)";
1878         }
1879
1880         $prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1881         if ($prototype =~ m/long (sys_.*?),/) {
1882                 $prototype =~ s/,/\(/;
1883         } elsif ($void) {
1884                 $prototype =~ s/\)/\(void\)/;
1885         }
1886
1887         # now delete all of the odd-number commas in $prototype
1888         # so that arg types & arg names don't have a comma between them
1889         my $count = 0;
1890         my $len = length($prototype);
1891         if ($void) {
1892                 $len = 0;       # skip the for-loop
1893         }
1894         for (my $ix = 0; $ix < $len; $ix++) {
1895                 if (substr($prototype, $ix, 1) eq ',') {
1896                         $count++;
1897                         if ($count % 2 == 1) {
1898                                 substr($prototype, $ix, 1) = ' ';
1899                         }
1900                 }
1901         }
1902 }
1903
1904 sub process_proto_function($$) {
1905     my $x = shift;
1906     my $file = shift;
1907
1908     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1909
1910     if ($x =~ m#\s*/\*\s+MACDOC\s*#io || ($x =~ /^#/ && $x !~ /^#\s*define/)) {
1911         # do nothing
1912     }
1913     elsif ($x =~ /([^\{]*)/) {
1914         $prototype .= $1;
1915     }
1916
1917     if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1918         $prototype =~ s@/\*.*?\*/@@gos; # strip comments.
1919         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1920         $prototype =~ s@^\s+@@gos; # strip leading spaces
1921
1922          # Handle prototypes for function pointers like:
1923          # int (*pcs_config)(struct foo)
1924         $prototype =~ s@^(\S+\s+)\(\s*\*(\S+)\)@$1$2@gos;
1925
1926         if ($prototype =~ /SYSCALL_DEFINE/) {
1927                 syscall_munge();
1928         }
1929         if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
1930             $prototype =~ /DEFINE_SINGLE_EVENT/)
1931         {
1932                 tracepoint_munge($file);
1933         }
1934         dump_function($prototype, $file);
1935         reset_state();
1936     }
1937 }
1938
1939 sub process_proto_type($$) {
1940     my $x = shift;
1941     my $file = shift;
1942
1943     $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1944     $x =~ s@^\s+@@gos; # strip leading spaces
1945     $x =~ s@\s+$@@gos; # strip trailing spaces
1946     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1947
1948     if ($x =~ /^#/) {
1949         # To distinguish preprocessor directive from regular declaration later.
1950         $x .= ";";
1951     }
1952
1953     while (1) {
1954         if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
1955             if( length $prototype ) {
1956                 $prototype .= " "
1957             }
1958             $prototype .= $1 . $2;
1959             ($2 eq '{') && $brcount++;
1960             ($2 eq '}') && $brcount--;
1961             if (($2 eq ';') && ($brcount == 0)) {
1962                 dump_declaration($prototype, $file);
1963                 reset_state();
1964                 last;
1965             }
1966             $x = $3;
1967         } else {
1968             $prototype .= $x;
1969             last;
1970         }
1971     }
1972 }
1973
1974
1975 sub map_filename($) {
1976     my $file;
1977     my ($orig_file) = @_;
1978
1979     if (defined($ENV{'SRCTREE'})) {
1980         $file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
1981     } else {
1982         $file = $orig_file;
1983     }
1984
1985     if (defined($source_map{$file})) {
1986         $file = $source_map{$file};
1987     }
1988
1989     return $file;
1990 }
1991
1992 sub process_export_file($) {
1993     my ($orig_file) = @_;
1994     my $file = map_filename($orig_file);
1995
1996     if (!open(IN,"<$file")) {
1997         print STDERR "Error: Cannot open file $file\n";
1998         ++$errors;
1999         return;
2000     }
2001
2002     while (<IN>) {
2003         if (/$export_symbol/) {
2004             next if (defined($nosymbol_table{$2}));
2005             $function_table{$2} = 1;
2006         }
2007         if (/$export_symbol_ns/) {
2008             next if (defined($nosymbol_table{$2}));
2009             $function_table{$2} = 1;
2010         }
2011     }
2012
2013     close(IN);
2014 }
2015
2016 #
2017 # Parsers for the various processing states.
2018 #
2019 # STATE_NORMAL: looking for the /** to begin everything.
2020 #
2021 sub process_normal() {
2022     if (/$doc_start/o) {
2023         $state = STATE_NAME;    # next line is always the function name
2024         $in_doc_sect = 0;
2025         $declaration_start_line = $. + 1;
2026     }
2027 }
2028
2029 #
2030 # STATE_NAME: Looking for the "name - description" line
2031 #
2032 sub process_name($$) {
2033     my $file = shift;
2034     my $descr;
2035
2036     if (/$doc_block/o) {
2037         $state = STATE_DOCBLOCK;
2038         $contents = "";
2039         $new_start_line = $.;
2040
2041         if ( $1 eq "" ) {
2042             $section = $section_intro;
2043         } else {
2044             $section = $1;
2045         }
2046     } elsif (/$doc_decl/o) {
2047         $identifier = $1;
2048         my $is_kernel_comment = 0;
2049         my $decl_start = qr{$doc_com};
2050         # test for pointer declaration type, foo * bar() - desc
2051         my $fn_type = qr{\w+\s*\*\s*};
2052         my $parenthesis = qr{\(\w*\)};
2053         my $decl_end = qr{[-:].*};
2054         if (/^$decl_start([\w\s]+?)$parenthesis?\s*$decl_end?$/) {
2055             $identifier = $1;
2056         }
2057         if ($identifier =~ m/^(struct|union|enum|typedef)\b\s*(\S*)/) {
2058             $decl_type = $1;
2059             $identifier = $2;
2060             $is_kernel_comment = 1;
2061         }
2062         # Look for foo() or static void foo() - description; or misspelt
2063         # identifier
2064         elsif (/^$decl_start$fn_type?(\w+)\s*$parenthesis?\s*$decl_end?$/ ||
2065             /^$decl_start$fn_type?(\w+.*)$parenthesis?\s*$decl_end$/) {
2066             $identifier = $1;
2067             $decl_type = 'function';
2068             $identifier =~ s/^define\s+//;
2069             $is_kernel_comment = 1;
2070         }
2071         $identifier =~ s/\s+$//;
2072
2073         $state = STATE_BODY;
2074         # if there's no @param blocks need to set up default section
2075         # here
2076         $contents = "";
2077         $section = $section_default;
2078         $new_start_line = $. + 1;
2079         if (/[-:](.*)/) {
2080             # strip leading/trailing/multiple spaces
2081             $descr= $1;
2082             $descr =~ s/^\s*//;
2083             $descr =~ s/\s*$//;
2084             $descr =~ s/\s+/ /g;
2085             $declaration_purpose = $descr;
2086             $state = STATE_BODY_MAYBE;
2087         } else {
2088             $declaration_purpose = "";
2089         }
2090
2091         if (!$is_kernel_comment) {
2092             emit_warning("${file}:$.", "This comment starts with '/**', but isn't a kernel-doc comment. Refer Documentation/doc-guide/kernel-doc.rst\n$_");
2093             $state = STATE_NORMAL;
2094         }
2095
2096         if (($declaration_purpose eq "") && $Wshort_desc) {
2097             emit_warning("${file}:$.", "missing initial short description on line:\n$_");
2098         }
2099
2100         if ($identifier eq "" && $decl_type ne "enum") {
2101             emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n$_");
2102             $state = STATE_NORMAL;
2103         }
2104
2105         if ($verbose) {
2106             print STDERR "${file}:$.: info: Scanning doc for $decl_type $identifier\n";
2107         }
2108     } else {
2109         emit_warning("${file}:$.", "Cannot understand $_ on line $. - I thought it was a doc line\n");
2110         $state = STATE_NORMAL;
2111     }
2112 }
2113
2114
2115 #
2116 # STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
2117 #
2118 sub process_body($$) {
2119     my $file = shift;
2120
2121     if ($state == STATE_BODY_WITH_BLANK_LINE && /^\s*\*\s?\S/) {
2122         dump_section($file, $section, $contents);
2123         $section = $section_default;
2124         $new_start_line = $.;
2125         $contents = "";
2126     }
2127
2128     if (/$doc_sect/i) { # case insensitive for supported section names
2129         $in_doc_sect = 1;
2130         $newsection = $1;
2131         $newcontents = $2;
2132
2133         # map the supported section names to the canonical names
2134         if ($newsection =~ m/^description$/i) {
2135             $newsection = $section_default;
2136         } elsif ($newsection =~ m/^context$/i) {
2137             $newsection = $section_context;
2138         } elsif ($newsection =~ m/^returns?$/i) {
2139             $newsection = $section_return;
2140         } elsif ($newsection =~ m/^\@return$/) {
2141             # special: @return is a section, not a param description
2142             $newsection = $section_return;
2143         }
2144
2145         if (($contents ne "") && ($contents ne "\n")) {
2146             if (!$in_doc_sect && $Wcontents_before_sections) {
2147                 emit_warning("${file}:$.", "contents before sections\n");
2148             }
2149             dump_section($file, $section, $contents);
2150             $section = $section_default;
2151         }
2152
2153         $in_doc_sect = 1;
2154         $state = STATE_BODY;
2155         $contents = $newcontents;
2156         $new_start_line = $.;
2157         while (substr($contents, 0, 1) eq " ") {
2158             $contents = substr($contents, 1);
2159         }
2160         if ($contents ne "") {
2161             $contents .= "\n";
2162         }
2163         $section = $newsection;
2164         $leading_space = undef;
2165     } elsif (/$doc_end/) {
2166         if (($contents ne "") && ($contents ne "\n")) {
2167             dump_section($file, $section, $contents);
2168             $section = $section_default;
2169             $contents = "";
2170         }
2171         # look for doc_com + <text> + doc_end:
2172         if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
2173             emit_warning("${file}:$.", "suspicious ending line: $_");
2174         }
2175
2176         $prototype = "";
2177         $state = STATE_PROTO;
2178         $brcount = 0;
2179         $new_start_line = $. + 1;
2180     } elsif (/$doc_content/) {
2181         if ($1 eq "") {
2182             if ($section eq $section_context) {
2183                 dump_section($file, $section, $contents);
2184                 $section = $section_default;
2185                 $contents = "";
2186                 $new_start_line = $.;
2187                 $state = STATE_BODY;
2188             } else {
2189                 if ($section ne $section_default) {
2190                     $state = STATE_BODY_WITH_BLANK_LINE;
2191                 } else {
2192                     $state = STATE_BODY;
2193                 }
2194                 $contents .= "\n";
2195             }
2196         } elsif ($state == STATE_BODY_MAYBE) {
2197             # Continued declaration purpose
2198             chomp($declaration_purpose);
2199             $declaration_purpose .= " " . $1;
2200             $declaration_purpose =~ s/\s+/ /g;
2201         } else {
2202             my $cont = $1;
2203             if ($section =~ m/^@/ || $section eq $section_context) {
2204                 if (!defined $leading_space) {
2205                     if ($cont =~ m/^(\s+)/) {
2206                         $leading_space = $1;
2207                     } else {
2208                         $leading_space = "";
2209                     }
2210                 }
2211                 $cont =~ s/^$leading_space//;
2212             }
2213             $contents .= $cont . "\n";
2214         }
2215     } else {
2216         # i dont know - bad line?  ignore.
2217         emit_warning("${file}:$.", "bad line: $_");
2218     }
2219 }
2220
2221
2222 #
2223 # STATE_PROTO: reading a function/whatever prototype.
2224 #
2225 sub process_proto($$) {
2226     my $file = shift;
2227
2228     if (/$doc_inline_oneline/) {
2229         $section = $1;
2230         $contents = $2;
2231         if ($contents ne "") {
2232             $contents .= "\n";
2233             dump_section($file, $section, $contents);
2234             $section = $section_default;
2235             $contents = "";
2236         }
2237     } elsif (/$doc_inline_start/) {
2238         $state = STATE_INLINE;
2239         $inline_doc_state = STATE_INLINE_NAME;
2240     } elsif ($decl_type eq 'function') {
2241         process_proto_function($_, $file);
2242     } else {
2243         process_proto_type($_, $file);
2244     }
2245 }
2246
2247 #
2248 # STATE_DOCBLOCK: within a DOC: block.
2249 #
2250 sub process_docblock($$) {
2251     my $file = shift;
2252
2253     if (/$doc_end/) {
2254         dump_doc_section($file, $section, $contents);
2255         $section = $section_default;
2256         $contents = "";
2257         $function = "";
2258         %parameterdescs = ();
2259         %parametertypes = ();
2260         @parameterlist = ();
2261         %sections = ();
2262         @sectionlist = ();
2263         $prototype = "";
2264         $state = STATE_NORMAL;
2265     } elsif (/$doc_content/) {
2266         if ( $1 eq "" ) {
2267             $contents .= $blankline;
2268         } else {
2269             $contents .= $1 . "\n";
2270         }
2271     }
2272 }
2273
2274 #
2275 # STATE_INLINE: docbook comments within a prototype.
2276 #
2277 sub process_inline($$) {
2278     my $file = shift;
2279
2280     # First line (state 1) needs to be a @parameter
2281     if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2282         $section = $1;
2283         $contents = $2;
2284         $new_start_line = $.;
2285         if ($contents ne "") {
2286             while (substr($contents, 0, 1) eq " ") {
2287                 $contents = substr($contents, 1);
2288             }
2289             $contents .= "\n";
2290         }
2291         $inline_doc_state = STATE_INLINE_TEXT;
2292         # Documentation block end */
2293     } elsif (/$doc_inline_end/) {
2294         if (($contents ne "") && ($contents ne "\n")) {
2295             dump_section($file, $section, $contents);
2296             $section = $section_default;
2297             $contents = "";
2298         }
2299         $state = STATE_PROTO;
2300         $inline_doc_state = STATE_INLINE_NA;
2301         # Regular text
2302     } elsif (/$doc_content/) {
2303         if ($inline_doc_state == STATE_INLINE_TEXT) {
2304             $contents .= $1 . "\n";
2305             # nuke leading blank lines
2306             if ($contents =~ /^\s*$/) {
2307                 $contents = "";
2308             }
2309         } elsif ($inline_doc_state == STATE_INLINE_NAME) {
2310             $inline_doc_state = STATE_INLINE_ERROR;
2311             emit_warning("${file}:$.", "Incorrect use of kernel-doc format: $_");
2312         }
2313     }
2314 }
2315
2316
2317 sub process_file($) {
2318     my $file;
2319     my $initial_section_counter = $section_counter;
2320     my ($orig_file) = @_;
2321
2322     $file = map_filename($orig_file);
2323
2324     if (!open(IN_FILE,"<$file")) {
2325         print STDERR "Error: Cannot open file $file\n";
2326         ++$errors;
2327         return;
2328     }
2329
2330     $. = 1;
2331
2332     $section_counter = 0;
2333     while (<IN_FILE>) {
2334         while (s/\\\s*$//) {
2335             $_ .= <IN_FILE>;
2336         }
2337         # Replace tabs by spaces
2338         while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2339         # Hand this line to the appropriate state handler
2340         if ($state == STATE_NORMAL) {
2341             process_normal();
2342         } elsif ($state == STATE_NAME) {
2343             process_name($file, $_);
2344         } elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE ||
2345                  $state == STATE_BODY_WITH_BLANK_LINE) {
2346             process_body($file, $_);
2347         } elsif ($state == STATE_INLINE) { # scanning for inline parameters
2348             process_inline($file, $_);
2349         } elsif ($state == STATE_PROTO) {
2350             process_proto($file, $_);
2351         } elsif ($state == STATE_DOCBLOCK) {
2352             process_docblock($file, $_);
2353         }
2354     }
2355
2356     # Make sure we got something interesting.
2357     if ($initial_section_counter == $section_counter && $
2358         output_mode ne "none") {
2359         if ($output_selection == OUTPUT_INCLUDE) {
2360             emit_warning("${file}:1", "'$_' not found\n")
2361                 for keys %function_table;
2362         }
2363         else {
2364             emit_warning("${file}:1", "no structured comments found\n");
2365         }
2366     }
2367     close IN_FILE;
2368 }
2369
2370
2371 if ($output_mode eq "rst") {
2372         get_sphinx_version() if (!$sphinx_major);
2373 }
2374
2375 $kernelversion = get_kernel_version();
2376
2377 # generate a sequence of code that will splice in highlighting information
2378 # using the s// operator.
2379 for (my $k = 0; $k < @highlights; $k++) {
2380     my $pattern = $highlights[$k][0];
2381     my $result = $highlights[$k][1];
2382 #   print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2383     $dohighlight .=  "\$contents =~ s:$pattern:$result:gs;\n";
2384 }
2385
2386 # Read the file that maps relative names to absolute names for
2387 # separate source and object directories and for shadow trees.
2388 if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2389         my ($relname, $absname);
2390         while(<SOURCE_MAP>) {
2391                 chop();
2392                 ($relname, $absname) = (split())[0..1];
2393                 $relname =~ s:^/+::;
2394                 $source_map{$relname} = $absname;
2395         }
2396         close(SOURCE_MAP);
2397 }
2398
2399 if ($output_selection == OUTPUT_EXPORTED ||
2400     $output_selection == OUTPUT_INTERNAL) {
2401
2402     push(@export_file_list, @ARGV);
2403
2404     foreach (@export_file_list) {
2405         chomp;
2406         process_export_file($_);
2407     }
2408 }
2409
2410 foreach (@ARGV) {
2411     chomp;
2412     process_file($_);
2413 }
2414 if ($verbose && $errors) {
2415   print STDERR "$errors errors\n";
2416 }
2417 if ($verbose && $warnings) {
2418   print STDERR "$warnings warnings\n";
2419 }
2420
2421 if ($Werror && $warnings) {
2422     print STDERR "$warnings warnings as Errors\n";
2423     exit($warnings);
2424 } else {
2425     exit($output_mode eq "none" ? 0 : $errors)
2426 }
2427
2428 __END__
2429
2430 =head1 OPTIONS
2431
2432 =head2 Output format selection (mutually exclusive):
2433
2434 =over 8
2435
2436 =item -man
2437
2438 Output troff manual page format.
2439
2440 =item -rst
2441
2442 Output reStructuredText format. This is the default.
2443
2444 =item -none
2445
2446 Do not output documentation, only warnings.
2447
2448 =back
2449
2450 =head2 Output format modifiers
2451
2452 =head3 reStructuredText only
2453
2454 =over 8
2455
2456 =item -sphinx-version VERSION
2457
2458 Use the ReST C domain dialect compatible with a specific Sphinx Version.
2459
2460 If not specified, kernel-doc will auto-detect using the sphinx-build version
2461 found on PATH.
2462
2463 =back
2464
2465 =head2 Output selection (mutually exclusive):
2466
2467 =over 8
2468
2469 =item -export
2470
2471 Only output documentation for the symbols that have been exported using
2472 EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2473
2474 =item -internal
2475
2476 Only output documentation for the symbols that have NOT been exported using
2477 EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2478
2479 =item -function NAME
2480
2481 Only output documentation for the given function or DOC: section title.
2482 All other functions and DOC: sections are ignored.
2483
2484 May be specified multiple times.
2485
2486 =item -nosymbol NAME
2487
2488 Exclude the specified symbol from the output documentation.
2489
2490 May be specified multiple times.
2491
2492 =back
2493
2494 =head2 Output selection modifiers:
2495
2496 =over 8
2497
2498 =item -no-doc-sections
2499
2500 Do not output DOC: sections.
2501
2502 =item -export-file FILE
2503
2504 Specify an additional FILE in which to look for EXPORT_SYMBOL information.
2505
2506 To be used with -export or -internal.
2507
2508 May be specified multiple times.
2509
2510 =back
2511
2512 =head3 reStructuredText only
2513
2514 =over 8
2515
2516 =item -enable-lineno
2517
2518 Enable output of .. LINENO lines.
2519
2520 =back
2521
2522 =head2 Other parameters:
2523
2524 =over 8
2525
2526 =item -h, -help
2527
2528 Print this help.
2529
2530 =item -v
2531
2532 Verbose output, more warnings and other information.
2533
2534 =item -Werror
2535
2536 Treat warnings as errors.
2537
2538 =back
2539
2540 =cut