src/libudev/meson.build

   1 libudev_sources = files('''
   2         libudev-private.h
   3         libudev-device-internal.h
   4         libudev.c
   5         libudev-list.c
   6         libudev-util.c
   7         libudev-device.c
   8         libudev-device-private.c
   9         libudev-enumerate.c
  10         libudev-monitor.c
  11         libudev-queue.c
  12         libudev-hwdb.c
  13 '''.split())
  14
  15 ############################################################
  16
  17 libudev_sym = 'libudev.sym'
  18 libudev_sym_path = '@0@/@1@'.format(meson.current_source_dir(), libudev_sym)
  19 libudev = shared_library(
  20         'udev',
  21         libudev_sources,
  22         version : libudev_version,
  23         include_directories : includes,
  24         link_args : ['-shared',
  25                      '-Wl,--version-script=' + libudev_sym_path],
  26         link_with : [libbasic,
  27                      libsystemd_internal],
  28         dependencies : [threads],
  29         link_depends : libudev_sym,
  30         install : true,
  31         install_dir : rootlibdir)
  32
  33 install_headers('libudev.h')
  34 libudev_h_path = '@0@/libudev.h'.format(meson.current_source_dir())
  35
  36 libudev_pc = configure_file(
  37         input : 'libudev.pc.in',
  38         output : 'libudev.pc',
  39         configuration : substs)
  40 install_data(libudev_pc,
  41              install_dir : pkgconfiglibdir)