shell-completion/zsh/_journalctl

   1 #compdef journalctl
   2
   3 _list_fields() {
   4     local -a journal_fields
   5     journal_fields=(MESSAGE{,_ID} PRIORITY CODE_{FILE,LINE,FUNC}
   6                     ERRNO SYSLOG_{FACILITY,IDENTIFIER,PID}
   7                     _{P,U,G}ID _COMM _EXE _CMDLINE
   8                     _AUDIT_{SESSION,LOGINUID}
   9                     _SYSTEMD_{CGROUP,SESSION,UNIT,OWNER_UID}
  10                     _SYSTEMD_USER_UNIT USER_UNIT
  11                     _SELINUX_CONTEXT _SOURCE_REALTIME_TIMESTAMP
  12                     _{BOOT,MACHINE}_ID _HOSTNAME _TRANSPORT
  13                     _KERNEL_{DEVICE,SUBSYSTEM}
  14                     _UDEV_{SYSNAME,DEVNODE,DEVLINK}
  15                     __CURSOR __{REALTIME,MONOTONIC}_TIMESTAMP)
  16     case $_jrnl_none in
  17         yes) _values -s '=' 'possible fields' \
  18                 "${journal_fields[@]}:value:_journal_fields ${words[CURRENT]%%=*}" ;;
  19         *)  _describe 'possible fields' journal_fields ;;
  20     esac
  21 }
  22
  23 _journal_none() {
  24     local -a _commands _files _jrnl_none
  25     # Setting use-cache will slow this down considerably
  26     _commands=( ${"$(_call_program commands "$service $_sys_service_mgr -F _EXE" 2>/dev/null)"} )
  27     _jrnl_none='yes'
  28     _alternative : \
  29         'files:/dev files:_files -W /dev -P /dev/' \
  30         "commands:commands:($_commands[@])" \
  31         'fields:fields:_list_fields'
  32 }
  33
  34 _journal_fields() {
  35     local -a _fields cmd
  36     cmd=("journalctl $_sys_service_mgr" "-F ${@[-1]}" "2>/dev/null" )
  37     _fields=$(_call_program fields $cmd[@])
  38     _fields=${_fields//'\'/'\\'}
  39     _fields=${_fields//':'/'\:'}
  40     _fields=( ${(f)_fields} )
  41     typeset -U _fields
  42     _describe 'possible values' _fields
  43 }
  44
  45 _journal_boots() {
  46   local -a _bootid _previousboots
  47   _bootid=( ${(f)"$(_call_program bootid "$service -F _BOOT_ID")"}  )
  48   _previousboots=( -{1..${#_bootid}} )
  49   _alternative : \
  50     "offsets:boot offsets:compadd -a '_previousboots[1,-2]'" \
  51     "bootid:boot ids:compadd -a _bootid"
  52 }
  53
  54 # Build arguments for "journalctl" to be used in completion.
  55 # Use both --user and --system modes, they are not exclusive.
  56 local -a _modes; _modes=(--user --system)
  57 local -a _modes_with_arg; _modes_with_arg=(--directory -D --file -M --machine --root)
  58 typeset -a _sys_service_mgr
  59 local w k v i=0 n=$#words
  60 while (( i++ < n )); do
  61     w=$words[$i]
  62     if (( $_modes[(I)$w] )); then
  63         _sys_service_mgr+=($w)
  64     else
  65         # Handle options with arguments. "--key=value" and "--key value".
  66         k=${w%%=*}
  67         if (( ${_modes_with_arg[(I)$k]} )); then
  68             v=${w#*=}
  69             if [[ "$k" != "$w" ]]; then
  70                 # "--key=value" style.
  71                 _sys_service_mgr+=($w)
  72             else
  73                 # "--key value" style.
  74                 _sys_service_mgr+=($w ${words[((++i))]})
  75             fi
  76         fi
  77     fi
  78 done
  79 _arguments -s \
  80     {-h,--help}'[Show this help]' \
  81     '--version[Show package version]' \
  82     '--no-pager[Do not pipe output into a pager]' \
  83     {-l,--full}'[Show long fields in full]' \
  84     {-a,--all}'[Show all fields, including long and unprintable]' \
  85     {-f,--follow}'[Follow journal]' \
  86     {-e,--pager-end}'[Jump to the end of the journal in the pager]' \
  87     {-n+,--lines=}'[Number of journal entries to show]:integer' \
  88     '--no-tail[Show all lines, even in follow mode]' \
  89     {-r,--reverse}'[Reverse output]' \
  90     {-o+,--output=}'[Change journal output mode]:output modes:_sd_outputmodes' \
  91     {-x,--catalog}'[Show explanatory texts with each log line]' \
  92     {-q,--quiet}"[Don't show privilege warning]" \
  93     {-m,--merge}'[Show entries from all available journals]' \
  94     {-b+,--boot=}'[Show data only from the specified boot or offset]::boot id or offset:_journal_boots' \
  95     '--list-boots[List boots ordered by time]' \
  96     {-k,--dmesg}'[Show only kernel messages from the current boot]' \
  97     {-u+,--unit=}'[Show data only from the specified unit]:units:_journal_fields _SYSTEMD_UNIT' \
  98     '--user-unit=[Show data only from the specified user session unit]:units:_journal_fields USER_UNIT' \
  99     {-p+,--priority=}'[Show only messages within the specified priority range]:priority:_journal_fields PRIORITY' \
 100     {-t+,--identifier=}'[Show only messages with the specified syslog identifier]:identifier:_journal_fields SYSLOG_IDENTIFIER' \
 101     {-c+,--cursor=}'[Start showing entries from the specified cursor]:cursors:_journal_fields __CURSORS' \
 102     '--after-cursor=[Start showing entries from after the specified cursor]:cursors:_journal_fields __CURSORS' \
 103     '--since=[Start showing entries on or newer than the specified date]:YYYY-MM-DD HH\:MM\:SS' \
 104     '--until=[Stop showing entries on or older than the specified date]:YYYY-MM-DD HH\:MM\:SS' \
 105     {-F,--field=}'[List all values a certain field takes]:Fields:_list_fields' \
 106     '--system[Show system and kernel messages]' \
 107     '--user[Show messages from user services]' \
 108     '(--directory -D -M --machine --root --file)'{-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
 109     '(--directory -D -M --machine --root --file)'{-D+,--directory=}'[Show journal files from directory]:directories:_directories' \
 110     '(--directory -D -M --machine --root --file)''--root=[Operate on catalog hierarchy under specified directory]:directories:_directories' \
 111     '(--directory -D -M --machine --root)--file=[Operate on specified journal files]:file:_files' \
 112     '--new-id128[Generate a new 128 Bit ID]' \
 113     '--header[Show journal header information]' \
 114     '--disk-usage[Show total disk usage]' \
 115     '--list-catalog[List messages in catalog]' \
 116     '--dump-catalog[Dump messages in catalog]' \
 117     '--update-catalog[Update binary catalog database]' \
 118     '--setup-keys[Generate a new FSS key pair]' \
 119     '--force[Force recreation of the FSS keys]' \
 120     '--interval=[Time interval for changing the FSS sealing key]:time interval' \
 121     '--verify[Verify journal file consistency]' \
 122     '--verify-key=[Specify FSS verification key]:FSS key' \
 123     '*::default: _journal_none'