shell-completion/zsh/_systemctl.in

   1 #compdef systemctl
   2
   3 (( $+functions[_systemctl_command] )) || _systemctl_command()
   4 {
   5   local -a _systemctl_cmds
   6   _systemctl_cmds=(
   7     "list-sockets:List sockets"
   8     "list-timers:List timers"
   9     "list-units:List units"
  10     "start:Start (activate) one or more units"
  11     "stop:Stop (deactivate) one or more units"
  12     "reload:Reload one or more units"
  13     "restart:Start or restart one or more units"
  14     "condrestart:Restart one or more units if active"
  15     "try-restart:Restart one or more units if active"
  16     "reload-or-restart:Reload one or more units if possible, otherwise start or restart"
  17     "force-reload:Reload one or more units if possible, otherwise restart if active"
  18     "hibernate:Hibernate the system"
  19     "hybrid-sleep:Hibernate and suspend the system"
  20     "reload-or-try-restart:Reload one or more units if possible, otherwise restart if active"
  21     "isolate:Start one unit and stop all others"
  22     "kill:Send signal to processes of a unit"
  23     "is-active:Check whether units are active"
  24     "is-failed:Check whether units are failed"
  25     "status:Show runtime status of one or more units"
  26     "show:Show properties of one or more units/jobs or the manager"
  27     "cat:Show the source unit files and drop-ins"
  28     "reset-failed:Reset failed state for all, one, or more units"
  29     "list-unit-files:List installed unit files"
  30     "enable:Enable one or more unit files"
  31     "disable:Disable one or more unit files"
  32     "reenable:Reenable one or more unit files"
  33     "preset:Enable/disable one or more unit files based on preset configuration"
  34     "set-default:Set the default target"
  35     "get-default:Query the default target"
  36     "edit:Edit one or more unit files"
  37     "is-system-running:Query overall status of the system"
  38     "help:Show documentation for specified units"
  39     "list-dependencies:Show unit dependency tree"
  40     "mask:Mask one or more units"
  41     "unmask:Unmask one or more units"
  42     "link:Link one or more units files into the search path"
  43     "is-enabled:Check whether unit files are enabled"
  44     "list-jobs:List jobs"
  45     "cancel:Cancel all, one, or more jobs"
  46     "snapshot:Create a snapshot"
  47     "delete:Remove one or more snapshots"
  48     "show-environment:Dump environment"
  49     "set-environment:Set one or more environment variables"
  50     "unset-environment:Unset one or more environment variables"
  51     "daemon-reload:Reload systemd manager configuration"
  52     "daemon-reexec:Reexecute systemd manager"
  53     "default:Enter system default mode"
  54     "rescue:Enter system rescue mode"
  55     "emergency:Enter system emergency mode"
  56     "halt:Shut down and halt the system"
  57     "suspend:Suspend the system"
  58     "poweroff:Shut down and power-off the system"
  59     "reboot:Shut down and reboot the system"
  60     "kexec:Shut down and reboot the system with kexec"
  61     "exit:Ask for user instance termination"
  62     "switch-root:Change root directory"
  63   )
  64
  65   if (( CURRENT == 1 )); then
  66     _describe -t commands 'systemctl command' _systemctl_cmds || compadd "$@"
  67   else
  68     local curcontext="$curcontext" expl
  69
  70     cmd="${${_systemctl_cmds[(r)$words[1]:*]%%:*}}"
  71     # Deal with any aliases
  72     case $cmd in
  73       condrestart) cmd="try-restart";;
  74       force-reload) cmd="reload-or-try-restart";;
  75     esac
  76
  77     if (( $#cmd )); then
  78       curcontext="${curcontext%:*:*}:systemctl-${cmd}:"
  79
  80       local update_policy
  81       zstyle -s ":completion:${curcontext}:" cache-policy update_policy
  82       if [[ -z "$update_policy" ]]; then
  83         zstyle ":completion:${curcontext}:" cache-policy _systemctl_caching_policy
  84       fi
  85
  86       _call_function ret _systemctl_$cmd || _message 'no more arguments'
  87     else
  88       _message "unknown systemctl command: $words[1]"
  89     fi
  90     return ret
  91   fi
  92 }
  93
  94 __systemctl()
  95 {
  96   local -a _modes
  97   _modes=("--user" "--system")
  98   systemctl ${words:*_modes} --full --no-legend --no-pager "$@"
  99 }
 100
 101
 102 # Fills the unit list
 103 _systemctl_all_units()
 104 {
 105   if ( [[ ${+_sys_all_units} -eq 0 ]] || _cache_invalid SYS_ALL_UNITS ) &&
 106     ! _retrieve_cache SYS_ALL_UNITS;
 107   then
 108     _sys_all_units=( ${${(f)"$(__systemctl list-units --all)"}%% *} )
 109     _store_cache SYS_ALL_UNITS _sys_all_units
 110   fi
 111 }
 112
 113 # Fills the unit list including all file units
 114 _systemctl_really_all_units()
 115 {
 116   local -a all_unit_files;
 117   local -a really_all_units;
 118   if ( [[ ${+_sys_really_all_units} -eq 0 ]] || _cache_invalid SYS_REALLY_ALL_UNITS ) &&
 119     ! _retrieve_cache SYS_REALLY_ALL_UNITS;
 120   then
 121     all_unit_files=( ${${(f)"$(__systemctl list-unit-files)"}%% *} )
 122     _systemctl_all_units
 123     really_all_units=($_sys_all_units $all_unit_files)
 124     _sys_really_all_units=(${(u)really_all_units})
 125     _store_cache SYS_REALLY_ALL_UNITS _sys_really_all_units
 126   fi
 127 }
 128
 129 _filter_units_by_property() {
 130   local property=$1 value=$2 ; shift ; shift
 131   local -a units ; units=($*)
 132   local prop unit
 133   for ((i=1; $i <= ${#units[*]}; i++)); do
 134     # FIXME: "Failed to issue method call: Unknown unit" errors are ignored for
 135     # now (related to DBUS_ERROR_UNKNOWN_OBJECT). in the future, we need to
 136     # revert to calling 'systemctl show' once for all units, which is way
 137     # faster
 138     unit=${units[i]}
 139     prop=${(f)"$(_call_program units "$service show --no-pager --property="$property" ${unit} 2>/dev/null")"}
 140     if [[ "${prop}" = "$property=$value" ]]; then
 141       echo -E - " ${unit}"
 142     fi
 143   done
 144 }
 145
 146 _systemctl_get_template_names() { echo -E - ${^${(M)${(f)"$(__systemctl list-unit-files)"}##*@.[^[:space:]]##}%%@.*}\@ }
 147
 148
 149 _systemctl_active_units()  {_sys_active_units=(  ${${(f)"$(__systemctl list-units)"}%% *} )}
 150
 151 _systemctl_startable_units(){
 152     _sys_startable_units=( $( _filter_units_by_property ActiveState inactive $(
 153                           _filter_units_by_property CanStart yes $(
 154                           __systemctl $mode list-unit-files --state enabled,disabled,static | \
 155                                { while read -r a b; do [[ $a =~ @\. ]] || echo -E - " $a"; done; }
 156                           __systemctl $mode list-units --state inactive,failed | \
 157                                { while read -r a b; do echo -E - " $a"; done; } )) ) )
 158 }
 159
 160 _systemctl_restartable_units(){
 161     _sys_restartable_units=( $(_filter_units_by_property CanStart yes $(
 162                           __systemctl $mode list-unit-files --state enabled,disabled,static | \
 163                                { while read -r a b; do [[ $a =~ @\. ]] || echo -E - " $a"; done; }
 164                           __systemctl $mode list-units | \
 165                                { while read -r a b; do echo -E - " $a"; done; } )) )
 166 }
 167
 168 _systemctl_failed_units()  {_sys_failed_units=( ${${(f)"$(__systemctl list-units --failed)"}%% *} ) }
 169 _systemctl_unit_state() { typeset -gA _sys_unit_state; _sys_unit_state=( $(__systemctl list-unit-files) ) }
 170
 171 local fun
 172 # Completion functions for ALL_UNITS
 173 for fun in is-active is-failed is-enabled status show cat mask preset help list-dependencies edit ; do
 174   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 175   {
 176     _systemctl_really_all_units
 177     _wanted systemd-units expl unit \
 178       compadd "$@" -a - _sys_really_all_units
 179   }
 180 done
 181
 182 # Completion functions for ENABLED_UNITS
 183 (( $+functions[_systemctl_disable] )) || _systemctl_disable()
 184 {
 185     local _sys_unit_state; _systemctl_unit_state
 186     _wanted systemd-units expl 'enabled unit' \
 187       compadd "$@" - ${(k)_sys_unit_state[(R)enabled]}
 188 }
 189
 190 (( $+functions[_systemctl_reenable] )) || _systemctl_reenable()
 191 {
 192     local _sys_unit_state; _systemctl_unit_state
 193     _wanted systemd-units expl 'enabled/disabled unit' \
 194       compadd "$@" - ${(k)_sys_unit_state[(R)(enabled|disabled)]} $(_systemctl_get_template_names)
 195 }
 196
 197 # Completion functions for DISABLED_UNITS
 198 (( $+functions[_systemctl_enable] )) || _systemctl_enable()
 199 {
 200   local _sys_unit_state; _systemctl_unit_state
 201   _wanted systemd-units expl 'disabled unit' \
 202     compadd "$@" - ${(k)_sys_unit_state[(R)disabled]} $(_systemctl_get_template_names)
 203 }
 204
 205 # Completion functions for FAILED_UNITS
 206 (( $+functions[_systemctl_reset-failed] )) || _systemctl_reset-failed()
 207 {
 208   local _sys_failed_units; _systemctl_failed_units
 209   _wanted systemd-units expl 'failed unit' \
 210     compadd "$@" -a - _sys_failed_units || _message "no failed unit found"
 211 }
 212
 213 # Completion functions for STARTABLE_UNITS
 214 (( $+functions[_systemctl_start] )) || _systemctl_start()
 215 {
 216    local _sys_startable_units; _systemctl_startable_units
 217    _wanted systemd-units expl 'startable unit' \
 218      compadd "$@" - ${_sys_startable_units[*]} $(_systemctl_get_template_names)
 219 }
 220
 221 # Completion functions for STOPPABLE_UNITS
 222 for fun in stop kill try-restart condrestart ; do
 223   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 224   {
 225     local _sys_active_units; _systemctl_active_units
 226     _wanted systemd-units expl 'stoppable unit' \
 227       compadd "$@" - $( _filter_units_by_property CanStop yes \
 228         ${_sys_active_units[*]} )
 229   }
 230 done
 231
 232 # Completion functions for ISOLATABLE_UNITS
 233 (( $+functions[_systemctl_isolate] )) || _systemctl_isolate()
 234 {
 235   _systemctl_all_units
 236   _wanted systemd-units expl 'isolatable unit' \
 237     compadd "$@" - $( _filter_units_by_property AllowIsolate yes \
 238       ${_sys_all_units[*]} )
 239 }
 240
 241 # Completion functions for RELOADABLE_UNITS
 242 for fun in reload reload-or-try-restart force-reload ; do
 243   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 244   {
 245     local _sys_active_units; _systemctl_active_units
 246     _wanted systemd-units expl 'reloadable unit' \
 247       compadd "$@" - $( _filter_units_by_property CanReload yes \
 248         ${_sys_active_units[*]} )
 249   }
 250 done
 251
 252 # Completion functions for RESTARTABLE_UNITS
 253 for fun in restart reload-or-restart ; do
 254   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 255   {
 256     local _sys_restartable_units; _systemctl_restartable_units
 257     _wanted systemd-units expl 'restartable unit' \
 258       compadd "$@" - ${_sys_restartable_units[*]} $(_systemctl_get_template_names)
 259   }
 260 done
 261
 262 # Completion functions for MASKED_UNITS
 263 (( $+functions[_systemctl_unmask] )) || _systemctl_unmask()
 264 {
 265   local _sys_unit_state; _systemctl_unit_state
 266   _wanted systemd-units expl 'masked unit' \
 267     compadd "$@" - ${(k)_sys_unit_state[(R)masked]} || _message "no masked units found"
 268 }
 269
 270 # Completion functions for JOBS
 271 (( $+functions[_systemctl_cancel] )) || _systemctl_cancel()
 272 {
 273   _wanted systemd-jobs expl job \
 274     compadd "$@" - ${${(f)"$(__systemctl list-jobs)"}%% *} ||
 275       _message "no jobs found"
 276 }
 277
 278 # Completion functions for SNAPSHOTS
 279 (( $+functions[_systemctl_delete] )) || _systemctl_delete()
 280 {
 281   _wanted systemd-snapshots expl snapshot \
 282     compadd "$@" - ${${(f)"$(__systemctl list-units --type snapshot --all)"}%% *} ||
 283       _message "no snapshots found"
 284 }
 285
 286 # Completion functions for TARGETS
 287 (( $+functions[_systemctl_set-default] )) || _systemctl_set-default()
 288 {
 289   _wanted systemd-targets expl target \
 290     compadd "$@" - ${${(f)"$(__systemctl list-unit-files --type target --all)"}%% *} ||
 291       _message "no targets found"
 292 }
 293
 294 # Completion functions for ENVS
 295 for fun in set-environment unset-environment ; do
 296   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 297   {
 298     local fun=$0 ; fun=${fun##_systemctl_}
 299     local suf
 300     if [[ "${fun}" = "set-environment" ]]; then
 301       suf='-S='
 302     fi
 303     _wanted systemd-environment expl 'environment variable' \
 304       compadd "$@" ${suf} - ${${(f)"$(systemctl show-environment)"}%%=*}
 305   }
 306 done
 307
 308 (( $+functions[_systemctl_link] )) || _systemctl_link() {
 309    _sd_unit_files
 310 }
 311
 312 (( $+functions[_systemctl_switch-root] )) || _systemctl_switch-root() {
 313    _files
 314 }
 315
 316 # no systemctl completion for:
 317 #    [STANDALONE]='daemon-reexec daemon-reload default
 318 #                  emergency exit halt kexec list-jobs list-units
 319 #                  list-unit-files poweroff reboot rescue show-environment'
 320 #         [NAME]='snapshot'
 321
 322 _systemctl_caching_policy()
 323 {
 324   local _sysunits
 325   local -a oldcache
 326
 327   # rebuild if cache is more than a day old
 328   oldcache=( "$1"(mh+1) )
 329   (( $#oldcache )) && return 0
 330
 331   _sysunits=(${${(f)"$(__systemctl --all)"}%% *})
 332
 333   if (( $#_sysunits )); then
 334     for unit in $_sysunits; do
 335       [[ "$unit" -nt "$1" ]] && return 0
 336     done
 337   fi
 338
 339   return 1
 340 }
 341
 342 _unit_states() {
 343     local -a _states
 344     _states=(loaded failed active inactive not-found listening running waiting plugged mounted exited dead masked)
 345     _values -s , "${_states[@]}"
 346 }
 347
 348 _unit_types() {
 349     local -a _types
 350     _types=(automount busname device mount path service snapshot socket swap target timer)
 351     _values -s , "${_types[@]}"
 352 }
 353
 354 _unit_properties() {
 355   if ( [[ ${+_sys_all_properties} -eq 0 ]] || _cache_invalid SYS_ALL_PROPERTIES ) &&
 356     ! _retrieve_cache SYS_ALL_PROPERTIES;
 357   then
 358     _sys_all_properties=( ${${(M)${(f)"$(__systemctl show --all;
 359     @rootlibexecdir@/systemd --dump-configuration-items)"}##[[:alnum:]]##=*}%%=*}
 360     )
 361     _store_cache SYS_ALL_PROPRTIES _sys_all_properties
 362   fi
 363   _values -s , "${_sys_all_properties[@]}"
 364 }
 365
 366 _job_modes() {
 367     local -a _modes
 368     _modes=(fail replace replace-irreversibly isolate ignore-dependencies ignore-requirements flush)
 369     _values -s , "${_modes[@]}"
 370 }
 371
 372 _arguments -s \
 373     {-h,--help}'[Show help]' \
 374     '--version[Show package version]' \
 375     {-t+,--type=}'[List only units of a particular type]:unit type:_unit_types' \
 376     '--state=[Display units in the specified state]:unit state:_unit_states' \
 377     '--job-mode=[Specify how to deal with other jobs]:mode:_job_modes' \
 378     {-p+,--property=}'[Show only properties by specific name]:unit property:_unit_properties' \
 379     {-a,--all}'[Show all units/properties, including dead/empty ones]' \
 380     '--reverse[Show reverse dependencies]' \
 381     '--after[Show units ordered after]' \
 382     '--before[Show units ordered before]' \
 383     '--failed[Show only failed units]' \
 384     {-l,--full}"[Don't ellipsize unit names on output]" \
 385     '--show-types[When showing sockets, show socket type]' \
 386     {-i,--ignore-inhibitors}'[When executing a job, ignore jobs dependencies]' \
 387     {-q,--quiet}'[Suppress output]' \
 388     '--no-block[Do not wait until operation finished]' \
 389     '--no-legend[Do not print a legend, i.e. the column headers and the footer with hints]' \
 390     '--no-pager[Do not pipe output into a pager]' \
 391     '--system[Connect to system manager]' \
 392     '--user[Connect to user service manager]' \
 393     "--no-wall[Don't send wall message before halt/power-off/reboot]" \
 394     '--global[Enable/disable unit files globally]' \
 395     "--no-reload[When enabling/disabling unit files, don't reload daemon configuration]" \
 396     '--no-ask-password[Do not ask for system passwords]' \
 397     '--kill-who=[Who to send signal to]:killwho:(main control all)' \
 398     {-s+,--signal=}'[Which signal to send]:signal:_signals' \
 399     {-f,--force}'[When enabling unit files, override existing symlinks. When shutting down, execute action immediately]' \
 400     '--root=[Enable unit files in the specified root directory]:directory:_directories' \
 401     '--runtime[Enable unit files only temporarily until next reboot]' \
 402     {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
 403     {-P,--privileged}'[Acquire privileges before execution]' \
 404     {-n+,--lines=}'[Journal entries to show]:number of entries' \
 405     {-o+,--output=}'[Change journal output mode]:modes:_sd_outputmodes' \
 406     '--firmware-setup[Tell the firmware to show the setup menu on next boot]' \
 407     '--plain[When used with list-dependencies, print output as a list]' \
 408     '*::systemctl command:_systemctl_command'