src/home/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 home_includes = [includes, include_directories('.')]
   4
   5 systemd_homework_sources = files('''
   6         home-util.c
   7         home-util.h
   8         homework-cifs.c
   9         homework-cifs.h
  10         homework-directory.c
  11         homework-directory.h
  12         homework-fido2.h
  13         homework-fscrypt.c
  14         homework-fscrypt.h
  15         homework-luks.c
  16         homework-luks.h
  17         homework-mount.c
  18         homework-mount.h
  19         homework-password-cache.c
  20         homework-password-cache.h
  21         homework-pkcs11.h
  22         homework-quota.c
  23         homework-quota.h
  24         homework.c
  25         homework.h
  26         user-record-util.c
  27         user-record-util.h
  28 '''.split())
  29
  30 if conf.get('HAVE_P11KIT') == 1
  31         systemd_homework_sources += files('homework-pkcs11.c')
  32 endif
  33 if conf.get('HAVE_LIBFIDO2') == 1
  34         systemd_homework_sources += files('homework-fido2.c')
  35 endif
  36
  37 systemd_homed_sources = files('''
  38         home-util.c
  39         home-util.h
  40         homed-bus.c
  41         homed-bus.h
  42         homed-conf.c
  43         homed-conf.h
  44         homed-home-bus.c
  45         homed-home-bus.h
  46         homed-home.c
  47         homed-home.h
  48         homed-manager-bus.c
  49         homed-manager-bus.h
  50         homed-manager.c
  51         homed-manager.h
  52         homed-operation.c
  53         homed-operation.h
  54         homed-varlink.c
  55         homed-varlink.h
  56         homed.c
  57         user-record-pwquality.c
  58         user-record-pwquality.h
  59         user-record-sign.c
  60         user-record-sign.h
  61         user-record-util.c
  62         user-record-util.h
  63 '''.split())
  64
  65 homed_gperf_c = custom_target(
  66         'homed_gperf.c',
  67         input : 'homed-gperf.gperf',
  68         output : 'homed-gperf.c',
  69         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  70
  71 systemd_homed_sources += [homed_gperf_c]
  72
  73 homectl_sources = files('''
  74         home-util.c
  75         home-util.h
  76         homectl-fido2.c
  77         homectl-fido2.h
  78         homectl-pkcs11.c
  79         homectl-pkcs11.h
  80         homectl-recovery-key.c
  81         homectl-recovery-key.h
  82         homectl.c
  83         user-record-pwquality.c
  84         user-record-pwquality.h
  85         user-record-util.c
  86         user-record-util.h
  87 '''.split())
  88
  89 pam_systemd_home_sym = 'src/home/pam_systemd_home.sym'
  90 pam_systemd_home_c = files('''
  91         home-util.c
  92         home-util.h
  93         pam_systemd_home.c
  94         user-record-util.c
  95         user-record-util.h
  96 '''.split())
  97
  98 if conf.get('ENABLE_HOMED') == 1
  99         install_data('org.freedesktop.home1.conf',
 100                      install_dir : dbuspolicydir)
 101         install_data('org.freedesktop.home1.service',
 102                      install_dir : dbussystemservicedir)
 103         install_data('org.freedesktop.home1.policy',
 104                      install_dir : polkitpolicydir)
 105
 106         if install_sysconfdir_samples
 107                 install_data('homed.conf',
 108                              install_dir : pkgsysconfdir)
 109         endif
 110 endif