src/journal/meson.build

   1 # -*- mode: meson -*-
   2
   3 libsystemd_journal_internal_sources = files('''
   4   audit-type.c
   5   audit-type.h
   6   catalog.c
   7   catalog.h
   8   compress.c
   9   compress.h
  10   journal-def.h
  11   journal-file.c
  12   journal-file.h
  13   journal-send.c
  14   journal-vacuum.c
  15   journal-vacuum.h
  16   journal-verify.c
  17   journal-verify.h
  18   lookup3.c
  19   lookup3.h
  20   mmap-cache.c
  21   mmap-cache.h
  22   sd-journal.c
  23 '''.split())
  24
  25 ############################################################
  26
  27 audit_type_includes = [config_h,
  28                        missing_h,
  29                        'linux/audit.h']
  30 if conf.get('HAVE_AUDIT', 0) == 1
  31   audit_type_includes += 'libaudit.h'
  32 endif
  33
  34 generate_audit_type_list = find_program('generate-audit_type-list.sh')
  35 audit_type_list_txt = custom_target(
  36     'audit_type-list.txt',
  37     output : 'audit_type-list.txt',
  38     command : [generate_audit_type_list] + audit_type_includes,
  39     capture : true)
  40
  41 audit_type_to_name = custom_target(
  42     'audit_type-to-name.h',
  43     input : ['audit_type-to-name.awk', audit_type_list_txt],
  44     output : 'audit_type-to-name.h',
  45     command : [awk, '-f', '@INPUT0@', '@INPUT1@'],
  46     capture : true)
  47
  48 ############################################################
  49
  50 libsystemd_journal_internal = static_library(
  51     'systemd-journal-internal',
  52     libsystemd_journal_internal_sources,
  53     audit_type_to_name,
  54     gcrypt_util_sources,
  55     install : false,
  56     include_directories : includes,
  57     link_with : libbasic,
  58     dependencies : [libaudit,
  59                    ])
  60
  61 libjournal_core_sources = files('''
  62   journald-kmsg.c
  63   journald-kmsg.h
  64   journald-syslog.c
  65   journald-syslog.h
  66   journald-stream.c
  67   journald-stream.h
  68   journald-server.c
  69   journald-server.h
  70   journald-console.c
  71   journald-console.h
  72   journald-wall.c
  73   journald-wall.h
  74   journald-native.c
  75   journald-native.h
  76   journald-audit.c
  77   journald-audit.h
  78   journald-rate-limit.c
  79   journald-rate-limit.h
  80   journal-internal.h
  81 '''.split())
  82
  83 systemd_journald_sources = files('''
  84   journald.c
  85   journald-server.h
  86 '''.split())
  87
  88 journald_gperf_c = custom_target(
  89     'journald-gperf.c',
  90     input : 'journald-gperf.gperf',
  91     output : 'journald-gperf.c',
  92     command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  93
  94 systemd_cat_sources = files('cat.c')
  95
  96 journalctl_sources = files('journalctl.c')
  97
  98 if conf.get('HAVE_QRENCODE', 0) == 1
  99   journalctl_sources += files('journal-qrcode.c',
 100                               'journal-qrcode.h')
 101 endif
 102
 103 install_data('journald.conf',
 104              install_dir : pkgsysconfdir)