shell-completion/zsh/_journalctl

   1 #compdef journalctl
   2 # SPDX-License-Identifier: LGPL-2.1+
   3
   4 _list_fields() {
   5     local -a journal_fields
   6     journal_fields=(MESSAGE{,_ID} PRIORITY CODE_{FILE,LINE,FUNC}
   7                     ERRNO SYSLOG_{FACILITY,IDENTIFIER,PID}
   8                     _{P,U,G}ID _COMM _EXE _CMDLINE
   9                     _AUDIT_{SESSION,LOGINUID}
  10                     _SYSTEMD_{CGROUP,SESSION,UNIT,OWNER_UID}
  11                     _SYSTEMD_USER_UNIT USER_UNIT
  12                     _SELINUX_CONTEXT _SOURCE_REALTIME_TIMESTAMP
  13                     _{BOOT,MACHINE}_ID _HOSTNAME _TRANSPORT
  14                     _KERNEL_{DEVICE,SUBSYSTEM}
  15                     _UDEV_{SYSNAME,DEVNODE,DEVLINK}
  16                     __CURSOR __{REALTIME,MONOTONIC}_TIMESTAMP)
  17     case $_jrnl_none in
  18         yes) _values -s '=' 'possible fields' \
  19                 "${journal_fields[@]}:value:_journal_fields ${words[CURRENT]%%=*}" ;;
  20         *)  _describe 'possible fields' journal_fields ;;
  21     esac
  22 }
  23
  24 _journal_none() {
  25     local -a _commands _files _jrnl_none
  26     # Setting use-cache will slow this down considerably
  27     _commands=( ${"$(_call_program commands "$service $_sys_service_mgr -F _EXE" 2>/dev/null)"} )
  28     _jrnl_none='yes'
  29     _alternative : \
  30         'files:/dev files:_files -W /dev -P /dev/' \
  31         "commands:commands:($_commands[@])" \
  32         'fields:fields:_list_fields'
  33 }
  34
  35 _journal_fields() {
  36     local -a _fields cmd
  37     cmd=("journalctl $_sys_service_mgr" "-F ${@[-1]}" "2>/dev/null" )
  38     _fields=$(_call_program fields $cmd[@])
  39     _fields=${_fields//'\'/'\\'}
  40     _fields=${_fields//':'/'\:'}
  41     _fields=( ${(f)_fields} )
  42     typeset -U _fields
  43     _describe 'possible values' _fields
  44 }
  45
  46 _journal_boots() {
  47   local -a _bootid _previousboots
  48   _bootid=( ${(f)"$(_call_program bootid "$service -F _BOOT_ID")"}  )
  49   _previousboots=( -{1..${#_bootid}} )
  50   _alternative : \
  51     "offsets:boot offsets:compadd -a '_previousboots[1,-2]'" \
  52     "bootid:boot ids:compadd -a _bootid"
  53 }
  54
  55 # Build arguments for "journalctl" to be used in completion.
  56 # Use both --user and --system modes, they are not exclusive.
  57 local -a _modes; _modes=(--user --system)
  58 local -a _modes_with_arg; _modes_with_arg=(--directory -D --file -M --machine --root)
  59 typeset -a _sys_service_mgr
  60 local w k v i=0 n=$#words
  61 while (( i++ < n )); do
  62     w=$words[$i]
  63     if (( $_modes[(I)$w] )); then
  64         _sys_service_mgr+=($w)
  65     else
  66         # Handle options with arguments. "--key=value" and "--key value".
  67         k=${w%%=*}
  68         if (( ${_modes_with_arg[(I)$k]} )); then
  69             v=${w#*=}
  70             if [[ "$k" != "$w" ]]; then
  71                 # "--key=value" style.
  72                 _sys_service_mgr+=($w)
  73             else
  74                 # "--key value" style.
  75                 _sys_service_mgr+=($w ${words[((++i))]})
  76             fi
  77         fi
  78     fi
  79 done
  80 _arguments -s \
  81     {-h,--help}'[Show this help]' \
  82     '--version[Show package version]' \
  83     '--no-pager[Do not pipe output into a pager]' \
  84     {-l,--full}'[Show long fields in full]' \
  85     {-a,--all}'[Show all fields, including long and unprintable]' \
  86     {-f,--follow}'[Follow journal]' \
  87     {-e,--pager-end}'[Jump to the end of the journal in the pager]' \
  88     {-n+,--lines=}'[Number of journal entries to show]:integer' \
  89     '--no-tail[Show all lines, even in follow mode]' \
  90     {-r,--reverse}'[Reverse output]' \
  91     {-o+,--output=}'[Change journal output mode]:output modes:_sd_outputmodes' \
  92     {-x,--catalog}'[Show explanatory texts with each log line]' \
  93     {-q,--quiet}"[Don't show privilege warning]" \
  94     {-m,--merge}'[Show entries from all available journals]' \
  95     {-b+,--boot=}'[Show data only from the specified boot or offset]::boot id or offset:_journal_boots' \
  96     '--list-boots[List boots ordered by time]' \
  97     {-k,--dmesg}'[Show only kernel messages from the current boot]' \
  98     {-u+,--unit=}'[Show data only from the specified unit]:units:_journal_fields _SYSTEMD_UNIT' \
  99     '--user-unit=[Show data only from the specified user session unit]:units:_journal_fields USER_UNIT' \
 100     {-p+,--priority=}'[Show only messages within the specified priority range]:priority:_journal_fields PRIORITY' \
 101     {-t+,--identifier=}'[Show only messages with the specified syslog identifier]:identifier:_journal_fields SYSLOG_IDENTIFIER' \
 102     {-c+,--cursor=}'[Start showing entries from the specified cursor]:cursors:_journal_fields __CURSORS' \
 103     '--after-cursor=[Start showing entries from after the specified cursor]:cursors:_journal_fields __CURSORS' \
 104     '--since=[Start showing entries on or newer than the specified date]:YYYY-MM-DD HH\:MM\:SS' \
 105     '--until=[Stop showing entries on or older than the specified date]:YYYY-MM-DD HH\:MM\:SS' \
 106     {-F,--field=}'[List all values a certain field takes]:Fields:_list_fields' \
 107     '--system[Show system and kernel messages]' \
 108     '--user[Show messages from user services]' \
 109     '(--directory -D -M --machine --root --file)'{-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
 110     '(--directory -D -M --machine --root --file)'{-D+,--directory=}'[Show journal files from directory]:directories:_directories' \
 111     '(--directory -D -M --machine --root --file)--root=[Operate on catalog hierarchy under specified directory]:directories:_directories' \
 112     '(--directory -D -M --machine --root)*--file=[Operate on specified journal files]:file:_files' \
 113     '--new-id128[Generate a new 128 Bit ID]' \
 114     '--header[Show journal header information]' \
 115     '--disk-usage[Show total disk usage]' \
 116     '--list-catalog[List messages in catalog]' \
 117     '--dump-catalog[Dump messages in catalog]' \
 118     '--update-catalog[Update binary catalog database]' \
 119     '--setup-keys[Generate a new FSS key pair]' \
 120     '--force[Force recreation of the FSS keys]' \
 121     '--interval=[Time interval for changing the FSS sealing key]:time interval' \
 122     '--verify[Verify journal file consistency]' \
 123     '--verify-key=[Specify FSS verification key]:FSS key' \
 124     '*::default: _journal_none'