src/network/meson.build

   1 sources = files('''
   2         netdev/bond.c
   3         netdev/bond.h
   4         netdev/bridge.c
   5         netdev/bridge.h
   6         netdev/dummy.c
   7         netdev/dummy.h
   8         netdev/ipvlan.c
   9         netdev/ipvlan.h
  10         netdev/macvlan.c
  11         netdev/macvlan.h
  12         netdev/netdev.c
  13         netdev/netdev.h
  14         netdev/tunnel.c
  15         netdev/tunnel.h
  16         netdev/tuntap.c
  17         netdev/tuntap.h
  18         netdev/vcan.c
  19         netdev/vcan.h
  20         netdev/veth.c
  21         netdev/veth.h
  22         netdev/vlan.c
  23         netdev/vlan.h
  24         netdev/vrf.c
  25         netdev/vrf.h
  26         netdev/vxlan.c
  27         netdev/vxlan.h
  28         networkd-address-pool.c
  29         networkd-address-pool.h
  30         networkd-address.c
  31         networkd-address.h
  32         networkd-brvlan.c
  33         networkd-brvlan.h
  34         networkd-conf.c
  35         networkd-conf.h
  36         networkd-dhcp4.c
  37         networkd-dhcp6.c
  38         networkd-fdb.c
  39         networkd-fdb.h
  40         networkd-ipv4ll.c
  41         networkd-ipv6-proxy-ndp.c
  42         networkd-ipv6-proxy-ndp.h
  43         networkd-link-bus.c
  44         networkd-link.c
  45         networkd-link.h
  46         networkd-lldp-tx.c
  47         networkd-lldp-tx.h
  48         networkd-manager-bus.c
  49         networkd-manager.c
  50         networkd-manager.h
  51         networkd-ndisc.c
  52         networkd-ndisc.h
  53         networkd-network-bus.c
  54         networkd-network.c
  55         networkd-network.h
  56         networkd-route.c
  57         networkd-route.h
  58         networkd-util.c
  59         networkd-util.h
  60 '''.split())
  61
  62 systemd_networkd_sources = files('networkd.c')
  63
  64 systemd_networkd_wait_online_sources = files('''
  65         wait-online/link.c
  66         wait-online/link.h
  67         wait-online/manager.c
  68         wait-online/manager.h
  69         wait-online/wait-online.c
  70 '''.split()) + network_internal_h
  71
  72 networkctl_sources = files('networkctl.c')
  73
  74 network_include_dir = include_directories('.')
  75
  76 if conf.get('ENABLE_NETWORKD', 0) == 1
  77         networkd_gperf_c = custom_target(
  78                 'networkd-gperf.c',
  79                 input : 'networkd-gperf.gperf',
  80                 output : 'networkd-gperf.c',
  81                 command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  82
  83         networkd_network_gperf_c = custom_target(
  84                 'networkd-network-gperf.c',
  85                 input : 'networkd-network-gperf.gperf',
  86                 output : 'networkd-network-gperf.c',
  87                 command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  88
  89         netdev_gperf_c = custom_target(
  90                 'netdev-gperf.c',
  91                 input : 'netdev/netdev-gperf.gperf',
  92                 output : 'netdev-gperf.c',
  93                 command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  94
  95         libnetworkd_core = static_library(
  96                 'networkd-core',
  97                 sources,
  98                 network_internal_h,
  99                 networkd_gperf_c,
 100                 networkd_network_gperf_c,
 101                 netdev_gperf_c,
 102                 include_directories : includes,
 103                 link_with : [libshared])
 104
 105         install_data('org.freedesktop.network1.conf',
 106                      install_dir : dbuspolicydir)
 107         install_data('org.freedesktop.network1.service',
 108                      install_dir : dbussystemservicedir)
 109         if install_polkit
 110                 install_data('systemd-networkd.rules',
 111                              install_dir : polkitrulesdir)
 112         endif
 113         if install_polkit_pkla
 114                 install_data('systemd-networkd.pkla',
 115                              install_dir : polkitpkladir)
 116         endif
 117
 118         tests += [
 119     [['src/network/test-networkd-conf.c'],
 120      [libnetworkd_core,
 121       libsystemd_network,
 122       libudev],
 123      []],
 124
 125     [['src/network/test-network.c'],
 126      [libnetworkd_core,
 127       libudev_internal,
 128       libsystemd_network,
 129       libshared,
 130       libfirewall],
 131      [libiptc]],
 132
 133     [['src/network/test-network-tables.c',
 134       'src/network/test-network-tables.c',
 135       test_tables_h],
 136      [libnetworkd_core,
 137       libudev_internal,
 138       libudev_core,
 139       libsystemd_network,
 140       libshared,
 141       libfirewall],
 142      [],
 143      '', '', [],
 144      [network_include_dir] + libudev_core_includes],
 145   ]
 146 endif