src/login/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 systemd_logind_sources = files('''
   4         logind.c
   5         logind.h
   6 '''.split())
   7
   8 logind_gperf_c = custom_target(
   9         'logind_gperf.c',
  10         input : 'logind-gperf.gperf',
  11         output : 'logind-gperf.c',
  12         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  13
  14 liblogind_core_sources = files('''
  15         logind-core.c
  16         logind-device.c
  17         logind-device.h
  18         logind-button.c
  19         logind-button.h
  20         logind-action.c
  21         logind-action.h
  22         logind-seat.c
  23         logind-seat.h
  24         logind-session.c
  25         logind-session.h
  26         logind-session-device.c
  27         logind-session-device.h
  28         logind-user.c
  29         logind-user.h
  30         logind-inhibit.c
  31         logind-inhibit.h
  32         logind-dbus.c
  33         logind-session-dbus.c
  34         logind-seat-dbus.c
  35         logind-user-dbus.c
  36         logind-utmp.c
  37         logind-acl.h
  38 '''.split())
  39
  40 liblogind_core_sources += [logind_gperf_c]
  41
  42 logind_acl_c = files('logind-acl.c')
  43 if conf.get('HAVE_ACL') == 1
  44         liblogind_core_sources += logind_acl_c
  45 endif
  46
  47 liblogind_core = static_library(
  48         'logind-core',
  49         liblogind_core_sources,
  50         include_directories : includes,
  51         dependencies : [libacl])
  52
  53 loginctl_sources = files('''
  54         loginctl.c
  55         sysfs-show.h
  56         sysfs-show.c
  57 '''.split())
  58
  59 user_runtime_dir_sources = files('''
  60         user-runtime-dir.c
  61         logind.h
  62 '''.split())
  63
  64 if conf.get('ENABLE_LOGIND') == 1
  65         logind_conf = configure_file(
  66                 input : 'logind.conf.in',
  67                 output : 'logind.conf',
  68                 configuration : substs)
  69         install_data(logind_conf,
  70                      install_dir : pkgsysconfdir)
  71
  72         pam_systemd_sym = 'src/login/pam_systemd.sym'
  73         pam_systemd_c = files('pam_systemd.c')
  74
  75         install_data('org.freedesktop.login1.conf',
  76                      install_dir : dbuspolicydir)
  77         install_data('org.freedesktop.login1.service',
  78                      install_dir : dbussystemservicedir)
  79         install_data('org.freedesktop.login1.policy',
  80                      install_dir : polkitpolicydir)
  81
  82         install_data('70-power-switch.rules', install_dir : udevrulesdir)
  83
  84         seat_rules = configure_file(
  85                 input : '71-seat.rules.in',
  86                 output : '71-seat.rules',
  87                 configuration : substs)
  88         install_data(seat_rules,
  89                      install_dir : udevrulesdir)
  90
  91         custom_target(
  92                 '70-uaccess.rules',
  93                 input : '70-uaccess.rules.m4',
  94                 output: '70-uaccess.rules',
  95                 command : [meson_apply_m4, config_h, '@INPUT@'],
  96                 capture : true,
  97                 install : conf.get('HAVE_ACL') == 1,
  98                 install_dir : udevrulesdir)
  99
 100         custom_target(
 101                 '73-seat-late.rules',
 102                 input : '73-seat-late.rules.m4',
 103                 output: '73-seat-late.rules',
 104                 command : [meson_apply_m4, config_h, '@INPUT@'],
 105                 capture : true,
 106                 install : true,
 107                 install_dir : udevrulesdir)
 108
 109         custom_target(
 110                 'systemd-user',
 111                 input : 'systemd-user.m4',
 112                 output: 'systemd-user',
 113                 command : [meson_apply_m4, config_h, '@INPUT@'],
 114                 capture : true,
 115                 install : pamconfdir != 'no',
 116                 install_dir : pamconfdir)
 117 endif