shell-completion/bash/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 bashcompletiondir = get_option('bashcompletiondir')
   4 if bashcompletiondir == ''
   5         bash_completion = dependency('bash-completion', required : false)
   6         if bash_completion.found()
   7                 bashcompletiondir = bash_completion.get_pkgconfig_variable('completionsdir')
   8         else
   9                 bashcompletiondir = join_paths(datadir, 'bash-completion/completions')
  10         endif
  11
  12         message('bash completions: @0@'.format(bashcompletiondir))
  13 endif
  14
  15 if bashcompletiondir != 'no'
  16         bash_systemctl = configure_file(
  17                 input : 'systemctl.in',
  18                 output : 'systemctl',
  19                 configuration : substs)
  20
  21         items = [['busctl',              ''],
  22                  ['journalctl',          ''],
  23                  ['systemd-analyze',     ''],
  24                  ['systemd-cat',         ''],
  25                  ['systemd-cgls',        ''],
  26                  ['systemd-cgtop',       ''],
  27                  ['systemd-delta',       ''],
  28                  ['systemd-detect-virt', ''],
  29                  ['systemd-nspawn',      ''],
  30                  ['systemd-path',        ''],
  31                  ['systemd-run',         ''],
  32                  ['udevadm',             ''],
  33                  ['kernel-install',      ''],
  34                  [bash_systemctl,        ''],
  35                  ['bootctl',             'ENABLE_EFI'],
  36                  ['coredumpctl',         'ENABLE_COREDUMP'],
  37                  ['hostnamectl',         'ENABLE_HOSTNAMED'],
  38                  ['localectl',           'ENABLE_LOCALED'],
  39                  ['loginctl',            'ENABLE_LOGIND'],
  40                  ['machinectl',          'ENABLE_MACHINED'],
  41                  ['networkctl',          'ENABLE_NETWORKD'],
  42                  ['portablectl',         'ENABLE_PORTABLED'],
  43                  ['resolvectl',          'ENABLE_RESOLVE'],
  44                  ['systemd-resolve',     'ENABLE_RESOLVE'],
  45                  ['timedatectl',         'ENABLE_TIMEDATED'],
  46                 ]
  47
  48         foreach item : items
  49                 if item[1] == '' or conf.get(item[1]) == 1
  50                         install_data(item[0],
  51                                      install_dir : bashcompletiondir)
  52                 endif
  53         endforeach
  54 endif