src/libply-splash-graphics/meson.build

   1 libply_splash_graphics_sources = files(
   2   'ply-animation.c',
   3   'ply-capslock-icon.c',
   4   'ply-entry.c',
   5   'ply-image.c',
   6   'ply-keymap-icon.c',
   7   'ply-label.c',
   8   'ply-progress-animation.c',
   9   'ply-progress-bar.c',
  10   'ply-throbber.c',
  11 )
  12
  13 libply_splash_graphics_deps = [
  14   libply_splash_core_dep,
  15   lm_dep,
  16   libpng_dep,
  17 ]
  18
  19 libply_splash_graphics_cflags = [
  20   '-DPLYMOUTH_BACKGROUND_COLOR=@0@'.format(get_option('background-color')),
  21   '-DPLYMOUTH_BACKGROUND_START_COLOR=@0@'.format(get_option('background-start-color-stop')),
  22   '-DPLYMOUTH_BACKGROUND_END_COLOR=@0@'.format(get_option('background-end-color-stop')),
  23   '-DPLYMOUTH_PLUGIN_PATH="@0@"'.format(plymouth_plugin_path),
  24 ]
  25
  26 libply_splash_graphics = library('ply-splash-graphics',
  27   libply_splash_graphics_sources,
  28   dependencies: libply_splash_graphics_deps,
  29   c_args: libply_splash_graphics_cflags,
  30   include_directories: config_h_inc,
  31   version: plymouth_soversion,
  32   install: true,
  33 )
  34
  35 libply_splash_graphics_dep = declare_dependency(
  36   link_with: libply_splash_graphics,
  37   include_directories: include_directories('.'),
  38 )
  39
  40 libply_splash_graphics_headers = files(
  41   'ply-animation.h',
  42   'ply-capslock-icon.h',
  43   'ply-entry.h',
  44   'ply-image.h',
  45   'ply-keymap-icon.h',
  46   'ply-keymap-metadata.h',
  47   'ply-label-plugin.h',
  48   'ply-label.h',
  49   'ply-progress-animation.h',
  50   'ply-progress-bar.h',
  51   'ply-throbber.h',
  52 )
  53
  54 install_headers(libply_splash_graphics_headers,
  55   install_dir: get_option('includedir') / 'plymouth-1' / 'ply-splash-graphics',
  56 )
  57
  58 pkgconfig.generate(libply_splash_graphics,
  59   filebase: 'ply-splash-graphics',
  60   name: 'Plymouth',
  61   description: 'Graphics Utility Library for Boot Splash Plugins',
  62   requires: [
  63     'ply-splash-core',
  64   ],
  65   subdirs: [
  66     'plymouth-1/ply-splash-graphics',
  67   ],
  68   variables: {
  69     'pluginsdir': plymouth_plugin_path,
  70     'themesdir': plymouth_theme_path,
  71   },
  72 )