src/udev/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 udevadm_sources = files('''
   4         udevadm.c
   5         udevadm.h
   6         udevadm-control.c
   7         udevadm-hwdb.c
   8         udevadm-info.c
   9         udevadm-monitor.c
  10         udevadm-settle.c
  11         udevadm-test.c
  12         udevadm-test-builtin.c
  13         udevadm-trigger.c
  14         udevadm-util.c
  15         udevadm-util.h
  16 '''.split())
  17
  18 systemd_udevd_sources = files('udevd.c')
  19
  20 libudev_core_sources = '''
  21         udev-ctrl.c
  22         udev-ctrl.h
  23         udev-event.c
  24         udev-event.h
  25         udev-node.c
  26         udev-node.h
  27         udev-rules.c
  28         udev-rules.h
  29         udev-watch.c
  30         udev-watch.h
  31         udev-builtin.c
  32         udev-builtin.h
  33         udev-builtin-btrfs.c
  34         udev-builtin-hwdb.c
  35         udev-builtin-input_id.c
  36         udev-builtin-keyboard.c
  37         udev-builtin-net_id.c
  38         udev-builtin-net_setup_link.c
  39         udev-builtin-path_id.c
  40         udev-builtin-usb_id.c
  41         net/link-config.c
  42         net/link-config.h
  43         net/naming-scheme.c
  44         net/naming-scheme.h
  45 '''.split()
  46
  47 if conf.get('HAVE_KMOD') == 1
  48         libudev_core_sources += ['udev-builtin-kmod.c']
  49 endif
  50
  51 if conf.get('HAVE_BLKID') == 1
  52         libudev_core_sources += ['udev-builtin-blkid.c']
  53 endif
  54
  55 if conf.get('HAVE_ACL') == 1
  56         libudev_core_sources += ['udev-builtin-uaccess.c',
  57                                  logind_acl_c,
  58                                  sd_login_sources]
  59 endif
  60
  61 ############################################################
  62
  63 generate_keyboard_keys_list = find_program('generate-keyboard-keys-list.sh')
  64 keyboard_keys_list_txt = custom_target(
  65         'keyboard-keys-list.txt',
  66         output : 'keyboard-keys-list.txt',
  67         command : [generate_keyboard_keys_list, cpp],
  68         capture : true)
  69
  70 generate_keyboard_keys_gperf = find_program('generate-keyboard-keys-gperf.sh')
  71 fname = 'keyboard-keys-from-name.gperf'
  72 gperf_file = custom_target(
  73         fname,
  74         input : keyboard_keys_list_txt,
  75         output : fname,
  76         command : [generate_keyboard_keys_gperf, '@INPUT@'],
  77         capture : true)
  78
  79 fname = 'keyboard-keys-from-name.h'
  80 keyboard_keys_from_name_h = custom_target(
  81         fname,
  82         input : gperf_file,
  83         output : fname,
  84         command : [gperf,
  85                    '-L', 'ANSI-C', '-t',
  86                    '-N', 'keyboard_lookup_key',
  87                    '-H', 'hash_key_name',
  88                    '-p', '-C',
  89                    '@INPUT@'],
  90         capture : true)
  91
  92 ############################################################
  93
  94 link_config_gperf_c = custom_target(
  95         'link-config-gperf.c',
  96         input : 'net/link-config-gperf.gperf',
  97         output : 'link-config-gperf.c',
  98         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  99
 100 ############################################################
 101
 102 if get_option('link-udev-shared')
 103         udev_link_with = [libshared]
 104         udev_rpath = rootlibexecdir
 105 else
 106         udev_link_with = [libshared_static,
 107                           libsystemd_static]
 108         udev_rpath = ''
 109 endif
 110
 111 libudev_basic = static_library(
 112         'udev-basic',
 113         libudev_sources,
 114         include_directories : includes,
 115         c_args : ['-fvisibility=default'])
 116
 117 libudev_static = static_library(
 118         'udev_static',
 119         include_directories : includes,
 120         link_with : udev_link_with,
 121         link_whole : libudev_basic)
 122
 123 static_libudev = get_option('static-libudev')
 124 static_libudev_pic = static_libudev == 'true' or static_libudev == 'pic'
 125 install_libudev_static = static_library(
 126         'udev',
 127         basic_sources,
 128         shared_sources,
 129         libsystemd_sources,
 130         libudev_sources,
 131         disable_mempool_c,
 132         include_directories : includes,
 133         build_by_default : static_libudev != 'false',
 134         install : static_libudev != 'false',
 135         install_dir : rootlibdir,
 136         link_depends : libudev_sym,
 137         dependencies : libshared_deps + [libmount],
 138         c_args : static_libudev_pic ? [] : ['-fno-PIC'],
 139         pic : static_libudev_pic)
 140
 141 libudev = shared_library(
 142         'udev',
 143         disable_mempool_c,
 144         version : libudev_version,
 145         include_directories : includes,
 146         link_args : ['-shared',
 147                      '-Wl,--version-script=' + libudev_sym_path],
 148         link_with : [libsystemd_static, libshared_static],
 149         link_whole : libudev_basic,
 150         dependencies : [threads],
 151         link_depends : libudev_sym,
 152         install : true,
 153         install_dir : rootlibdir)
 154
 155 libudev_core_includes = [includes, include_directories('net')]
 156 libudev_core = static_library(
 157         'udev-core',
 158         libudev_core_sources,
 159         link_config_gperf_c,
 160         keyboard_keys_from_name_h,
 161         include_directories : libudev_core_includes,
 162         c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 163         link_with : udev_link_with,
 164         dependencies : [libblkid, libkmod])
 165
 166 foreach prog : [['ata_id/ata_id.c'],
 167                 ['cdrom_id/cdrom_id.c'],
 168                 ['fido_id/fido_id.c',
 169                  'fido_id/fido_id_desc.c',
 170                  'fido_id/fido_id_desc.h'],
 171                 ['scsi_id/scsi_id.c',
 172                  'scsi_id/scsi_id.h',
 173                  'scsi_id/scsi_serial.c',
 174                  'scsi_id/scsi.h'],
 175                 ['v4l_id/v4l_id.c'],
 176                 ['mtd_probe/mtd_probe.c',
 177                  'mtd_probe/mtd_probe.h',
 178                  'mtd_probe/probe_smartmedia.c']]
 179
 180         executable(prog[0].split('/')[0],
 181                    prog,
 182                    include_directories : includes,
 183                    c_args : ['-DLOG_REALM=LOG_REALM_UDEV'],
 184                    dependencies : [versiondep],
 185                    link_with : [libudev_static],
 186                    install_rpath : udev_rpath,
 187                    install : true,
 188                    install_dir : udevlibexecdir)
 189 endforeach
 190
 191 install_data('udev.conf',
 192              install_dir : join_paths(sysconfdir, 'udev'))
 193
 194 configure_file(
 195         input : 'udev.pc.in',
 196         output : 'udev.pc',
 197         configuration : substs,
 198         install_dir : pkgconfigdatadir == 'no' ? '' : pkgconfigdatadir)
 199
 200 meson.add_install_script('sh', '-c',
 201                          mkdir_p.format(join_paths(sysconfdir, 'udev/rules.d')))
 202
 203 fuzzers += [
 204         [['src/udev/net/fuzz-link-parser.c',
 205           'src/fuzz/fuzz.h'],
 206          [libudev_core,
 207           libudev_static,
 208           libsystemd_network,
 209           libshared],
 210          [threads,
 211           libacl]]
 212         ]