sysdeps/powerpc/powerpc32/fpu/s_floor.S

   1 /* Floor function.  PowerPC32 version.
   2    Copyright (C) 2004-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align  2
  24 .LC0:   /* 2**52 */
  25         .long 0x59800000
  26
  27         .section        ".text"
  28 ENTRY (__floor)
  29 #ifdef SHARED
  30         mflr    r11
  31         cfi_register(lr,r11)
  32         SETUP_GOT_ACCESS(r9,got_label)
  33         addis   r9,r9,.LC0-got_label@ha
  34         lfs     fp13,.LC0-got_label@l(r9)
  35         mtlr    r11
  36         cfi_same_value (lr)
  37 #else
  38         lis     r9,.LC0@ha
  39         lfs     fp13,.LC0@l(r9)
  40 #endif
  41         fabs    fp0,fp1
  42         fsub    fp12,fp13,fp13  /* generate 0.0  */
  43         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  44         mffs    fp11            /* Save current FPU rounding mode and
  45                                    "inexact" state.  */
  46         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  47         bnl-    cr7,.L10
  48         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  49         ble-    cr6,.L4
  50         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  51         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  52         fabs    fp1,fp1         /* if (x == 0.0)  */
  53                                 /* x = 0.0; */
  54         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  55                                    "inexact" state.  */
  56         blr
  57 .L4:
  58         bge-    cr6,.L9         /* if (x < 0.0)  */
  59         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  60         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  61         fnabs   fp1,fp1         /* if (x == 0.0)  */
  62                                 /* x = -0.0; */
  63 .L9:
  64         mtfsf   0xff,fp11       /* Restore previous rounding mode and
  65                                    "inexact" state.  */
  66         blr
  67 .L10:
  68         /* Ensure sNaN input is converted to qNaN.  */
  69         fcmpu   cr7,fp1,fp1
  70         beqlr   cr7
  71         fadd    fp1,fp1,fp1
  72         blr
  73         END (__floor)
  74
  75 weak_alias (__floor, floor)
  76
  77 #ifdef NO_LONG_DOUBLE
  78 weak_alias (__floor, floorl)
  79 strong_alias (__floor, __floorl)
  80 #endif
  81 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  82 compat_symbol (libm, __floor, floorl, GLIBC_2_0)
  83 #endif