sysdeps/arm/strlen.S

   1 /* Copyright (C) 1998-2016 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Code contributed by Matthew Wilcox <willy@odie.barnet.ac.uk>
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* Thumb requires excessive IT insns here.  */
  20 #define NO_THUMB
  21 #include <sysdep.h>
  22
  23 /* size_t strlen(const char *S)
  24  * entry: r0 -> string
  25  * exit: r0 = len
  26  */
  27
  28         .syntax unified
  29         .text
  30
  31 ENTRY(strlen)
  32         bic     r1, r0, $3              @ addr of word containing first byte
  33         sfi_breg r1, \
  34         ldr     r2, [\B], $4            @ get the first word
  35         ands    r3, r0, $3              @ how many bytes are duff?
  36         rsb     r0, r3, $0              @ get - that number into counter.
  37         beq     Laligned                @ skip into main check routine if no
  38                                         @ more
  39 #ifdef __ARMEB__
  40         orr     r2, r2, $0xff000000     @ set this byte to non-zero
  41         subs    r3, r3, $1              @ any more to do?
  42         orrgt   r2, r2, $0x00ff0000     @ if so, set this byte
  43         subs    r3, r3, $1              @ more?
  44         orrgt   r2, r2, $0x0000ff00     @ then set.
  45 #else
  46         orr     r2, r2, $0x000000ff     @ set this byte to non-zero
  47         subs    r3, r3, $1              @ any more to do?
  48         orrgt   r2, r2, $0x0000ff00     @ if so, set this byte
  49         subs    r3, r3, $1              @ more?
  50         orrgt   r2, r2, $0x00ff0000     @ then set.
  51 #endif
  52 Laligned:                               @ here, we have a word in r2.  Does it
  53         tst     r2, $0x000000ff         @ contain any zeroes?
  54         tstne   r2, $0x0000ff00         @
  55         tstne   r2, $0x00ff0000         @
  56         tstne   r2, $0xff000000         @
  57         addne   r0, r0, $4              @ if not, the string is 4 bytes longer
  58         sfi_breg r1, \
  59         ldrne   r2, [\B], $4            @ and we continue to the next word
  60         bne     Laligned                @
  61 Llastword:                              @ drop through to here once we find a
  62 #ifdef __ARMEB__
  63         tst     r2, $0xff000000         @ word that has a zero byte in it
  64         addne   r0, r0, $1              @
  65         tstne   r2, $0x00ff0000         @ and add up to 3 bytes on to it
  66         addne   r0, r0, $1              @
  67         tstne   r2, $0x0000ff00         @ (if first three all non-zero, 4th
  68         addne   r0, r0, $1              @  must be zero)
  69 #else
  70         tst     r2, $0x000000ff         @ word that has a zero byte in it
  71         addne   r0, r0, $1              @
  72         tstne   r2, $0x0000ff00         @ and add up to 3 bytes on to it
  73         addne   r0, r0, $1              @
  74         tstne   r2, $0x00ff0000         @ (if first three all non-zero, 4th
  75         addne   r0, r0, $1              @  must be zero)
  76 #endif
  77         DO_RET(lr)
  78 END(strlen)
  79 libc_hidden_builtin_def (strlen)