src/network/meson.build

   1 sources = files('''
   2         netdev/bond.c
   3         netdev/bond.h
   4         netdev/bridge.c
   5         netdev/bridge.h
   6         netdev/dummy.c
   7         netdev/dummy.h
   8         netdev/ipvlan.c
   9         netdev/ipvlan.h
  10         netdev/macvlan.c
  11         netdev/macvlan.h
  12         netdev/netdev.c
  13         netdev/netdev.h
  14         netdev/tunnel.c
  15         netdev/tunnel.h
  16         netdev/tuntap.c
  17         netdev/tuntap.h
  18         netdev/vcan.c
  19         netdev/vcan.h
  20         netdev/veth.c
  21         netdev/veth.h
  22         netdev/vlan.c
  23         netdev/vlan.h
  24         netdev/vrf.c
  25         netdev/vrf.h
  26         netdev/vxlan.c
  27         netdev/vxlan.h
  28         netdev/geneve.c
  29         netdev/geneve.h
  30         networkd-address-label.c
  31         networkd-address-label.h
  32         networkd-address-pool.c
  33         networkd-address-pool.h
  34         networkd-address.c
  35         networkd-address.h
  36         networkd-brvlan.c
  37         networkd-brvlan.h
  38         networkd-conf.c
  39         networkd-conf.h
  40         networkd-dhcp4.c
  41         networkd-dhcp6.c
  42         networkd-fdb.c
  43         networkd-fdb.h
  44         networkd-ipv4ll.c
  45         networkd-ipv6-proxy-ndp.c
  46         networkd-ipv6-proxy-ndp.h
  47         networkd-link-bus.c
  48         networkd-link.c
  49         networkd-link.h
  50         networkd-lldp-tx.c
  51         networkd-lldp-tx.h
  52         networkd-manager-bus.c
  53         networkd-manager.c
  54         networkd-manager.h
  55         networkd-ndisc.c
  56         networkd-ndisc.h
  57         networkd-radv.c
  58         networkd-radv.h
  59         networkd-network-bus.c
  60         networkd-network.c
  61         networkd-network.h
  62         networkd-route.c
  63         networkd-route.h
  64         networkd-util.c
  65         networkd-util.h
  66 '''.split())
  67
  68 systemd_networkd_sources = files('networkd.c')
  69
  70 systemd_networkd_wait_online_sources = files('''
  71         wait-online/link.c
  72         wait-online/link.h
  73         wait-online/manager.c
  74         wait-online/manager.h
  75         wait-online/wait-online.c
  76 '''.split()) + network_internal_h
  77
  78 networkctl_sources = files('networkctl.c')
  79
  80 network_include_dir = include_directories('.')
  81
  82 if conf.get('ENABLE_NETWORKD', false)
  83         networkd_gperf_c = custom_target(
  84                 'networkd-gperf.c',
  85                 input : 'networkd-gperf.gperf',
  86                 output : 'networkd-gperf.c',
  87                 command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  88
  89         networkd_network_gperf_c = custom_target(
  90                 'networkd-network-gperf.c',
  91                 input : 'networkd-network-gperf.gperf',
  92                 output : 'networkd-network-gperf.c',
  93                 command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  94
  95         netdev_gperf_c = custom_target(
  96                 'netdev-gperf.c',
  97                 input : 'netdev/netdev-gperf.gperf',
  98                 output : 'netdev-gperf.c',
  99                 command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 100
 101         libnetworkd_core = static_library(
 102                 'networkd-core',
 103                 sources,
 104                 network_internal_h,
 105                 networkd_gperf_c,
 106                 networkd_network_gperf_c,
 107                 netdev_gperf_c,
 108                 include_directories : includes,
 109                 link_with : [libshared])
 110
 111         install_data('org.freedesktop.network1.conf',
 112                      install_dir : dbuspolicydir)
 113         install_data('org.freedesktop.network1.service',
 114                      install_dir : dbussystemservicedir)
 115         if install_polkit
 116                 install_data('systemd-networkd.rules',
 117                              install_dir : polkitrulesdir)
 118         endif
 119         if install_polkit_pkla
 120                 install_data('systemd-networkd.pkla',
 121                              install_dir : polkitpkladir)
 122         endif
 123
 124         tests += [
 125     [['src/network/test-networkd-conf.c'],
 126      [libnetworkd_core,
 127       libsystemd_network,
 128       libudev],
 129      []],
 130
 131     [['src/network/test-network.c'],
 132      [libnetworkd_core,
 133       libudev_internal,
 134       libsystemd_network,
 135       libshared],
 136      []],
 137
 138     [['src/network/test-network-tables.c',
 139       'src/network/test-network-tables.c',
 140       test_tables_h],
 141      [libnetworkd_core,
 142       libudev_internal,
 143       libudev_core,
 144       libsystemd_network,
 145       libshared],
 146      [],
 147      '', '', [],
 148      [network_include_dir] + libudev_core_includes],
 149   ]
 150 endif