shell-completion/zsh/_systemctl.in

   1 #compdef systemctl
   2 # SPDX-License-Identifier: LGPL-2.1+
   3
   4 (( $+functions[_systemctl_command] )) || _systemctl_command()
   5 {
   6   local -a _systemctl_cmds
   7   _systemctl_cmds=(
   8     "list-sockets:List sockets"
   9     "list-timers:List timers"
  10     "list-units:List units"
  11     "start:Start (activate) one or more units"
  12     "stop:Stop (deactivate) one or more units"
  13     "reload:Reload one or more units"
  14     "restart:Start or restart one or more units"
  15     "condrestart:Restart one or more units if active"
  16     "try-restart:Restart one or more units if active"
  17     "reload-or-restart:Reload one or more units if possible, otherwise start or restart"
  18     "force-reload:Reload one or more units if possible, otherwise restart if active"
  19     "hibernate:Hibernate the system"
  20     "hybrid-sleep:Hibernate and suspend the system"
  21     "suspend-to-hibernate:Suspend the system for a period of time, and then hibernate it"
  22     "try-reload-or-restart:Reload one or more units if possible, otherwise restart if active"
  23     "isolate:Start one unit and stop all others"
  24     "kill:Send signal to processes of a unit"
  25     "is-active:Check whether units are active"
  26     "is-failed:Check whether units are failed"
  27     "status:Show runtime status of one or more units"
  28     "show:Show properties of one or more units/jobs or the manager"
  29     "cat:Show the source unit files and drop-ins"
  30     "reset-failed:Reset failed state for all, one, or more units"
  31     "list-unit-files:List installed unit files"
  32     "enable:Enable one or more unit files"
  33     "disable:Disable one or more unit files"
  34     "add-wants:Add Wants= dependencies to a unit"
  35     "add-requires:Add Requires= dependencies to a unit"
  36     "reenable:Reenable one or more unit files"
  37     "preset:Enable/disable one or more unit files based on preset configuration"
  38     "set-default:Set the default target"
  39     "get-default:Query the default target"
  40     "edit:Edit one or more unit files"
  41     "is-system-running:Query overall status of the system"
  42     "help:Show documentation for specified units"
  43     "list-dependencies:Show unit dependency tree"
  44     "mask:Mask one or more units"
  45     "unmask:Unmask one or more units"
  46     "link:Link one or more units files into the search path"
  47     "is-enabled:Check whether unit files are enabled"
  48     "list-jobs:List jobs"
  49     "cancel:Cancel all, one, or more jobs"
  50     "show-environment:Dump environment"
  51     "set-environment:Set one or more environment variables"
  52     "unset-environment:Unset one or more environment variables"
  53     "daemon-reload:Reload systemd manager configuration"
  54     "daemon-reexec:Reexecute systemd manager"
  55     "default:Enter system default mode"
  56     "rescue:Enter system rescue mode"
  57     "emergency:Enter system emergency mode"
  58     "halt:Shut down and halt the system"
  59     "suspend:Suspend the system"
  60     "poweroff:Shut down and power-off the system"
  61     "reboot:Shut down and reboot the system"
  62     "kexec:Shut down and reboot the system with kexec"
  63     "exit:Ask for user instance termination"
  64     "switch-root:Change root directory"
  65     "revert:Revert unit files to their vendor versions"
  66   )
  67
  68   if (( CURRENT == 1 )); then
  69     _describe -t commands 'systemctl command' _systemctl_cmds || compadd "$@"
  70   else
  71     local curcontext="$curcontext" expl
  72
  73     cmd="${${_systemctl_cmds[(r)$words[1]:*]%%:*}}"
  74     # Deal with any aliases
  75     case $cmd in
  76       condrestart) cmd="try-restart";;
  77       force-reload) cmd="try-reload-or-restart";;
  78     esac
  79
  80     if (( $#cmd )); then
  81       curcontext="${curcontext%:*:*}:systemctl-${cmd}:"
  82
  83       local update_policy
  84       zstyle -s ":completion:${curcontext}:" cache-policy update_policy
  85       if [[ -z "$update_policy" ]]; then
  86         zstyle ":completion:${curcontext}:" cache-policy _systemctl_caching_policy
  87       fi
  88
  89       _call_function ret _systemctl_$cmd || _message 'no more arguments'
  90     else
  91       _message "unknown systemctl command: $words[1]"
  92     fi
  93     return ret
  94   fi
  95 }
  96
  97 __systemctl()
  98 {
  99   systemctl $_sys_service_mgr --full --no-legend --no-pager "$@" 2>/dev/null
 100 }
 101
 102
 103 # Fills the unit list
 104 _systemctl_all_units()
 105 {
 106   if ( [[ ${+_sys_all_units} -eq 0 ]] || _cache_invalid SYS_ALL_UNITS$_sys_service_mgr ) ||
 107     ! _retrieve_cache SYS_ALL_UNITS$_sys_service_mgr;
 108   then
 109     _sys_all_units=( ${${(f)"$(__systemctl list-units --all)"}%% *} )
 110     _store_cache SYS_ALL_UNITS$_sys_service_mgr _sys_all_units
 111   fi
 112 }
 113
 114 # Fills the unit list including all file units
 115 _systemctl_really_all_units()
 116 {
 117   local -a all_unit_files;
 118   local -a really_all_units;
 119   if ( [[ ${+_sys_really_all_units} -eq 0 ]] || _cache_invalid SYS_REALLY_ALL_UNITS$_sys_service_mgr ) ||
 120     ! _retrieve_cache SYS_REALLY_ALL_UNITS$_sys_service_mgr;
 121   then
 122     all_unit_files=( ${${(f)"$(__systemctl list-unit-files)"}%% *} )
 123     _systemctl_all_units
 124     really_all_units=($_sys_all_units $all_unit_files)
 125     _sys_really_all_units=(${(u)really_all_units})
 126     _store_cache SYS_REALLY_ALL_UNITS$_sys_service_mgr _sys_really_all_units
 127   fi
 128 }
 129
 130 _filter_units_by_property() {
 131   local property=$1 value=$2; shift 2
 132   local -a units; units=("${(q-)@}")
 133   local -A props
 134   props=(${(f)"$(_call_program units "$service $_sys_service_mgr show --no-pager --property=\"Id,$property\" -- ${units} 2>/dev/null")"})
 135   echo -E - "${(@g:o:)${(k@)props[(Re)$property=$value]}#Id=}"
 136 }
 137
 138 _systemctl_get_template_names() { echo -E - ${^${(M)${(f)"$(__systemctl list-unit-files "*$PREFIX*$SUFFIX*" )"}##*@.[^[:space:]]##}%%@.*}\@ }
 139
 140
 141 _systemctl_active_units()  {_sys_active_units=(  ${${(f)"$(__systemctl list-units "*$PREFIX*$SUFFIX*" )"}%% *} )}
 142
 143 _systemctl_startable_units(){
 144   _sys_startable_units=( $( _filter_units_by_property ActiveState inactive $(
 145     _filter_units_by_property CanStart yes ${${${(f)"$(
 146       __systemctl $mode list-unit-files --state enabled,disabled,static "*$PREFIX*$SUFFIX*"
 147       __systemctl $mode list-units --state inactive,failed "*$PREFIX*$SUFFIX*"
 148     )"}:#*@.*}%%[[:space:]]*}
 149   )) )
 150 }
 151
 152 _systemctl_restartable_units(){
 153   _sys_restartable_units=( $( _filter_units_by_property CanStart yes ${${${(f)"$(
 154     __systemctl $mode list-unit-files --state enabled,disabled,static "*$PREFIX*$SUFFIX*"
 155     __systemctl $mode list-units "*$PREFIX*$SUFFIX*"
 156   )"}:#*@.*}%%[[:space:]]*} ) )
 157 }
 158
 159 _systemctl_failed_units()  {_sys_failed_units=( ${${(f)"$(__systemctl list-units --state=failed "*$PREFIX*$SUFFIX*" )"}%% *} ) }
 160 _systemctl_unit_state() { typeset -gA _sys_unit_state; _sys_unit_state=( $(__systemctl list-unit-files "*$PREFIX*$SUFFIX*" ) ) }
 161
 162 local fun
 163 # Completion functions for ALL_UNITS
 164 for fun in is-active is-failed is-enabled status show cat mask preset help list-dependencies edit revert add-wants add-requires ; do
 165   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 166   {
 167     _systemctl_really_all_units
 168     _wanted systemd-units expl unit \
 169       compadd "$@" -a - _sys_really_all_units
 170   }
 171 done
 172
 173 # Completion functions for ENABLED_UNITS
 174 (( $+functions[_systemctl_disable] )) || _systemctl_disable()
 175 {
 176     local _sys_unit_state; _systemctl_unit_state
 177     _wanted systemd-units expl 'enabled unit' \
 178       compadd "$@" - ${(k)_sys_unit_state[(R)enabled]}
 179 }
 180
 181 (( $+functions[_systemctl_reenable] )) || _systemctl_reenable()
 182 {
 183     local _sys_unit_state; _systemctl_unit_state
 184     _wanted systemd-units expl 'enabled/disabled unit' \
 185       compadd "$@" - ${(k)_sys_unit_state[(R)(enabled|disabled)]} $(_systemctl_get_template_names)
 186 }
 187
 188 # Completion functions for DISABLED_UNITS
 189 (( $+functions[_systemctl_enable] )) || _systemctl_enable()
 190 {
 191   local _sys_unit_state; _systemctl_unit_state
 192   _wanted systemd-units expl 'disabled unit' \
 193     compadd "$@" - ${(k)_sys_unit_state[(R)disabled]} $(_systemctl_get_template_names)
 194 }
 195
 196 # Completion functions for FAILED_UNITS
 197 (( $+functions[_systemctl_reset-failed] )) || _systemctl_reset-failed()
 198 {
 199   local _sys_failed_units; _systemctl_failed_units
 200   _wanted systemd-units expl 'failed unit' \
 201     compadd "$@" -a - _sys_failed_units || _message "no failed unit found"
 202 }
 203
 204 # Completion functions for STARTABLE_UNITS
 205 (( $+functions[_systemctl_start] )) || _systemctl_start()
 206 {
 207    local _sys_startable_units; _systemctl_startable_units
 208    _wanted systemd-units expl 'startable unit' \
 209      compadd "$@" - ${_sys_startable_units[*]} $(_systemctl_get_template_names)
 210 }
 211
 212 # Completion functions for STOPPABLE_UNITS
 213 for fun in stop kill try-restart condrestart ; do
 214   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 215   {
 216     local _sys_active_units; _systemctl_active_units
 217     _wanted systemd-units expl 'stoppable unit' \
 218       compadd "$@" - $( _filter_units_by_property CanStop yes \
 219         ${_sys_active_units[*]} )
 220   }
 221 done
 222
 223 # Completion functions for ISOLATABLE_UNITS
 224 (( $+functions[_systemctl_isolate] )) || _systemctl_isolate()
 225 {
 226   _systemctl_all_units
 227   _wanted systemd-units expl 'isolatable unit' \
 228     compadd "$@" - $( _filter_units_by_property AllowIsolate yes \
 229       ${_sys_all_units[*]} )
 230 }
 231
 232 # Completion functions for RELOADABLE_UNITS
 233 for fun in reload try-reload-or-restart force-reload ; do
 234   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 235   {
 236     local _sys_active_units; _systemctl_active_units
 237     _wanted systemd-units expl 'reloadable unit' \
 238       compadd "$@" - $( _filter_units_by_property CanReload yes \
 239         ${_sys_active_units[*]} )
 240   }
 241 done
 242
 243 # Completion functions for RESTARTABLE_UNITS
 244 for fun in restart reload-or-restart ; do
 245   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 246   {
 247     local _sys_restartable_units; _systemctl_restartable_units
 248     _wanted systemd-units expl 'restartable unit' \
 249       compadd "$@" - ${_sys_restartable_units[*]} $(_systemctl_get_template_names)
 250   }
 251 done
 252
 253 # Completion functions for MASKED_UNITS
 254 (( $+functions[_systemctl_unmask] )) || _systemctl_unmask()
 255 {
 256   local _sys_unit_state; _systemctl_unit_state
 257   _wanted systemd-units expl 'masked unit' \
 258     compadd "$@" - ${(k)_sys_unit_state[(R)masked]} || _message "no masked units found"
 259 }
 260
 261 # Completion functions for JOBS
 262 (( $+functions[_systemctl_cancel] )) || _systemctl_cancel()
 263 {
 264   _wanted systemd-jobs expl job \
 265     compadd "$@" - ${${(f)"$(__systemctl list-jobs)"}%% *} ||
 266       _message "no jobs found"
 267 }
 268
 269 # Completion functions for TARGETS
 270 (( $+functions[_systemctl_set-default] )) || _systemctl_set-default()
 271 {
 272   _wanted systemd-targets expl target \
 273     compadd "$@" - ${${(f)"$(__systemctl list-unit-files --type target --all)"}%% *} ||
 274       _message "no targets found"
 275 }
 276
 277 # Completion functions for ENVS
 278 for fun in set-environment unset-environment ; do
 279   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 280   {
 281     local fun=$0 ; fun=${fun##_systemctl_}
 282     local suf
 283     if [[ "${fun}" = "set-environment" ]]; then
 284       suf='-S='
 285     fi
 286     _wanted systemd-environment expl 'environment variable' \
 287       compadd "$@" ${suf} - ${${(f)"$(systemctl show-environment)"}%%=*}
 288   }
 289 done
 290
 291 (( $+functions[_systemctl_link] )) || _systemctl_link() {
 292    _sd_unit_files
 293 }
 294
 295 (( $+functions[_systemctl_switch-root] )) || _systemctl_switch-root() {
 296    _files
 297 }
 298
 299 # no systemctl completion for:
 300 #    [STANDALONE]='daemon-reexec daemon-reload default
 301 #                  emergency exit halt kexec list-jobs list-units
 302 #                  list-unit-files poweroff reboot rescue show-environment'
 303
 304 _systemctl_caching_policy()
 305 {
 306   local _sysunits
 307   local -a oldcache
 308
 309   # rebuild if cache is more than a day old
 310   oldcache=( "$1"(mh+1) )
 311   (( $#oldcache )) && return 0
 312
 313   _sysunits=(${${(f)"$(__systemctl --all)"}%% *})
 314
 315   if (( $#_sysunits )); then
 316     for unit in $_sysunits; do
 317       [[ "$unit" -nt "$1" ]] && return 0
 318     done
 319   fi
 320
 321   return 1
 322 }
 323
 324 _unit_states() {
 325     local -a _states
 326     _states=("${(fo)$(__systemctl --state=help)}")
 327     _values -s , "${_states[@]}"
 328 }
 329
 330 _unit_types() {
 331     local -a _types
 332     _types=("${(fo)$(__systemctl -t help)}")
 333     _values -s , "${_types[@]}"
 334 }
 335
 336 _unit_properties() {
 337   if ( [[ ${+_sys_all_properties} -eq 0 ]] || _cache_invalid SYS_ALL_PROPERTIES$_sys_service_mgr ) ||
 338     ! _retrieve_cache SYS_ALL_PROPERTIES$_sys_service_mgr;
 339   then
 340     _sys_all_properties=( ${${(M)${(f)"$(__systemctl show --all;
 341     @rootlibexecdir@/systemd --dump-configuration-items)"}##[[:alnum:]]##=*}%%=*}
 342     )
 343     _store_cache SYS_ALL_PROPERTIES$_sys_service_mgr _sys_all_properties
 344   fi
 345   _values -s , "${_sys_all_properties[@]}"
 346 }
 347
 348 _job_modes() {
 349     local -a _modes
 350     _modes=(fail replace replace-irreversibly isolate ignore-dependencies ignore-requirements flush)
 351     _values -s , "${_modes[@]}"
 352 }
 353
 354 # Build arguments for "systemctl" to be used in completion.
 355 local -a _modes; _modes=("--user" "--system")
 356 # Use the last mode (they are exclusive and the last one is used).
 357 local _sys_service_mgr=${${words:*_modes}[(R)(${(j.|.)_modes})]}
 358 _arguments -s \
 359     {-h,--help}'[Show help]' \
 360     '--version[Show package version]' \
 361     {-t+,--type=}'[List only units of a particular type]:unit type:_unit_types' \
 362     '--state=[Display units in the specified state]:unit state:_unit_states' \
 363     '--job-mode=[Specify how to deal with other jobs]:mode:_job_modes' \
 364     {-p+,--property=}'[Show only properties by specific name]:unit property:_unit_properties' \
 365     {-a,--all}'[Show all units/properties, including dead/empty ones]' \
 366     '--reverse[Show reverse dependencies]' \
 367     '--after[Show units ordered after]' \
 368     '--before[Show units ordered before]' \
 369     {-l,--full}"[Don't ellipsize unit names on output]" \
 370     '--show-types[When showing sockets, show socket type]' \
 371     {-i,--ignore-inhibitors}'[When executing a job, ignore jobs dependencies]' \
 372     {-q,--quiet}'[Suppress output]' \
 373     '--no-block[Do not wait until operation finished]' \
 374     '--no-legend[Do not print a legend, i.e. the column headers and the footer with hints]' \
 375     '--no-pager[Do not pipe output into a pager]' \
 376     '--system[Connect to system manager]' \
 377     '--user[Connect to user service manager]' \
 378     "--no-wall[Don't send wall message before halt/power-off/reboot]" \
 379     '--global[Enable/disable/mask unit files globally]' \
 380     "--no-reload[When enabling/disabling unit files, don't reload daemon configuration]" \
 381     '--no-ask-password[Do not ask for system passwords]' \
 382     '--kill-who=[Who to send signal to]:killwho:(main control all)' \
 383     {-s+,--signal=}'[Which signal to send]:signal:_signals' \
 384     {-f,--force}'[When enabling unit files, override existing symlinks. When shutting down, execute action immediately]' \
 385     '--root=[Enable/disable/mask unit files in the specified root directory]:directory:_directories' \
 386     '--runtime[Enable/disable/mask unit files only temporarily until next reboot]' \
 387     {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
 388     {-P,--privileged}'[Acquire privileges before execution]' \
 389     {-n+,--lines=}'[Journal entries to show]:number of entries' \
 390     {-o+,--output=}'[Change journal output mode]:modes:_sd_outputmodes' \
 391     '--firmware-setup[Tell the firmware to show the setup menu on next boot]' \
 392     '--plain[When used with list-dependencies, print output as a list]' \
 393     '--failed[Show failed units]' \
 394     '*::systemctl command:_systemctl_command'