sysdeps/gnu/errlist.awk

   1 # Copyright (C) 1991-2013 Free Software Foundation, Inc.
   2 # This file is part of the GNU C Library.
   3
   4 # The GNU C Library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2.1 of the License, or (at your option) any later version.
   8
   9 # The GNU C Library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with the GNU C Library; if not, see
  16 # <http://www.gnu.org/licenses/>.
  17
  18 # errno.texi contains lines like:
  19 # @comment errno.h
  20 # @comment POSIX.1: Function not implemented
  21 # @deftypevr Macro int ENOSYS
  22 # @comment errno 78
  23 # Descriptive paragraph...
  24 # @end deftypevr
  25
  26 BEGIN {
  27
  28     # Here we list the E* names that might be duplicate names for the
  29     # same integer value on some systems.  This causes the code below
  30     # to generate ``#if defined (ALIAS) && ALIAS != ORIGINAL'' in the code,
  31     # so the output does not presume that these are in fact aliases.
  32     # We list here all the known potential cases on any system,
  33     # so that the C source we produce will do the right thing based
  34     # on the actual #define'd values it's compiled with.
  35     alias["EWOULDBLOCK"]= "EAGAIN";
  36     alias["EDEADLOCK"]  = "EDEADLK";
  37     alias["ENOTSUP"]    = "EOPNOTSUPP";
  38
  39     print "/* This file is generated from errno.texi by errlist.awk.  */"
  40     print "";
  41     print "#include <errno.h>";
  42     print "#include <libintl.h>";
  43     print "";
  44     print "#ifndef ERR_REMAP";
  45     print "# define ERR_REMAP(n) n";
  46     print "#endif";
  47     print "";
  48
  49     print "#if !defined EMIT_ERR_MAX && !defined ERRLIST_NO_COMPAT";
  50     print "# include <errlist-compat.h>";
  51     print "#endif";
  52     print "#ifdef ERR_MAX";
  53     print "# define ERRLIST_SIZE ERR_MAX + 1";
  54     print "#else"
  55     print "# define ERRLIST_SIZE";
  56     print "#endif";
  57
  58     print "const char *const _sys_errlist_internal[ERRLIST_SIZE] =";
  59     print "  {";
  60     print "    [0] = N_(\"Success\"),"
  61   }
  62
  63 $1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
  64 errnoh == 1 && $1 == "@comment" \
  65   {
  66     ++errnoh;
  67     etext = $3;
  68     for (i = 4; i <= NF; ++i)
  69       etext = etext " " $i;
  70     next;
  71   }
  72 errnoh == 2 && $1 == "@deftypevr" && $2 == "Macro" && $3 == "int" \
  73   {
  74     e = $4; errnoh++; next;
  75   }
  76 errnoh == 3 && $1 == "@comment" && $2 == "errno" \
  77   {
  78     errno = $3 + 0;
  79     if (alias[e])
  80       printf "#if defined (%s) && %s != %s\n", e, e, alias[e];
  81     else
  82       printf "#ifdef %s\n", e;
  83     errnoh = 4;
  84     desc="";
  85     next;
  86   }
  87 errnoh == 4 && $1 == "@end" && $2 == "deftypevr" \
  88   {
  89     printf "/*%s */\n", desc;
  90     printf "    [ERR_REMAP (%s)] = N_(\"%s\"),\n", e, etext;
  91     printf "# if %s > ERR_MAX\n", e;
  92     print  "# undef ERR_MAX";
  93     printf "# define ERR_MAX %s\n", e;
  94     print  "# endif";
  95     print "#endif";
  96     errnoh = 0;
  97     next;
  98   }
  99 errnoh == 4 \
 100   {
 101     # This magic tag in C comments gets them copied into libc.pot.
 102     desc = desc "\nTRANS" ($0 != "" ? " " : "") $0; next
 103   }
 104 { errnoh=0 }
 105 END {
 106   print "  };";
 107   print "";
 108   print "#define NERR \\";
 109   print "  (sizeof _sys_errlist_internal / sizeof _sys_errlist_internal [0])";
 110   print "const int _sys_nerr_internal = NERR;"
 111   print "";
 112   print "#if !defined NOT_IN_libc && !ERRLIST_NO_COMPAT";
 113   print "# include <errlist-compat.c>";
 114   print "#endif";
 115   print "";
 116   print "#ifdef EMIT_ERR_MAX";
 117   print "void dummy (void)"
 118   print "{ asm volatile (\" @@@ %0 @@@ \" : : \"i\" (ERR_REMAP (ERR_MAX))); }"
 119   print "#endif";
 120 }