sysdeps/s390/s390-64/strncpy.S

   1 /* strncpy - copy at most n characters from a string from source to
   2    destination.  64 bit S/390 version
   3    Copyright (C) 2001-2016 Free Software Foundation, Inc.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <http://www.gnu.org/licenses/>.  */
  20
  21 /* INPUT PARAMETERS
  22      %r2 = address of destination (dst)
  23      %r3 = address of source (src)
  24      %r4 = max of bytes to copy.  */
  25
  26 #include "sysdep.h"
  27 #include "asm-syntax.h"
  28
  29 ENTRY(strncpy)
  30         .text
  31         stg   %r2,48(%r15)          # save dst pointer
  32         slgr  %r2,%r3               # %r3 points to src, %r2+%r3 to dst
  33         lghi  %r1,7
  34         ngr   %r1,%r4               # last 3 bits of # bytes
  35         srlg  %r4,%r4,3
  36         ltgr  %r4,%r4               # less than 8 bytes to copy ?
  37         jz    .L1
  38         bras  %r5,.L0               # enter loop & load address of a 0
  39         .long 0
  40 .L0:    icmh  %r0,8,0(%r3)          # first byte
  41         jz    .L3
  42         icmh  %r0,4,1(%r3)          # second byte
  43         jz    .L4
  44         icmh  %r0,2,2(%r3)          # third byte
  45         jz    .L5
  46         icmh  %r0,1,3(%r3)          # fourth byte
  47         jz    .L6
  48         icm   %r0,8,4(%r3)          # fifth byte
  49         jz    .L7
  50         icm   %r0,4,5(%r3)          # sixth byte
  51         jz    .L8
  52         icm   %r0,2,6(%r3)          # seventh byte
  53         jz    .L9
  54         icm   %r0,1,7(%r3)          # eigth byte
  55         jz    .L10
  56         stg   %r0,0(%r2,%r3)        # store all eight to dest.
  57         la    %r3,8(%r3)
  58         brct  %r4,.L0
  59 .L1:    ltgr  %r1,%r1
  60         jz    .Lexit
  61 .L2:    icm   %r0,1,0(%r3)
  62         stc   %r0,0(%r2,%r3)
  63         la    %r3,1(%r3)
  64         jz    .L11
  65         brct  %r1,.L2
  66         j     .Lexit
  67 .L3:    icmh  %r0,4,0(%r5)
  68 .L4:    icmh  %r0,2,0(%r5)
  69 .L5:    icmh  %r0,1,0(%r5)
  70 .L6:    icm   %r0,8,0(%r5)
  71 .L7:    icm   %r0,4,0(%r5)
  72 .L8:    icm   %r0,2,0(%r5)
  73 .L9:    icm   %r0,1,0(%r5)
  74 .L10:   stg   %r0,0(%r2,%r3)
  75         la    %r3,8(%r3)
  76         aghi  %r4,-1
  77         j     .L12
  78 .L11:   aghi  %r1,-1
  79 .L12:   sllg  %r4,%r4,3
  80         algr  %r4,%r1
  81         algr  %r2,%r3               # start of dst area to be zeroed
  82         lgr   %r3,%r4
  83         slgr  %r4,%r4
  84         slgr  %r5,%r5
  85 .L13:   mvcle %r2,%r4,0             # pad dst with zeroes
  86         jo    .L13
  87 .Lexit: lg    %r2,48(%r15)          # return dst pointer
  88         br    %r14
  89 END(strncpy)
  90 libc_hidden_builtin_def (strncpy)