sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2 Copyright (C) 1995, 1996 Free Software Foundation, Inc.
   3 This file is part of the GNU C Library.
   4
   5 The GNU C Library is free software; you can redistribute it and/or
   6 modify it under the terms of the GNU Library General Public License as
   7 published by the Free Software Foundation; either version 2 of the
   8 License, or (at your option) any later version.
   9
  10 The GNU C Library is distributed in the hope that it will be useful,
  11 but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 Library General Public License for more details.
  14
  15 You should have received a copy of the GNU Library General Public
  16 License along with the GNU C Library; see the file COPYING.LIB.  If
  17 not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  18 Cambridge, MA 02139, USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #include <jmp_buf.h>
  23
  24         /* Binary compatibility entry point.  */
  25 ENTRY (__setjmp)
  26         popl %eax               /* Pop return address.  */
  27         pushl $0                /* Push zero argument.  */
  28         pushl %eax              /* Push back return address.  */
  29
  30 ENTRY (__sigsetjmp)
  31         movl 4(%esp), %eax      /* User's jmp_buf in %eax.  */
  32         /* Save registers.  */
  33         movl %ebx, (JB_BX*4)(%eax)
  34         movl %esi, (JB_SI*4)(%eax)
  35         movl %edi, (JB_DI*4)(%eax)
  36         movl %ebp, (JB_BP*4)(%eax)
  37         leal 4(%esp), %ecx      /* Save SP as it will be after we return.  */
  38         movl %ecx, (JB_SP*4)(%eax)
  39         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  40         movl %ecx, (JB_PC*4)(%eax)
  41
  42         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  43 #ifdef  PIC
  44         /* We cannot use the PLT, because it requires that %ebx be set, but
  45            we can't save and restore our caller's value.  Instead, we do an
  46            indirect jump through the GOT, using for the temporary register
  47            %ecx, which is call-clobbered.  */
  48         call here
  49 here:   popl %ecx
  50         addl $_GLOBAL_OFFSET_TABLE_+[.-here], %ecx
  51         movl C_SYMBOL_NAME(__sigjmp_save@GOT)(%ecx), %ecx
  52         jmp *%ecx
  53 #else
  54         jmp __sigjmp_save
  55 #endif