src/login/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2 #
   3 # Copyright 2017 Zbigniew Jędrzejewski-Szmek
   4 #
   5 # systemd is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU Lesser General Public License as published by
   7 # the Free Software Foundation; either version 2.1 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # systemd is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 # Lesser General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU Lesser General Public License
  16 # along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 systemd_logind_sources = files('''
  19         logind.c
  20         logind.h
  21 '''.split())
  22
  23 logind_gperf_c = custom_target(
  24         'logind_gperf.c',
  25         input : 'logind-gperf.gperf',
  26         output : 'logind-gperf.c',
  27         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  28
  29 systemd_logind_sources += [logind_gperf_c]
  30
  31
  32 liblogind_core_sources = files('''
  33         logind-core.c
  34         logind-device.c
  35         logind-device.h
  36         logind-button.c
  37         logind-button.h
  38         logind-action.c
  39         logind-action.h
  40         logind-seat.c
  41         logind-seat.h
  42         logind-session.c
  43         logind-session.h
  44         logind-session-device.c
  45         logind-session-device.h
  46         logind-user.c
  47         logind-user.h
  48         logind-inhibit.c
  49         logind-inhibit.h
  50         logind-dbus.c
  51         logind-session-dbus.c
  52         logind-seat-dbus.c
  53         logind-user-dbus.c
  54         logind-utmp.c
  55         logind-acl.h
  56 '''.split())
  57
  58 logind_acl_c = files('logind-acl.c')
  59 if conf.get('HAVE_ACL') == 1
  60         liblogind_core_sources += logind_acl_c
  61 endif
  62
  63 liblogind_core = static_library(
  64         'logind-core',
  65         liblogind_core_sources,
  66         include_directories : includes,
  67         dependencies : [libacl])
  68
  69 loginctl_sources = files('''
  70         loginctl.c
  71         sysfs-show.h
  72         sysfs-show.c
  73 '''.split())
  74
  75 if conf.get('ENABLE_LOGIND') == 1
  76         logind_conf = configure_file(
  77                 input : 'logind.conf.in',
  78                 output : 'logind.conf',
  79                 configuration : substs)
  80         install_data(logind_conf,
  81                      install_dir : pkgsysconfdir)
  82
  83         pam_systemd_sym = 'src/login/pam_systemd.sym'
  84         pam_systemd_c = files('pam_systemd.c')
  85
  86         install_data('org.freedesktop.login1.conf',
  87                      install_dir : dbuspolicydir)
  88         install_data('org.freedesktop.login1.service',
  89                      install_dir : dbussystemservicedir)
  90
  91         i18n.merge_file(
  92                 'org.freedesktop.login1.policy',
  93                 input : 'org.freedesktop.login1.policy.in',
  94                 output : 'org.freedesktop.login1.policy',
  95                 po_dir : po_dir,
  96                 data_dirs : po_dir,
  97                 install : install_polkit,
  98                 install_dir : polkitpolicydir)
  99
 100         install_data('70-power-switch.rules', install_dir : udevrulesdir)
 101
 102         if conf.get('HAVE_ACL') == 1
 103                 install_data('70-uaccess.rules', install_dir : udevrulesdir)
 104         endif
 105
 106         seat_rules = configure_file(
 107                 input : '71-seat.rules.in',
 108                 output : '71-seat.rules',
 109                 configuration : substs)
 110         install_data(seat_rules,
 111                      install_dir : udevrulesdir)
 112
 113         custom_target(
 114                 '73-seat-late.rules',
 115                 input : '73-seat-late.rules.m4',
 116                 output: '73-seat-late.rules',
 117                 command : [m4, '-P'] + m4_defines + ['@INPUT@'],
 118                 capture : true,
 119                 install : true,
 120                 install_dir : udevrulesdir)
 121
 122         custom_target(
 123                 'systemd-user',
 124                 input : 'systemd-user.m4',
 125                 output: 'systemd-user',
 126                 command : [m4, '-P'] + m4_defines + ['@INPUT@'],
 127                 capture : true,
 128                 install : pamconfdir != 'no',
 129                 install_dir : pamconfdir)
 130 endif