src/home/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 systemd_homework_sources = files('''
   4         home-util.c
   5         home-util.h
   6         homework-cifs.c
   7         homework-cifs.h
   8         homework-directory.c
   9         homework-directory.h
  10         homework-fido2.h
  11         homework-fscrypt.c
  12         homework-fscrypt.h
  13         homework-luks.c
  14         homework-luks.h
  15         homework-mount.c
  16         homework-mount.h
  17         homework-pkcs11.h
  18         homework-quota.c
  19         homework-quota.h
  20         homework.c
  21         homework.h
  22         user-record-util.c
  23         user-record-util.h
  24 '''.split())
  25
  26 if conf.get('HAVE_P11KIT') == 1
  27         systemd_homework_sources += files('homework-pkcs11.c')
  28 endif
  29 if conf.get('HAVE_LIBFIDO2') == 1
  30         systemd_homework_sources += files('homework-fido2.c')
  31 endif
  32
  33 systemd_homed_sources = files('''
  34         home-util.c
  35         home-util.h
  36         homed-bus.c
  37         homed-bus.h
  38         homed-conf.c
  39         homed-conf.h
  40         homed-home-bus.c
  41         homed-home-bus.h
  42         homed-home.c
  43         homed-home.h
  44         homed-manager-bus.c
  45         homed-manager-bus.h
  46         homed-manager.c
  47         homed-manager.h
  48         homed-operation.c
  49         homed-operation.h
  50         homed-varlink.c
  51         homed-varlink.h
  52         homed.c
  53         user-record-pwquality.c
  54         user-record-pwquality.h
  55         user-record-sign.c
  56         user-record-sign.h
  57         user-record-util.c
  58         user-record-util.h
  59 '''.split())
  60
  61 homed_gperf_c = custom_target(
  62         'homed_gperf.c',
  63         input : 'homed-gperf.gperf',
  64         output : 'homed-gperf.c',
  65         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  66
  67 systemd_homed_sources += [homed_gperf_c]
  68
  69 homectl_sources = files('''
  70         home-util.c
  71         home-util.h
  72         homectl-fido2.c
  73         homectl-fido2.h
  74         homectl-pkcs11.c
  75         homectl-pkcs11.h
  76         homectl-recovery-key.c
  77         homectl-recovery-key.h
  78         homectl.c
  79         user-record-pwquality.c
  80         user-record-pwquality.h
  81         user-record-util.c
  82         user-record-util.h
  83 '''.split())
  84
  85 pam_systemd_home_sym = 'src/home/pam_systemd_home.sym'
  86 pam_systemd_home_c = files('''
  87         home-util.c
  88         home-util.h
  89         pam_systemd_home.c
  90         user-record-util.c
  91         user-record-util.h
  92 '''.split())
  93
  94 if conf.get('ENABLE_HOMED') == 1
  95         install_data('org.freedesktop.home1.conf',
  96                      install_dir : dbuspolicydir)
  97         install_data('org.freedesktop.home1.service',
  98                      install_dir : dbussystemservicedir)
  99         install_data('org.freedesktop.home1.policy',
 100                      install_dir : polkitpolicydir)
 101
 102         if install_sysconfdir_samples
 103                 install_data('homed.conf',
 104                              install_dir : pkgsysconfdir)
 105         endif
 106 endif