src/udev/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 udevadm_sources = files('''
   4         udevadm.c
   5         udevadm.h
   6         udevadm-control.c
   7         udevadm-hwdb.c
   8         udevadm-info.c
   9         udevadm-monitor.c
  10         udevadm-settle.c
  11         udevadm-test.c
  12         udevadm-test-builtin.c
  13         udevadm-trigger.c
  14         udevadm-util.c
  15         udevadm-util.h
  16 '''.split())
  17
  18 systemd_udevd_sources = files('udevd.c')
  19
  20 libudev_core_sources = '''
  21         udev.h
  22         udev-event.c
  23         udev-watch.c
  24         udev-node.c
  25         udev-rules.c
  26         udev-ctrl.c
  27         udev-builtin.c
  28         udev-builtin-btrfs.c
  29         udev-builtin-hwdb.c
  30         udev-builtin-input_id.c
  31         udev-builtin-keyboard.c
  32         udev-builtin-net_id.c
  33         udev-builtin-net_setup_link.c
  34         udev-builtin-path_id.c
  35         udev-builtin-usb_id.c
  36         net/link-config.c
  37         net/link-config.h
  38         net/ethtool-util.c
  39         net/ethtool-util.h
  40 '''.split()
  41
  42 if conf.get('HAVE_KMOD') == 1
  43         libudev_core_sources += ['udev-builtin-kmod.c']
  44 endif
  45
  46 if conf.get('HAVE_BLKID') == 1
  47         libudev_core_sources += ['udev-builtin-blkid.c']
  48 endif
  49
  50 if conf.get('HAVE_ACL') == 1
  51         libudev_core_sources += ['udev-builtin-uaccess.c',
  52                                  logind_acl_c,
  53                                  sd_login_c]
  54 endif
  55
  56 ############################################################
  57
  58 generate_keyboard_keys_list = find_program('generate-keyboard-keys-list.sh')
  59 keyboard_keys_list_txt = custom_target(
  60         'keyboard-keys-list.txt',
  61         output : 'keyboard-keys-list.txt',
  62         command : [generate_keyboard_keys_list, cpp],
  63         capture : true)
  64
  65 generate_keyboard_keys_gperf = find_program('generate-keyboard-keys-gperf.sh')
  66 fname = 'keyboard-keys-from-name.gperf'
  67 gperf_file = custom_target(
  68         fname,
  69         input : keyboard_keys_list_txt,
  70         output : fname,
  71         command : [generate_keyboard_keys_gperf, '@INPUT@'],
  72         capture : true)
  73
  74 fname = 'keyboard-keys-from-name.h'
  75 keyboard_keys_from_name_h = custom_target(
  76         fname,
  77         input : gperf_file,
  78         output : fname,
  79         command : [gperf,
  80                    '-L', 'ANSI-C', '-t',
  81                    '-N', 'keyboard_lookup_key',
  82                    '-H', 'hash_key_name',
  83                    '-p', '-C',
  84                    '@INPUT@'],
  85         capture : true)
  86
  87 ############################################################
  88
  89 link_config_gperf_c = custom_target(
  90         'link-config-gperf.c',
  91         input : 'net/link-config-gperf.gperf',
  92         output : 'link-config-gperf.c',
  93         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  94
  95 ############################################################
  96
  97 if get_option('link-udev-shared')
  98         udev_link_with = [libshared]
  99         udev_rpath = rootlibexecdir
 100 else
 101         udev_link_with = [libshared_static,
 102                           libsystemd_static]
 103         udev_rpath = ''
 104 endif
 105
 106 libudev_basic = static_library(
 107         'udev-basic',
 108         libudev_sources,
 109         include_directories : includes,
 110         c_args : ['-fvisibility=default'])
 111
 112 libudev_static = static_library(
 113         'udev_static',
 114         'udev.h',
 115         include_directories : includes,
 116         link_with : udev_link_with,
 117         link_whole : libudev_basic)
 118
 119 static_libudev = get_option('static-libudev')
 120 static_libudev_pic = static_libudev == 'true' or static_libudev == 'pic'
 121 install_libudev_static = static_library(
 122         'udev',
 123         basic_sources,
 124         shared_sources,
 125         libsystemd_sources,
 126         libudev_sources,
 127         include_directories : includes,
 128         build_by_default : static_libudev != 'false',
 129         install : static_libudev != 'false',
 130         install_dir : rootlibdir,
 131         link_depends : libudev_sym,
 132         dependencies : libshared_deps + [libmount],
 133         c_args : static_libudev_pic ? [] : ['-fno-PIC'],
 134         pic : static_libudev_pic)
 135
 136 libudev = shared_library(
 137         'udev',
 138         'udev.h', # pick a header file at random to work around old meson bug
 139         version : libudev_version,
 140         include_directories : includes,
 141         link_args : ['-shared',
 142                      '-Wl,--version-script=' + libudev_sym_path],
 143         link_with : [libsystemd_static, libshared_static],
 144         link_whole : libudev_basic,
 145         dependencies : [threads],
 146         link_depends : libudev_sym,
 147         install : true,
 148         install_dir : rootlibdir)
 149
 150 libudev_core_includes = [includes, include_directories('net')]
 151 libudev_core = static_library(
 152         'udev-core',
 153         libudev_core_sources,
 154         link_config_gperf_c,
 155         keyboard_keys_from_name_h,
 156         include_directories : libudev_core_includes,
 157         c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 158         link_with : udev_link_with,
 159         dependencies : [libblkid, libkmod])
 160
 161 foreach prog : [['ata_id/ata_id.c'],
 162                 ['cdrom_id/cdrom_id.c'],
 163                 ['scsi_id/scsi_id.c',
 164                  'scsi_id/scsi_id.h',
 165                  'scsi_id/scsi_serial.c',
 166                  'scsi_id/scsi.h'],
 167                 ['v4l_id/v4l_id.c'],
 168                 ['mtd_probe/mtd_probe.c',
 169                  'mtd_probe/mtd_probe.h',
 170                  'mtd_probe/probe_smartmedia.c']]
 171
 172         executable(prog[0].split('/')[0],
 173                    prog,
 174                    include_directories : includes,
 175                    c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 176                    link_with : [libudev_static],
 177                    install_rpath : udev_rpath,
 178                    install : true,
 179                    install_dir : udevlibexecdir)
 180 endforeach
 181
 182 install_data('udev.conf',
 183              install_dir : join_paths(sysconfdir, 'udev'))
 184
 185 udev_pc = configure_file(
 186         input : 'udev.pc.in',
 187         output : 'udev.pc',
 188         configuration : substs)
 189 install_data(udev_pc,
 190              install_dir : pkgconfigdatadir)
 191
 192 meson.add_install_script('sh', '-c',
 193                          mkdir_p.format(join_paths(sysconfdir, 'udev/rules.d')))