sysdeps/s390/s390-32/start.S

   1 /* Startup code compliant to the ELF s390 ABI.
   2    Copyright (C) 2000-2016 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, see
  35    <http://www.gnu.org/licenses/>.  */
  36
  37 /*
  38    This is the canonical entry point, usually the first thing in the text
  39    segment. Most registers' values are unspecified, except for:
  40
  41    %r14         Contains a function pointer to be registered with `atexit'.
  42                 This is how the dynamic linker arranges to have DT_FINI
  43                 functions called for shared libraries that have been loaded
  44                 before this code runs.
  45
  46    %r15         The stack contains the arguments and environment:
  47                 0(%r15)                 argc
  48                 4(%r15)                 argv[0]
  49                 ...
  50                 (4*argc)(%r15)          NULL
  51                 (4*(argc+1))(%r15)      envp[0]
  52                 ...
  53                                         NULL
  54 */
  55
  56         .text
  57         .globl _start
  58         .type _start,@function
  59 _start:
  60         /* Check if the kernel provides highgprs facility if needed by
  61            the binary.  */
  62
  63         lr      %r6,%r15
  64         la      %r6,4(%r6)     /* Skip the argument counter.  */
  65
  66 .L11:   l       %r5,0(%r6)     /* Skip the argument vector.  */
  67         la      %r6,4(%r6)
  68         ltr     %r5,%r5
  69         jne     .L11
  70
  71 .L12:   l       %r5,0(%r6)     /* Skip the environment vector.  */
  72         la      %r6,4(%r6)
  73         ltr     %r5,%r5
  74         jne     .L12
  75
  76         /* Usually the auxiliary vector can be expected directly after
  77            the environment variables.  But we have to skip extra zeros
  78            because the loader might have removed unsecure variables for
  79            setuid programs.  */
  80
  81 .L26:   l       %r5,0(%r6)
  82         la      %r6,4(%r6)
  83         ltr     %r5,%r5
  84         jz      .L26
  85
  86         ahi     %r6,-4
  87
  88         /* Obtain the needed values from the auxiliary vector.  */
  89
  90         lhi     %r7,16         /* AT_HWCAP */
  91         lhi     %r8,3          /* AT_PHDR */
  92         lhi     %r9,5          /* AT_PHNUM */
  93         lhi     %r2,4          /* AT_PHENT */
  94 .L13:   l       %r5,0(%r6)
  95         clr     %r5,%r7
  96         jne     .L15
  97         l       %r10,4(%r6)    /* r10 = AT_HWCAP value.  */
  98 .L15:   clr     %r5,%r8
  99         jne     .L16
 100         l       %r11,4(%r6)    /* r11 = AT_PHDR value.  */
 101 .L16:   clr     %r5,%r9
 102         jne     .L17
 103         l       %r12,4(%r6)    /* r12 = AT_PHNUM value.  */
 104 .L17:   clr     %r5,%r2
 105         jne     .L18
 106         l       %r0,4(%r6)     /* r0 = AT_PHENT value.  */
 107 .L18:   ltr     %r5,%r5
 108         la      %r6,8(%r6)
 109         jnz     .L13
 110
 111         /* Locate the ELF header by looking for the first PT_LOAD
 112            segment with a p_offset of zero.  */
 113
 114         lr      %r4,%r11       /* Backup AT_PHDR.  */
 115         lhi     %r7,1          /* PT_LOAD id */
 116         lhi     %r8,0
 117 .L19:   cl      %r7,0(%r4)     /* p_type == PT_LOAD? */
 118         jne     .L20
 119         cl      %r8,4(%r4)     /* p_offset == 0? */
 120         jne     .L20
 121         l       %r9,8(%r4)     /* r9 = PT_LOAD.p_vaddr <- ELF header address  */
 122         j       .L24
 123 .L20:   alr     %r4,%r0        /* r4 += AT_PHENT value */
 124         brct    %r12,.L19
 125
 126         j       .+2            /* Trap, there must be such a phdr.  */
 127
 128 .L24:   lr      %r4,%r11       /* Backup AT_PHDR.  */
 129         lhi     %r2,6          /* PT_PHDR id */
 130 .L23:   cl      %r2,0(%r4)
 131         jne     .L22
 132         l       %r3,8(%r4)     /* r3 = PT_PHDR p_vaddr */
 133         j       .L25
 134 .L22:   alr     %r4,%r0        /* r4 += AT_PHENT value */
 135         brct    %r12,.L23
 136
 137         j       .L14           /* No PT_PHDR found - skip checking.  */
 138
 139 .L25:   slr     %r11,%r3       /* AT_PHDR - PT_PHDR.p_vaddr (relocation offset)*/
 140         alr     %r9,%r11       /* PT_LOAD.p_vaddr += relocation offset */
 141
 142         l       %r5,36(%r9)    /* Load the e_flags field.  */
 143         tml     %r5,1
 144         jz      .L14           /* Binary does not require highgprs facility.  */
 145
 146         tml     %r10,512       /* Check the AT_HWCAP value.  */
 147         jz      2              /* Trap if no highgprs facility available.  */
 148 .L14:
 149
 150         /* Setup pointer to literal pool of _start */
 151         basr    %r13,0
 152 .L0:    ahi     %r13,.Llit-.L0
 153
 154         /* load argc and argv from stack */
 155         la      %r4,4(%r15)             # get argv
 156         l       %r3,0(%r15)             # get argc
 157
 158         /* align the stack to a double word boundary */
 159         lhi     %r0,-8
 160         nr      %r15,%r0
 161
 162         /* Setup a stack frame and a parameter area */
 163         ahi     %r15,-104               # make room on stack
 164         xc      0(4,%r15),0(%r15)       # clear back-chain
 165
 166         /* set up arguments for __libc_start_main:
 167            main, argc, argv, envp, _init, _fini, rtld_fini, stack_end
 168            Note that envp will be determined later in __libc_start_main
 169          */
 170         stm     %r14,%r15,96(%r15)      # store rtld_fini/stack_end to parameter area
 171         la      %r7,96(%r15)
 172         l       %r6,.L2-.Llit(%r13)     # load pointer to __libc_csu_fini
 173         l       %r5,.L1-.Llit(%r13)     # load pointer to __libc_csu_init
 174         l       %r2,.L3-.Llit(%r13)     # load pointer to main
 175         l       %r1,.L4-.Llit(%r13)     # load pointer to __libc_start_main
 176 #ifdef PIC
 177         l       %r12,.L5-.Llit(%r13)    # load .got pointer
 178         la      %r6,0(%r13,%r6)
 179         la      %r5,0(%r13,%r5)
 180         la      %r12,0(%r13,%r12)
 181         l       %r2,0(%r12,%r2)
 182         la      %r1,0(%r13,%r1)
 183 #endif
 184
 185         /* ok, now branch to the libc main routine */
 186         basr    %r14,%r1
 187
 188         /* crash if __libc_start_main returns */
 189         .word   0
 190
 191 .Llit:
 192 #ifndef PIC
 193 .L1:    .long  __libc_csu_init
 194 .L2:    .long  __libc_csu_fini
 195 .L3:    .long  main
 196 .L4:    .long  __libc_start_main
 197 #else
 198 .L1:    .long  __libc_csu_init-.Llit
 199 .L2:    .long  __libc_csu_fini-.Llit
 200 .L3:    .long  main@GOT
 201 .L4:    .long  __libc_start_main@plt-.Llit
 202 .L5:    .long  _GLOBAL_OFFSET_TABLE_-.Llit
 203 #endif
 204
 205 /* Define a symbol for the first piece of initialized data.  */
 206         .data
 207         .globl __data_start
 208 __data_start:
 209         .long 0
 210         .weak data_start
 211         data_start = __data_start