src/udev/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 udevadm_sources = files('''
   4         udevadm.c
   5         udevadm.h
   6         udevadm-control.c
   7         udevadm-hwdb.c
   8         udevadm-info.c
   9         udevadm-monitor.c
  10         udevadm-settle.c
  11         udevadm-test.c
  12         udevadm-test-builtin.c
  13         udevadm-trigger.c
  14         udevadm-util.c
  15         udevadm-util.h
  16 '''.split())
  17
  18 systemd_udevd_sources = files('udevd.c')
  19
  20 libudev_core_sources = '''
  21         udev-ctrl.c
  22         udev-ctrl.h
  23         udev-event.c
  24         udev-event.h
  25         udev-node.c
  26         udev-node.h
  27         udev-rules.c
  28         udev-rules.h
  29         udev-watch.c
  30         udev-watch.h
  31         udev-builtin.c
  32         udev-builtin.h
  33         udev-builtin-btrfs.c
  34         udev-builtin-hwdb.c
  35         udev-builtin-input_id.c
  36         udev-builtin-keyboard.c
  37         udev-builtin-net_id.c
  38         udev-builtin-net_setup_link.c
  39         udev-builtin-path_id.c
  40         udev-builtin-usb_id.c
  41         net/link-config.c
  42         net/link-config.h
  43         net/ethtool-util.c
  44         net/ethtool-util.h
  45         net/naming-scheme.c
  46         net/naming-scheme.h
  47 '''.split()
  48
  49 if conf.get('HAVE_KMOD') == 1
  50         libudev_core_sources += ['udev-builtin-kmod.c']
  51 endif
  52
  53 if conf.get('HAVE_BLKID') == 1
  54         libudev_core_sources += ['udev-builtin-blkid.c']
  55 endif
  56
  57 if conf.get('HAVE_ACL') == 1
  58         libudev_core_sources += ['udev-builtin-uaccess.c',
  59                                  logind_acl_c,
  60                                  sd_login_sources]
  61 endif
  62
  63 ############################################################
  64
  65 generate_keyboard_keys_list = find_program('generate-keyboard-keys-list.sh')
  66 keyboard_keys_list_txt = custom_target(
  67         'keyboard-keys-list.txt',
  68         output : 'keyboard-keys-list.txt',
  69         command : [generate_keyboard_keys_list, cpp],
  70         capture : true)
  71
  72 generate_keyboard_keys_gperf = find_program('generate-keyboard-keys-gperf.sh')
  73 fname = 'keyboard-keys-from-name.gperf'
  74 gperf_file = custom_target(
  75         fname,
  76         input : keyboard_keys_list_txt,
  77         output : fname,
  78         command : [generate_keyboard_keys_gperf, '@INPUT@'],
  79         capture : true)
  80
  81 fname = 'keyboard-keys-from-name.h'
  82 keyboard_keys_from_name_h = custom_target(
  83         fname,
  84         input : gperf_file,
  85         output : fname,
  86         command : [gperf,
  87                    '-L', 'ANSI-C', '-t',
  88                    '-N', 'keyboard_lookup_key',
  89                    '-H', 'hash_key_name',
  90                    '-p', '-C',
  91                    '@INPUT@'],
  92         capture : true)
  93
  94 ############################################################
  95
  96 link_config_gperf_c = custom_target(
  97         'link-config-gperf.c',
  98         input : 'net/link-config-gperf.gperf',
  99         output : 'link-config-gperf.c',
 100         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 101
 102 ############################################################
 103
 104 if get_option('link-udev-shared')
 105         udev_link_with = [libshared]
 106         udev_rpath = rootlibexecdir
 107 else
 108         udev_link_with = [libshared_static,
 109                           libsystemd_static]
 110         udev_rpath = ''
 111 endif
 112
 113 libudev_basic = static_library(
 114         'udev-basic',
 115         libudev_sources,
 116         include_directories : includes,
 117         c_args : ['-fvisibility=default'])
 118
 119 libudev_static = static_library(
 120         'udev_static',
 121         include_directories : includes,
 122         link_with : udev_link_with,
 123         link_whole : libudev_basic)
 124
 125 static_libudev = get_option('static-libudev')
 126 static_libudev_pic = static_libudev == 'true' or static_libudev == 'pic'
 127 install_libudev_static = static_library(
 128         'udev',
 129         basic_sources,
 130         shared_sources,
 131         libsystemd_sources,
 132         libudev_sources,
 133         disable_mempool_c,
 134         include_directories : includes,
 135         build_by_default : static_libudev != 'false',
 136         install : static_libudev != 'false',
 137         install_dir : rootlibdir,
 138         link_depends : libudev_sym,
 139         dependencies : libshared_deps + [libmount],
 140         c_args : static_libudev_pic ? [] : ['-fno-PIC'],
 141         pic : static_libudev_pic)
 142
 143 libudev = shared_library(
 144         'udev',
 145         disable_mempool_c,
 146         version : libudev_version,
 147         include_directories : includes,
 148         link_args : ['-shared',
 149                      '-Wl,--version-script=' + libudev_sym_path],
 150         link_with : [libsystemd_static, libshared_static],
 151         link_whole : libudev_basic,
 152         dependencies : [threads],
 153         link_depends : libudev_sym,
 154         install : true,
 155         install_dir : rootlibdir)
 156
 157 libudev_core_includes = [includes, include_directories('net')]
 158 libudev_core = static_library(
 159         'udev-core',
 160         libudev_core_sources,
 161         link_config_gperf_c,
 162         keyboard_keys_from_name_h,
 163         include_directories : libudev_core_includes,
 164         c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 165         link_with : udev_link_with,
 166         dependencies : [libblkid, libkmod])
 167
 168 foreach prog : [['ata_id/ata_id.c'],
 169                 ['cdrom_id/cdrom_id.c'],
 170                 ['scsi_id/scsi_id.c',
 171                  'scsi_id/scsi_id.h',
 172                  'scsi_id/scsi_serial.c',
 173                  'scsi_id/scsi.h'],
 174                 ['v4l_id/v4l_id.c'],
 175                 ['mtd_probe/mtd_probe.c',
 176                  'mtd_probe/mtd_probe.h',
 177                  'mtd_probe/probe_smartmedia.c']]
 178
 179         executable(prog[0].split('/')[0],
 180                    prog,
 181                    include_directories : includes,
 182                    c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 183                    dependencies : [versiondep],
 184                    link_with : [libudev_static],
 185                    install_rpath : udev_rpath,
 186                    install : true,
 187                    install_dir : udevlibexecdir)
 188 endforeach
 189
 190 install_data('udev.conf',
 191              install_dir : join_paths(sysconfdir, 'udev'))
 192
 193 configure_file(
 194         input : 'udev.pc.in',
 195         output : 'udev.pc',
 196         configuration : substs,
 197         install_dir : pkgconfigdatadir == 'no' ? '' : pkgconfigdatadir)
 198
 199 meson.add_install_script('sh', '-c',
 200                          mkdir_p.format(join_paths(sysconfdir, 'udev/rules.d')))
 201
 202 fuzzers += [
 203         [['src/udev/net/fuzz-link-parser.c',
 204           'src/fuzz/fuzz.h'],
 205          [libudev_core,
 206           libudev_static,
 207           libsystemd_network,
 208           libshared],
 209          [threads,
 210           libacl]]
 211         ]