shell-completion/zsh/_systemctl.in

   1 #compdef systemctl
   2
   3 (( $+functions[_systemctl_command] )) || _systemctl_command()
   4 {
   5   local -a _systemctl_cmds
   6   _systemctl_cmds=(
   7     "list-sockets:List sockets"
   8     "list-timers:List timers"
   9     "list-units:List units"
  10     "start:Start (activate) one or more units"
  11     "stop:Stop (deactivate) one or more units"
  12     "reload:Reload one or more units"
  13     "restart:Start or restart one or more units"
  14     "condrestart:Restart one or more units if active"
  15     "try-restart:Restart one or more units if active"
  16     "reload-or-restart:Reload one or more units if possible, otherwise start or restart"
  17     "force-reload:Reload one or more units if possible, otherwise restart if active"
  18     "hibernate:Hibernate the system"
  19     "hybrid-sleep:Hibernate and suspend the system"
  20     "reload-or-try-restart:Reload one or more units if possible, otherwise restart if active"
  21     "isolate:Start one unit and stop all others"
  22     "kill:Send signal to processes of a unit"
  23     "is-active:Check whether units are active"
  24     "is-failed:Check whether units are failed"
  25     "status:Show runtime status of one or more units"
  26     "show:Show properties of one or more units/jobs or the manager"
  27     "cat:Show the source unit files and drop-ins"
  28     "reset-failed:Reset failed state for all, one, or more units"
  29     "list-unit-files:List installed unit files"
  30     "enable:Enable one or more unit files"
  31     "disable:Disable one or more unit files"
  32     "reenable:Reenable one or more unit files"
  33     "preset:Enable/disable one or more unit files based on preset configuration"
  34     "help:Show documentation for specified units"
  35     "list-dependencies:Show unit dependency tree"
  36     "mask:Mask one or more units"
  37     "unmask:Unmask one or more units"
  38     "link:Link one or more units files into the search path"
  39     "is-enabled:Check whether unit files are enabled"
  40     "list-jobs:List jobs"
  41     "cancel:Cancel all, one, or more jobs"
  42     "snapshot:Create a snapshot"
  43     "delete:Remove one or more snapshots"
  44     "show-environment:Dump environment"
  45     "set-environment:Set one or more environment variables"
  46     "unset-environment:Unset one or more environment variables"
  47     "daemon-reload:Reload systemd manager configuration"
  48     "daemon-reexec:Reexecute systemd manager"
  49     "default:Enter system default mode"
  50     "rescue:Enter system rescue mode"
  51     "emergency:Enter system emergency mode"
  52     "halt:Shut down and halt the system"
  53     "suspend:Suspend the system"
  54     "poweroff:Shut down and power-off the system"
  55     "reboot:Shut down and reboot the system"
  56     "kexec:Shut down and reboot the system with kexec"
  57     "exit:Ask for user instance termination"
  58   )
  59
  60   if (( CURRENT == 1 )); then
  61     _describe -t commands 'systemctl command' _systemctl_cmds || compadd "$@"
  62   else
  63     local curcontext="$curcontext"
  64
  65     cmd="${${_systemctl_cmds[(r)$words[1]:*]%%:*}}"
  66     # Deal with any aliases
  67     case $cmd in
  68       condrestart) cmd="try-restart";;
  69       force-reload) cmd="reload-or-try-restart";;
  70     esac
  71
  72     if (( $#cmd )); then
  73       curcontext="${curcontext%:*:*}:systemctl-${cmd}:"
  74
  75       local update_policy
  76       zstyle -s ":completion:${curcontext}:" cache-policy update_policy
  77       if [[ -z "$update_policy" ]]; then
  78         zstyle ":completion:${curcontext}:" cache-policy _systemctl_caching_policy
  79       fi
  80
  81       _call_function ret _systemctl_$cmd || _message 'no more arguments'
  82     else
  83       _message "unknown systemctl command: $words[1]"
  84     fi
  85     return ret
  86   fi
  87 }
  88
  89 __systemctl()
  90 {
  91   local -a _modes
  92   _modes=("--user" "--system")
  93   systemctl ${words:*_modes} --full --no-legend --no-pager "$@"
  94 }
  95
  96
  97 # Fills the unit list
  98 _systemctl_all_units()
  99 {
 100   if ( [[ ${+_sys_all_units} -eq 0 ]] || _cache_invalid SYS_ALL_UNITS ) &&
 101     ! _retrieve_cache SYS_ALL_UNITS;
 102   then
 103     _sys_all_units=( $(__systemctl list-units --all | { while read -r a b; do echo -E - " $a"; done; }) )
 104     _store_cache SYS_ALL_UNITS _sys_all_units
 105   fi
 106 }
 107
 108 # Fills the unit list including all file units
 109 _systemctl_really_all_units()
 110 {
 111   local -a all_unit_files;
 112   local -a really_all_units;
 113   if ( [[ ${+_sys_really_all_units} -eq 0 ]] || _cache_invalid SYS_REALLY_ALL_UNITS ) &&
 114     ! _retrieve_cache SYS_REALLY_ALL_UNITS;
 115   then
 116     all_unit_files=( $(__systemctl list-unit-files | { while read -r a b; do echo -E - " $a"; done; }) )
 117     _systemctl_all_units
 118     really_all_units=($_sys_all_units $all_unit_files)
 119     _sys_really_all_units=(${(u)really_all_units})
 120     _store_cache SYS_REALLY_ALL_UNITS _sys_really_all_units
 121   fi
 122 }
 123
 124 _filter_units_by_property() {
 125   local property=$1 value=$2 ; shift ; shift
 126   local -a units ; units=($*)
 127   local prop unit
 128   for ((i=1; $i <= ${#units[*]}; i++)); do
 129     # FIXME: "Failed to issue method call: Unknown unit" errors are ignored for
 130     # now (related to DBUS_ERROR_UNKNOWN_OBJECT). in the future, we need to
 131     # revert to calling 'systemctl show' once for all units, which is way
 132     # faster
 133     unit=${units[i]}
 134     prop=${(f)"$(_call_program units "$service show --no-pager --property="$property" ${unit} 2>/dev/null")"}
 135     if [[ "${prop}" = "$property=$value" ]]; then
 136       echo " ${unit}"
 137     fi
 138   done
 139 }
 140
 141 _systemctl_all_units() { { __systemctl list-unit-files; __systemctl list-units --all; } | { while read -r a b; do echo -E - " $a"; done; } }
 142
 143 _systemctl_active_units()  {_sys_active_units=(  $(__systemctl list-units          | { while read -r a b; do echo -E - " $a"; done; }) )}
 144 _systemctl_startable_units(){_sys_startable_units=($(__systemctl list-units --state inactive,failed -- $(_systemctl_all_units) | { while read -r a b c d; do [[ $b == "loaded" ]] && echo -E - " $a"; done; }) )}
 145 _systemctl_restartable_units(){_sys_restartable_units=($(__systemctl list-units --state inactive,failed,active -- $(_systemctl_all_units) | { while read -r a b c d; do [[ $b == "loaded" ]] && echo -E - " $a"; done; }) )}
 146 _systemctl_failed_units()  {_sys_failed_units=(  $(__systemctl list-units --failed | { while read -r a b; do echo -E - " $a"; done; }) )}
 147 _systemctl_enabled_units() {_sys_enabled_units=( $(__systemctl list-unit-files     | { while read -r a b; do [[ $b == "enabled" ]] && echo -E - " $a"; done; }) )}
 148 _systemctl_disabled_units(){_sys_disabled_units=($(__systemctl list-unit-files     | { while read -r a b; do [[ $b == "disabled" ]] && echo -E - " $a"; done; }) )}
 149 _systemctl_masked_units()  {_sys_masked_units=(  $(__systemctl list-unit-files     | { while read -r a b; do [[ $b == "masked" ]] && echo -E - " $a"; done; }) )}
 150
 151 # Completion functions for ALL_UNITS
 152 for fun in is-active is-failed is-enabled status show cat mask preset help list-dependencies ; do
 153   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 154   {
 155     _systemctl_really_all_units
 156     compadd "$@" -a - _sys_really_all_units
 157   }
 158 done
 159
 160 # Completion functions for ENABLED_UNITS
 161 for fun in disable reenable ; do
 162   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 163   {
 164     _systemctl_enabled_units
 165     _systemctl_disabled_units
 166     compadd "$@" -a - _sys_enabled_units _sys_disabled_units
 167   }
 168 done
 169
 170 # Completion functions for DISABLED_UNITS
 171 (( $+functions[_systemctl_enable] )) || _systemctl_enable()
 172 {
 173   _systemctl_disabled_units
 174   compadd "$@" -a - _sys_disabled_units
 175 }
 176
 177 # Completion functions for FAILED_UNITS
 178 (( $+functions[_systemctl_reset-failed] )) || _systemctl_reset-failed()
 179 {
 180   _systemctl_failed_units
 181   compadd "$@" -a - _sys_failed_units || _message "no failed unit found"
 182 }
 183
 184 # Completion functions for STARTABLE_UNITS
 185 (( $+functions[_systemctl_start] )) || _systemctl_start()
 186 {
 187    _systemctl_startable_units
 188    compadd "$@" - $( _filter_units_by_property CanStart yes \
 189       ${_sys_startable_units[*]} )
 190 }
 191
 192 # Completion functions for STOPPABLE_UNITS
 193 for fun in stop kill try-restart condrestart ; do
 194   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 195   {
 196     _systemctl_active_units
 197     compadd "$@" - $( _filter_units_by_property CanStop yes \
 198       ${_sys_active_units[*]} )
 199   }
 200 done
 201
 202 # Completion functions for ISOLATABLE_UNITS
 203 (( $+functions[_systemctl_isolate] )) || _systemctl_isolate()
 204 {
 205   _systemctl_all_units
 206   compadd "$@" - $( _filter_units_by_property AllowIsolate yes \
 207     ${_sys_all_units[*]} )
 208 }
 209
 210 # Completion functions for RELOADABLE_UNITS
 211 for fun in reload reload-or-try-restart force-reload ; do
 212   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 213   {
 214     _systemctl_active_units
 215     compadd "$@" - $( _filter_units_by_property CanReload yes \
 216       ${_sys_active_units[*]} )
 217   }
 218 done
 219
 220 # Completion functions for RESTARTABLE_UNITS
 221 for fun in restart reload-or-restart ; do
 222   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 223   {
 224     _systemctl_restartable_units
 225     compadd "$@" - $( _filter_units_by_property CanStart yes \
 226       ${_sys_restartable_units[*]} )
 227   }
 228 done
 229
 230 # Completion functions for MASKED_UNITS
 231 (( $+functions[_systemctl_unmask] )) || _systemctl_unmask()
 232 {
 233   _systemctl_masked_units
 234   compadd "$@" -a - _sys_masked_units || _message "no masked unit found"
 235 }
 236
 237 # Completion functions for JOBS
 238 (( $+functions[_systemctl_cancel] )) || _systemctl_cancel()
 239 {
 240   compadd "$@" - $(__systemctl list-jobs \
 241     | cut -d' ' -f1  2>/dev/null ) || _message "no job found"
 242 }
 243
 244 # Completion functions for SNAPSHOTS
 245 (( $+functions[_systemctl_delete] )) || _systemctl_delete()
 246 {
 247   compadd "$@" - $(__systemctl list-units --type snapshot --all \
 248     | cut -d' ' -f1  2>/dev/null ) || _message "no snapshot found"
 249 }
 250
 251 # Completion functions for ENVS
 252 for fun in set-environment unset-environment ; do
 253   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
 254   {
 255     local fun=$0 ; fun=${fun##_systemctl_}
 256     local suf
 257     if [[ "${fun}" = "set-environment" ]]; then
 258       suf='-S='
 259     fi
 260
 261     compadd "$@" ${suf} - $(systemctl show-environment \
 262       | while read line; do echo " ${line%%\=}";done )
 263   }
 264 done
 265
 266 (( $+functions[_systemctl_link] )) || _systemctl_link() {
 267    _sd_unit_files
 268 }
 269
 270 # no systemctl completion for:
 271 #    [STANDALONE]='daemon-reexec daemon-reload default
 272 #                  emergency exit halt kexec list-jobs list-units
 273 #                  list-unit-files poweroff reboot rescue show-environment'
 274 #         [NAME]='snapshot'
 275
 276 _systemctl_caching_policy()
 277 {
 278   local _sysunits
 279   local -a oldcache
 280
 281   # rebuild if cache is more than a day old
 282   oldcache=( "$1"(mh+1) )
 283   (( $#oldcache )) && return 0
 284
 285   _sysunits=($(__systemctl --all | cut -d' ' -f1))
 286
 287   if (( $#_sysunits )); then
 288     for unit in $_sysunits; do
 289       [[ "$unit" -nt "$1" ]] && return 0
 290     done
 291   fi
 292
 293   return 1
 294 }
 295
 296 _unit_states() {
 297     local -a _states
 298     _states=(loaded failed active inactive not-found listening running waiting plugged mounted exited dead masked)
 299     _values -s , "${_states[@]}"
 300 }
 301
 302 _unit_types() {
 303     local -a _types
 304     _types=(automount busname device mount path service snapshot socket swap target timer)
 305     _values -s , "${_types[@]}"
 306 }
 307
 308 _unit_properties() {
 309   if ( [[ ${+_sys_all_properties} -eq 0 ]] || _cache_invalid SYS_ALL_PROPERTIES ) &&
 310     ! _retrieve_cache SYS_ALL_PROPERTIES;
 311   then
 312     _sys_all_properties=( $( {__systemctl show --all;
 313        @rootlibexecdir@/systemd --dump-configuration-items; } | {
 314        while IFS='=' read -r a b; do [ -n "$b" ] && echo "$a"; done
 315     }) )
 316     _store_cache SYS_ALL_PROPRTIES _sys_all_properties
 317   fi
 318   _values -s , "${_sys_all_properties[@]}"
 319 }
 320
 321 _arguments -s \
 322     {-h,--help}'[Show help]' \
 323     '--version[Show package version]' \
 324     {-t+,--type=}'[List only units of a particular type]:unit type:_unit_types' \
 325     '--state=[Display units in the specifyied state]:unit state:_unit_states' \
 326     {-p+,--property=}'[Show only properties by specific name]:unit property:_unit_properties' \
 327     {-a,--all}'[Show all units/properties, including dead/empty ones]' \
 328     '--reverse[Show reverse dependencies]' \
 329     '--after[Show units ordered after]' \
 330     '--before[Show units ordered before]' \
 331     '--failed[Show only failed units]' \
 332     {-l,--full}"[Don't ellipsize unit names on output]" \
 333     '--fail[When queueing a new job, fail if conflicting jobs are pending]' \
 334     '--show-types[When showing sockets, show socket type]' \
 335     '--irreversible[Mark transactions as irreversible]' \
 336     '--ignore-dependencies[When queueing a new job, ignore all its dependencies]' \
 337     {-i,--ignore-inhibitors}'[When executing a job, ignore jobs dependencies]' \
 338     {-q,--quiet}'[Suppress output]' \
 339     '--no-block[Do not wait until operation finished]' \
 340     '--no-legend[Do not print a legend, i.e. the column headers and the footer with hints]' \
 341     '--no-pager[Do not pipe output into a pager]' \
 342     '--system[Connect to system manager]' \
 343     '--user[Connect to user service manager]' \
 344     "--no-wall[Don't send wall message before halt/power-off/reboot]" \
 345     '--global[Enable/disable unit files globally]' \
 346     "--no-reload[When enabling/disabling unit files, don't reload daemon configuration]" \
 347     '--no-ask-password[Do not ask for system passwords]' \
 348     '--kill-who=[Who to send signal to]:killwho:(main control all)' \
 349     {-s+,--signal=}'[Which signal to send]:signal:_signals' \
 350     {-f,--force}'[When enabling unit files, override existing symlinks. When shutting down, execute action immediately]' \
 351     '--root=[Enable unit files in the specified root directory]:directory:_directories' \
 352     '--runtime[Enable unit files only temporarily until next reboot]' \
 353     {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
 354     {-P,--privileged}'[Acquire privileges before execution]' \
 355     {-n+,--lines=}'[Journal entries to show]:number of entries' \
 356     {-o+,--output=}'[Change journal output mode]:modes:_sd_outputmodes' \
 357     '--plain[When used with list-dependencies, print output as a list]' \
 358     '*::systemctl command:_systemctl_command'