src/udev/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 udevadm_sources = files('''
   4         udevadm.c
   5         udevadm.h
   6         udevadm-control.c
   7         udevadm-hwdb.c
   8         udevadm-info.c
   9         udevadm-monitor.c
  10         udevadm-settle.c
  11         udevadm-test.c
  12         udevadm-test-builtin.c
  13         udevadm-trigger.c
  14         udevadm-util.c
  15         udevadm-util.h
  16 '''.split())
  17
  18 systemd_udevd_sources = files('udevd.c')
  19
  20 libudev_core_sources = '''
  21         udev-ctrl.c
  22         udev-ctrl.h
  23         udev-event.c
  24         udev-event.h
  25         udev-node.c
  26         udev-node.h
  27         udev-rules.c
  28         udev-rules.h
  29         udev-watch.c
  30         udev-watch.h
  31         udev-builtin.c
  32         udev-builtin.h
  33         udev-builtin-btrfs.c
  34         udev-builtin-hwdb.c
  35         udev-builtin-input_id.c
  36         udev-builtin-keyboard.c
  37         udev-builtin-net_id.c
  38         udev-builtin-net_setup_link.c
  39         udev-builtin-path_id.c
  40         udev-builtin-usb_id.c
  41         net/link-config.c
  42         net/link-config.h
  43 '''.split()
  44
  45 if conf.get('HAVE_KMOD') == 1
  46         libudev_core_sources += ['udev-builtin-kmod.c']
  47 endif
  48
  49 if conf.get('HAVE_BLKID') == 1
  50         libudev_core_sources += ['udev-builtin-blkid.c']
  51 endif
  52
  53 if conf.get('HAVE_ACL') == 1
  54         libudev_core_sources += ['udev-builtin-uaccess.c',
  55                                  logind_acl_c,
  56                                  sd_login_sources]
  57 endif
  58
  59 ############################################################
  60
  61 generate_keyboard_keys_list = find_program('generate-keyboard-keys-list.sh')
  62 keyboard_keys_list_txt = custom_target(
  63         'keyboard-keys-list.txt',
  64         output : 'keyboard-keys-list.txt',
  65         command : [generate_keyboard_keys_list, cpp],
  66         capture : true)
  67
  68 generate_keyboard_keys_gperf = find_program('generate-keyboard-keys-gperf.sh')
  69 fname = 'keyboard-keys-from-name.gperf'
  70 gperf_file = custom_target(
  71         fname,
  72         input : keyboard_keys_list_txt,
  73         output : fname,
  74         command : [generate_keyboard_keys_gperf, '@INPUT@'],
  75         capture : true)
  76
  77 fname = 'keyboard-keys-from-name.h'
  78 keyboard_keys_from_name_h = custom_target(
  79         fname,
  80         input : gperf_file,
  81         output : fname,
  82         command : [gperf,
  83                    '-L', 'ANSI-C', '-t',
  84                    '-N', 'keyboard_lookup_key',
  85                    '-H', 'hash_key_name',
  86                    '-p', '-C',
  87                    '@INPUT@'],
  88         capture : true)
  89
  90 ############################################################
  91
  92 link_config_gperf_c = custom_target(
  93         'link-config-gperf.c',
  94         input : 'net/link-config-gperf.gperf',
  95         output : 'link-config-gperf.c',
  96         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  97
  98 ############################################################
  99
 100 if get_option('link-udev-shared')
 101         udev_link_with = [libshared]
 102         udev_rpath = rootlibexecdir
 103 else
 104         udev_link_with = [libshared_static,
 105                           libsystemd_static]
 106         udev_rpath = ''
 107 endif
 108
 109 libudev_basic = static_library(
 110         'udev-basic',
 111         libudev_sources,
 112         include_directories : includes,
 113         c_args : ['-fvisibility=default'])
 114
 115 libudev_static = static_library(
 116         'udev_static',
 117         include_directories : includes,
 118         link_with : udev_link_with,
 119         link_whole : libudev_basic)
 120
 121 static_libudev = get_option('static-libudev')
 122 static_libudev_pic = static_libudev == 'true' or static_libudev == 'pic'
 123 install_libudev_static = static_library(
 124         'udev',
 125         basic_sources,
 126         shared_sources,
 127         libsystemd_sources,
 128         libudev_sources,
 129         disable_mempool_c,
 130         include_directories : includes,
 131         build_by_default : static_libudev != 'false',
 132         install : static_libudev != 'false',
 133         install_dir : rootlibdir,
 134         link_depends : libudev_sym,
 135         dependencies : libshared_deps + [libmount],
 136         c_args : static_libudev_pic ? [] : ['-fno-PIC'],
 137         pic : static_libudev_pic)
 138
 139 libudev = shared_library(
 140         'udev',
 141         disable_mempool_c,
 142         version : libudev_version,
 143         include_directories : includes,
 144         link_args : ['-shared',
 145                      '-Wl,--version-script=' + libudev_sym_path],
 146         link_with : [libsystemd_static, libshared_static],
 147         link_whole : libudev_basic,
 148         dependencies : [threads],
 149         link_depends : libudev_sym,
 150         install : true,
 151         install_dir : rootlibdir)
 152
 153 libudev_core_includes = [includes, include_directories('net')]
 154 libudev_core = static_library(
 155         'udev-core',
 156         libudev_core_sources,
 157         link_config_gperf_c,
 158         keyboard_keys_from_name_h,
 159         include_directories : libudev_core_includes,
 160         c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 161         link_with : udev_link_with,
 162         dependencies : [libblkid, libkmod])
 163
 164 foreach prog : [['ata_id/ata_id.c'],
 165                 ['cdrom_id/cdrom_id.c'],
 166                 ['fido_id/fido_id.c',
 167                  'fido_id/fido_id_desc.c',
 168                  'fido_id/fido_id_desc.h'],
 169                 ['scsi_id/scsi_id.c',
 170                  'scsi_id/scsi_id.h',
 171                  'scsi_id/scsi_serial.c',
 172                  'scsi_id/scsi.h'],
 173                 ['v4l_id/v4l_id.c'],
 174                 ['mtd_probe/mtd_probe.c',
 175                  'mtd_probe/mtd_probe.h',
 176                  'mtd_probe/probe_smartmedia.c']]
 177
 178         executable(prog[0].split('/')[0],
 179                    prog,
 180                    include_directories : includes,
 181                    c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 182                    dependencies : [versiondep],
 183                    link_with : [libudev_static],
 184                    install_rpath : udev_rpath,
 185                    install : true,
 186                    install_dir : udevlibexecdir)
 187 endforeach
 188
 189 install_data('udev.conf',
 190              install_dir : join_paths(sysconfdir, 'udev'))
 191
 192 configure_file(
 193         input : 'udev.pc.in',
 194         output : 'udev.pc',
 195         configuration : substs,
 196         install_dir : pkgconfigdatadir == 'no' ? '' : pkgconfigdatadir)
 197
 198 meson.add_install_script('sh', '-c',
 199                          mkdir_p.format(join_paths(sysconfdir, 'udev/rules.d')))
 200
 201 fuzzers += [
 202         [['src/udev/net/fuzz-link-parser.c',
 203           'src/fuzz/fuzz.h'],
 204          [libudev_core,
 205           libudev_static,
 206           libsystemd_network,
 207           libshared],
 208          [threads,
 209           libacl]],
 210
 211         [['src/udev/fido_id/fuzz-fido-id-desc.c',
 212           'src/udev/fido_id/fido_id_desc.c'],
 213          [],
 214          []],
 215         ]
 216
 217 tests += [
 218         [['src/udev/fido_id/test-fido-id-desc.c',
 219           'src/udev/fido_id/fido_id_desc.c'],
 220          [],
 221          []],
 222         ]